contrib/sb-bsd-sockets/name-service.lisp

   1 (in-package :sb-bsd-sockets)
   2 #|| <a name="name-service"><h2>Name Service</h2></a>
   3
   4 <p>Presently name service is implemented by calling whatever
   5 gethostbyname(2) uses.  This may be any or all of /etc/hosts, NIS, DNS,
   6 or something completely different.  Typically it's controlled by
   7 /etc/nsswitch.conf
   8
   9 <p> Direct links to the asynchronous resolver(3) routines would be nice to have
  10 eventually, so that we can do DNS lookups in parallel with other things
  11 |#
  12
  13 (defclass host-ent ()
  14   ((name :initarg :name :accessor host-ent-name)
  15    (aliases :initarg :aliases :accessor host-ent-aliases)
  16    (address-type :initarg :type :accessor host-ent-address-type)
  17                                         ; presently always AF_INET
  18    (addresses :initarg :addresses :accessor host-ent-addresses)))
  19
  20 (defgeneric host-ent-address (host-ent))
  21
  22 (defmethod host-ent-address ((host-ent host-ent))
  23   (car (host-ent-addresses host-ent)))
  24
  25 ;(define-condition host-not-found-error (socket-error)) ; host unknown
  26 ;(define-condition no-address-error (socket-error)) ; valid name but no IP address
  27 ;(define-condition no-recovery-error (socket-error)) ; name server error
  28 ;(define-condition try-again-error (socket-error)) ; temporary
  29
  30 (defun get-host-by-name (host-name)
  31   "Returns a HOST-ENT instance for HOST-NAME or throws some kind of condition.
  32 HOST-NAME may also be an IP address in dotted quad notation or some other
  33 weird stuff - see gethostbyname(3) for grisly details."
  34   (make-host-ent (sockint::gethostbyname host-name)))
  35
  36 (defun get-host-by-address (address)
  37   "Returns a HOST-ENT instance for ADDRESS, which should be a vector of
  38  (integer 0 255), or throws some kind of error.  See gethostbyaddr(3) for
  39 grisly details."
  40   (sockint::with-in-addr packed-addr ()
  41     (let ((addr-vector (coerce address 'vector)))
  42       (loop for i from 0 below (length addr-vector)
  43             do (setf (sb-alien:deref (sockint::in-addr-addr packed-addr) i)
  44                      (elt addr-vector i)))
  45       (make-host-ent (sockint::gethostbyaddr packed-addr
  46                                              4
  47                                              sockint::af-inet)))))
  48
  49 (defun make-host-ent (h)
  50   (if (sb-grovel::foreign-nullp h) (name-service-error "gethostbyname"))
  51   (let* ((length (sockint::hostent-length h))
  52          (aliases (loop for i = 0 then (1+ i)
  53                         for al = (sb-alien:deref (sockint::hostent-aliases h) i)
  54                         while al
  55                         collect al))
  56          (address0 (sockint::hostent-addresses h))
  57          (addresses
  58           (loop for i = 0 then (1+ i)
  59                 for ad = (sb-alien:deref address0 i)
  60                 until (sb-alien:null-alien ad)
  61                 collect (ecase (sockint::hostent-type h)
  62                           (#.sockint::af-inet
  63                            (loop for i from 0 below length
  64                                  collect (sb-alien:deref ad i)))
  65                           (#.sockint::af-local
  66                            (sb-alien:cast ad sb-alien:c-string))))))
  67     (make-instance 'host-ent
  68                    :name (sockint::hostent-name h)
  69                    :type (sockint::hostent-type h)
  70                    :aliases aliases
  71                    :addresses addresses)))
  72
  73 ;;; The remainder is my fault - gw
  74
  75 (defvar *name-service-errno* 0
  76   "The value of h_errno, after it's been fetched from Unix-land by calling
  77 GET-NAME-SERVICE-ERRNO")
  78
  79 (defun name-service-error (where)
  80   (get-name-service-errno)
  81   ;; Comment next to NETDB_INTERNAL in netdb.h says "See errno.".
  82   ;; This special case treatment hasn't actually been tested yet.
  83   (if (= *name-service-errno* sockint::NETDB-INTERNAL)
  84       (socket-error where)
  85     (let ((condition
  86            (condition-for-name-service-errno *name-service-errno*)))
  87       (error condition :errno *name-service-errno* :syscall where))))
  88
  89 (define-condition name-service-error (condition)
  90   ((errno :initform nil
  91           :initarg :errno
  92           :reader name-service-error-errno)
  93    (symbol :initform nil :initarg :symbol :reader name-service-error-symbol)
  94    (syscall :initform "an unknown location" :initarg :syscall :reader name-service-error-syscall))
  95   (:report (lambda (c s)
  96              (let ((num (name-service-error-errno c)))
  97                (format s "Name service error in \"~A\": ~A (~A)"
  98                        (name-service-error-syscall c)
  99                        (or (name-service-error-symbol c)
 100                            (name-service-error-errno c))
 101                        (get-name-service-error-message num))))))
 102
 103 (defmacro define-name-service-condition (symbol name)
 104   `(progn
 105      (define-condition ,name (name-service-error)
 106        ((symbol :reader name-service-error-symbol :initform (quote ,symbol))))
 107      (push (cons ,symbol (quote ,name)) *conditions-for-name-service-errno*)))
 108
 109 (defparameter *conditions-for-name-service-errno* nil)
 110
 111 (define-name-service-condition sockint::NETDB-INTERNAL netdb-internal-error)
 112 (define-name-service-condition sockint::NETDB-SUCCESS netdb-success-error)
 113 (define-name-service-condition sockint::HOST-NOT-FOUND host-not-found-error)
 114 (define-name-service-condition sockint::TRY-AGAIN try-again-error)
 115 (define-name-service-condition sockint::NO-RECOVERY no-recovery-error)
 116 ;; this is the same as the next one
 117 ;;(define-name-service-condition sockint::NO-DATA no-data-error)
 118 (define-name-service-condition sockint::NO-ADDRESS no-address-error)
 119
 120 (defun condition-for-name-service-errno (err)
 121   (or (cdr (assoc err *conditions-for-name-service-errno* :test #'eql))
 122       'name-service))
 123
 124
 125
 126 (defun get-name-service-errno ()
 127   (setf *name-service-errno*
 128         (sb-alien:alien-funcall
 129          (sb-alien:extern-alien "get_h_errno" (function integer)))))
 130
 131 #-(and cmu solaris)
 132 (progn
 133   #+sbcl
 134   (sb-alien:define-alien-routine "hstrerror"
 135       sb-c-call:c-string
 136     (errno integer))
 137   #+cmu
 138   (alien:def-alien-routine "hstrerror"
 139       sb-c-call:c-string
 140     (errno integer))
 141   (defun get-name-service-error-message (num)
 142   (hstrerror num))
 143 )