contrib/sb-introspect/sb-introspect.lisp

   1 ;;; introspection library
   2
   3 ;;; This is here as a discussion point, not yet a supported interface.  If
   4 ;;; you would like to use the functions here, or you would like other
   5 ;;; functions to be here, join the debate on navel@metacircles.com.
   6 ;;; List info at http://lists.metacircles.com/cgi-bin/mailman/listinfo/navel
   7
   8 ;;; For the avoidance of doubt, the exported interface is the proposed
   9 ;;; supported interface.  Anything else is internal, though you're
  10 ;;; welcome to argue a case for exporting it.
  11
  12 ;;; If you steal the code from this file to cut and paste into your
  13 ;;; own project, there will be much wailing and gnashing of teeth.
  14 ;;; Your teeth.  If need be, we'll kick them for you.  This is a
  15 ;;; contrib, we're allowed to look in internals.  You're an
  16 ;;; application programmer, and are not.
  17
  18 ;;; TODO
  19 ;;; 1) structs don't have within-file location info.  problem for the
  20 ;;;   structure itself, accessors and the predicate
  21 ;;; 3) error handling.  Signal random errors, or handle and resignal 'our'
  22 ;;;   error, or return NIL?
  23 ;;; 4) FIXMEs
  24
  25 (defpackage :sb-introspect
  26   (:use "CL")
  27   (:export "FUNCTION-ARGLIST"
  28            "VALID-FUNCTION-NAME-P"
  29            "FIND-DEFINITION-SOURCE"
  30            "FIND-DEFINITION-SOURCES-BY-NAME"
  31            "DEFINITION-SOURCE"
  32            "DEFINITION-SOURCE-PATHNAME"
  33            "DEFINITION-SOURCE-FORM-PATH"
  34            "DEFINITION-SOURCE-CHARACTER-OFFSET"
  35            "DEFINITION-SOURCE-FILE-WRITE-DATE"
  36            "DEFINITION-SOURCE-PLIST"
  37            "DEFINITION-NOT-FOUND" "DEFINITION-NAME"
  38            "FIND-FUNCTION-CALLEES"
  39            "FIND-FUNCTION-CALLERS"
  40            "WHO-BINDS"
  41            "WHO-CALLS"
  42            "WHO-REFERENCES"
  43            "WHO-SETS"
  44            "WHO-MACROEXPANDS"))
  45
  46 (in-package :sb-introspect)
  47
  48 ;;;; Internal interface for SBCL debug info
  49
  50 ;;; Here are some tutorial-style type definitions to help understand
  51 ;;; the internal SBCL debugging data structures we're using. The
  52 ;;; commentary is based on CMUCL's debug internals manual.
  53 ;;;
  54 (deftype debug-info ()
  55   "Structure containing all the debug information related to a function.
  56 Function objects reference debug-infos which in turn reference
  57 debug-sources and so on."
  58   'sb-c::compiled-debug-info)
  59
  60 (deftype debug-source ()
  61   "Debug sources describe where to find source code.
  62 For example, the debug source for a function compiled from a file will
  63 include the pathname of the file and the position of the definition."
  64   'sb-c::debug-source)
  65
  66 (deftype debug-function ()
  67   "Debug function represent static compile-time information about a function."
  68   'sb-c::compiled-debug-fun)
  69
  70 (declaim (ftype (function (function) debug-info) function-debug-info))
  71 (defun function-debug-info (function)
  72   (let* ((function-object (sb-kernel::%closure-fun function))
  73          (function-header (sb-kernel:fun-code-header function-object)))
  74     (sb-kernel:%code-debug-info function-header)))
  75
  76 (declaim (ftype (function (function) debug-source) function-debug-source))
  77 (defun function-debug-source (function)
  78   (debug-info-source (function-debug-info function)))
  79
  80 (declaim (ftype (function (debug-info) debug-source) debug-info-source))
  81 (defun debug-info-source (debug-info)
  82   (sb-c::debug-info-source debug-info))
  83
  84 (declaim (ftype (function (debug-info) debug-function) debug-info-debug-function))
  85 (defun debug-info-debug-function (debug-info)
  86   (elt (sb-c::compiled-debug-info-fun-map debug-info) 0))
  87
  88 (defun valid-function-name-p (name)
  89   "True if NAME denotes a function name that can be passed to MACRO-FUNCTION or FDEFINITION "
  90   (and (sb-int:valid-function-name-p name) t))
  91
  92 ;;;; Finding definitions
  93
  94 (defstruct definition-source
  95   ;; Pathname of the source file that the definition was compiled from.
  96   ;; This is null if the definition was not compiled from a file.
  97   (pathname nil :type (or null pathname))
  98   ;; Source-path of the definition within the file.
  99   ;; This may be incomplete depending on the debug level at which the
 100   ;; source was compiled.
 101   (form-path '() :type list)
 102   ;; Character offset of the top-level-form containing the definition.
 103   ;; This corresponds to the first element of form-path.
 104   (character-offset nil :type (or null integer))
 105   ;; File-write-date of the source file when compiled.
 106   ;; Null if not compiled from a file.
 107   (file-write-date nil :type (or null integer))
 108   ;; plist from WITH-COMPILATION-UNIT
 109   (plist nil)
 110   ;; Any extra metadata that the caller might be interested in. For
 111   ;; example the specializers of the method whose definition-source this
 112   ;; is.
 113   (description nil :type list))
 114
 115 (defun find-definition-sources-by-name (name type)
 116   "Returns a list of DEFINITION-SOURCEs for the objects of type TYPE
 117 defined with name NAME. NAME may be a symbol or a extended function
 118 name. Type can currently be one of the following:
 119
 120    (Public)
 121    :CLASS
 122    :COMPILER-MACRO
 123    :CONDITION
 124    :CONSTANT
 125    :FUNCTION
 126    :GENERIC-FUNCTION
 127    :MACRO
 128    :METHOD
 129    :METHOD-COMBINATION
 130    :PACKAGE
 131    :SETF-EXPANDER
 132    :STRUCTURE
 133    :SYMBOL-MACRO
 134    :TYPE
 135    :VARIABLE
 136
 137    (Internal)
 138    :OPTIMIZER
 139    :SOURCE-TRANSFORM
 140    :TRANSFORM
 141    :VOP
 142
 143 If an unsupported TYPE is requested, the function will return NIL.
 144 "
 145   (flet ((listify (x)
 146            (if (listp x)
 147                x
 148                (list x)))
 149          (get-class (name)
 150            (and (symbolp name)
 151                 (find-class name nil)))
 152          (real-fdefinition (name)
 153            ;; for getting the real function object, even if the
 154            ;; function is being profiled
 155            (let ((profile-info (gethash name sb-profile::*profiled-fun-name->info*)))
 156              (if profile-info
 157                  (sb-profile::profile-info-encapsulated-fun profile-info)
 158                  (fdefinition name)))))
 159     (listify
 160      (case type
 161        ((:variable)
 162         (when (and (symbolp name)
 163                    (eq (sb-int:info :variable :kind name) :special))
 164           (translate-source-location (sb-int:info :source-location type name))))
 165        ((:constant)
 166         (when (and (symbolp name)
 167                    (eq (sb-int:info :variable :kind name) :constant))
 168           (translate-source-location (sb-int:info :source-location type name))))
 169        ((:symbol-macro)
 170         (when (and (symbolp name)
 171                    (eq (sb-int:info :variable :kind name) :macro))
 172           (translate-source-location (sb-int:info :source-location type name))))
 173        ((:macro)
 174         (when (and (symbolp name)
 175                    (macro-function name))
 176           (find-definition-source (macro-function name))))
 177        ((:compiler-macro)
 178         (when (compiler-macro-function name)
 179           (find-definition-source (compiler-macro-function name))))
 180        ((:function :generic-function)
 181         (when (and (fboundp name)
 182                    (or (not (symbolp name))
 183                        (not (macro-function name))))
 184           (let ((fun (real-fdefinition name)))
 185             (when (eq (not (typep fun 'generic-function))
 186                       (not (eq type :generic-function)))
 187               (find-definition-source fun)))))
 188        ((:type)
 189         ;; Source locations for types are saved separately when the expander
 190         ;; is a closure without a good source-location.
 191         (let ((loc (sb-int:info :type :source-location name)))
 192           (if loc
 193               (translate-source-location loc)
 194               (let ((expander-fun (sb-int:info :type :expander name)))
 195                 (find-definition-source expander-fun)))))
 196        ((:method)
 197         (when (fboundp name)
 198           (let ((fun (real-fdefinition name)))
 199            (when (typep fun 'generic-function)
 200              (loop for method in (sb-mop::generic-function-methods
 201                                   fun)
 202                 for source = (find-definition-source method)
 203                 when source collect source)))))
 204        ((:setf-expander)
 205         (when (and (consp name)
 206                    (eq (car name) 'setf))
 207           (setf name (cadr name)))
 208         (let ((expander (or (sb-int:info :setf :inverse name)
 209                             (sb-int:info :setf :expander name))))
 210           (when expander
 211             (sb-introspect:find-definition-source (if (symbolp expander)
 212                                                       (symbol-function expander)
 213                                                       expander)))))
 214        ((:structure)
 215         (let ((class (get-class name)))
 216           (if class
 217               (when (typep class 'sb-pcl::structure-class)
 218                 (find-definition-source class))
 219               (when (sb-int:info :typed-structure :info name)
 220                 (translate-source-location
 221                  (sb-int:info :source-location :typed-structure name))))))
 222        ((:condition :class)
 223         (let ((class (get-class name)))
 224           (when (and class
 225                      (not (typep class 'sb-pcl::structure-class)))
 226             (when (eq (not (typep class 'sb-pcl::condition-class))
 227                       (not (eq type :condition)))
 228               (find-definition-source class)))))
 229        ((:method-combination)
 230         (let ((combination-fun
 231                (find-method #'sb-mop:find-method-combination
 232                             nil
 233                             (list (find-class 'generic-function)
 234                                   (list 'eql name)
 235                                   t)
 236                             nil)))
 237           (when combination-fun
 238             (find-definition-source combination-fun))))
 239        ((:package)
 240         (when (symbolp name)
 241           (let ((package (find-package name)))
 242             (when package
 243               (find-definition-source package)))))
 244        ;; TRANSFORM and OPTIMIZER handling from swank-sbcl
 245        ((:transform)
 246         (when (symbolp name)
 247           (let ((fun-info (sb-int:info :function :info name)))
 248             (when fun-info
 249               (loop for xform in (sb-c::fun-info-transforms fun-info)
 250                     for source = (find-definition-source
 251                                   (sb-c::transform-function xform))
 252                     for typespec = (sb-kernel:type-specifier
 253                                     (sb-c::transform-type xform))
 254                     for note = (sb-c::transform-note xform)
 255                     do (setf (definition-source-description source)
 256                              (if (consp typespec)
 257                                  (list (second typespec) note)
 258                                  (list note)))
 259                     collect source)))))
 260        ((:optimizer)
 261         (when (symbolp name)
 262           (let ((fun-info (sb-int:info :function :info name)))
 263             (when fun-info
 264               (let ((otypes '((sb-c::fun-info-derive-type . sb-c:derive-type)
 265                               (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
 266                               (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
 267                               (sb-c::fun-info-optimizer . sb-c:optimizer))))
 268                 (loop for (reader . name) in otypes
 269                       for fn = (funcall reader fun-info)
 270                       when fn collect
 271                       (let ((source (find-definition-source fn)))
 272                         (setf (definition-source-description source)
 273                               (list name))
 274                         source)))))))
 275        ((:vop)
 276         (when (symbolp name)
 277           (let ((fun-info (sb-int:info :function :info name)))
 278             (when fun-info
 279               (loop for vop in (sb-c::fun-info-templates fun-info)
 280                     for source = (find-definition-source
 281                                   (sb-c::vop-info-generator-function vop))
 282                     do (setf (definition-source-description source)
 283                              (list (sb-c::template-name vop)
 284                                    (sb-c::template-note vop)))
 285                     collect source)))))
 286        ((:source-transform)
 287         (when (symbolp name)
 288           (let ((transform-fun (sb-int:info :function :source-transform name)))
 289             (when transform-fun
 290               (sb-introspect:find-definition-source transform-fun)))))
 291        (t
 292         nil)))))
 293
 294 (defun find-definition-source (object)
 295   (typecase object
 296     ((or sb-pcl::condition-class sb-pcl::structure-class)
 297      (let ((classoid (sb-impl::find-classoid (class-name object))))
 298        (when classoid
 299          (let ((layout (sb-impl::classoid-layout classoid)))
 300            (when layout
 301              (translate-source-location
 302               (sb-kernel::layout-source-location layout)))))))
 303     (method-combination
 304      (car
 305       (find-definition-sources-by-name
 306        (sb-pcl::method-combination-type-name object) :method-combination)))
 307     (package
 308      (translate-source-location (sb-impl::package-source-location object)))
 309     (class
 310      (translate-source-location (sb-pcl::definition-source object)))
 311     ;; Use the PCL definition location information instead of the function
 312     ;; debug-info for methods and generic functions. Sometimes the
 313     ;; debug-info would point into PCL internals instead of the proper
 314     ;; location.
 315     (generic-function
 316      (let ((source (translate-source-location
 317                     (sb-pcl::definition-source object))))
 318        (when source
 319          (setf (definition-source-description source)
 320                (list (sb-mop:generic-function-lambda-list object))))
 321        source))
 322     (method
 323      (let ((source (translate-source-location
 324                     (sb-pcl::definition-source object))))
 325        (when source
 326          (setf (definition-source-description source)
 327                (append (method-qualifiers object)
 328                        (if (sb-mop:method-generic-function object)
 329                            (sb-pcl::unparse-specializers
 330                             (sb-mop:method-generic-function object)
 331                             (sb-mop:method-specializers object))
 332                            (sb-mop:method-specializers object)))))
 333        source))
 334     #+sb-eval
 335     (sb-eval:interpreted-function
 336      (let ((source (translate-source-location
 337                     (sb-eval:interpreted-function-source-location object))))
 338        source))
 339     (function
 340      (cond ((struct-accessor-p object)
 341             (find-definition-source
 342              (struct-accessor-structure-class object)))
 343            ((struct-predicate-p object)
 344             (find-definition-source
 345              (struct-predicate-structure-class object)))
 346            (t
 347             (find-function-definition-source object))))
 348     ((or condition standard-object structure-object)
 349      (find-definition-source (class-of object)))
 350     (t
 351      (error "Don't know how to retrieve source location for a ~S~%"
 352             (type-of object)))))
 353
 354 (defun find-function-definition-source (function)
 355   (let* ((debug-info (function-debug-info function))
 356          (debug-source (debug-info-source debug-info))
 357          (debug-fun (debug-info-debug-function debug-info))
 358          (tlf (if debug-fun (sb-c::compiled-debug-fun-tlf-number debug-fun))))
 359     (make-definition-source
 360      :pathname
 361      ;; KLUDGE: at the moment, we don't record the correct toplevel
 362      ;; form number for forms processed by EVAL (including EVAL-WHEN
 363      ;; :COMPILE-TOPLEVEL).  Until that's fixed, don't return a
 364      ;; DEFINITION-SOURCE with a pathname.  (When that's fixed, take
 365      ;; out the (not (debug-source-form ...)) test.
 366      (if (and (sb-c::debug-source-namestring debug-source)
 367               (not (sb-c::debug-source-form debug-source)))
 368          (parse-namestring (sb-c::debug-source-namestring debug-source)))
 369      :character-offset
 370      (if tlf
 371          (elt (sb-c::debug-source-start-positions debug-source) tlf))
 372      ;; Unfortunately there is no proper source path available in the
 373      ;; debug-source. FIXME: We could use sb-di:code-locations to get
 374      ;; a full source path. -luke (12/Mar/2005)
 375      :form-path (if tlf (list tlf))
 376      :file-write-date (sb-c::debug-source-created debug-source)
 377      :plist (sb-c::debug-source-plist debug-source))))
 378
 379 (defun translate-source-location (location)
 380   (if location
 381       (make-definition-source
 382        :pathname (let ((n (sb-c:definition-source-location-namestring location)))
 383                    (when n
 384                      (parse-namestring n)))
 385        :form-path
 386        (let ((number (sb-c:definition-source-location-toplevel-form-number
 387                          location)))
 388          (when number
 389            (list number)))
 390        :plist (sb-c:definition-source-location-plist location))
 391       (make-definition-source)))
 392
 393 ;;; This is kludgey.  We expect these functions (the underlying functions,
 394 ;;; not the closures) to be in static space and so not move ever.
 395 ;;; FIXME It's also possibly wrong: not all structures use these vanilla
 396 ;;; accessors, e.g. when the :type option is used
 397 (defvar *struct-slotplace-reader*
 398   (sb-vm::%simple-fun-self #'definition-source-pathname))
 399 (defvar *struct-slotplace-writer*
 400   (sb-vm::%simple-fun-self #'(setf definition-source-pathname)))
 401 (defvar *struct-predicate*
 402   (sb-vm::%simple-fun-self #'definition-source-p))
 403
 404 (defun struct-accessor-p (function)
 405   (let ((self (sb-vm::%simple-fun-self function)))
 406     ;; FIXME there are other kinds of struct accessor.  Fill out this list
 407     (member self (list *struct-slotplace-reader*
 408                        *struct-slotplace-writer*))))
 409
 410 (defun struct-predicate-p (function)
 411   (let ((self (sb-vm::%simple-fun-self function)))
 412     ;; FIXME there may be other structure predicate functions
 413     (member self (list *struct-predicate*))))
 414
 415 ;;; FIXME: maybe this should be renamed as FUNCTION-LAMBDA-LIST?
 416 (defun function-arglist (function)
 417   "Describe the lambda list for the extended function designator FUNCTION.
 418 Works for special-operators, macros, simple functions,
 419 interpreted functions, and generic functions.  Signals error if
 420 not found"
 421   (cond ((valid-function-name-p function)
 422          (function-arglist (or (and (symbolp function)
 423                                     (macro-function function))
 424                                (fdefinition function))))
 425         ((typep function 'generic-function)
 426          (sb-pcl::generic-function-pretty-arglist function))
 427         #+sb-eval
 428         ((typep function 'sb-eval:interpreted-function)
 429          (sb-eval:interpreted-function-lambda-list function))
 430         (t (sb-kernel:%simple-fun-arglist (sb-kernel:%fun-fun function)))))
 431
 432 (defun struct-accessor-structure-class (function)
 433   (let ((self (sb-vm::%simple-fun-self function)))
 434     (cond
 435       ((member self (list *struct-slotplace-reader* *struct-slotplace-writer*))
 436        (find-class
 437         (sb-kernel::classoid-name
 438          (sb-kernel::layout-classoid
 439           (sb-kernel:%closure-index-ref function 1)))))
 440       )))
 441
 442 (defun struct-predicate-structure-class (function)
 443   (let ((self (sb-vm::%simple-fun-self function)))
 444     (cond
 445       ((member self (list *struct-predicate*))
 446        (find-class
 447         (sb-kernel::classoid-name
 448          (sb-kernel::layout-classoid
 449           (sb-kernel:%closure-index-ref function 0)))))
 450       )))
 451
 452 ;;;; find callers/callees, liberated from Helmut Eller's code in SLIME
 453
 454 ;;; This interface is trmendously experimental.
 455
 456 ;;; For the moment I'm taking the view that FDEFN is an internal
 457 ;;; object (one out of one CMUCL developer surveyed didn't know what
 458 ;;; they were for), so these routines deal in FUNCTIONs
 459
 460 ;;; Find callers and callees by looking at the constant pool of
 461 ;;; compiled code objects.  We assume every fdefn object in the
 462 ;;; constant pool corresponds to a call to that function.  A better
 463 ;;; strategy would be to use the disassembler to find actual
 464 ;;; call-sites.
 465
 466 (defun find-function-callees (function)
 467   "Return functions called by FUNCTION."
 468   (let ((callees '()))
 469     (map-code-constants
 470      (sb-kernel:fun-code-header function)
 471      (lambda (obj)
 472        (when (sb-kernel:fdefn-p obj)
 473          (push (sb-kernel:fdefn-fun obj)
 474                callees))))
 475     callees))
 476
 477
 478 (defun find-function-callers (function &optional (spaces '(:read-only :static
 479                                                            :dynamic)))
 480   "Return functions which call FUNCTION, by searching SPACES for code objects"
 481   (let ((referrers '()))
 482     (map-caller-code-components
 483      function
 484      spaces
 485      (lambda (code)
 486        (let ((entry (sb-kernel:%code-entry-points  code)))
 487          (cond ((not entry)
 488                 (push (princ-to-string code) referrers))
 489                (t
 490                 (loop for e = entry then (sb-kernel::%simple-fun-next e)
 491                       while e
 492                       do (pushnew e referrers)))))))
 493     referrers))
 494
 495 (declaim (inline map-code-constants))
 496 (defun map-code-constants (code fn)
 497   "Call FN for each constant in CODE's constant pool."
 498   (check-type code sb-kernel:code-component)
 499   (loop for i from sb-vm:code-constants-offset below
 500         (sb-kernel:get-header-data code)
 501         do (funcall fn (sb-kernel:code-header-ref code i))))
 502
 503 (declaim (inline map-allocated-code-components))
 504 (defun map-allocated-code-components (spaces fn)
 505   "Call FN for each allocated code component in one of SPACES.  FN
 506 receives the object and its size as arguments.  SPACES should be a
 507 list of the symbols :dynamic, :static, or :read-only."
 508   (dolist (space spaces)
 509     (sb-vm::map-allocated-objects
 510      (lambda (obj header size)
 511        (when (= sb-vm:code-header-widetag header)
 512          (funcall fn obj size)))
 513      space
 514      t)))
 515
 516 (declaim (inline map-caller-code-components))
 517 (defun map-caller-code-components (function spaces fn)
 518   "Call FN for each code component with a fdefn for FUNCTION in its
 519 constant pool."
 520   (let ((function (coerce function 'function)))
 521     (map-allocated-code-components
 522      spaces
 523      (lambda (obj size)
 524        (declare (ignore size))
 525        (map-code-constants
 526         obj
 527         (lambda (constant)
 528           (when (and (sb-kernel:fdefn-p constant)
 529                      (eq (sb-kernel:fdefn-fun constant)
 530                          function))
 531             (funcall fn obj))))))))
 532
 533 ;;; XREF facility
 534
 535 (defun get-simple-fun (functoid)
 536   (etypecase functoid
 537     (sb-kernel::fdefn
 538      (get-simple-fun (sb-vm::fdefn-fun functoid)))
 539     ((or null sb-impl::funcallable-instance)
 540      nil)
 541     (function
 542      (sb-kernel::%closure-fun functoid))))
 543
 544 (defun collect-xref (kind-index wanted-name)
 545   (let ((ret nil))
 546     (dolist (env sb-c::*info-environment* ret)
 547       ;; Loop through the infodb ...
 548       (sb-c::do-info (env :class class :type type :name info-name
 549                           :value value)
 550         ;; ... looking for function or macro definitions
 551         (when (and (eql class :function)
 552                    (or (eql type :macro-function)
 553                        (eql type :definition)))
 554           ;; Get a simple-fun for the definition, and an xref array
 555           ;; from the table if available.
 556           (let* ((simple-fun (get-simple-fun value))
 557                  (xrefs (when simple-fun
 558                           (sb-vm::%simple-fun-xrefs simple-fun)))
 559                  (array (when xrefs
 560                           (aref xrefs kind-index))))
 561             ;; Loop through the name/path xref entries in the table
 562             (loop for i from 0 below (length array) by 2
 563                   for xref-name = (aref array i)
 564                   for xref-path = (aref array (1+ i))
 565                   do (when (eql xref-name wanted-name)
 566                        (let ((source-location
 567                               (find-function-definition-source simple-fun)))
 568                          ;; Use the more accurate source path from
 569                          ;; the xref entry.
 570                          (setf (definition-source-form-path source-location)
 571                                xref-path)
 572                          (push (cons info-name source-location)
 573                                ret))))))))))
 574
 575 (defun who-calls (function-name)
 576   "Use the xref facility to search for source locations where the
 577 global function named FUNCTION-NAME is called. Returns a list of
 578 function name, definition-source pairs."
 579   (collect-xref #.(position :calls sb-c::*xref-kinds*) function-name))
 580
 581 (defun who-binds (symbol)
 582   "Use the xref facility to search for source locations where the
 583 special variable SYMBOL is rebound. Returns a list of function name,
 584 definition-source pairs."
 585   (collect-xref #.(position :binds sb-c::*xref-kinds*) symbol))
 586
 587 (defun who-references (symbol)
 588   "Use the xref facility to search for source locations where the
 589 special variable or constant SYMBOL is read. Returns a list of function
 590 name, definition-source pairs."
 591   (collect-xref #.(position :references sb-c::*xref-kinds*) symbol))
 592
 593 (defun who-sets (symbol)
 594   "Use the xref facility to search for source locations where the
 595 special variable SYMBOL is written to. Returns a list of function name,
 596 definition-source pairs."
 597   (collect-xref #.(position :sets sb-c::*xref-kinds*) symbol))
 598
 599 (defun who-macroexpands (macro-name)
 600   "Use the xref facility to search for source locations where the
 601 macro MACRO-NAME is expanded. Returns a list of function name,
 602 definition-source pairs."
 603   (collect-xref #.(position :macroexpands sb-c::*xref-kinds*) macro-name))
 604
 605 (provide 'sb-introspect)