contrib/sb-posix/macros.lisp

   1 (in-package :sb-posix)
   2
   3 (define-designator filename c-string
   4   (pathname
   5    (sb-ext:native-namestring (translate-logical-pathname filename)
   6                              :as-file t))
   7   (string filename))
   8
   9 (define-designator file-descriptor (integer 32)
  10   (file-stream (sb-sys:fd-stream-fd file-descriptor))
  11   (fixnum file-descriptor))
  12
  13 (define-designator sap-or-nil sb-sys:system-area-pointer
  14   (null (sb-sys:int-sap 0))
  15   (sb-sys:system-area-pointer sap-or-nil))
  16
  17 (define-designator alien-pointer-to-anything-or-nil (* t)
  18   (null (sb-alien:sap-alien (sb-sys:int-sap 0) (* t)))
  19   ((alien (* t)) alien-pointer-to-anything-or-nil))
  20
  21 (defun lisp-for-c-symbol (name)
  22   (etypecase name
  23     (list
  24      (lisp-for-c-symbol (car name)))
  25     (string
  26      (let ((root (if (eql #\_ (char name 0)) (subseq name 1) name)))
  27        (intern (substitute #\- #\_ (string-upcase root)) :sb-posix)))))
  28
  29 ;; Note: this variable is set in interface.lisp.  defined here for
  30 ;; clarity and so the real-c-name compile as desired.
  31 (defparameter *c-functions-in-runtime* nil)
  32
  33 (defun real-c-name (name)
  34   (let  ((maybe-name
  35           (etypecase name
  36             (list
  37              (destructuring-bind (name &key c-name options) name
  38                (declare (ignorable options))
  39                (if c-name
  40                    c-name
  41                    (cond #+largefile
  42                          ((or (eql options :largefile)
  43                               (member :largefile options))
  44                           (format nil "~a_largefile" name))
  45                          (t
  46                           name)))))
  47             (string
  48              name))))
  49     (if (member maybe-name *c-functions-in-runtime*
  50                 :test #'string=)
  51         (format nil "_~A" maybe-name)
  52         maybe-name)))
  53
  54 (defmacro define-call-internally (lisp-name c-name return-type error-predicate
  55                                   &rest arguments)
  56   (if (sb-sys:find-foreign-symbol-address c-name)
  57       `(progn
  58         (declaim (inline ,lisp-name))
  59         (defun ,lisp-name ,(mapcar #'car arguments)
  60           (let ((r (alien-funcall
  61                     (extern-alien
  62                      ,c-name
  63                      (function ,return-type
  64                                ,@(mapcar
  65                                   (lambda (x)
  66                                     (gethash (cadr x)
  67                                              *designator-types*
  68                                              (cadr x)))
  69                                   arguments)))
  70                     ,@(mapcar (lambda (x)
  71                                 (if (nth-value 1
  72                                                (gethash (cadr x)
  73                                                         *designator-types*))
  74                                     `(,(intern (symbol-name (cadr x))
  75                                                :sb-posix)
  76                                       ,(car x))
  77                                     (car x)))
  78                               arguments))))
  79             (if (,error-predicate r) (syscall-error) r))))
  80       `(sb-int:style-warn "Didn't find definition for ~S" ,c-name)))
  81
  82 (defmacro define-call (name return-type error-predicate &rest arguments)
  83   (let ((lisp-name (lisp-for-c-symbol name))
  84         (real-c-name (real-c-name name)))
  85     `(progn
  86        (export ',lisp-name :sb-posix)
  87        (define-call-internally ,lisp-name
  88            ,real-c-name
  89          ,return-type
  90          ,error-predicate
  91          ,@arguments))))
  92
  93 (defmacro define-entry-point (name arglist &body body)
  94   (let ((lisp-name (lisp-for-c-symbol name)))
  95     `(progn
  96       (export ',lisp-name :sb-posix)
  97       (declaim (inline ,lisp-name))
  98       (defun ,lisp-name ,arglist
  99         ,@body))))