contrib/sb-bsd-sockets/name-service.lisp

   1 (in-package :sb-bsd-sockets)
   2
   3 (defclass host-ent ()
   4   ((name :initarg :name :accessor host-ent-name)
   5    (aliases :initarg :aliases :accessor host-ent-aliases)
   6    (address-type :initarg :type :accessor host-ent-address-type)
   7                                         ; presently always AF_INET
   8    (addresses :initarg :addresses :accessor host-ent-addresses))
   9   ;; FIXME: Our Texinfo documentation extracter need at least his to spit
  10   ;; out the signature. Real documentation would be better...
  11   (:documentation ""))
  12
  13 (defgeneric host-ent-address (host-ent)
  14   ;; FIXME: Our Texinfo documentation extracter need at least his to spit
  15   ;; out the signature. Real documentation would be better...
  16   (:documentation ""))
  17
  18 (defmethod host-ent-address ((host-ent host-ent))
  19   (car (host-ent-addresses host-ent)))
  20
  21 ;(define-condition host-not-found-error (socket-error)) ; host unknown
  22 ;(define-condition no-address-error (socket-error)) ; valid name but no IP address
  23 ;(define-condition no-recovery-error (socket-error)) ; name server error
  24 ;(define-condition try-again-error (socket-error)) ; temporary
  25
  26 (defun make-host-ent (h)
  27   (if (sb-grovel::foreign-nullp h) (name-service-error "gethostbyname"))
  28   (let* ((length (sockint::hostent-length h))
  29          (aliases (loop for i = 0 then (1+ i)
  30                         for al = (sb-alien:deref (sockint::hostent-aliases h) i)
  31                         while al
  32                         collect al))
  33          (addresses
  34           (loop for i = 0 then (1+ i)
  35                 for ad = (sb-alien:deref (sockint::hostent-addresses h) i)
  36                 until (sb-alien:null-alien ad)
  37                 collect (ecase (sockint::hostent-type h)
  38                           (#.sockint::af-inet
  39                              (assert (= length 4))
  40                              (let ((addr (make-array 4 :element-type '(unsigned-byte 8))))
  41                                (loop for i from 0 below length
  42                                      do (setf (elt addr i) (sb-alien:deref ad i)))
  43                                addr))
  44                           (#.sockint::af-local
  45                            (sb-alien:cast ad sb-alien:c-string))))))
  46     (make-instance 'host-ent
  47                    :name (sockint::hostent-name h)
  48                    :type (sockint::hostent-type h)
  49                    :aliases aliases
  50                    :addresses addresses)))
  51
  52 (defun get-host-by-name (host-name)
  53   "Returns a HOST-ENT instance for HOST-NAME or throws some kind of condition.
  54 HOST-NAME may also be an IP address in dotted quad notation or some other
  55 weird stuff - see gethostbyname(3) for grisly details."
  56   (make-host-ent (sockint::gethostbyname host-name)))
  57
  58 (defun get-host-by-address (address)
  59   "Returns a HOST-ENT instance for ADDRESS, which should be a vector of
  60  (integer 0 255), or throws some kind of error.  See gethostbyaddr(3) for
  61 grisly details."
  62   (sockint::with-in-addr packed-addr ()
  63     (let ((addr-vector (coerce address 'vector)))
  64       (loop for i from 0 below (length addr-vector)
  65             do (setf (sb-alien:deref (sockint::in-addr-addr packed-addr) i)
  66                      (elt addr-vector i)))
  67       (make-host-ent (sockint::gethostbyaddr packed-addr
  68                                              4
  69                                              sockint::af-inet)))))
  70
  71 ;;; The remainder is my fault - gw
  72
  73 (defvar *name-service-errno* 0
  74   "The value of h_errno, after it's been fetched from Unix-land by calling
  75 GET-NAME-SERVICE-ERRNO")
  76
  77 (defun name-service-error (where)
  78   ;; FIXME: Our Texinfo documentation extracter need at least his to spit
  79   ;; out the signature. Real documentation would be better...
  80   ""
  81   (get-name-service-errno)
  82   ;; Comment next to NETDB_INTERNAL in netdb.h says "See errno.".
  83   ;; This special case treatment hasn't actually been tested yet.
  84   (if (= *name-service-errno* sockint::NETDB-INTERNAL)
  85       (socket-error where)
  86     (let ((condition
  87            (condition-for-name-service-errno *name-service-errno*)))
  88       (error condition :errno *name-service-errno* :syscall where))))
  89
  90 (define-condition name-service-error (condition)
  91   ((errno :initform nil
  92           :initarg :errno
  93           :reader name-service-error-errno)
  94    (symbol :initform nil :initarg :symbol :reader name-service-error-symbol)
  95    (syscall :initform "an unknown location" :initarg :syscall :reader name-service-error-syscall))
  96   (:report (lambda (c s)
  97              (let ((num (name-service-error-errno c)))
  98                (format s "Name service error in \"~A\": ~A (~A)"
  99                        (name-service-error-syscall c)
 100                        (or (name-service-error-symbol c)
 101                            (name-service-error-errno c))
 102                        (get-name-service-error-message num))))))
 103
 104 (defmacro define-name-service-condition (symbol name)
 105   `(progn
 106      (define-condition ,name (name-service-error)
 107        ((symbol :reader name-service-error-symbol :initform (quote ,symbol))))
 108      (push (cons ,symbol (quote ,name)) *conditions-for-name-service-errno*)))
 109
 110 (defparameter *conditions-for-name-service-errno* nil)
 111
 112 (define-name-service-condition sockint::NETDB-INTERNAL netdb-internal-error)
 113 (define-name-service-condition sockint::NETDB-SUCCESS netdb-success-error)
 114 (define-name-service-condition sockint::HOST-NOT-FOUND host-not-found-error)
 115 (define-name-service-condition sockint::TRY-AGAIN try-again-error)
 116 (define-name-service-condition sockint::NO-RECOVERY no-recovery-error)
 117 ;; this is the same as the next one
 118 ;;(define-name-service-condition sockint::NO-DATA no-data-error)
 119 (define-name-service-condition sockint::NO-ADDRESS no-address-error)
 120
 121 (defun condition-for-name-service-errno (err)
 122   (or (cdr (assoc err *conditions-for-name-service-errno* :test #'eql))
 123       'name-service))
 124
 125
 126
 127 (defun get-name-service-errno ()
 128   (setf *name-service-errno*
 129         (sb-alien:alien-funcall
 130          (sb-alien:extern-alien "get_h_errno" (function integer)))))
 131
 132 #-(and cmu solaris)
 133 (progn
 134   #+sbcl
 135   (sb-alien:define-alien-routine "hstrerror"
 136       sb-c-call:c-string
 137     (errno integer))
 138   #+cmu
 139   (alien:def-alien-routine "hstrerror"
 140       sb-c-call:c-string
 141     (errno integer))
 142   (defun get-name-service-error-message (num)
 143   (hstrerror num))
 144 )