contrib/sb-bsd-sockets/inet.lisp

   1 (in-package :sb-bsd-sockets)
   2
   3 ;;; Our class and constructor
   4
   5 (eval-when (:compile-toplevel :load-toplevel :execute)
   6   (defclass inet-socket (socket)
   7     ((family :initform sockint::AF-INET))
   8     (:documentation "Class representing TCP and UDP sockets.
   9
  10 Examples:
  11
  12  (make-instance 'inet-socket :type :stream :protocol :tcp)
  13
  14  (make-instance 'inet-socket :type :datagram :protocol :udp)
  15 ")))
  16
  17 ;;; XXX should we *...* this?
  18 (defparameter inet-address-any (vector 0 0 0 0))
  19
  20 ;;; binding a socket to an address and port.  Doubt that anyone's
  21 ;;; actually using this much, to be honest.
  22
  23 (defun make-inet-address (dotted-quads)
  24   "Return a vector of octets given a string DOTTED-QUADS in the format
  25 \"127.0.0.1\""
  26   (map 'vector
  27        #'parse-integer
  28        (split dotted-quads nil '(#\.))))
  29
  30 ;;; getprotobyname only works in the internet domain, which is why this
  31 ;;; is here
  32 (defun get-protocol-by-name (name)      ;exported
  33   "Returns the network protocol number associated with the string NAME,
  34 using getprotobyname(2) which typically looks in NIS or /etc/protocols"
  35   ;; for extra brownie points, could return canonical protocol name
  36   ;; and aliases as extra values
  37   (let ((ent (sockint::getprotobyname name)))
  38     (sockint::protoent-proto ent)))
  39
  40 ;;; our protocol provides make-sockaddr-for, size-of-sockaddr,
  41 ;;; bits-of-sockaddr
  42
  43 (defmethod make-sockaddr-for ((socket inet-socket) &optional sockaddr &rest address &aux (host (first address)) (port (second address)))
  44   (let ((sockaddr (or sockaddr (sockint::allocate-sockaddr-in))))
  45     (when (and host port)
  46       (setf host (coerce host '(simple-array (unsigned-byte 8) (4))))
  47       ;; port and host are represented in C as "network-endian" unsigned
  48       ;; integers of various lengths.  This is stupid.  The value of the
  49       ;; integer doesn't matter (and will change depending on your
  50       ;; machine's endianness); what the bind(2) call is interested in
  51       ;; is the pattern of bytes within that integer.
  52
  53       ;; We have no truck with such dreadful type punning.  Octets to
  54       ;; octets, dust to dust.
  55
  56       (setf (sockint::sockaddr-in-family sockaddr) sockint::af-inet)
  57       (setf (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 0) (ldb (byte 8 8) port))
  58       (setf (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 1) (ldb (byte 8 0) port))
  59
  60       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 0) (elt host 0))
  61       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 1) (elt host 1))
  62       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 2) (elt host 2))
  63       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 3) (elt host 3)))
  64     sockaddr))
  65
  66 (defmethod free-sockaddr-for ((socket inet-socket) sockaddr)
  67   (sockint::free-sockaddr-in sockaddr))
  68
  69 (defmethod size-of-sockaddr ((socket inet-socket))
  70   sockint::size-of-sockaddr-in)
  71
  72 (defmethod bits-of-sockaddr ((socket inet-socket) sockaddr)
  73   "Returns address and port of SOCKADDR as multiple values"
  74   (values
  75    (coerce (loop for i from 0 below 4
  76                  collect (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) i))
  77            '(vector (unsigned-byte 8) 4))
  78    (+ (* 256 (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 0))
  79       (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 1))))
  80
  81 (defun make-inet-socket (type protocol)
  82   "Make an INET socket.  Deprecated in favour of make-instance"
  83   (make-instance 'inet-socket :type type :protocol protocol))