contrib/sb-posix/interface.lisp

   1 (cl:in-package :sb-posix-internal)
   2
   3 (defmacro define-protocol-class
   4     (name alien-type superclasses slots &rest options)
   5   (let ((to-protocol (intern (format nil "ALIEN-TO-~A" name)))
   6         (to-alien (intern (format nil "~A-TO-ALIEN" name))))
   7     `(progn
   8       (defclass ,name ,superclasses
   9         ,(loop for slotd in slots
  10                collect (ldiff slotd (member :array-length slotd)))
  11         ,@options)
  12       (declaim (inline ,to-alien ,to-protocol))
  13       (defun ,to-protocol (alien &optional instance)
  14         (declare (type (sb-alien:alien (* ,alien-type)) alien)
  15                  (type (or null ,name) instance))
  16         (unless instance
  17           (setf instance (make-instance ',name)))
  18         ,@(loop for slotd in slots
  19                 ;; FIXME: slotds in source are more complicated in general
  20                 ;;
  21                 ;; FIXME: baroque construction of intricate fragility
  22                 for array-length = (getf (cdr slotd) :array-length)
  23                 if array-length
  24                   collect `(progn
  25                              (let ((array (make-array ,array-length)))
  26                                (setf (slot-value instance ',(car slotd))
  27                                      array)
  28                                (dotimes (i ,array-length)
  29                                  (setf (aref array i)
  30                                        (sb-alien:deref
  31                                         (sb-alien:slot alien ',(car slotd))
  32                                         i)))))
  33                 else
  34                   collect `(setf (slot-value instance ',(car slotd))
  35                                  (sb-alien:slot alien ',(car slotd))))
  36         instance)
  37       (defun ,to-alien (instance &optional alien)
  38         (declare (type (or null (sb-alien:alien (* ,alien-type))) alien)
  39                  (type ,name instance))
  40         (unless alien
  41           (setf alien (sb-alien:make-alien ,alien-type)))
  42         ,@(loop for slotd in slots
  43                 for array-length = (getf (cdr slotd) :array-length)
  44                 if array-length
  45                   collect `(progn
  46                              (let ((array (slot-value instance ',(car slotd))))
  47                                (dotimes (i ,array-length)
  48                                  (setf (sb-alien:deref
  49                                         (sb-alien:slot alien ',(car slotd))
  50                                         i)
  51                                        (aref array i)))))
  52                 else
  53                   collect `(setf (sb-alien:slot alien ',(car slotd))
  54                                  (slot-value instance ',(car slotd)))))
  55       (find-class ',name))))
  56
  57 (define-condition sb-posix:syscall-error (error)
  58   ((errno :initarg :errno :reader sb-posix:syscall-errno))
  59   (:report (lambda (c s)
  60              (let ((errno (sb-posix:syscall-errno c)))
  61                (format s "System call error ~A (~A)"
  62                        errno (sb-int:strerror errno))))))
  63
  64 (defun syscall-error ()
  65   (error 'sb-posix:syscall-error :errno (get-errno)))
  66
  67 (declaim (inline never-fails))
  68 (defun never-fails (&rest args)
  69   (declare (ignore args))
  70   nil)
  71
  72 ;;; filesystem access
  73
  74 (define-call "access" int minusp (pathname filename) (mode int))
  75 (define-call "chdir" int minusp (pathname filename))
  76 (define-call "chmod" int minusp (pathname filename) (mode sb-posix::mode-t))
  77 (define-call "chown" int minusp (pathname filename)
  78              (owner sb-posix::uid-t)  (group sb-posix::gid-t))
  79 (define-call "chroot" int minusp (pathname filename))
  80 (define-call "close" int minusp (fd file-descriptor))
  81 (define-call "creat" int minusp (pathname filename) (mode sb-posix::mode-t))
  82 (define-call "dup" int minusp (oldfd file-descriptor))
  83 (define-call "dup2" int minusp (oldfd file-descriptor) (newfd file-descriptor))
  84 (define-call "fchdir" int minusp (fd file-descriptor))
  85 (define-call "fchmod" int minusp (fd file-descriptor) (mode sb-posix::mode-t))
  86 (define-call "fchown" int minusp (fd file-descriptor)
  87              (owner sb-posix::uid-t)  (group sb-posix::gid-t))
  88 (define-call "fdatasync" int minusp (fd file-descriptor))
  89 (define-call "ftruncate" int minusp (fd file-descriptor) (length sb-posix::off-t))
  90 (define-call "fsync" int minusp (fd file-descriptor))
  91 (define-call "lchown" int minusp (pathname filename)
  92              (owner sb-posix::uid-t)  (group sb-posix::gid-t))
  93 (define-call "link" int minusp (oldpath filename) (newpath filename))
  94 (define-call "lseek" sb-posix::off-t minusp (fd file-descriptor) (offset sb-posix::off-t) (whence int))
  95 (define-call "mkdir" int minusp (pathname filename) (mode sb-posix::mode-t))
  96 (define-call "mkfifo" int minusp (pathname filename) (mode sb-posix::mode-t))
  97 (define-call-internally open-with-mode "open" int minusp (pathname filename) (flags int) (mode sb-posix::mode-t))
  98 (define-call-internally open-without-mode "open" int minusp (pathname filename) (flags int))
  99 (define-entry-point "open" (pathname flags &optional (mode nil mode-supplied))
 100   (if mode-supplied
 101       (open-with-mode pathname flags mode)
 102       (open-without-mode pathname flags)))
 103 ;;(define-call "readlink" int minusp (path filename) (buf (* t)) (len int))
 104 (define-call "rename" int minusp (oldpath filename) (newpath filename))
 105 (define-call "rmdir" int minusp (pathname filename))
 106 (define-call "symlink" int minusp (oldpath filename) (newpath filename))
 107 (define-call "sync" void never-fails)
 108 (define-call "truncate" int minusp (pathname filename) (length sb-posix::off-t))
 109 (define-call "unlink" int minusp (pathname filename))
 110
 111 (define-call-internally ioctl-without-arg "ioctl" int minusp (fd file-descriptor) (cmd int))
 112 (define-call-internally ioctl-with-int-arg "ioctl" int minusp (fd file-descriptor) (cmd int) (arg int))
 113 (define-call-internally ioctl-with-pointer-arg "ioctl" int minusp (fd file-descriptor) (cmd int) (arg alien-pointer-to-anything-or-nil))
 114 (define-entry-point "ioctl" (fd cmd &optional (arg nil argp))
 115   (if argp
 116       (etypecase arg
 117         ((alien int) (ioctl-with-int-arg fd cmd arg))
 118         ((or (alien (* t)) null) (ioctl-with-pointer-arg fd cmd arg)))
 119       (ioctl-without-arg fd cmd)))
 120
 121 (define-call-internally fcntl-without-arg "fcntl" int minusp (fd file-descriptor) (cmd int))
 122 (define-call-internally fcntl-with-int-arg "fcntl" int minusp (fd file-descriptor) (cmd int) (arg int))
 123 (define-call-internally fcntl-with-pointer-arg "fcntl" int minusp (fd file-descriptor) (cmd int) (arg alien-pointer-to-anything-or-nil))
 124 (define-entry-point "fcntl" (fd cmd &optional (arg nil argp))
 125   (if argp
 126       (etypecase arg
 127         ((alien int) (fcntl-with-int-arg fd cmd arg))
 128         ((or (alien (* t)) null) (fcntl-with-pointer-arg fd cmd arg)))
 129       (fcntl-without-arg fd cmd)))
 130
 131 (define-call "opendir" (* t) null-alien (pathname filename))
 132 (define-call "readdir" (* sb-posix::dirent)
 133   ;; readdir() has the worst error convention in the world.  It's just
 134   ;; too painful to support.  (return is NULL _and_ errno "unchanged"
 135   ;; is not an error, it's EOF).
 136   not
 137   (dir (* t)))
 138 (define-call "closedir" int minusp (dir (* t)))
 139
 140 (define-call "umask" sb-posix::mode-t never-fails (mode sb-posix::mode-t))
 141
 142 ;;; uid, gid
 143
 144 (define-call "geteuid" sb-posix::uid-t never-fails) ; "always successful", it says
 145 (define-call "getresuid" sb-posix::uid-t never-fails)
 146 (define-call "getuid" sb-posix::uid-t never-fails)
 147 (define-call "seteuid" int minusp (uid sb-posix::uid-t))
 148 (define-call "setfsuid" int minusp (uid sb-posix::uid-t))
 149 (define-call "setreuid" int minusp
 150              (ruid sb-posix::uid-t) (euid sb-posix::uid-t))
 151 (define-call "setresuid" int minusp
 152              (ruid sb-posix::uid-t) (euid sb-posix::uid-t)
 153              (suid sb-posix::uid-t))
 154 (define-call "setuid" int minusp (uid sb-posix::uid-t))
 155
 156 (define-call "getegid" sb-posix::gid-t never-fails)
 157 (define-call "getgid" sb-posix::gid-t never-fails)
 158 (define-call "getresgid" sb-posix::gid-t never-fails)
 159 (define-call "setegid" int minusp (gid sb-posix::gid-t))
 160 (define-call "setfsgid" int minusp (gid sb-posix::gid-t))
 161 (define-call "setgid" int minusp (gid sb-posix::gid-t))
 162 (define-call "setregid" int minusp
 163              (rgid sb-posix::gid-t) (egid sb-posix::gid-t))
 164 (define-call "setresgid" int minusp
 165              (rgid sb-posix::gid-t)
 166              (egid sb-posix::gid-t) (sgid sb-posix::gid-t))
 167
 168 ;;; processes, signals
 169 (define-call "alarm" int never-fails (seconds unsigned))
 170 (define-call "fork" sb-posix::pid-t minusp)
 171 (define-call "getpgid" sb-posix::pid-t minusp (pid sb-posix::pid-t))
 172 (define-call "getpid" sb-posix::pid-t never-fails)
 173 (define-call "getppid" sb-posix::pid-t never-fails)
 174 (define-call "getpgrp" sb-posix::pid-t never-fails)
 175 (define-call "getsid" sb-posix::pid-t minusp  (pid sb-posix::pid-t))
 176 (define-call "kill" int minusp (pid sb-posix::pid-t) (signal int))
 177 (define-call "killpg" int minusp (pgrp int) (signal int))
 178 (define-call "pause" int minusp)
 179 (define-call "setpgid" int minusp
 180              (pid sb-posix::pid-t) (pgid sb-posix::pid-t))
 181 (define-call "setpgrp" int minusp)
 182
 183 (export 'sb-posix::wait :sb-posix)
 184 (declaim (inline sb-posix::wait))
 185 (defun sb-posix::wait (&optional statusptr)
 186   (declare (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 187   (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 188          (pid (alien-funcall
 189                (extern-alien "wait" (function sb-posix::pid-t (* int)))
 190                (sb-sys:vector-sap ptr))))
 191     (if (minusp pid)
 192         (syscall-error)
 193         (values pid (aref ptr 0)))))
 194
 195 (export 'sb-posix::waitpid :sb-posix)
 196 (declaim (inline sb-posix::waitpid))
 197 (defun sb-posix::waitpid (pid options &optional statusptr)
 198   (declare (type (sb-alien:alien sb-posix::pid-t) pid)
 199            (type (sb-alien:alien int) options)
 200            (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 201   (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 202          (pid (alien-funcall
 203                (extern-alien "waitpid" (function sb-posix::pid-t
 204                                                  sb-posix::pid-t (* int) int))
 205                              pid (sb-sys:vector-sap ptr) options)))
 206          (if (minusp pid)
 207              (syscall-error)
 208              (values pid (aref ptr 0)))))
 209
 210 ;; waitpid macros
 211 (define-call "wifexited" boolean never-fails (status int))
 212 (define-call "wexitstatus" int never-fails (status int))
 213 (define-call "wifsignaled" boolean never-fails (status int))
 214 (define-call "wtermsig" int never-fails (status int))
 215 (define-call "wifstopped" boolean never-fails (status int))
 216 (define-call "wstopsig" int never-fails (status int))
 217 #+nil ; see alien/waitpid-macros.c
 218 (define-call "wifcontinued" boolean never-fails (status int))
 219
 220 ;;; mmap, msync
 221 (define-call "mmap" sb-sys:system-area-pointer
 222   (lambda (res)
 223     (= (sb-sys:sap-int res) #.(1- (expt 2 sb-vm::n-machine-word-bits))))
 224   (addr sap-or-nil) (length unsigned) (prot unsigned)
 225   (flags unsigned) (fd file-descriptor) (offset sb-posix::off-t))
 226
 227 (define-call "munmap" int minusp
 228   (start sb-sys:system-area-pointer) (length unsigned))
 229
 230 (define-call "msync" int minusp
 231   (addr sb-sys:system-area-pointer) (length unsigned) (flags int))
 232
 233 (define-call "getpagesize" int minusp)
 234
 235 (define-protocol-class sb-posix::stat sb-posix::alien-stat ()
 236   ((sb-posix::mode :initarg :mode :accessor sb-posix:stat-mode)
 237    (sb-posix::ino :initarg :ino :accessor sb-posix:stat-ino)
 238    (sb-posix::dev :initarg :dev :accessor sb-posix:stat-dev)
 239    (sb-posix::nlink :initarg :nlink :accessor sb-posix:stat-nlink)
 240    (sb-posix::uid :initarg :uid :accessor sb-posix:stat-uid)
 241    (sb-posix::gid :initarg :gid :accessor sb-posix:stat-gid)
 242    (sb-posix::size :initarg :size :accessor sb-posix:stat-size)
 243    (sb-posix::atime :initarg :atime :accessor sb-posix:stat-atime)
 244    (sb-posix::mtime :initarg :mtime :accessor sb-posix:stat-mtime)
 245    (sb-posix::ctime :initarg :ctime :accessor sb-posix:stat-ctime)))
 246
 247 (defmacro define-stat-call (name arg designator-fun type)
 248   ;; FIXME: this isn't the documented way of doing this, surely?
 249   (let ((lisp-name (intern (string-upcase name) :sb-posix)))
 250     `(progn
 251       (export ',lisp-name :sb-posix)
 252       (declaim (inline ,lisp-name))
 253       (defun ,lisp-name (,arg &optional stat)
 254         (declare (type (or null (sb-alien:alien (* sb-posix::alien-stat))) stat))
 255         (sb-posix::with-alien-stat a-stat ()
 256           (let ((r (alien-funcall
 257                     (extern-alien ,name ,type)
 258                     (,designator-fun ,arg)
 259                     a-stat)))
 260             (when (minusp r)
 261               (syscall-error))
 262             (alien-to-stat a-stat stat)))))))
 263
 264 (define-stat-call "stat" pathname sb-posix::filename
 265                   (function int c-string (* sb-posix::alien-stat)))
 266 (define-stat-call "lstat" pathname sb-posix::filename
 267                   (function int c-string (* sb-posix::alien-stat)))
 268 (define-stat-call "fstat" fd sb-posix::file-descriptor
 269                   (function int int (* sb-posix::alien-stat)))
 270
 271
 272 ;;; mode flags
 273 (define-call "s_isreg" boolean never-fails (mode sb-posix::mode-t))
 274 (define-call "s_isdir" boolean never-fails (mode sb-posix::mode-t))
 275 (define-call "s_ischr" boolean never-fails (mode sb-posix::mode-t))
 276 (define-call "s_isblk" boolean never-fails (mode sb-posix::mode-t))
 277 (define-call "s_isfifo" boolean never-fails (mode sb-posix::mode-t))
 278 (define-call "s_islnk" boolean never-fails (mode sb-posix::mode-t))
 279 (define-call "s_issock" boolean never-fails (mode sb-posix::mode-t))
 280
 281 (export 'sb-posix::pipe :sb-posix)
 282 (declaim (inline sb-posix::pipe))
 283 (defun sb-posix::pipe (&optional filedes2)
 284   (declare (type (or null (simple-array (signed-byte 32) (2))) filedes2))
 285   (unless filedes2
 286     (setq filedes2 (make-array 2 :element-type '(signed-byte 32))))
 287   (let ((r (alien-funcall
 288             ;; FIXME: (* INT)?  (ARRAY INT 2) would be better
 289             (extern-alien "pipe" (function int (* int)))
 290             (sb-sys:vector-sap filedes2))))
 291     (when (minusp r)
 292       (syscall-error)))
 293   (values (aref filedes2 0) (aref filedes2 1)))
 294
 295 (define-protocol-class sb-posix::termios sb-posix::alien-termios ()
 296   ((sb-posix::iflag :initarg :iflag :accessor sb-posix:termios-iflag)
 297    (sb-posix::oflag :initarg :oflag :accessor sb-posix:termios-oflag)
 298    (sb-posix::cflag :initarg :cflag :accessor sb-posix:termios-cflag)
 299    (sb-posix::lflag :initarg :lflag :accessor sb-posix:termios-lflag)
 300    (sb-posix::cc :initarg :cc :accessor sb-posix:termios-cc :array-length sb-posix::nccs)))
 301
 302 (export 'sb-posix::tcsetattr :sb-posix)
 303 (declaim (inline sb-posix::tcsetattr))
 304 (defun sb-posix::tcsetattr (fd actions termios)
 305   (sb-posix::with-alien-termios a-termios ()
 306     (termios-to-alien termios a-termios)
 307     (let ((fd (sb-posix::file-descriptor fd)))
 308       (let* ((r (alien-funcall
 309                  (extern-alien
 310                   "tcsetattr"
 311                   (function int int int (* sb-posix::alien-termios)))
 312                  fd actions a-termios)))
 313         (when (minusp r)
 314           (syscall-error)))
 315       (values))))
 316 (export 'sb-posix::tcgetattr :sb-posix)
 317 (declaim (inline sb-posix::tcgetattr))
 318 (defun sb-posix::tcgetattr (fd &optional termios)
 319   (sb-posix::with-alien-termios a-termios ()
 320     (let ((r (alien-funcall
 321               (extern-alien "tcgetattr"
 322                             (function int int (* sb-posix::alien-termios)))
 323               (sb-posix::file-descriptor fd)
 324               a-termios)))
 325       (when (minusp r)
 326         (syscall-error))
 327       (setf termios (alien-to-termios a-termios termios))))
 328   termios)