contrib/sb-introspect/sb-introspect.lisp

   1 ;;; introspection library
   2
   3 ;;; This is here as a discussion point, not yet a supported interface.  If
   4 ;;; you would like to use the functions here, or you would like other
   5 ;;; functions to be here, join the debate on navel@metacircles.com.
   6 ;;; List info at http://lists.metacircles.com/cgi-bin/mailman/listinfo/navel
   7
   8 ;;; For the avoidance of doubt, the exported interface is the proposed
   9 ;;; supported interface.  Anything else is internal, though you're
  10 ;;; welcome to argue a case for exporting it.
  11
  12 ;;; If you steal the code from this file to cut and paste into your
  13 ;;; own project, there will be much wailing and gnashing of teeth.
  14 ;;; Your teeth.  If need be, we'll kick them for you.  This is a
  15 ;;; contrib, we're allowed to look in internals.  You're an
  16 ;;; application programmer, and are not.
  17
  18 ;;; TODO
  19 ;;; 1) structs don't have within-file location info.  problem for the
  20 ;;;   structure itself, accessors and the predicate
  21 ;;; 3) error handling.  Signal random errors, or handle and resignal 'our'
  22 ;;;   error, or return NIL?
  23 ;;; 4) FIXMEs
  24
  25 (defpackage :sb-introspect
  26   (:use "CL")
  27   (:export "FUNCTION-ARGLIST"
  28            "VALID-FUNCTION-NAME-P"
  29            "FIND-DEFINITION-SOURCE"
  30            "FIND-DEFINITION-SOURCES-BY-NAME"
  31            "DEFINITION-SOURCE"
  32            "DEFINITION-SOURCE-PATHNAME"
  33            "DEFINITION-SOURCE-FORM-PATH"
  34            "DEFINITION-SOURCE-CHARACTER-OFFSET"
  35            "DEFINITION-SOURCE-FILE-WRITE-DATE"
  36            "DEFINITION-SOURCE-PLIST"
  37            "DEFINITION-NOT-FOUND" "DEFINITION-NAME"
  38            "FIND-FUNCTION-CALLEES"
  39            "FIND-FUNCTION-CALLERS"))
  40
  41 (in-package :sb-introspect)
  42
  43 ;;;; Internal interface for SBCL debug info
  44
  45 ;;; Here are some tutorial-style type definitions to help understand
  46 ;;; the internal SBCL debugging data structures we're using. The
  47 ;;; commentary is based on CMUCL's debug internals manual.
  48 ;;;
  49 (deftype debug-info ()
  50   "Structure containing all the debug information related to a function.
  51 Function objects reference debug-infos which in turn reference
  52 debug-sources and so on."
  53   'sb-c::compiled-debug-info)
  54
  55 (deftype debug-source ()
  56   "Debug sources describe where to find source code.
  57 For example, the debug source for a function compiled from a file will
  58 include the pathname of the file and the position of the definition."
  59   'sb-c::debug-source)
  60
  61 (deftype debug-function ()
  62   "Debug function represent static compile-time information about a function."
  63   'sb-c::compiled-debug-fun)
  64
  65 (declaim (ftype (function (function) debug-info) function-debug-info))
  66 (defun function-debug-info (function)
  67   (let* ((function-object (sb-kernel::%closure-fun function))
  68          (function-header (sb-kernel:fun-code-header function-object)))
  69     (sb-kernel:%code-debug-info function-header)))
  70
  71 (declaim (ftype (function (function) debug-source) function-debug-source))
  72 (defun function-debug-source (function)
  73   (debug-info-source (function-debug-info function)))
  74
  75 (declaim (ftype (function (debug-info) debug-source) debug-info-source))
  76 (defun debug-info-source (debug-info)
  77   (sb-c::debug-info-source debug-info))
  78
  79 (declaim (ftype (function (debug-info) debug-function) debug-info-debug-function))
  80 (defun debug-info-debug-function (debug-info)
  81   (elt (sb-c::compiled-debug-info-fun-map debug-info) 0))
  82
  83 (defun valid-function-name-p (name)
  84   "True if NAME denotes a function name that can be passed to MACRO-FUNCTION or FDEFINITION "
  85   (and (sb-int:valid-function-name-p name) t))
  86
  87 ;;;; Finding definitions
  88
  89 (defstruct definition-source
  90   ;; Pathname of the source file that the definition was compiled from.
  91   ;; This is null if the definition was not compiled from a file.
  92   (pathname nil :type (or null pathname))
  93   ;; Source-path of the definition within the file.
  94   ;; This may be incomplete depending on the debug level at which the
  95   ;; source was compiled.
  96   (form-path '() :type list)
  97   ;; Character offset of the top-level-form containing the definition.
  98   ;; This corresponds to the first element of form-path.
  99   (character-offset nil :type (or null integer))
 100   ;; File-write-date of the source file when compiled.
 101   ;; Null if not compiled from a file.
 102   (file-write-date nil :type (or null integer))
 103   ;; plist from WITH-COMPILATION-UNIT
 104   (plist nil)
 105   ;; Any extra metadata that the caller might be interested in. For
 106   ;; example the specializers of the method whose definition-source this
 107   ;; is.
 108   (description nil :type list))
 109
 110 (defun find-definition-sources-by-name (name type)
 111   "Returns a list of DEFINITION-SOURCEs for the objects of type TYPE
 112 defined with name NAME. NAME may be a symbol or a extended function
 113 name. Type can currently be one of the following:
 114
 115    (Public)
 116    :CLASS
 117    :COMPILER-MACRO
 118    :CONDITION
 119    :CONSTANT
 120    :FUNCTION
 121    :GENERIC-FUNCTION
 122    :MACRO
 123    :METHOD
 124    :METHOD-COMBINATION
 125    :PACKAGE
 126    :SETF-EXPANDER
 127    :STRUCTURE
 128    :SYMBOL-MACRO
 129    :TYPE
 130    :VARIABLE
 131
 132    (Internal)
 133    :OPTIMIZER
 134    :SOURCE-TRANSFORM
 135    :TRANSFORM
 136    :VOP
 137
 138 If an unsupported TYPE is requested, the function will return NIL.
 139 "
 140   (flet ((listify (x)
 141            (if (listp x)
 142                x
 143                (list x))))
 144     (listify
 145      (case type
 146        ((:variable)
 147         (when (and (symbolp name)
 148                    (eq (sb-int:info :variable :kind name) :special))
 149           (translate-source-location (sb-int:info :source-location type name))))
 150        ((:constant)
 151         (when (and (symbolp name)
 152                    (eq (sb-int:info :variable :kind name) :constant))
 153           (translate-source-location (sb-int:info :source-location type name))))
 154        ((:symbol-macro)
 155         (when (and (symbolp name)
 156                    (eq (sb-int:info :variable :kind name) :macro))
 157           (translate-source-location (sb-int:info :source-location type name))))
 158        ((:macro)
 159         (when (and (symbolp name)
 160                    (macro-function name))
 161           (find-definition-source (macro-function name))))
 162        ((:compiler-macro)
 163         (when (compiler-macro-function name)
 164           (find-definition-source (compiler-macro-function name))))
 165        ((:function :generic-function)
 166         (when (and (fboundp name)
 167                    (or (not (symbolp name))
 168                        (not (macro-function name))))
 169           (let ((fun (fdefinition name)))
 170             (when (eq (not (typep fun 'generic-function))
 171                       (not (eq type :generic-function)))
 172               (find-definition-source fun)))))
 173        ((:type)
 174         (let ((expander-fun (sb-int:info :type :expander name)))
 175           (when expander-fun
 176             (find-definition-source expander-fun))))
 177        ((:method)
 178         (when (and (fboundp name)
 179                    (typep (fdefinition name) 'generic-function))
 180           (loop for method in (sb-mop::generic-function-methods
 181                                (fdefinition name))
 182                 for source = (find-definition-source method)
 183                 when source collect source)))
 184        ((:setf-expander)
 185         (when (and (consp name)
 186                    (eq (car name) 'setf))
 187           (setf name (cadr name)))
 188         (let ((expander (or (sb-int:info :setf :inverse name)
 189                             (sb-int:info :setf :expander name))))
 190           (when expander
 191             (sb-introspect:find-definition-source (if (symbolp expander)
 192                                                       (symbol-function expander)
 193                                                       expander)))))
 194        ((:structure)
 195         (let ((class (find-class name nil)))
 196           (if class
 197               (when (typep class 'sb-pcl::structure-class)
 198                 (find-definition-source class))
 199               (when (sb-int:info :typed-structure :info name)
 200                 (translate-source-location
 201                  (sb-int:info :source-location :typed-structure name))))))
 202        ((:condition :class)
 203         (let ((class (find-class name nil)))
 204           (when (and class
 205                      (not (typep class 'sb-pcl::structure-class)))
 206             (when (eq (not (typep class 'sb-pcl::condition-class))
 207                       (not (eq type :condition)))
 208               (find-definition-source class)))))
 209        ((:method-combination)
 210         (let ((combination-fun
 211                (ignore-errors (find-method #'sb-mop:find-method-combination
 212                                            nil
 213                                            (list (find-class 'generic-function)
 214                                                  (list 'eql name)
 215                                                  t)))))
 216           (when combination-fun
 217             (find-definition-source combination-fun))))
 218        ((:package)
 219         (when (symbolp name)
 220           (let ((package (find-package name)))
 221             (when package
 222               (find-definition-source package)))))
 223        ;; TRANSFORM and OPTIMIZER handling from swank-sbcl
 224        ((:transform)
 225         (when (symbolp name)
 226           (let ((fun-info (sb-int:info :function :info name)))
 227             (when fun-info
 228               (loop for xform in (sb-c::fun-info-transforms fun-info)
 229                     for source = (find-definition-source
 230                                   (sb-c::transform-function xform))
 231                     for typespec = (sb-kernel:type-specifier
 232                                     (sb-c::transform-type xform))
 233                     for note = (sb-c::transform-note xform)
 234                     do (setf (definition-source-description source)
 235                              (if (consp typespec)
 236                                  (list (second typespec) note)
 237                                  (list note)))
 238                     collect source)))))
 239        ((:optimizer)
 240         (when (symbolp name)
 241           (let ((fun-info (sb-int:info :function :info name)))
 242             (when fun-info
 243               (let ((otypes '((sb-c::fun-info-derive-type . sb-c:derive-type)
 244                               (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
 245                               (sb-c::fun-info-ltn-annotate . sb-c:ltn-annotate)
 246                               (sb-c::fun-info-optimizer . sb-c:optimizer))))
 247                 (loop for (reader . name) in otypes
 248                       for fn = (funcall reader fun-info)
 249                       when fn collect
 250                       (let ((source (find-definition-source fn)))
 251                         (setf (definition-source-description source)
 252                               (list name))
 253                         source)))))))
 254        ((:vop)
 255         (when (symbolp name)
 256           (let ((fun-info (sb-int:info :function :info name)))
 257             (when fun-info
 258               (loop for vop in (sb-c::fun-info-templates fun-info)
 259                     for source = (find-definition-source
 260                                   (sb-c::vop-info-generator-function vop))
 261                     do (setf (definition-source-description source)
 262                              (list (sb-c::template-name vop)
 263                                    (sb-c::template-note vop)))
 264                     collect source)))))
 265        ((:source-transform)
 266         (when (symbolp name)
 267           (let ((transform-fun (sb-int:info :function :source-transform name)))
 268             (when transform-fun
 269               (sb-introspect:find-definition-source transform-fun)))))
 270        (t
 271         nil)))))
 272
 273 (defun find-definition-source (object)
 274   (typecase object
 275     ((or sb-pcl::condition-class sb-pcl::structure-class)
 276      (let ((classoid (sb-impl::find-classoid (class-name object))))
 277        (when classoid
 278          (let ((layout (sb-impl::classoid-layout classoid)))
 279            (when layout
 280              (translate-source-location
 281               (sb-kernel::layout-source-location layout)))))))
 282     (method-combination
 283      (car
 284       (find-definition-sources-by-name (sb-pcl::method-combination-type object)
 285                                        :method-combination)))
 286     (package
 287      (translate-source-location (sb-impl::package-source-location object)))
 288     (class
 289      (translate-source-location (sb-pcl::definition-source object)))
 290     ;; Use the PCL definition location information instead of the function
 291     ;; debug-info for methods and generic functions. Sometimes the
 292     ;; debug-info would point into PCL internals instead of the proper
 293     ;; location.
 294     (generic-function
 295      (let ((source (translate-source-location
 296                     (sb-pcl::definition-source object))))
 297        (when source
 298          (setf (definition-source-description source)
 299                (list (sb-mop:generic-function-lambda-list object))))
 300        source))
 301     (method
 302      (let ((source (translate-source-location
 303                     (sb-pcl::definition-source object))))
 304        (when source
 305          (setf (definition-source-description source)
 306                (append (method-qualifiers object)
 307                        (sb-pcl::unparse-specializers
 308                         (sb-mop:method-specializers object)))))
 309        source))
 310     (function
 311      (cond ((struct-accessor-p object)
 312             (find-definition-source
 313              (struct-accessor-structure-class object)))
 314            ((struct-predicate-p object)
 315             (find-definition-source
 316              (struct-predicate-structure-class object)))
 317            (t
 318             (find-function-definition-source object))))
 319     (t
 320      (error "Don't know how to retrive source location for a ~S~%"
 321             (type-of object)))))
 322
 323 (defun find-function-definition-source (function)
 324   (let* ((debug-info (function-debug-info function))
 325          (debug-source (debug-info-source debug-info))
 326          (debug-fun (debug-info-debug-function debug-info))
 327          (tlf (if debug-fun (sb-c::compiled-debug-fun-tlf-number debug-fun))))
 328     (make-definition-source
 329      :pathname
 330      (if (eql (sb-c::debug-source-from debug-source) :file)
 331          (parse-namestring (sb-c::debug-source-name debug-source)))
 332      :character-offset
 333      (if tlf
 334          (elt (sb-c::debug-source-start-positions debug-source) tlf))
 335      ;; Unfortunately there is no proper source path available in the
 336      ;; debug-source. FIXME: We could use sb-di:code-locations to get
 337      ;; a full source path. -luke (12/Mar/2005)
 338      :form-path (if tlf (list tlf))
 339      :file-write-date (sb-c::debug-source-created debug-source)
 340      :plist (sb-c::debug-source-plist debug-source))))
 341
 342 (defun translate-source-location (location)
 343   (if location
 344       (make-definition-source
 345        :pathname (let ((n (sb-c:definition-source-location-namestring location)))
 346                    (when n
 347                      (parse-namestring n)))
 348        :form-path
 349        (let ((number (sb-c:definition-source-location-toplevel-form-number
 350                          location)))
 351          (when number
 352            (list number)))
 353        :plist (sb-c:definition-source-location-plist location))
 354       (make-definition-source)))
 355
 356 ;;; This is kludgey.  We expect these functions (the underlying functions,
 357 ;;; not the closures) to be in static space and so not move ever.
 358 ;;; FIXME It's also possibly wrong: not all structures use these vanilla
 359 ;;; accessors, e.g. when the :type option is used
 360 (defvar *struct-slotplace-reader*
 361   (sb-vm::%simple-fun-self #'definition-source-pathname))
 362 (defvar *struct-slotplace-writer*
 363   (sb-vm::%simple-fun-self #'(setf definition-source-pathname)))
 364 (defvar *struct-predicate*
 365   (sb-vm::%simple-fun-self #'definition-source-p))
 366
 367 (defun struct-accessor-p (function)
 368   (let ((self (sb-vm::%simple-fun-self function)))
 369     ;; FIXME there are other kinds of struct accessor.  Fill out this list
 370     (member self (list *struct-slotplace-reader*
 371                        *struct-slotplace-writer*))))
 372
 373 (defun struct-predicate-p (function)
 374   (let ((self (sb-vm::%simple-fun-self function)))
 375     ;; FIXME there may be other structure predicate functions
 376     (member self (list *struct-predicate*))))
 377
 378 ;;; FIXME: maybe this should be renamed as FUNCTION-LAMBDA-LIST?
 379 (defun function-arglist (function)
 380   "Describe the lambda list for the function designator FUNCTION.
 381 Works for special-operators, macros, simple functions and generic
 382 functions.  Signals error if not found"
 383   (cond ((valid-function-name-p function)
 384          (function-arglist
 385           (or (macro-function function) (fdefinition function))))
 386         ((typep function 'generic-function)
 387          (sb-pcl::generic-function-pretty-arglist function))
 388         (t (sb-impl::%simple-fun-arglist
 389             (sb-impl::%closure-fun function)))))
 390
 391 (defun struct-accessor-structure-class (function)
 392   (let ((self (sb-vm::%simple-fun-self function)))
 393     (cond
 394       ((member self (list *struct-slotplace-reader* *struct-slotplace-writer*))
 395        (find-class
 396         (sb-kernel::classoid-name
 397          (sb-kernel::layout-classoid
 398           (sb-kernel:%closure-index-ref function 1)))))
 399       )))
 400
 401 (defun struct-predicate-structure-class (function)
 402   (let ((self (sb-vm::%simple-fun-self function)))
 403     (cond
 404       ((member self (list *struct-predicate*))
 405        (find-class
 406         (sb-kernel::classoid-name
 407          (sb-kernel::layout-classoid
 408           (sb-kernel:%closure-index-ref function 0)))))
 409       )))
 410
 411 ;;;; find callers/callees, liberated from Helmut Eller's code in SLIME
 412
 413 ;;; This interface is trmendously experimental.
 414
 415 ;;; For the moment I'm taking the view that FDEFN is an internal
 416 ;;; object (one out of one CMUCL developer surveyed didn't know what
 417 ;;; they were for), so these routines deal in FUNCTIONs
 418
 419 ;;; Find callers and callees by looking at the constant pool of
 420 ;;; compiled code objects.  We assume every fdefn object in the
 421 ;;; constant pool corresponds to a call to that function.  A better
 422 ;;; strategy would be to use the disassembler to find actual
 423 ;;; call-sites.
 424
 425 (defun find-function-callees (function)
 426   "Return functions called by FUNCTION."
 427   (let ((callees '()))
 428     (map-code-constants
 429      (sb-kernel:fun-code-header function)
 430      (lambda (obj)
 431        (when (sb-kernel:fdefn-p obj)
 432          (push (sb-kernel:fdefn-fun obj)
 433                callees))))
 434     callees))
 435
 436
 437 (defun find-function-callers (function &optional (spaces '(:read-only :static
 438                                                            :dynamic)))
 439   "Return functions which call FUNCTION, by searching SPACES for code objects"
 440   (let ((referrers '()))
 441     (map-caller-code-components
 442      function
 443      spaces
 444      (lambda (code)
 445        (let ((entry (sb-kernel:%code-entry-points  code)))
 446          (cond ((not entry)
 447                 (push (princ-to-string code) referrers))
 448                (t
 449                 (loop for e = entry then (sb-kernel::%simple-fun-next e)
 450                       while e
 451                       do (pushnew e referrers)))))))
 452     referrers))
 453
 454 (declaim (inline map-code-constants))
 455 (defun map-code-constants (code fn)
 456   "Call FN for each constant in CODE's constant pool."
 457   (check-type code sb-kernel:code-component)
 458   (loop for i from sb-vm:code-constants-offset below
 459         (sb-kernel:get-header-data code)
 460         do (funcall fn (sb-kernel:code-header-ref code i))))
 461
 462 (declaim (inline map-allocated-code-components))
 463 (defun map-allocated-code-components (spaces fn)
 464   "Call FN for each allocated code component in one of SPACES.  FN
 465 receives the object and its size as arguments.  SPACES should be a
 466 list of the symbols :dynamic, :static, or :read-only."
 467   (dolist (space spaces)
 468     (sb-vm::map-allocated-objects
 469      (lambda (obj header size)
 470        (when (= sb-vm:code-header-widetag header)
 471          (funcall fn obj size)))
 472      space)))
 473
 474 (declaim (inline map-caller-code-components))
 475 (defun map-caller-code-components (function spaces fn)
 476   "Call FN for each code component with a fdefn for FUNCTION in its
 477 constant pool."
 478   (let ((function (coerce function 'function)))
 479     (map-allocated-code-components
 480      spaces
 481      (lambda (obj size)
 482        (declare (ignore size))
 483        (map-code-constants
 484         obj
 485         (lambda (constant)
 486           (when (and (sb-kernel:fdefn-p constant)
 487                      (eq (sb-kernel:fdefn-fun constant)
 488                          function))
 489             (funcall fn obj))))))))
 490
 491 (provide 'sb-introspect)