contrib/sb-posix/interface.lisp

   1 (cl:in-package :sb-posix)
   2
   3 (defmacro define-protocol-class
   4     (name alien-type superclasses slots &rest options)
   5   (let ((to-protocol (intern (format nil "ALIEN-TO-~A" name)))
   6         (to-alien (intern (format nil "~A-TO-ALIEN" name))))
   7     `(progn
   8       (defclass ,name ,superclasses
   9         ,(loop for slotd in slots
  10                collect (ldiff slotd (member :array-length slotd)))
  11         ,@options)
  12       (declaim (inline ,to-alien ,to-protocol))
  13       (declaim (inline ,to-protocol ,to-alien))
  14       (defun ,to-protocol (alien &optional instance)
  15         (declare (type (sb-alien:alien (* ,alien-type)) alien)
  16                  (type (or null ,name) instance))
  17         (unless instance
  18           (setf instance (make-instance ',name)))
  19         ,@(loop for slotd in slots
  20                 ;; FIXME: slotds in source are more complicated in general
  21                 ;;
  22                 ;; FIXME: baroque construction of intricate fragility
  23                 for array-length = (getf (cdr slotd) :array-length)
  24                 if array-length
  25                   collect `(progn
  26                              (let ((array (make-array ,array-length)))
  27                                (setf (slot-value instance ',(car slotd))
  28                                      array)
  29                                (dotimes (i ,array-length)
  30                                  (setf (aref array i)
  31                                        (sb-alien:deref
  32                                         (sb-alien:slot alien ',(car slotd))
  33                                         i)))))
  34                 else
  35                   collect `(setf (slot-value instance ',(car slotd))
  36                                  (sb-alien:slot alien ',(car slotd))))
  37         instance)
  38       (defun ,to-alien (instance &optional alien)
  39         (declare (type (or null (sb-alien:alien (* ,alien-type))) alien)
  40                  (type ,name instance))
  41         (unless alien
  42           (setf alien (sb-alien:make-alien ,alien-type)))
  43         ,@(loop for slotd in slots
  44                 for array-length = (getf (cdr slotd) :array-length)
  45                 if array-length
  46                   collect `(progn
  47                              (let ((array (slot-value instance ',(car slotd))))
  48                                (dotimes (i ,array-length)
  49                                  (setf (sb-alien:deref
  50                                         (sb-alien:slot alien ',(car slotd))
  51                                         i)
  52                                        (aref array i)))))
  53                 else
  54                   collect `(setf (sb-alien:slot alien ',(car slotd))
  55                                  (slot-value instance ',(car slotd)))))
  56       (find-class ',name))))
  57
  58 (define-condition sb-posix:syscall-error (error)
  59   ((errno :initarg :errno :reader sb-posix:syscall-errno))
  60   (:report (lambda (c s)
  61              (let ((errno (sb-posix:syscall-errno c)))
  62                (format s "System call error ~A (~A)"
  63                        errno (sb-int:strerror errno))))))
  64
  65 (defun syscall-error ()
  66   (error 'sb-posix:syscall-error :errno (get-errno)))
  67
  68 (declaim (inline never-fails))
  69 (defun never-fails (&rest args)
  70   (declare (ignore args))
  71   nil)
  72
  73 ;;; Some systems may need C-level wrappers, which can live in the
  74 ;;; runtime (so that save-lisp-and-die can produce standalone
  75 ;;; executables).  See REAL-C-NAME in macros.lisp for the use of this
  76 ;;; variable.
  77 (eval-when (:compile-toplevel :load-toplevel)
  78   (setf *c-functions-in-runtime*
  79         '`(#+netbsd ,@("stat" "lstat" "fstat" "readdir" "opendir"))))
  80
  81
  82 ;;; filesystem access
  83 (defmacro define-call* (name &rest arguments)
  84   #-win32 `(define-call ,name ,@arguments)
  85   #+win32 `(define-call ,(if (consp name)
  86                              `(,(concatenate 'string "_" (car name))
  87                                 ,@(cdr name))
  88                              (concatenate 'string "_" name))
  89                ,@arguments))
  90
  91 (define-call* "access" int minusp (pathname filename) (mode int))
  92 (define-call* "chdir" int minusp (pathname filename))
  93 (define-call* "chmod" int minusp (pathname filename) (mode mode-t))
  94 (define-call* "close" int minusp (fd file-descriptor))
  95 (define-call* "creat" int minusp (pathname filename) (mode mode-t))
  96 (define-call* "dup" int minusp (oldfd file-descriptor))
  97 (define-call* "dup2" int minusp (oldfd file-descriptor)
  98               (newfd file-descriptor))
  99 (define-call* ("lseek" :options :largefile)
 100     off-t minusp (fd file-descriptor) (offset off-t)
 101     (whence int))
 102 (define-call* "mkdir" int minusp (pathname filename) (mode mode-t))
 103 (macrolet ((def (x)
 104                `(progn
 105                  (define-call-internally open-with-mode ,x int minusp
 106                    (pathname filename) (flags int) (mode mode-t))
 107                  (define-call-internally open-without-mode ,x int minusp
 108                    (pathname filename) (flags int))
 109                  (define-entry-point ,x
 110                      (pathname flags &optional (mode nil mode-supplied))
 111                    (if mode-supplied
 112                        (open-with-mode pathname flags mode)
 113                        (open-without-mode pathname flags))))))
 114     (def #-win32 "open" #+win32 "_open"))
 115 (define-call "rename" int minusp (oldpath filename) (newpath filename))
 116 (define-call* "rmdir" int minusp (pathname filename))
 117 (define-call* "unlink" int minusp (pathname filename))
 118 (define-call #-netbsd "opendir" #+netbsd "_opendir"
 119     (* t) null-alien (pathname filename))
 120 (define-call (#-netbsd "readdir" #+netbsd "_readdir" :options :largefile)
 121   (* dirent)
 122   ;; readdir() has the worst error convention in the world.  It's just
 123   ;; too painful to support.  (return is NULL _and_ errno "unchanged"
 124   ;; is not an error, it's EOF).
 125   not
 126   (dir (* t)))
 127 (define-call "closedir" int minusp (dir (* t)))
 128 ;; need to do this here because we can't do it in the DEFPACKAGE
 129 (define-call* "umask" mode-t never-fails (mode mode-t))
 130 (define-call* "getpid" pid-t never-fails)
 131
 132 #-win32
 133 (progn
 134   (define-call "chown" int minusp (pathname filename)
 135                (owner uid-t) (group gid-t))
 136   (define-call "chroot" int minusp (pathname filename))
 137   (define-call "fchdir" int minusp (fd file-descriptor))
 138   (define-call "fchmod" int minusp (fd file-descriptor) (mode mode-t))
 139   (define-call "fchown" int minusp (fd file-descriptor)
 140                (owner uid-t)  (group gid-t))
 141   (define-call "fdatasync" int minusp (fd file-descriptor))
 142   (define-call ("ftruncate" :options :largefile)
 143       int minusp (fd file-descriptor) (length off-t))
 144   (define-call "fsync" int minusp (fd file-descriptor))
 145   (define-call "lchown" int minusp (pathname filename)
 146                (owner uid-t)  (group gid-t))
 147   (define-call "link" int minusp (oldpath filename) (newpath filename))
 148   (define-call "mkfifo" int minusp (pathname filename) (mode mode-t))
 149   (define-call "symlink" int minusp (oldpath filename) (newpath filename))
 150   (define-call "sync" void never-fails)
 151   (define-call ("truncate" :options :largefile)
 152       int minusp (pathname filename) (length off-t))
 153   ;; FIXME: Windows does have _mktemp, which has a slightlty different
 154   ;; interface
 155   (defun mkstemp (template)
 156     ;; we are emulating sb-alien's charset conversion for strings
 157     ;; here, to accommodate for the call-by-reference nature of
 158     ;; mkstemp's template strings.
 159     (let ((arg (sb-ext:string-to-octets
 160                 (filename template)
 161                 :external-format sb-alien::*default-c-string-external-format*)))
 162       (sb-sys:with-pinned-objects (arg)
 163         (let ((result (alien-funcall (extern-alien "mkstemp"
 164                                                    (function int c-string))
 165                                      (sap-alien (sb-alien::vector-sap arg)
 166                                                 (* char)))))
 167           (when (minusp result)
 168             (syscall-error))
 169           (values result
 170                   (sb-ext:octets-to-string
 171                    arg
 172                    :external-format sb-alien::*default-c-string-external-format*))))))
 173   (define-call-internally ioctl-without-arg "ioctl" int minusp
 174                           (fd file-descriptor) (cmd int))
 175   (define-call-internally ioctl-with-int-arg "ioctl" int minusp
 176                           (fd file-descriptor) (cmd int) (arg int))
 177   (define-call-internally ioctl-with-pointer-arg "ioctl" int minusp
 178                           (fd file-descriptor) (cmd int)
 179                           (arg alien-pointer-to-anything-or-nil))
 180   (define-entry-point "ioctl" (fd cmd &optional (arg nil argp))
 181     (if argp
 182         (etypecase arg
 183           ((alien int) (ioctl-with-int-arg fd cmd arg))
 184           ((or (alien (* t)) null) (ioctl-with-pointer-arg fd cmd arg)))
 185         (ioctl-without-arg fd cmd)))
 186   (define-call-internally fcntl-without-arg "fcntl" int minusp
 187                           (fd file-descriptor) (cmd int))
 188   (define-call-internally fcntl-with-int-arg "fcntl" int minusp
 189                           (fd file-descriptor) (cmd int) (arg int))
 190   (define-call-internally fcntl-with-pointer-arg "fcntl" int minusp
 191                           (fd file-descriptor) (cmd int)
 192                           (arg alien-pointer-to-anything-or-nil))
 193   (define-entry-point "fcntl" (fd cmd &optional (arg nil argp))
 194     (if argp
 195         (etypecase arg
 196           ((alien int) (fcntl-with-int-arg fd cmd arg))
 197           ((or (alien (* t)) null) (fcntl-with-pointer-arg fd cmd arg)))
 198         (fcntl-without-arg fd cmd)))
 199
 200   ;; uid, gid
 201   (define-call "geteuid" uid-t never-fails) ; "always successful", it says
 202   (define-call "getresuid" uid-t never-fails)
 203   (define-call "getuid" uid-t never-fails)
 204   (define-call "seteuid" int minusp (uid uid-t))
 205   (define-call "setfsuid" int minusp (uid uid-t))
 206   (define-call "setreuid" int minusp (ruid uid-t) (euid uid-t))
 207   (define-call "setresuid" int minusp (ruid uid-t) (euid uid-t) (suid uid-t))
 208   (define-call "setuid" int minusp (uid uid-t))
 209   (define-call "getegid" gid-t never-fails)
 210   (define-call "getgid" gid-t never-fails)
 211   (define-call "getresgid" gid-t never-fails)
 212   (define-call "setegid" int minusp (gid gid-t))
 213   (define-call "setfsgid" int minusp (gid gid-t))
 214   (define-call "setgid" int minusp (gid gid-t))
 215   (define-call "setregid" int minusp (rgid gid-t) (egid gid-t))
 216   (define-call "setresgid" int minusp (rgid gid-t) (egid gid-t) (sgid gid-t))
 217
 218   ;; processes, signals
 219   (define-call "alarm" int never-fails (seconds unsigned))
 220
 221
 222
 223   #+mach-exception-handler
 224   (progn
 225     ;; FIXME this is a lie, of course this can fail, but there's no
 226     ;; error handling here yet!
 227     (define-call "setup_mach_exceptions" void never-fails)
 228     (define-call ("posix_fork" :c-name "fork") pid-t minusp)
 229     (defun fork ()
 230       (let ((pid (posix-fork)))
 231         (when (= pid 0)
 232           (setup-mach-exceptions))
 233         pid))
 234     (export 'fork :sb-posix))
 235
 236   #-mach-exception-handler
 237   (define-call "fork" pid-t minusp)
 238
 239   (define-call "getpgid" pid-t minusp (pid pid-t))
 240   (define-call "getppid" pid-t never-fails)
 241   (define-call "getpgrp" pid-t never-fails)
 242   (define-call "getsid" pid-t minusp  (pid pid-t))
 243   (define-call "kill" int minusp (pid pid-t) (signal int))
 244   (define-call "killpg" int minusp (pgrp int) (signal int))
 245   (define-call "pause" int minusp)
 246   (define-call "setpgid" int minusp (pid pid-t) (pgid pid-t))
 247   (define-call "setpgrp" int minusp))
 248
 249 ;;(define-call "readlink" int minusp (path filename) (buf (* t)) (len int))
 250
 251 #-win32
 252 (progn
 253  (export 'wait :sb-posix)
 254  (declaim (inline wait))
 255  (defun wait (&optional statusptr)
 256    (declare (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 257    (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 258           (pid (alien-funcall
 259                 (extern-alien "wait" (function pid-t (* int)))
 260                 (sb-sys:vector-sap ptr))))
 261      (if (minusp pid)
 262          (syscall-error)
 263          (values pid (aref ptr 0))))))
 264
 265 #-win32
 266 (progn
 267  (export 'waitpid :sb-posix)
 268  (declaim (inline waitpid))
 269  (defun waitpid (pid options &optional statusptr)
 270    (declare (type (sb-alien:alien pid-t) pid)
 271             (type (sb-alien:alien int) options)
 272             (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 273    (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 274           (pid (alien-funcall
 275                 (extern-alien "waitpid" (function pid-t
 276                                                   pid-t (* int) int))
 277                 pid (sb-sys:vector-sap ptr) options)))
 278      (if (minusp pid)
 279          (syscall-error)
 280          (values pid (aref ptr 0)))))
 281  ;; waitpid macros
 282  (define-call "wifexited" boolean never-fails (status int))
 283  (define-call "wexitstatus" int never-fails (status int))
 284  (define-call "wifsignaled" boolean never-fails (status int))
 285  (define-call "wtermsig" int never-fails (status int))
 286  (define-call "wifstopped" boolean never-fails (status int))
 287  (define-call "wstopsig" int never-fails (status int))
 288  #+nil ; see alien/waitpid-macros.c
 289  (define-call "wifcontinued" boolean never-fails (status int)))
 290
 291 ;;; mmap, msync
 292 #-win32
 293 (progn
 294  (define-call ("mmap" :options :largefile) sb-sys:system-area-pointer
 295    (lambda (res)
 296      (= (sb-sys:sap-int res) #.(1- (expt 2 sb-vm::n-machine-word-bits))))
 297    (addr sap-or-nil) (length unsigned) (prot unsigned)
 298    (flags unsigned) (fd file-descriptor) (offset off-t))
 299
 300  (define-call "munmap" int minusp
 301    (start sb-sys:system-area-pointer) (length unsigned))
 302
 303 (define-call "msync" int minusp
 304   (addr sb-sys:system-area-pointer) (length unsigned) (flags int)))
 305
 306 #-win32
 307 (define-call "getpagesize" int minusp)
 308 #+win32
 309 ;;; KLUDGE: This could be taken from GetSystemInfo
 310 (export (defun getpagesize () 4096))
 311
 312 ;;; passwd database
 313 #-win32
 314 (define-protocol-class passwd alien-passwd ()
 315   ((name :initarg :name :accessor passwd-name)
 316    (passwd :initarg :passwd :accessor passwd-passwd)
 317    (uid :initarg :uid :accessor passwd-uid)
 318    (gid :initarg :gid :accessor passwd-gid)
 319    (gecos :initarg :gecos :accessor passwd-gecos)
 320    (dir :initarg :dir :accessor passwd-dir)
 321    (shell :initarg :shell :accessor passwd-shell)))
 322
 323 (defmacro define-pw-call (name arg type)
 324   #-win32
 325   ;; FIXME: this isn't the documented way of doing this, surely?
 326   (let ((lisp-name (intern (string-upcase name) :sb-posix)))
 327     `(progn
 328       (export ',lisp-name :sb-posix)
 329       (declaim (inline ,lisp-name))
 330       (defun ,lisp-name (,arg)
 331         (let ((r (alien-funcall (extern-alien ,name ,type) ,arg)))
 332           (if (null r)
 333               r
 334               (alien-to-passwd r)))))))
 335
 336 (define-pw-call "getpwnam" login-name (function (* alien-passwd) c-string))
 337 (define-pw-call "getpwuid" uid (function (* alien-passwd) uid-t))
 338
 339 (define-protocol-class stat alien-stat ()
 340   ((mode :initarg :mode :accessor stat-mode)
 341    (ino :initarg :ino :accessor stat-ino)
 342    (dev :initarg :dev :accessor stat-dev)
 343    (nlink :initarg :nlink :accessor stat-nlink)
 344    (uid :initarg :uid :accessor stat-uid)
 345    (gid :initarg :gid :accessor stat-gid)
 346    (size :initarg :size :accessor stat-size)
 347    (atime :initarg :atime :accessor stat-atime)
 348    (mtime :initarg :mtime :accessor stat-mtime)
 349    (ctime :initarg :ctime :accessor stat-ctime)))
 350
 351 (defmacro define-stat-call (name arg designator-fun type)
 352   ;; FIXME: this isn't the documented way of doing this, surely?
 353   (let ((lisp-name (lisp-for-c-symbol name)))
 354     `(progn
 355       (export ',lisp-name :sb-posix)
 356       (declaim (inline ,lisp-name))
 357       (defun ,lisp-name (,arg &optional stat)
 358         (declare (type (or null (sb-alien:alien (* alien-stat))) stat))
 359         (with-alien-stat a-stat ()
 360           (let ((r (alien-funcall
 361                     (extern-alien ,(real-c-name (list name :options :largefile)) ,type)
 362                     (,designator-fun ,arg)
 363                     a-stat)))
 364             (when (minusp r)
 365               (syscall-error))
 366             (alien-to-stat a-stat stat)))))))
 367
 368 (define-stat-call #-win32 "stat" #+win32 "_stat"
 369                   pathname filename
 370                   (function int c-string (* alien-stat)))
 371
 372 #-win32
 373 (define-stat-call "lstat"
 374                   pathname filename
 375                   (function int c-string (* alien-stat)))
 376 ;;; No symbolic links on Windows, so use stat
 377 #+win32
 378 (progn
 379   (declaim (inline lstat))
 380   (export (defun lstat (filename &optional stat)
 381             (if stat (stat filename stat) (stat filename)))))
 382
 383 (define-stat-call #-win32 "fstat" #+win32 "_fstat"
 384                   fd file-descriptor
 385                   (function int int (* alien-stat)))
 386
 387
 388 ;;; mode flags
 389 (define-call "s_isreg" boolean never-fails (mode mode-t))
 390 (define-call "s_isdir" boolean never-fails (mode mode-t))
 391 (define-call "s_ischr" boolean never-fails (mode mode-t))
 392 (define-call "s_isblk" boolean never-fails (mode mode-t))
 393 (define-call "s_isfifo" boolean never-fails (mode mode-t))
 394 (define-call "s_islnk" boolean never-fails (mode mode-t))
 395 (define-call "s_issock" boolean never-fails (mode mode-t))
 396
 397 #-win32
 398 (progn
 399  (export 'pipe :sb-posix)
 400  (declaim (inline pipe))
 401  (defun pipe (&optional filedes2)
 402    (declare (type (or null (simple-array (signed-byte 32) (2))) filedes2))
 403    (unless filedes2
 404      (setq filedes2 (make-array 2 :element-type '(signed-byte 32))))
 405    (let ((r (alien-funcall
 406              ;; FIXME: (* INT)?  (ARRAY INT 2) would be better
 407              (extern-alien "pipe" (function int (* int)))
 408              (sb-sys:vector-sap filedes2))))
 409      (when (minusp r)
 410        (syscall-error)))
 411    (values (aref filedes2 0) (aref filedes2 1))))
 412
 413 #-win32
 414 (define-protocol-class termios alien-termios ()
 415   ((iflag :initarg :iflag :accessor sb-posix:termios-iflag)
 416    (oflag :initarg :oflag :accessor sb-posix:termios-oflag)
 417    (cflag :initarg :cflag :accessor sb-posix:termios-cflag)
 418    (lflag :initarg :lflag :accessor sb-posix:termios-lflag)
 419    (cc :initarg :cc :accessor sb-posix:termios-cc :array-length nccs)))
 420
 421 #-win32
 422 (progn
 423  (export 'tcsetattr :sb-posix)
 424  (declaim (inline tcsetattr))
 425  (defun tcsetattr (fd actions termios)
 426    (declare (type termios termios))
 427    (with-alien-termios a-termios ()
 428      (termios-to-alien termios a-termios)
 429      (let ((fd (file-descriptor fd)))
 430        (let* ((r (alien-funcall
 431                   (extern-alien
 432                    "tcsetattr"
 433                    (function int int int (* alien-termios)))
 434                   fd actions a-termios)))
 435          (when (minusp r)
 436            (syscall-error)))
 437        (values))))
 438  (export 'tcgetattr :sb-posix)
 439  (declaim (inline tcgetattr))
 440  (defun tcgetattr (fd &optional termios)
 441    (declare (type (or null termios) termios))
 442    (with-alien-termios a-termios ()
 443      (let ((r (alien-funcall
 444                (extern-alien "tcgetattr"
 445                              (function int int (* alien-termios)))
 446                (file-descriptor fd)
 447                a-termios)))
 448        (when (minusp r)
 449          (syscall-error))
 450        (setf termios (alien-to-termios a-termios termios))))
 451    termios)
 452  (export 'cfsetispeed :sb-posix)
 453  (declaim (inline cfsetispeed))
 454  (defun cfsetispeed (speed &optional termios)
 455    (declare (type (or null termios) termios))
 456    (with-alien-termios a-termios ()
 457      (let ((r (alien-funcall
 458                (extern-alien "cfsetispeed"
 459                              (function int (* alien-termios) speed-t))
 460                a-termios
 461                speed)))
 462        (when (minusp r)
 463          (syscall-error))
 464        (setf termios (alien-to-termios a-termios termios))))
 465    termios)
 466  (export 'cfsetospeed :sb-posix)
 467  (declaim (inline cfsetospeed))
 468  (defun cfsetospeed (speed &optional termios)
 469    (declare (type (or null termios) termios))
 470    (with-alien-termios a-termios ()
 471      (let ((r (alien-funcall
 472                (extern-alien "cfsetospeed"
 473                              (function int (* alien-termios) speed-t))
 474                a-termios
 475                speed)))
 476        (when (minusp r)
 477          (syscall-error))
 478        (setf termios (alien-to-termios a-termios termios))))
 479    termios)
 480  (export 'cfgetispeed :sb-posix)
 481  (declaim (inline cfgetispeed))
 482  (defun cfgetispeed (termios)
 483    (declare (type termios termios))
 484    (with-alien-termios a-termios ()
 485      (termios-to-alien termios a-termios)
 486      (alien-funcall (extern-alien "cfgetispeed"
 487                                   (function speed-t (* alien-termios)))
 488                     a-termios)))
 489  (export 'cfgetospeed :sb-posix)
 490  (declaim (inline cfgetospeed))
 491  (defun cfgetospeed (termios)
 492    (declare (type termios termios))
 493    (with-alien-termios a-termios ()
 494      (termios-to-alien termios a-termios)
 495      (alien-funcall (extern-alien "cfgetospeed"
 496                                  (function speed-t (* alien-termios)))
 497                     a-termios))))
 498
 499
 500 #-win32
 501 (progn
 502   (export 'time :sb-posix)
 503   (defun time ()
 504     (let ((result (alien-funcall (extern-alien "time"
 505                                                (function time-t (* time-t)))
 506                                  nil)))
 507       (if (minusp result)
 508           (syscall-error)
 509           result)))
 510   (export 'utime :sb-posix)
 511   (defun utime (filename &optional access-time modification-time)
 512     (let ((fun (extern-alien "utime" (function int c-string
 513                                                (* alien-utimbuf))))
 514           (name (filename filename)))
 515       (if (not (and access-time modification-time))
 516           (alien-funcall fun name nil)
 517           (with-alien ((utimbuf (struct alien-utimbuf)))
 518             (setf (slot utimbuf 'actime) (or access-time 0)
 519                   (slot utimbuf 'modtime) (or modification-time 0))
 520             (let ((result (alien-funcall fun name (alien-sap utimbuf))))
 521               (if (minusp result)
 522                   (syscall-error)
 523                   result))))))
 524   (export 'utimes :sb-posix)
 525   (defun utimes (filename &optional access-time modification-time)
 526     (flet ((seconds-and-useconds (time)
 527              (multiple-value-bind (integer fractional)
 528                  (cl:truncate time)
 529                (values integer (cl:truncate (* fractional 1000000)))))
 530            (maybe-syscall-error (value)
 531              (if (minusp value)
 532                  (syscall-error)
 533                  value)))
 534       (let ((fun (extern-alien "utimes" (function int c-string
 535                                                   (* (array alien-timeval 2)))))
 536             (name (filename filename)))
 537         (if (not (and access-time modification-time))
 538             (maybe-syscall-error (alien-funcall fun name nil))
 539             (with-alien ((buf (array alien-timeval 2)))
 540               (let ((actime (deref buf 0))
 541                     (modtime (deref buf 1)))
 542                 (setf (values (slot actime 'sec)
 543                               (slot actime 'usec))
 544                       (seconds-and-useconds (or access-time 0))
 545                       (values (slot modtime 'sec)
 546                               (slot modtime 'usec))
 547                       (seconds-and-useconds (or modification-time 0)))
 548                 (maybe-syscall-error (alien-funcall fun name
 549                                                     (alien-sap buf))))))))))
 550
 551
 552 ;;; environment
 553
 554 (export 'getenv :sb-posix)
 555 (defun getenv (name)
 556   (let ((r (alien-funcall
 557             (extern-alien "getenv" (function (* char) c-string))
 558             name)))
 559     (declare (type (alien (* char)) r))
 560     (unless (null-alien r)
 561       (cast r c-string))))
 562 (define-call "putenv" int minusp (string c-string))
 563
 564 ;;; syslog
 565 #-win32
 566 (progn
 567   (export 'openlog :sb-posix)
 568   (export 'syslog :sb-posix)
 569   (export 'closelog :sb-posix)
 570   (defun openlog (ident options &optional (facility log-user))
 571     (alien-funcall (extern-alien
 572                     "openlog" (function void c-string int int))
 573                    ident options facility))
 574   (defun syslog (priority format &rest args)
 575     "Send a message to the syslog facility, with severity level
 576 PRIORITY.  The message will be formatted as by CL:FORMAT (rather
 577 than C's printf) with format string FORMAT and arguments ARGS."
 578     (flet ((syslog1 (priority message)
 579              (alien-funcall (extern-alien
 580                              "syslog" (function void int c-string c-string))
 581                             priority "%s" message)))
 582       (syslog1 priority (apply #'format nil format args))))
 583   (define-call "closelog" void never-fails))
 584