contrib/sb-bsd-sockets/name-service.lisp

   1 (in-package :sb-bsd-sockets)
   2 #|| <a name="name-service"><h2>Name Service</h2></a>
   3
   4 <p>Presently name service is implemented by calling whatever
   5 gethostbyname(2) uses.  This may be any or all of /etc/hosts, NIS, DNS,
   6 or something completely different.  Typically it's controlled by
   7 /etc/nsswitch.conf
   8
   9 <p> Direct links to the asynchronous resolver(3) routines would be nice to have
  10 eventually, so that we can do DNS lookups in parallel with other things
  11 |#
  12
  13 (defclass host-ent ()
  14   ((name :initarg :name :accessor host-ent-name)
  15    (aliases :initarg :aliases :accessor host-ent-aliases)
  16    (address-type :initarg :type :accessor host-ent-address-type)
  17                                         ; presently always AF_INET
  18    (addresses :initarg :addresses :accessor host-ent-addresses)))
  19
  20 (defgeneric host-ent-address (host-ent))
  21
  22 (defmethod host-ent-address ((host-ent host-ent))
  23   (car (host-ent-addresses host-ent)))
  24
  25 ;(define-condition host-not-found-error (socket-error)) ; host unknown
  26 ;(define-condition no-address-error (socket-error)) ; valid name but no IP address
  27 ;(define-condition no-recovery-error (socket-error)) ; name server error
  28 ;(define-condition try-again-error (socket-error)) ; temporary
  29
  30 (defun make-host-ent (h)
  31   (if (sb-grovel::foreign-nullp h) (name-service-error "gethostbyname"))
  32   (let* ((length (sockint::hostent-length h))
  33          (aliases (loop for i = 0 then (1+ i)
  34                         for al = (sb-alien:deref (sockint::hostent-aliases h) i)
  35                         while al
  36                         collect al))
  37          (addresses
  38           (loop for i = 0 then (1+ i)
  39                 for ad = (sb-alien:deref (sockint::hostent-addresses h) i)
  40                 until (sb-alien:null-alien ad)
  41                 collect (ecase (sockint::hostent-type h)
  42                           (#.sockint::af-inet
  43                              (assert (= length 4))
  44                              (let ((addr (make-array 4 :element-type '(unsigned-byte 8))))
  45                                (loop for i from 0 below length
  46                                      do (setf (elt addr i) (sb-alien:deref ad i)))
  47                                addr))
  48                           (#.sockint::af-local
  49                            (sb-alien:cast ad sb-alien:c-string))))))
  50     (make-instance 'host-ent
  51                    :name (sockint::hostent-name h)
  52                    :type (sockint::hostent-type h)
  53                    :aliases aliases
  54                    :addresses addresses)))
  55
  56 (defun get-host-by-name (host-name)
  57   "Returns a HOST-ENT instance for HOST-NAME or throws some kind of condition.
  58 HOST-NAME may also be an IP address in dotted quad notation or some other
  59 weird stuff - see gethostbyname(3) for grisly details."
  60   (make-host-ent (sockint::gethostbyname host-name)))
  61
  62 (defun get-host-by-address (address)
  63   "Returns a HOST-ENT instance for ADDRESS, which should be a vector of
  64  (integer 0 255), or throws some kind of error.  See gethostbyaddr(3) for
  65 grisly details."
  66   (sockint::with-in-addr packed-addr ()
  67     (let ((addr-vector (coerce address 'vector)))
  68       (loop for i from 0 below (length addr-vector)
  69             do (setf (sb-alien:deref (sockint::in-addr-addr packed-addr) i)
  70                      (elt addr-vector i)))
  71       (make-host-ent (sockint::gethostbyaddr packed-addr
  72                                              4
  73                                              sockint::af-inet)))))
  74
  75 ;;; The remainder is my fault - gw
  76
  77 (defvar *name-service-errno* 0
  78   "The value of h_errno, after it's been fetched from Unix-land by calling
  79 GET-NAME-SERVICE-ERRNO")
  80
  81 (defun name-service-error (where)
  82   (get-name-service-errno)
  83   ;; Comment next to NETDB_INTERNAL in netdb.h says "See errno.".
  84   ;; This special case treatment hasn't actually been tested yet.
  85   (if (= *name-service-errno* sockint::NETDB-INTERNAL)
  86       (socket-error where)
  87     (let ((condition
  88            (condition-for-name-service-errno *name-service-errno*)))
  89       (error condition :errno *name-service-errno* :syscall where))))
  90
  91 (define-condition name-service-error (condition)
  92   ((errno :initform nil
  93           :initarg :errno
  94           :reader name-service-error-errno)
  95    (symbol :initform nil :initarg :symbol :reader name-service-error-symbol)
  96    (syscall :initform "an unknown location" :initarg :syscall :reader name-service-error-syscall))
  97   (:report (lambda (c s)
  98              (let ((num (name-service-error-errno c)))
  99                (format s "Name service error in \"~A\": ~A (~A)"
 100                        (name-service-error-syscall c)
 101                        (or (name-service-error-symbol c)
 102                            (name-service-error-errno c))
 103                        (get-name-service-error-message num))))))
 104
 105 (defmacro define-name-service-condition (symbol name)
 106   `(progn
 107      (define-condition ,name (name-service-error)
 108        ((symbol :reader name-service-error-symbol :initform (quote ,symbol))))
 109      (push (cons ,symbol (quote ,name)) *conditions-for-name-service-errno*)))
 110
 111 (defparameter *conditions-for-name-service-errno* nil)
 112
 113 (define-name-service-condition sockint::NETDB-INTERNAL netdb-internal-error)
 114 (define-name-service-condition sockint::NETDB-SUCCESS netdb-success-error)
 115 (define-name-service-condition sockint::HOST-NOT-FOUND host-not-found-error)
 116 (define-name-service-condition sockint::TRY-AGAIN try-again-error)
 117 (define-name-service-condition sockint::NO-RECOVERY no-recovery-error)
 118 ;; this is the same as the next one
 119 ;;(define-name-service-condition sockint::NO-DATA no-data-error)
 120 (define-name-service-condition sockint::NO-ADDRESS no-address-error)
 121
 122 (defun condition-for-name-service-errno (err)
 123   (or (cdr (assoc err *conditions-for-name-service-errno* :test #'eql))
 124       'name-service))
 125
 126
 127
 128 (defun get-name-service-errno ()
 129   (setf *name-service-errno*
 130         (sb-alien:alien-funcall
 131          (sb-alien:extern-alien "get_h_errno" (function integer)))))
 132
 133 #-(and cmu solaris)
 134 (progn
 135   #+sbcl
 136   (sb-alien:define-alien-routine "hstrerror"
 137       sb-c-call:c-string
 138     (errno integer))
 139   #+cmu
 140   (alien:def-alien-routine "hstrerror"
 141       sb-c-call:c-string
 142     (errno integer))
 143   (defun get-name-service-error-message (num)
 144   (hstrerror num))
 145 )