contrib/sb-bsd-sockets/inet.lisp

   1 (in-package :sb-bsd-sockets)
   2
   3 #|| <h2>INET-domain sockets</h2>
   4
   5 <p>The TCP and UDP sockets that you know and love.  Some representation issues:
   6 <ul>
   7 <li>These functions do not accept hostnames directly: see <a href="#name-service">name resolution</a>
   8 <li>Internet <b>addresses</b> are represented by vectors of <tt>(unsigned-byte 8)</tt> - viz. <tt>#(127 0 0 1)</tt>.  <b>Ports</b> are just integers: <tt>6010</tt>.  No conversion between network- and host-order data is needed from the user of this package.
   9 <li><b><i>socket addresses</i></b> are represented by the two values for <b>address</b> and <b>port</b>, so for example, <tt>(<a href="#SOCKET-CONNECT">socket-connect</a> s #(192 168 1 1) 80)</tt>
  10 </ul>
  11
  12 |#
  13
  14 ;;; Our class and constructor
  15
  16 (eval-when (:compile-toplevel :load-toplevel :execute)
  17   (defclass inet-socket (socket)
  18     ((family :initform sockint::AF-INET))))
  19
  20 ;;; XXX should we *...* this?
  21 (defparameter inet-address-any (vector 0 0 0 0))
  22
  23 ;;; binding a socket to an address and port.  Doubt that anyone's
  24 ;;; actually using this much, to be honest.
  25
  26 (defun make-inet-address (dotted-quads)
  27   "Return a vector of octets given a string DOTTED-QUADS in the format
  28 \"127.0.0.1\""
  29   (map 'vector
  30        #'parse-integer
  31        (split dotted-quads nil '(#\.))))
  32
  33 ;;; getprotobyname only works in the internet domain, which is why this
  34 ;;; is here
  35 (defun get-protocol-by-name (name)      ;exported
  36   "Returns the network protocol number associated with the string NAME,
  37 using getprotobyname(2) which typically looks in NIS or /etc/protocols"
  38   ;; for extra brownie points, could return canonical protocol name
  39   ;; and aliases as extra values
  40   (let ((ent (sockint::getprotobyname name)))
  41     (sockint::protoent-proto ent)))
  42
  43 ;;; our protocol provides make-sockaddr-for, size-of-sockaddr,
  44 ;;; bits-of-sockaddr
  45
  46 (defmethod make-sockaddr-for ((socket inet-socket) &optional sockaddr &rest address &aux (host (first address)) (port (second address)))
  47   (let ((sockaddr (or sockaddr (sockint::allocate-sockaddr-in))))
  48     (when (and host port)
  49       (setf host (coerce host '(simple-array (unsigned-byte 8) (4))))
  50       ;; port and host are represented in C as "network-endian" unsigned
  51       ;; integers of various lengths.  This is stupid.  The value of the
  52       ;; integer doesn't matter (and will change depending on your
  53       ;; machine's endianness); what the bind(2) call is interested in
  54       ;; is the pattern of bytes within that integer.
  55
  56       ;; We have no truck with such dreadful type punning.  Octets to
  57       ;; octets, dust to dust.
  58
  59       (setf (sockint::sockaddr-in-family sockaddr) sockint::af-inet)
  60       (setf (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 0) (ldb (byte 8 8) port))
  61       (setf (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 1) (ldb (byte 8 0) port))
  62
  63       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 0) (elt host 0))
  64       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 1) (elt host 1))
  65       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 2) (elt host 2))
  66       (setf (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) 3) (elt host 3)))
  67     sockaddr))
  68
  69 (defmethod free-sockaddr-for ((socket inet-socket) sockaddr)
  70   (sockint::free-sockaddr-in sockaddr))
  71
  72 (defmethod size-of-sockaddr ((socket inet-socket))
  73   sockint::size-of-sockaddr-in)
  74
  75 (defmethod bits-of-sockaddr ((socket inet-socket) sockaddr)
  76   "Returns address and port of SOCKADDR as multiple values"
  77   (values
  78    (coerce (loop for i from 0 below 4
  79                  collect (sb-alien:deref (sockint::sockaddr-in-addr sockaddr) i))
  80            '(vector (unsigned-byte 8) 4))
  81    (+ (* 256 (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 0))
  82       (sb-alien:deref (sockint::sockaddr-in-port sockaddr) 1))))
  83
  84 (defun make-inet-socket (type protocol)
  85   "Make an INET socket.  Deprecated in favour of make-instance"
  86   (make-instance 'inet-socket :type type :protocol protocol))