;;;; Dump the current Lisp image into a core file. Also contains
;;;; various high-level initialization stuff: loading init files and
;;;; parsing environment variables.
;;;;
;;;; (All the real work is done by C.)

;;;; This software is part of the SBCL system. See the README file for
;;;; more information.
;;;;
;;;; This software is derived from the CMU CL system, which was
;;;; written at Carnegie Mellon University and released into the
;;;; public domain. The software is in the public domain and is
;;;; provided with absolutely no warranty. See the COPYING and CREDITS
;;;; files for more information.

(in-package "SB!IMPL")

(defvar *before-save-initializations* nil
  #!+sb-doc
  "This is a list of functions which are called before creating a saved core
  image. These functions are executed in the child process which has no ports,
  so they cannot do anything that tries to talk to the outside world.")

(defvar *after-save-initializations* nil
  #!+sb-doc
  "This is a list of functions which are called when a saved core image starts
  up. The system itself should be initialized at this point, but applications
  might not be.")

;;;; SAVE-LISP-AND-DIE itself

(sb!alien:def-alien-routine "save" (sb!alien:boolean)
  (file sb!c-call:c-string)
  (initial-function (sb!alien:unsigned #.sb!vm:word-bits)))

;;; FIXME: When this is run without the PURIFY option under GENCGC, it
;;; seems to save memory all the way up to the high-water mark, not
;;; just what's currently used; and then after loading the image to
;;; make a running Lisp, the memory never gets reclaimed. (But with
;;; the PURIFY option it seems to work OK.)
(defun save-lisp-and-die (core-file-name &key
					 (toplevel #'toplevel-init)
					 (purify nil)
					 (root-structures ())
					 (environment-name "auxiliary"))
  #!+sb-doc
  "Save a CMU Common Lisp core image in the file of the specified name,
  killing the current Lisp invocation in the process (unless it bails
  out early because of some argument error or something).

  The following &KEY arguments are defined:

  :TOPLEVEL
      The function to run when the created core file is resumed.
  The default function handles command line toplevel option
  processing and runs the top level read-eval-print loop. This
  function should not return.

  :PURIFY
      If true, do a purifying GC which moves all dynamically allocated
  objects into static space so that they stay pure. This takes somewhat
  longer than the normal GC which is otherwise done, but it's only done
  once, and subsequent GC's will be done less often and will take less
  time in the resulting core file. See PURIFY.

  :ROOT-STRUCTURES
      This should be a list of the main entry points in any newly loaded
  systems. This need not be supplied, but locality and/or GC performance
  may be better if they are. Meaningless if :PURIFY is NIL. See PURIFY.

  :ENVIRONMENT-NAME
      This is also passed to PURIFY when :PURIFY is T. (rarely used)"

  #!+mp (sb!mp::shutdown-multi-processing)
  (when (fboundp 'sb!eval:flush-interpreted-function-cache)
    (sb!eval:flush-interpreted-function-cache))
  ;; FIXME: What is this for? Explain.
  (when (fboundp 'cancel-finalization)
    (cancel-finalization sb!sys:*tty*))
  ;; FIXME: Would it be possible to unmix the PURIFY logic from this
  ;; function, and just do a GC :FULL T here? (Then if the user wanted
  ;; a PURIFYed image, he'd just run PURIFY immediately before calling
  ;; SAVE-LISP-AND-DIE.)
  (if purify
      (purify :root-structures root-structures
	      :environment-name environment-name)
      #!-gencgc (gc) #!+gencgc (gc :full t))
  ;; FIXME: Wouldn't it be more correct to go through this list backwards
  ;; instead of forwards?
  (dolist (f *before-save-initializations*)
    (funcall f))
  (flet ((restart-lisp ()
           (handling-end-of-the-world
	     (reinit)
	     (dolist (f *after-save-initializations*)
	       (funcall f))
	     (funcall toplevel))))
    ;; FIXME: Perhaps WITHOUT-GCING should be wrapped around the LET
    ;; as well, to avoid the off chance of an interrupt triggering GC
    ;; and making our saved RESTART-LISP address invalid?
    (without-gcing
      (save (unix-namestring core-file-name nil)
	    (get-lisp-obj-address #'restart-lisp)))))

;;;; functions used by worldload.lisp in CMU CL bootstrapping

;;; If NAME has been byte-compiled, and :RUNTIME is a feature, then
;;; load the byte-compiled version, otherwise just do normal load.
#+nil ; no longer needed in SBCL.. I think.. -- WHN 19990814
(defun maybe-byte-load (name &optional (load-native t))
  (let ((bname (make-pathname
		:defaults name
		:type #.(sb!c:backend-byte-fasl-file-type))))
    (cond ((and (featurep :runtime)
		(probe-file bname))
	   (load bname))
	  (load-native
	   (load name)))))

;;; Replace a cold-loaded native object file with a byte-compiled one,
;;; if it exists.
#+nil ; no longer needed in SBCL.. I think.. -- WHN 19990814
(defun byte-load-over (name)
  (load (make-pathname
	 :defaults name
	 :type #.(sb!c:backend-byte-fasl-file-type))
	:if-does-not-exist nil))