contrib/sb-posix/macros.lisp

   1 (in-package :sb-posix-internal)
   2
   3 ;;; some explanation may be necessary.  The namestring "[foo]"
   4 ;;; denotes a wild pathname.  When there's a file on the disk whose
   5 ;;; Unix name is "[foo]", the appropriate CL namestring for it is
   6 ;;; "\\[foo]".  So, don't call NAMESTRING, instead call a function
   7 ;;; that gets us the Unix name
   8 (defun native-filename (pathname)
   9   (let ((directory (pathname-directory pathname))
  10         (name (pathname-name pathname))
  11         (type (pathname-type pathname)))
  12     (with-output-to-string (s nil :element-type 'base-char)
  13       (etypecase directory
  14         (string (write-string directory s))
  15         (list
  16          (when (eq (car directory) :absolute)
  17            (write-char #\/ s))
  18          (dolist (piece (cdr directory))
  19            (etypecase piece
  20              (string (write-string piece s) (write-char #\/ s))
  21              ((member :up) (write-string "../" s))))))
  22       (etypecase name
  23         (null)
  24         (string (write-string name s)))
  25       (etypecase type
  26         (null)
  27         (string (write-char #\. s) (write-string type s))))))
  28
  29 (define-designator filename c-string
  30   (pathname
  31    (native-filename (translate-logical-pathname filename)))
  32   (string filename))
  33
  34 (define-designator file-descriptor (integer 32)
  35   (file-stream (sb-sys:fd-stream-fd file-descriptor))
  36   (fixnum file-descriptor))
  37
  38 (define-designator sap-or-nil sb-sys:system-area-pointer
  39   (null (sb-sys:int-sap 0))
  40   (sb-sys:system-area-pointer sap-or-nil))
  41
  42 (define-designator alien-pointer-to-anything-or-nil (* t)
  43   (null (sb-alien:sap-alien (sb-sys:int-sap 0) (* t)))
  44   ((alien (* t)) alien-pointer-to-anything-or-nil))
  45
  46 (defun lisp-for-c-symbol (s)
  47   (intern (substitute #\- #\_ (string-upcase s)) :sb-posix))
  48
  49 (defmacro define-call-internally (lisp-name c-name return-type error-predicate
  50                                   &rest arguments)
  51   (if (sb-sys:foreign-symbol-address-as-integer-or-nil c-name)
  52       `(progn
  53         (declaim (inline ,lisp-name))
  54         (defun ,lisp-name ,(mapcar #'car arguments)
  55           (let ((r (alien-funcall
  56                     (extern-alien
  57                      ,c-name
  58                      (function ,return-type
  59                                ,@(mapcar
  60                                   (lambda (x)
  61                                     (gethash (cadr x)
  62                                              *designator-types*
  63                                              (cadr x)))
  64                                   arguments)))
  65                     ,@(mapcar (lambda (x)
  66                                 (if (nth-value 1
  67                                                (gethash (cadr x)
  68                                                         *designator-types*))
  69                                     `(,(intern (symbol-name (cadr x))
  70                                                :sb-posix)
  71                                       ,(car x))
  72                                     (car x)))
  73                               arguments))))
  74             (if (,error-predicate r) (syscall-error) r))))
  75       `(sb-int:style-warn "Didn't find definition for ~S" ,c-name)))
  76
  77 (defmacro define-call (name return-type error-predicate &rest arguments)
  78   (let ((lisp-name (lisp-for-c-symbol name)))
  79     `(progn
  80        (export ',lisp-name :sb-posix)
  81        (define-call-internally ,lisp-name
  82            ,name
  83          ,return-type
  84          ,error-predicate
  85          ,@arguments))))
  86
  87 (defmacro define-entry-point (name arglist &body body)
  88   (let ((lisp-name (lisp-for-c-symbol name)))
  89     `(progn
  90       (export ',lisp-name :sb-posix)
  91       (declaim (inline ,lisp-name))
  92       (defun ,lisp-name ,arglist
  93         ,@body))))