contrib/sb-posix/macros.lisp

   1 (in-package :sb-posix-internal)
   2
   3 ;;; some explanation may be necessary.  The namestring "[foo]"
   4 ;;; denotes a wild pathname.  When there's a file on the disk whose
   5 ;;; Unix name is "[foo]", the appropriate CL namestring for it is
   6 ;;; "\\[foo]".  So, don't call NAMESTRING, instead call a function
   7 ;;; that gets us the Unix name
   8 (defun native-filename (pathname)
   9   (let ((directory (pathname-directory pathname))
  10         (name (pathname-name pathname))
  11         (type (pathname-type pathname)))
  12     (with-output-to-string (s nil :element-type 'base-char)
  13       (etypecase directory
  14         (string (write-string directory s))
  15         (list
  16          (when (eq (car directory) :absolute)
  17            (write-char #\/ s))
  18          (dolist (piece (cdr directory))
  19            (etypecase piece
  20              (string (write-string piece s) (write-char #\/ s))
  21              ((member :up) (write-string "../" s))))))
  22       (etypecase name
  23         (null)
  24         (string (write-string name s)))
  25       (etypecase type
  26         (null)
  27         (string (write-char #\. s) (write-string type s))))))
  28
  29 (define-designator filename c-string
  30   (pathname
  31    (native-filename (translate-logical-pathname filename)))
  32   (string filename))
  33
  34 (define-designator file-descriptor (integer 32)
  35   (file-stream (sb-sys:fd-stream-fd file-descriptor))
  36   (fixnum file-descriptor))
  37
  38 (define-designator sap-or-nil sb-sys:system-area-pointer
  39   (null (sb-sys:int-sap 0))
  40   (sb-sys:system-area-pointer sap-or-nil))
  41
  42 (define-designator alien-pointer-to-anything-or-nil (* t)
  43   (null (sb-alien:sap-alien (sb-sys:int-sap 0) (* t)))
  44   ((alien (* t)) alien-pointer-to-anything-or-nil))
  45
  46 (defun lisp-for-c-symbol (s)
  47   (intern (substitute #\- #\_ (string-upcase s)) :sb-posix))
  48
  49 (defmacro define-call-internally (lisp-name c-name return-type error-predicate &rest arguments)
  50   (if (sb-sys:foreign-symbol-address-as-integer-or-nil c-name)
  51       `(progn
  52         (declaim (inline ,lisp-name))
  53         (defun ,lisp-name ,(mapcar #'car arguments)
  54           (let ((r (alien-funcall
  55                     (extern-alien
  56                      ,c-name
  57                      (function ,return-type
  58                                ,@(mapcar
  59                                   (lambda (x)
  60                                     (gethash (cadr x) *designator-types* (cadr x)))
  61                                   arguments)))
  62                     ,@(mapcar (lambda (x)
  63                                 (if (nth-value 1 (gethash (cadr x) *designator-types*))
  64                                     `(,(intern (symbol-name (cadr x)) :sb-posix)
  65                                       ,(car x))
  66                                     (car x)))
  67                               arguments))))
  68             (if (,error-predicate r) (syscall-error) r))))
  69       `(sb-int:style-warn "Didn't find definition for ~S" ,c-name)))
  70
  71 (defmacro define-call (name return-type error-predicate &rest arguments)
  72   (let ((lisp-name (lisp-for-c-symbol name)))
  73     `(progn
  74        (export ',lisp-name :sb-posix)
  75        (define-call-internally ,lisp-name ,name ,return-type ,error-predicate ,@arguments))))
  76
  77 (defmacro define-entry-point (name arglist &body body)
  78   (let ((lisp-name (lisp-for-c-symbol name)))
  79     `(progn
  80       (export ',lisp-name :sb-posix)
  81       (declaim (inline ,lisp-name))
  82       (defun ,lisp-name ,arglist
  83         ,@body))))