contrib/sb-bsd-sockets/tests.lisp

   1 (defpackage "SB-BSD-SOCKETS-TEST"
   2   (:use "CL" "SB-BSD-SOCKETS" "SB-RT"))
   3
   4 (in-package :sb-bsd-sockets-test)
   5
   6 ;;; a real address
   7 (deftest make-inet-address
   8   (equalp (make-inet-address "127.0.0.1")  #(127 0 0 1))
   9   t)
  10 ;;; and an address with bit 8 set on some octets
  11 (deftest make-inet-address2
  12   (equalp (make-inet-address "242.1.211.3")  #(242 1 211 3))
  13   t)
  14
  15 (deftest get-protocol-by-name/tcp
  16     (integerp (get-protocol-by-name "tcp"))
  17   t)
  18
  19 (deftest get-protocol-by-name/udp
  20   (integerp (get-protocol-by-name "udp"))
  21   t)
  22
  23 (deftest get-protocol-by-name/error
  24   (handler-case (get-protocol-by-name "nonexistent-protocol")
  25     (unknown-protocol ()
  26       t)
  27     (:no-error ()
  28       nil))
  29   t)
  30
  31 (deftest make-inet-socket
  32   ;; make a socket
  33   (let ((s (make-instance 'inet-socket :type :stream :protocol (get-protocol-by-name "tcp"))))
  34     (and (> (socket-file-descriptor s) 1) t))
  35   t)
  36
  37 (deftest make-inet-socket-keyword
  38     ;; make a socket
  39     (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
  40       (and (> (socket-file-descriptor s) 1) t))
  41   t)
  42
  43 (deftest make-inet-socket-wrong
  44     ;; fail to make a socket: check correct error return.  There's no nice
  45     ;; way to check the condition stuff on its own, which is a shame
  46     (handler-case
  47         (make-instance 'inet-socket :type :stream :protocol (get-protocol-by-name "udp"))
  48       ((or socket-type-not-supported-error protocol-not-supported-error) (c)
  49         (declare (ignorable c)) t)
  50       (:no-error nil))
  51   t)
  52
  53 (deftest make-inet-socket-keyword-wrong
  54     ;; same again with keywords
  55     (handler-case
  56         (make-instance 'inet-socket :type :stream :protocol :udp)
  57       ((or protocol-not-supported-error socket-type-not-supported-error) (c)
  58         (declare (ignorable c)) t)
  59       (:no-error nil))
  60   t)
  61
  62
  63 (deftest non-block-socket
  64   (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
  65     (setf (non-blocking-mode s) t)
  66     (non-blocking-mode s))
  67   t)
  68
  69 (defun do-gc-portably ()
  70   ;; cmucl on linux has generational gc with a keyword argument,
  71   ;; sbcl GC function takes same arguments no matter what collector is in
  72   ;; use
  73   #+(or sbcl gencgc) (SB-EXT:gc :full t)
  74   ;; other platforms have full gc or nothing
  75   #-(or sbcl gencgc) (sb-ext:gc))
  76
  77 (deftest inet-socket-bind
  78   (let ((s (make-instance 'inet-socket :type :stream :protocol (get-protocol-by-name "tcp"))))
  79     ;; Given the functions we've got so far, if you can think of a
  80     ;; better way to make sure the bind succeeded than trying it
  81     ;; twice, let me know
  82     ;; 1974 has no special significance, unless you're the same age as me
  83     (do-gc-portably) ;gc should clear out any old sockets bound to this port
  84     (socket-bind s (make-inet-address "127.0.0.1") 1974)
  85     (handler-case
  86         (let ((s2 (make-instance 'inet-socket :type :stream :protocol (get-protocol-by-name "tcp"))))
  87           (socket-bind s2 (make-inet-address "127.0.0.1") 1974)
  88           nil)
  89       (address-in-use-error () t)))
  90   t)
  91
  92 (deftest simple-sockopt-test
  93   ;; test we can set SO_REUSEADDR on a socket and retrieve it, and in
  94   ;; the process that all the weird macros in sockopt happened right.
  95   (let ((s (make-instance 'inet-socket :type :stream :protocol (get-protocol-by-name "tcp"))))
  96     (setf (sockopt-reuse-address s) t)
  97     (sockopt-reuse-address s))
  98   t)
  99
 100 (defun read-buf-nonblock (buffer stream)
 101   "Like READ-SEQUENCE, but returns early if the full quantity of data isn't there to be read.  Blocks if no input at all"
 102   (let ((eof (gensym)))
 103     (do ((i 0 (1+ i))
 104          (c (read-char stream nil eof)
 105             (read-char-no-hang stream nil eof)))
 106         ((or (>= i (length buffer)) (not c) (eq c eof)) i)
 107       (setf (elt buffer i) c))))
 108
 109 #+internet-available
 110 (deftest name-service-return-type
 111   (vectorp (host-ent-address (get-host-by-address #(127 0 0 1))))
 112   t)
 113
 114 ;;; these require that the echo services are turned on in inetd
 115 #+internet-available
 116 (deftest simple-tcp-client
 117     (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp))
 118           (data (make-string 200)))
 119       (socket-connect s #(127 0 0 1) 7)
 120       (let ((stream (socket-make-stream s :input t :output t :buffering :none)))
 121         (format stream "here is some text")
 122         (let ((data (subseq data 0 (read-buf-nonblock data stream))))
 123           (format t "~&Got ~S back from TCP echo server~%" data)
 124           (> (length data) 0))))
 125   t)
 126
 127 #+internet-available
 128 (deftest sockaddr-return-type
 129   (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
 130     (unwind-protect
 131          (progn
 132            (socket-connect s #(127 0 0 1) 7)
 133            (multiple-value-bind (host port) (socket-peername s)
 134              (and (vectorp host)
 135                   (numberp port))))
 136       (socket-close s)))
 137   t)
 138
 139 #+internet-available
 140 (deftest simple-udp-client
 141   (let ((s (make-instance 'inet-socket :type :datagram :protocol (get-protocol-by-name "udp")))
 142         (data (make-string 200)))
 143     (format t "Socket type is ~A~%" (sockopt-type s))
 144     (socket-connect s #(127 0 0 1) 7)
 145     (let ((stream (socket-make-stream s :input t :output t :buffering :none)))
 146       (format stream "here is some text")
 147       (let ((data (subseq data 0 (read-buf-nonblock data stream))))
 148         (format t "~&Got ~S back from UDP echo server~%" data)
 149         (> (length data) 0))))
 150   t)
 151
 152 ;;; A fairly rudimentary test that connects to the syslog socket and
 153 ;;; sends a message.  Priority 7 is kern.debug; you'll probably want
 154 ;;; to look at /etc/syslog.conf or local equivalent to find out where
 155 ;;; the message ended up
 156
 157 (deftest simple-local-client
 158     #-win32
 159     (progn
 160       ;; SunOS (Solaris) and Darwin systems don't have a socket at
 161       ;; /dev/log.  We might also be building in a chroot or
 162       ;; something, so don't fail this test just because the file is
 163       ;; unavailable, or if it's a symlink to some weird character
 164       ;; device.
 165       (when (and (probe-file "/dev/log")
 166                  (sb-posix:s-issock
 167                   (sb-posix::stat-mode (sb-posix:stat "/dev/log"))))
 168         (let ((s (make-instance 'local-socket :type :datagram)))
 169           (format t "Connecting ~A... " s)
 170           (finish-output)
 171           (handler-case
 172               (socket-connect s "/dev/log")
 173             (sb-bsd-sockets::socket-error ()
 174               (setq s (make-instance 'local-socket :type :stream))
 175               (format t "failed~%Retrying with ~A... " s)
 176               (finish-output)
 177               (socket-connect s "/dev/log")))
 178           (format t "ok.~%")
 179           (let ((stream (socket-make-stream s :input t :output t :buffering :none)))
 180             (format stream
 181                     "<7>bsd-sockets: Don't panic.  We're testing local-domain client code; this message can safely be ignored"))))
 182       t)
 183   t)
 184
 185
 186 ;;; these require that the internet (or bits of it, at least) is available
 187
 188 #+internet-available
 189 (deftest get-host-by-name
 190   (equalp (car (host-ent-addresses (get-host-by-name "a.root-servers.net")))
 191           #(198 41 0 4))
 192   t)
 193
 194 #+internet-available
 195 (deftest get-host-by-address
 196     (host-ent-name (get-host-by-address #(198 41 0 4)))
 197   "a.root-servers.net")
 198
 199 ;;; These days lots of people seem to be using DNS servers that don't
 200 ;;; report resolving failures for non-existing domains. This test
 201 ;;; will fail there, so we've disabled it.
 202 #+nil
 203 (deftest get-host-by-name-wrong
 204   (handler-case
 205    (get-host-by-name "foo.tninkpad.telent.net.")
 206    (NAME-SERVICE-ERROR () t)
 207    (:no-error nil))
 208   t)
 209
 210 (defun http-stream (host port request)
 211   (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
 212     (socket-connect
 213      s (car (host-ent-addresses (get-host-by-name host))) port)
 214     (let ((stream (socket-make-stream s :input t :output t :buffering :none)))
 215       (format stream "~A HTTP/1.0~%~%" request))
 216     s))
 217
 218 #+internet-available
 219 (deftest simple-http-client-1
 220     (handler-case
 221         (let ((s (http-stream "ww.telent.net" 80 "HEAD /")))
 222           (let ((data (make-string 200)))
 223             (setf data (subseq data 0
 224                                (read-buf-nonblock data
 225                                                   (socket-make-stream s))))
 226             (princ data)
 227             (> (length data) 0)))
 228       (network-unreachable-error () 'network-unreachable))
 229   t)
 230
 231
 232 #+internet-available
 233 (deftest sockopt-receive-buffer
 234     ;; on Linux x86, the receive buffer size appears to be doubled in the
 235     ;; kernel: we set a size of x and then getsockopt() returns 2x.
 236     ;; This is why we compare with >= instead of =
 237     (handler-case
 238         (let ((s (http-stream "ww.telent.net" 80 "HEAD /")))
 239           (setf (sockopt-receive-buffer s) 1975)
 240           (let ((data (make-string 200)))
 241             (setf data (subseq data 0
 242                                (read-buf-nonblock data
 243                                                   (socket-make-stream s))))
 244             (and (> (length data) 0)
 245                  (>= (sockopt-receive-buffer s) 1975))))
 246       (network-unreachable-error () 'network-unreachable))
 247   t)
 248
 249 (deftest socket-open-p-true.1
 250     (socket-open-p (make-instance 'inet-socket :type :stream :protocol :tcp))
 251   t)
 252 #+internet-available
 253 (deftest socket-open-p-true.2
 254     (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
 255       (unwind-protect
 256            (progn
 257              (socket-connect s #(127 0 0 1) 7)
 258              (socket-open-p s))
 259         (socket-close s)))
 260   t)
 261 (deftest socket-open-p-false
 262     (let ((s (make-instance 'inet-socket :type :stream :protocol :tcp)))
 263       (socket-close s)
 264       (socket-open-p s))
 265   nil)
 266
 267 ;;; we don't have an automatic test for some of this yet.  There's no
 268 ;;; simple way to run servers and have something automatically connect
 269 ;;; to them as client, unless we spawn external programs.  Then we
 270 ;;; have to start telling people what external programs they should
 271 ;;; have installed.  Which, eventually, we will, but not just yet
 272
 273
 274 ;;; to check with this: can display packets from multiple peers
 275 ;;; peer address is shown correctly for each packet
 276 ;;; packet length is correct
 277 ;;; long (>500 byte) packets have the full length shown (doesn't work)
 278
 279 (defun udp-server (port)
 280   (let ((s (make-instance 'inet-socket :type :datagram :protocol :udp)))
 281     (socket-bind s #(0 0 0 0) port)
 282     (loop
 283      (multiple-value-bind (buf len address port) (socket-receive s nil 500)
 284        (format t "Received ~A bytes from ~A:~A - ~A ~%"
 285                len address port (subseq buf 0 (min 10 len)))))))
 286
 287