contrib/sb-simple-streams/impl.lisp

   1 ;;; -*- lisp -*-
   2 ;;;
   3 ;;; **********************************************************************
   4 ;;; This code was written by Paul Foley and has been placed in the public
   5 ;;; domain.
   6 ;;;
   7
   8 ;;; Sbcl port by Rudi Schlatte.
   9
  10 (in-package "SB-SIMPLE-STREAMS")
  11
  12 ;;;
  13 ;;; **********************************************************************
  14 ;;;
  15 ;;; Implementations of standard Common Lisp functions for simple-streams
  16
  17 (defun %uninitialized (stream)
  18   (error "~S has not been initialized." stream))
  19
  20 (defun %check (stream kind)
  21   (declare (type simple-stream stream)
  22            (optimize (speed 3) (space 1) (debug 0) (safety 0)))
  23   (with-stream-class (simple-stream stream)
  24     (cond ((not (any-stream-instance-flags stream :simple))
  25            (%uninitialized stream))
  26           ((and (eq kind :open)
  27                 (not (any-stream-instance-flags stream :input :output)))
  28            (sb-kernel:closed-flame stream))
  29           ((and (or (eq kind :input) (eq kind :io))
  30                 (not (any-stream-instance-flags stream :input)))
  31            (sb-kernel:ill-in stream))
  32           ((and (or (eq kind :output) (eq kind :io))
  33                 (not (any-stream-instance-flags stream :output)))
  34            (sb-kernel:ill-out stream)))))
  35
  36 (defmethod input-stream-p ((stream simple-stream))
  37   (any-stream-instance-flags stream :input))
  38
  39 (defmethod output-stream-p ((stream simple-stream))
  40   (any-stream-instance-flags stream :output))
  41
  42 (defmethod open-stream-p ((stream simple-stream))
  43   (any-stream-instance-flags stream :input :output))
  44
  45 ;;; From the simple-streams documentation: "A generic function implies
  46 ;;; a specialization capability that does not exist for
  47 ;;; simple-streams; simple-stream specializations should be on
  48 ;;; device-close."  So don't do it.
  49 (defmethod close ((stream simple-stream) &key abort)
  50   (device-close stream abort))
  51
  52 (defun %file-position (stream position)
  53   (declare (type simple-stream stream)
  54            (type (or (integer 0 *) (member nil :start :end)) position))
  55   (with-stream-class (simple-stream stream)
  56     (%check stream :open)
  57     (if position
  58         ;; Adjust current position
  59         (let ((position (case position (:start 0) (:end -1)
  60                               (otherwise position))))
  61           (etypecase stream
  62             (single-channel-simple-stream
  63              (when (sc-dirty-p stream)
  64                (flush-buffer stream t)))
  65             (dual-channel-simple-stream
  66              (with-stream-class (dual-channel-simple-stream stream)
  67                (when (> (sm outpos stream) 0)
  68                  (device-write stream :flush 0 nil t))))
  69             (string-simple-stream
  70              nil))
  71
  72           (setf (sm last-char-read-size stream) 0)
  73           (setf (sm buffpos stream) 0   ; set pointer to 0 to force a read
  74                 (sm buffer-ptr stream) 0)
  75           (setf (sm charpos stream) nil)
  76           (remove-stream-instance-flags stream :eof)
  77           (setf (device-file-position stream) position))
  78         ;; Just report current position
  79         (let ((posn (device-file-position stream)))
  80           (when posn
  81             (when (sm handler stream)
  82               (dolist (queued (sm pending stream))
  83                 (incf posn (- (the sb-int:index (third queued))
  84                               (the sb-int:index (second queued))))))
  85             (etypecase stream
  86               (single-channel-simple-stream
  87                (case (sm mode stream)
  88                  ((0 3)         ; read, read-modify
  89                   ;; Note that posn can increase here if we wrote
  90                   ;; past the end of previously-read data
  91                   (decf posn (- (sm buffer-ptr stream) (sm buffpos stream))))
  92                  (1                     ; write
  93                   (incf posn (sm buffpos stream)))))
  94               (dual-channel-simple-stream
  95                (with-stream-class (dual-channel-simple-stream stream)
  96                  (incf posn (sm outpos stream))
  97                  (when (>= (sm buffer-ptr stream) 0)
  98                    (decf posn (- (sm buffer-ptr stream) (sm buffpos stream))))))
  99               (string-simple-stream
 100                nil)))
 101           posn))))
 102
 103 (defun %file-length (stream)
 104   (declare (type simple-stream stream))
 105   (%check stream :open)
 106   (device-file-length stream))
 107
 108
 109 (defun %file-name (stream)
 110   (declare (type simple-stream stream))
 111   (%check stream nil)
 112   (typecase stream
 113     (file-simple-stream
 114      (with-stream-class (file-simple-stream stream)
 115        (sm pathname stream)))
 116     (probe-simple-stream
 117      (with-stream-class (probe-simple-stream stream)
 118        (sm pathname stream)))
 119     (otherwise
 120      nil)))
 121
 122
 123 (defun %file-rename (stream new-name)
 124   (declare (type simple-stream stream))
 125   (%check stream nil)
 126   (if (typep stream 'file-simple-stream)
 127       (with-stream-class (file-simple-stream stream)
 128         (setf (sm pathname stream) new-name)
 129         (setf (sm filename stream) (file-namestring new-name))
 130         t)
 131       nil))
 132
 133
 134 (defun %file-string-length (stream object)
 135   (declare (type simple-stream stream))
 136   (with-stream-class (simple-stream stream)
 137     (%check stream :output)
 138     ;; FIXME: need to account for compositions on the stream...
 139     (let ((count 0))
 140       (flet ((fn (octet)
 141                (declare (ignore octet))
 142                (incf count)))
 143         (etypecase object
 144           (character
 145            (let ((x nil))
 146              (char-to-octets (sm external-format stream) object x #'fn)))
 147           (string
 148            (let ((x nil)
 149                  (ef (sm external-format stream)))
 150              (dotimes (i (length object))
 151                (declare (type sb-int:index i))
 152                (char-to-octets ef (char object i) x #'fn))))))
 153       count)))
 154
 155
 156 (defun %read-line (stream eof-error-p eof-value recursive-p)
 157   (declare (optimize (speed 3) (space 1) (safety 0) (debug 0))
 158            (type simple-stream stream)
 159            (ignore recursive-p))
 160   (with-stream-class (simple-stream stream)
 161     (%check stream :input)
 162     (when (any-stream-instance-flags stream :eof)
 163       (return-from %read-line
 164         (sb-impl::eof-or-lose stream eof-error-p eof-value)))
 165     ;; for interactive streams, finish output first to force prompt
 166     (when (and (any-stream-instance-flags stream :output)
 167                (any-stream-instance-flags stream :interactive))
 168       (%finish-output stream))
 169     (let* ((encap (sm melded-stream stream)) ; encapsulating stream
 170            (cbuf (make-string 80))      ; current buffer
 171            (bufs (list cbuf))           ; list of buffers
 172            (tail bufs)                  ; last cons of bufs list
 173            (index 0)                    ; current index in current buffer
 174            (total 0))                   ; total characters
 175       (declare (type simple-stream encap)
 176                (type simple-string cbuf)
 177                (type cons bufs tail)
 178                (type sb-int:index index total))
 179       (loop
 180         (multiple-value-bind (chars done)
 181             (funcall-stm-handler j-read-chars encap cbuf
 182                                  #\Newline index (length cbuf) t)
 183           (declare (type sb-int:index chars))
 184           (incf index chars)
 185           (incf total chars)
 186           (when (and (eq done :eof) (zerop total))
 187             (if eof-error-p
 188                 (error 'end-of-file :stream stream)
 189                 (return (values eof-value t))))
 190           (when done
 191             ;; If there's only one buffer in use, return it directly
 192             (when (null (cdr bufs))
 193               (return (values (sb-kernel:shrink-vector cbuf total)
 194                               (eq done :eof))))
 195             ;; If total fits in final buffer, use it
 196             (when (<= total (length cbuf))
 197               (replace cbuf cbuf :start1 (- total index) :end2 index)
 198               (let ((idx 0))
 199                 (declare (type sb-int:index idx))
 200                 (do ((list bufs (cdr list)))
 201                     ((eq list tail))
 202                   (let ((buf (car list)))
 203                     (declare (type simple-string buf))
 204                     (replace cbuf buf :start1 idx)
 205                     (incf idx (length buf)))))
 206               (return (values (sb-kernel:shrink-vector cbuf total)
 207                               (eq done :eof))))
 208             ;; Allocate new string of appropriate length
 209             (let ((string (make-string total))
 210                   (index 0))
 211               (declare (type sb-int:index index))
 212               (dolist (buf bufs)
 213                 (declare (type simple-string buf))
 214                 (replace string buf :start1 index)
 215                 (incf index (length buf)))
 216               (return  (values string (eq done :eof)))))
 217           (when (>= index (length cbuf))
 218             (setf cbuf (make-string (the sb-int:index (* 2 index))))
 219             (setf index 0)
 220             (setf (cdr tail) (cons cbuf nil))
 221             (setf tail (cdr tail))))))))
 222
 223 (defun %read-char (stream eof-error-p eof-value recursive-p blocking-p)
 224   (declare (type simple-stream stream)
 225            (ignore recursive-p))
 226   (with-stream-class (simple-stream stream)
 227     (%check stream :input)
 228     (when (any-stream-instance-flags stream :eof)
 229       (return-from %read-char
 230         (sb-impl::eof-or-lose stream eof-error-p eof-value)))
 231     ;; for interactive streams, finish output first to force prompt
 232     (when (and (any-stream-instance-flags stream :output)
 233                (any-stream-instance-flags stream :interactive))
 234       (%finish-output stream))
 235     (funcall-stm-handler j-read-char (sm melded-stream stream)
 236                          eof-error-p eof-value blocking-p)))
 237
 238
 239 (defun %unread-char (stream character)
 240   (declare (type simple-stream stream) (ignore character))
 241   (with-stream-class (simple-stream stream)
 242     (%check stream :input)
 243     (if (zerop (sm last-char-read-size stream))
 244         (error "Nothing to unread.")
 245         (progn
 246           (funcall-stm-handler j-unread-char (sm melded-stream stream) nil)
 247           (remove-stream-instance-flags stream :eof)
 248           (setf (sm last-char-read-size stream) 0)))))
 249
 250
 251 (defun %peek-char (stream peek-type eof-error-p eof-value recursive-p)
 252   (declare (type simple-stream stream)
 253            (ignore recursive-p))
 254   (with-stream-class (simple-stream stream)
 255     (%check stream :input)
 256     (when (any-stream-instance-flags stream :eof)
 257       (return-from %peek-char
 258         (sb-impl::eof-or-lose stream eof-error-p eof-value)))
 259     (let* ((encap (sm melded-stream stream))
 260            (char (funcall-stm-handler j-read-char encap
 261                                      eof-error-p stream t)))
 262       (cond ((eq char stream) eof-value)
 263             ((characterp peek-type)
 264              (do ((char char (funcall-stm-handler j-read-char encap
 265                                                   eof-error-p
 266                                                   stream t)))
 267                  ((or (eq char stream) (char= char peek-type))
 268                   (unless (eq char stream)
 269                     (funcall-stm-handler j-unread-char encap t))
 270                   (if (eq char stream) eof-value char))))
 271             ((eq peek-type t)
 272              (do ((char char (funcall-stm-handler j-read-char encap
 273                                                   eof-error-p
 274                                                   stream t)))
 275                  ((or (eq char stream)
 276                       (not (sb-impl::whitespace[2]p char)))
 277                   (unless (eq char stream)
 278                     (funcall-stm-handler j-unread-char encap t))
 279                   (if (eq char stream) eof-value char))))
 280             (t
 281              (funcall-stm-handler j-unread-char encap t)
 282              char)))))
 283
 284 (defun %listen (stream width)
 285   (declare (type simple-stream stream))
 286   ;; WIDTH is number of octets which must be available; any value
 287   ;; other than 1 is treated as 'character.
 288   (with-stream-class (simple-stream stream)
 289     (%check stream :input)
 290     (when (any-stream-instance-flags stream :eof)
 291       (return-from %listen nil))
 292     (if (not (or (eql width 1) (null width)))
 293         (funcall-stm-handler j-listen (sm melded-stream stream))
 294         (or (< (sm buffpos stream) (sm buffer-ptr stream))
 295             ;; Attempt buffer refill
 296             (when (and (not (any-stream-instance-flags stream :dual :string))
 297                        (>= (sm mode stream) 0))
 298               ;; single-channel stream dirty -> write data before reading
 299               (flush-buffer stream nil))
 300             (>= (refill-buffer stream nil) width)))))
 301
 302 (defun %clear-input (stream buffer-only)
 303   (declare (type simple-stream stream))
 304   (with-stream-class (simple-stream stream)
 305     (%check stream :input)
 306     (setf (sm buffpos stream) 0
 307           (sm buffer-ptr stream) 0
 308           (sm last-char-read-size stream) 0
 309           #|(sm unread-past-soft-eof stream) nil|#)
 310     #| (setf (sm reread-count stream) 0)  on dual-channel streams? |#
 311     )
 312   (device-clear-input stream buffer-only))
 313
 314
 315 (defun %read-byte (stream eof-error-p eof-value)
 316   (declare (type simple-stream stream))
 317   (with-stream-class (simple-stream stream)
 318     (%check stream :input)
 319     (if (any-stream-instance-flags stream :eof)
 320         (sb-impl::eof-or-lose stream eof-error-p eof-value)
 321         (etypecase stream
 322           (single-channel-simple-stream
 323            (read-byte-internal stream eof-error-p eof-value t))
 324           (dual-channel-simple-stream
 325            (read-byte-internal stream eof-error-p eof-value t))
 326           (string-simple-stream
 327            (with-stream-class (string-simple-stream stream)
 328              (let ((encap (sm input-handle stream)))
 329                (unless encap
 330                  (error 'simple-type-error
 331                         :datum stream
 332                         :expected-type 'stream
 333                         :format-control "Can't read-byte on string streams"
 334                         :format-arguments '()))
 335                (prog1
 336                    (read-byte encap eof-error-p eof-value)
 337                  (setf (sm last-char-read-size stream) 0
 338                        (sm encapsulated-char-read-size stream) 0)))))))))
 339
 340
 341 (defun %write-char (stream character)
 342   (declare (type simple-stream stream))
 343   (with-stream-class (simple-stream stream)
 344     (%check stream :output)
 345     (funcall-stm-handler-2 j-write-char character (sm melded-stream stream))))
 346
 347
 348 (defun %fresh-line (stream)
 349   (declare (type simple-stream stream))
 350   (with-stream-class (simple-stream stream)
 351     (%check stream :output)
 352     (when (/= (or (sm charpos stream) 1) 0)
 353       (funcall-stm-handler-2 j-write-char #\Newline (sm melded-stream stream))
 354       t)))
 355
 356
 357 (defun %write-string (stream string start end)
 358   (declare (type simple-stream stream))
 359   (with-stream-class (simple-stream stream)
 360     (%check stream :output)
 361     (funcall-stm-handler-2 j-write-chars string (sm melded-stream stream)
 362                            start end)))
 363
 364
 365 (defun %line-length (stream)
 366   (declare (type simple-stream stream))
 367   (%check stream :output)
 368   ;; implement me
 369   nil)
 370
 371
 372 (defun %finish-output (stream)
 373   (declare (type simple-stream stream))
 374   (with-stream-class (simple-stream stream)
 375     (%check stream :output)
 376     (when (sm handler stream)
 377       (do ()
 378           ((null (sm pending stream)))
 379         (sb-sys:serve-all-events)))
 380     (etypecase stream
 381       (single-channel-simple-stream
 382        ;(when (and (> (sm mode stream) 0) (> (sm buffer-ptr stream) 0))
 383        ;  (setf (device-file-position stream)
 384        ;        (- (device-file-position stream) (sm buffer-ptr stream))))
 385        ;(device-write stream :flush 0 nil t)
 386        (flush-buffer stream t)
 387        (setf (sm buffpos stream) 0))
 388       (dual-channel-simple-stream
 389        (with-stream-class (dual-channel-simple-stream stream)
 390          (device-write stream :flush 0 nil t)
 391          (setf (sm outpos stream) 0)))
 392       (string-simple-stream
 393            (device-write stream :flush 0 nil t))))
 394   nil)
 395
 396
 397 (defun %force-output (stream)
 398   (declare (type simple-stream stream))
 399   (with-stream-class (simple-stream stream)
 400     (%check stream :output)
 401     (etypecase stream
 402       (single-channel-simple-stream
 403        ;(when (> (sm buffer-ptr stream) 0)
 404        ;  (setf (device-file-position stream)
 405        ;        (- (device-file-position stream) (sm buffer-ptr stream))))
 406        ;(device-write stream :flush 0 nil nil)
 407        (flush-buffer stream nil)
 408        (setf (sm buffpos stream) 0))
 409       (dual-channel-simple-stream
 410        (with-stream-class (dual-channel-simple-stream stream)
 411          (device-write stream :flush 0 nil nil)
 412          (setf (sm outpos stream) 0)))
 413       (string-simple-stream
 414        (device-write stream :flush 0 nil nil))))
 415   nil)
 416
 417
 418 (defun %clear-output (stream)
 419   (declare (type simple-stream stream))
 420   (with-stream-class (simple-stream stream)
 421     (%check stream :output)
 422     (when (sm handler stream)
 423       (sb-sys:remove-fd-handler (sm handler stream))
 424       (setf (sm handler stream) nil
 425             (sm pending stream) nil))
 426     (etypecase stream
 427       (single-channel-simple-stream
 428        (with-stream-class (single-channel-simple-stream stream)
 429          (case (sm mode stream)
 430            (1 (setf (sm buffpos stream) 0))
 431            (3 (setf (sm mode stream) 0)))))
 432       (dual-channel-simple-stream
 433        (setf (sm outpos stream) 0))
 434       (string-simple-stream
 435        nil))
 436     (device-clear-output stream)))
 437
 438
 439 (defun %write-byte (stream integer)
 440   (declare (type simple-stream stream))
 441   (with-stream-class (simple-stream stream)
 442     (%check stream :output)
 443     (etypecase stream
 444       (single-channel-simple-stream
 445        (with-stream-class (single-channel-simple-stream stream)
 446          (let ((ptr (sm buffpos stream)))
 447           (when (>= ptr (sm buf-len stream))
 448             (setf ptr (flush-buffer stream t)))
 449           (setf (sm buffpos stream) (1+ ptr))
 450           (setf (sm charpos stream) nil)
 451           (setf (bref (sm buffer stream) ptr) integer)
 452           (sc-set-dirty stream))))
 453       (dual-channel-simple-stream
 454        (with-stream-class (dual-channel-simple-stream stream)
 455          (let ((ptr (sm outpos stream)))
 456            (when (>= ptr (sm max-out-pos stream))
 457              (setf ptr (flush-out-buffer stream t)))
 458            (setf (sm outpos stream) (1+ ptr))
 459            (setf (sm charpos stream) nil)
 460            (setf (bref (sm out-buffer stream) ptr) integer))))
 461       (string-simple-stream
 462        (with-stream-class (string-simple-stream stream)
 463          (let ((encap (sm output-handle stream)))
 464            (unless encap
 465              (error 'simple-type-error
 466                     :datum stream
 467                     :expected-type 'stream
 468                     :format-control "Can't write-byte on string streams."
 469                     :format-arguments '()))
 470            (write-byte integer encap)))))))
 471
 472
 473 (defun %read-sequence (stream seq start end partial-fill)
 474   (declare (type simple-stream stream)
 475            (type sequence seq)
 476            (type sb-int:index start end)
 477            (type boolean partial-fill))
 478   (with-stream-class (simple-stream stream)
 479     (%check stream :input)
 480     (when (any-stream-instance-flags stream :eof)
 481       (return-from %read-sequence 0))
 482     (when (and (not (any-stream-instance-flags stream :dual :string))
 483                (sc-dirty-p stream))
 484       (flush-buffer stream t))
 485     (etypecase seq
 486       (string
 487        (funcall-stm-handler j-read-chars (sm melded-stream stream) seq nil
 488                             start end
 489                             (if partial-fill :bnb t)))
 490       ((or (simple-array (unsigned-byte 8) (*))
 491            (simple-array (signed-byte 8) (*)))
 492        (when (any-stream-instance-flags stream :string)
 493          (error "Can't read into byte sequence from a string stream."))
 494        ;; "read-vector" equivalent, but blocking if partial-fill is NIL
 495        ;; FIXME: this could be implemented faster via buffer-copy
 496        (loop with encap = (sm melded-stream stream)
 497             for index from start below end
 498             for byte = (read-byte-internal encap nil nil t)
 499               then (read-byte-internal encap nil nil partial-fill)
 500             while byte
 501             do (setf (bref seq index) byte)
 502             finally (return index)))
 503       ;; extend to work on other sequences: repeated read-byte
 504       )))
 505
 506 (defun %write-sequence (stream seq start end)
 507   (declare (type simple-stream stream)
 508            (type sequence seq)
 509            (type sb-int:index start end))
 510   (with-stream-class (simple-stream stream)
 511     (%check stream :output)
 512     (etypecase seq
 513       (string
 514        (funcall-stm-handler-2 j-write-chars seq (sm melded-stream stream)
 515                               start end))
 516       ((or (simple-array (unsigned-byte 8) (*))
 517            (simple-array (signed-byte 8) (*)))
 518        ;; "write-vector" equivalent
 519        (setf (sm charpos stream) nil)
 520        (etypecase stream
 521          (single-channel-simple-stream
 522           (with-stream-class (single-channel-simple-stream stream)
 523             (loop with max-ptr fixnum = (sm buf-len stream)
 524                   for src-pos fixnum = start then (+ src-pos count)
 525                   for src-rest fixnum = (- end src-pos)
 526                   while (> src-rest 0) ; FIXME: this is non-ANSI
 527                   for ptr fixnum = (let ((ptr (sm buffpos stream)))
 528                                      (if (>= ptr max-ptr)
 529                                          (flush-buffer stream t)
 530                                          ptr))
 531                   for buf-rest fixnum = (- max-ptr ptr)
 532                   for count fixnum = (min buf-rest src-rest)
 533                   do (progn (setf (sm mode stream) 1)
 534                             (setf (sm buffpos stream) (+ ptr count))
 535                             (buffer-copy seq src-pos (sm buffer stream) ptr count)))))
 536          (dual-channel-simple-stream
 537           (with-stream-class (dual-channel-simple-stream stream)
 538             (loop with max-ptr fixnum = (sm max-out-pos stream)
 539                   for src-pos fixnum = start then (+ src-pos count)
 540                   for src-rest fixnum = (- end src-pos)
 541                   while (> src-rest 0) ; FIXME: this is non-ANSI
 542                   for ptr fixnum = (let ((ptr (sm outpos stream)))
 543                                      (if (>= ptr max-ptr)
 544                                          (flush-out-buffer stream t)
 545                                          ptr))
 546                   for buf-rest fixnum = (- max-ptr ptr)
 547                   for count fixnum = (min buf-rest src-rest)
 548                   do (progn (setf (sm outpos stream) (+ ptr count))
 549                             (buffer-copy seq src-pos (sm out-buffer stream) ptr count)))))
 550          (string-simple-stream
 551           (error 'simple-type-error
 552                  :datum stream
 553                  :expected-type 'stream
 554                  :format-control "Can't write a byte sequence to a string stream."
 555                  :format-arguments '())))
 556        )
 557       ;; extend to work on other sequences: repeated write-byte
 558       ))
 559   seq)
 560
 561
 562 (defun read-vector (vector stream &key (start 0) end (endian-swap :byte-8))
 563   (declare (type (sb-kernel:simple-unboxed-array (*)) vector)
 564            (type stream stream))
 565   ;; START and END are octet offsets, not vector indices!  [Except for strings]
 566   ;; Return value is index of next octet to be read into (i.e., start+count)
 567   (etypecase stream
 568     (simple-stream
 569      (with-stream-class (simple-stream stream)
 570        (cond ((stringp vector)
 571               (let* ((start (or start 0))
 572                      (end (or end (length vector)))
 573                      (encap (sm melded-stream stream))
 574                      (char (funcall-stm-handler j-read-char encap nil nil t)))
 575                 (when char
 576                   (setf (schar vector start) char)
 577                   (incf start)
 578                   (+ start (funcall-stm-handler j-read-chars encap vector nil
 579                                                 start end nil)))))
 580              ((any-stream-instance-flags stream :string)
 581               (error "Can't READ-BYTE on string streams."))
 582              (t
 583               (do* ((encap (sm melded-stream stream))
 584                     (index (or start 0) (1+ index))
 585                     (end (or end (* (length vector) (vector-elt-width vector))))
 586                     (endian-swap (endian-swap-value vector endian-swap))
 587                     (flag t nil))
 588                    ((>= index end) index)
 589                 (let ((byte (read-byte-internal encap nil nil flag)))
 590                   (unless byte
 591                     (return index))
 592                   (setf (bref vector (logxor index endian-swap)) byte)))))))
 593     ((or ansi-stream fundamental-stream)
 594      (unless (typep vector '(or string
 595                              (simple-array (signed-byte 8) (*))
 596                              (simple-array (unsigned-byte 8) (*))))
 597        (error "Wrong vector type for read-vector on stream not of type simple-stream."))
 598      (read-sequence vector stream :start (or start 0) :end end))))
 599
 600
 601 ;;;
 602 ;;; USER-LEVEL FUNCTIONS
 603 ;;;
 604
 605 (defmethod open-stream-p ((stream simple-stream))
 606   (any-stream-instance-flags stream :input :output))
 607
 608 (defmethod input-stream-p ((stream simple-stream))
 609   (any-stream-instance-flags stream :input))
 610
 611 (defmethod output-stream-p ((stream simple-stream))
 612   (any-stream-instance-flags stream :output))
 613
 614 (defmethod stream-element-type ((stream simple-stream))
 615   '(unsigned-byte 8))
 616
 617 (defun interactive-stream-p (stream)
 618   "Return true if Stream does I/O on a terminal or other interactive device."
 619   (etypecase stream
 620     (simple-stream
 621      (%check stream :open)
 622      (any-stream-instance-flags stream :interactive))
 623     (ansi-stream
 624      (funcall (sb-kernel:ansi-stream-misc stream) stream :interactive-p))
 625     (fundamental-stream
 626      nil)))
 627
 628 (defun (setf interactive-stream-p) (flag stream)
 629   (typecase stream
 630     (simple-stream
 631      (%check stream :open)
 632      (if flag
 633          (add-stream-instance-flags stream :interactive)
 634          (remove-stream-instance-flags stream :interactive)))
 635     (t
 636      (error 'simple-type-error
 637             :datum stream
 638             :expected-type 'simple-stream
 639             :format-control "Can't set interactive flag on ~S."
 640             :format-arguments (list stream)))))
 641
 642 (defun file-string-length (stream object)
 643   (declare (type (or string character) object) (type stream stream))
 644   "Return the delta in STREAM's FILE-POSITION that would be caused by writing
 645    OBJECT to STREAM. Non-trivial only in implementations that support
 646    international character sets."
 647   (typecase stream
 648     (simple-stream (%file-string-length stream object))
 649     (t
 650      (etypecase object
 651        (character 1)
 652        (string (length object))))))
 653
 654 (defun stream-external-format (stream)
 655   "Returns Stream's external-format."
 656   (etypecase stream
 657     (simple-stream
 658      (with-stream-class (simple-stream)
 659        (%check stream :open)
 660        (sm external-format stream)))
 661     (ansi-stream
 662      :default)
 663     (fundamental-stream
 664      :default)))
 665
 666 (defun open (filename &rest options
 667              &key (direction :input)
 668              (element-type 'character element-type-given)
 669              if-exists if-does-not-exist
 670              (external-format :default)
 671              class mapped input-handle output-handle
 672              &allow-other-keys)
 673   "Return a stream which reads from or writes to Filename.
 674   Defined keywords:
 675    :direction - one of :input, :output, :io, or :probe
 676    :element-type - type of object to read or write, default BASE-CHAR
 677    :if-exists - one of :error, :new-version, :rename, :rename-and-delete,
 678                        :overwrite, :append, :supersede or NIL
 679    :if-does-not-exist - one of :error, :create or NIL
 680    :external-format - :default
 681   See the manual for details.
 682
 683   The following are simple-streams-specific additions:
 684    :class - class of stream object to be created
 685    :mapped - T to open a memory-mapped file
 686    :input-handle - a stream or Unix file descriptor to read from
 687    :output-handle - a stream or Unix file descriptor to write to"
 688   (declare (ignore element-type external-format input-handle output-handle
 689                    if-exists if-does-not-exist))
 690   (let ((class (or class 'sb-sys:fd-stream))
 691         (options (copy-list options))
 692         (filespec (merge-pathnames filename)))
 693     (cond ((eq class 'sb-sys:fd-stream)
 694            (remf options :class)
 695            (remf options :mapped)
 696            (remf options :input-handle)
 697            (remf options :output-handle)
 698            (apply #'open-fd-stream filespec options))
 699           ((subtypep class 'simple-stream)
 700            (when element-type-given
 701              (cerror "Do it anyway."
 702                      "Can't create simple-streams with an element-type."))
 703            (when (and (eq class 'file-simple-stream) mapped)
 704              (setq class 'mapped-file-simple-stream)
 705              (setf (getf options :class) 'mapped-file-simple-stream))
 706            (when (subtypep class 'file-simple-stream)
 707              (when (eq direction :probe)
 708                (setq class 'probe-simple-stream)))
 709            (apply #'make-instance class :filename filespec options))
 710           ((subtypep class 'sb-gray:fundamental-stream)
 711            (remf options :class)
 712            (remf options :mapped)
 713            (remf options :input-handle)
 714            (remf options :output-handle)
 715            (make-instance class :lisp-stream
 716                           (apply #'open-fd-stream filespec options))))))
 717
 718
 719 (declaim (inline read-byte read-char read-char-no-hang unread-char))
 720
 721 (defun read-byte (stream &optional (eof-error-p t) eof-value)
 722   "Returns the next byte of the Stream."
 723   (let ((stream (sb-impl::in-synonym-of stream)))
 724     (etypecase stream
 725       (simple-stream
 726        (%read-byte stream eof-error-p eof-value))
 727       (ansi-stream
 728        (sb-impl::ansi-stream-read-byte stream eof-error-p eof-value nil))
 729       (fundamental-stream
 730        (let ((char (sb-gray:stream-read-byte stream)))
 731          (if (eq char :eof)
 732              (sb-impl::eof-or-lose stream eof-error-p eof-value)
 733              char))))))
 734
 735 (defun read-char (&optional (stream *standard-input*) (eof-error-p t)
 736                             eof-value recursive-p)
 737   "Inputs a character from Stream and returns it."
 738   (let ((stream (sb-impl::in-synonym-of stream)))
 739     (etypecase stream
 740       (simple-stream
 741        (%read-char stream eof-error-p eof-value recursive-p t))
 742       (ansi-stream
 743        (sb-impl::ansi-stream-read-char stream eof-error-p eof-value
 744                                        recursive-p))
 745       (fundamental-stream
 746        (let ((char (sb-gray:stream-read-char stream)))
 747          (if (eq char :eof)
 748              (sb-impl::eof-or-lose stream eof-error-p eof-value)
 749              char))))))
 750
 751 (defun read-char-no-hang (&optional (stream *standard-input*) (eof-error-p t)
 752                                     eof-value recursive-p)
 753   "Returns the next character from the Stream if one is availible, or nil."
 754   (let ((stream (sb-impl::in-synonym-of stream)))
 755     (etypecase stream
 756       (simple-stream
 757        (%check stream :input)
 758        (with-stream-class (simple-stream)
 759          (funcall-stm-handler j-read-char stream eof-error-p eof-value nil)))
 760       (ansi-stream
 761        (sb-impl::ansi-stream-read-char-no-hang stream eof-error-p eof-value
 762                                                recursive-p))
 763       (fundamental-stream
 764        (let ((char (sb-gray:stream-read-char-no-hang stream)))
 765          (if (eq char :eof)
 766              (sb-impl::eof-or-lose stream eof-error-p eof-value)
 767              char))))))
 768
 769 (defun unread-char (character &optional (stream *standard-input*))
 770   "Puts the Character back on the front of the input Stream."
 771   (let ((stream (sb-impl::in-synonym-of stream)))
 772     (etypecase stream
 773       (simple-stream
 774        (%unread-char stream character))
 775       (ansi-stream
 776        (sb-impl::ansi-stream-unread-char character stream))
 777       (fundamental-stream
 778        (sb-gray:stream-unread-char stream character))))
 779   nil)
 780
 781 (declaim (notinline read-byte read-char read-char-no-hang unread-char))
 782
 783 (defun peek-char (&optional (peek-type nil) (stream *standard-input*)
 784                             (eof-error-p t) eof-value recursive-p)
 785   "Peeks at the next character in the input Stream.  See manual for details."
 786   (let ((stream (sb-impl::in-synonym-of stream)))
 787     (etypecase stream
 788       (simple-stream
 789        (%peek-char stream peek-type eof-error-p eof-value recursive-p))
 790       ;; FIXME: Broken on ECHO-STREAM (cf internal implementation?) --
 791       ;; CSR, 2004-01-19
 792       (ansi-stream
 793        (sb-impl::ansi-stream-peek-char peek-type stream eof-error-p eof-value
 794                                        recursive-p))
 795       (fundamental-stream
 796        (cond ((characterp peek-type)
 797               (do ((char (sb-gray:stream-read-char stream)
 798                          (sb-gray:stream-read-char stream)))
 799                   ((or (eq char :eof) (char= char peek-type))
 800                    (cond ((eq char :eof)
 801                           (sb-impl::eof-or-lose stream eof-error-p eof-value))
 802                          (t
 803                           (sb-gray:stream-unread-char stream char)
 804                           char)))))
 805              ((eq peek-type t)
 806               (do ((char (sb-gray:stream-read-char stream)
 807                          (sb-gray:stream-read-char stream)))
 808                   ((or (eq char :eof) (not (sb-impl::whitespace[2]p char)))
 809                    (cond ((eq char :eof)
 810                           (sb-impl::eof-or-lose stream eof-error-p eof-value))
 811                          (t
 812                           (sb-gray:stream-unread-char stream char)
 813                           char)))))
 814              (t
 815               (let ((char (sb-gray:stream-peek-char stream)))
 816                 (if (eq char :eof)
 817                     (sb-impl::eof-or-lose stream eof-error-p eof-value)
 818                     char))))))))
 819
 820 (defun listen (&optional (stream *standard-input*) (width 1))
 821   "Returns T if WIDTH octets are available on STREAM.  If WIDTH is
 822 given as 'CHARACTER, check for a character.  Note: the WIDTH argument
 823 is supported only on simple-streams."
 824   ;; WIDTH is number of octets which must be available; any value
 825   ;; other than 1 is treated as 'character.
 826   (let ((stream (sb-impl::in-synonym-of stream)))
 827     (etypecase stream
 828       (simple-stream
 829        (%listen stream width))
 830       (ansi-stream
 831        (sb-impl::ansi-stream-listen stream))
 832       (fundamental-stream
 833        (sb-gray:stream-listen stream)))))
 834
 835
 836 (defun read-line (&optional (stream *standard-input*) (eof-error-p t)
 837                             eof-value recursive-p)
 838   "Returns a line of text read from the Stream as a string, discarding the
 839   newline character."
 840   (let ((stream (sb-impl::in-synonym-of stream)))
 841     (etypecase stream
 842       (simple-stream
 843        (%read-line stream eof-error-p eof-value recursive-p))
 844       (ansi-stream
 845        (sb-impl::ansi-stream-read-line stream eof-error-p eof-value
 846                                        recursive-p))
 847       (fundamental-stream
 848        (multiple-value-bind (string eof) (sb-gray:stream-read-line stream)
 849          (if (and eof (zerop (length string)))
 850              (values (sb-impl::eof-or-lose stream eof-error-p eof-value) t)
 851              (values string eof)))))))
 852
 853 (defun read-sequence (seq stream &key (start 0) (end nil) partial-fill)
 854   "Destructively modify SEQ by reading elements from STREAM.
 855   SEQ is bounded by START and END. SEQ is destructively modified by
 856   copying successive elements into it from STREAM. If the end of file
 857   for STREAM is reached before copying all elements of the subsequence,
 858   then the extra elements near the end of sequence are not updated, and
 859   the index of the next element is returned."
 860   (let ((stream (sb-impl::in-synonym-of stream))
 861         (end (or end (length seq))))
 862     (etypecase stream
 863       (simple-stream
 864        (with-stream-class (simple-stream stream)
 865          (%read-sequence stream seq start end partial-fill)))
 866       (ansi-stream
 867        (sb-impl::ansi-stream-read-sequence seq stream start end))
 868       (fundamental-stream
 869        (sb-gray:stream-read-sequence stream seq start end)))))
 870
 871 (defun clear-input (&optional (stream *standard-input*) buffer-only)
 872   "Clears any buffered input associated with the Stream."
 873   (let ((stream (sb-impl::in-synonym-of stream)))
 874     (etypecase stream
 875       (simple-stream
 876        (%clear-input stream buffer-only))
 877       (ansi-stream
 878        (sb-impl::ansi-stream-clear-input stream))
 879       (fundamental-stream
 880        (sb-gray:stream-clear-input stream))))
 881   nil)
 882
 883 (defun write-byte (integer stream)
 884   "Outputs an octet to the Stream."
 885   (let ((stream (sb-impl::out-synonym-of stream)))
 886     (etypecase stream
 887       (simple-stream
 888        (%write-byte stream integer))
 889       (ansi-stream
 890        (funcall (sb-kernel:ansi-stream-bout stream) stream integer))
 891       (fundamental-stream
 892        (sb-gray:stream-write-byte stream integer))))
 893   integer)
 894
 895 (defun write-char (character &optional (stream *standard-output*))
 896   "Outputs the Character to the Stream."
 897   (let ((stream (sb-impl::out-synonym-of stream)))
 898     (etypecase stream
 899       (simple-stream
 900        (%write-char stream character))
 901       (ansi-stream
 902        (funcall (sb-kernel:ansi-stream-out stream) stream character))
 903       (fundamental-stream
 904        (sb-gray:stream-write-char stream character))))
 905   character)
 906
 907 (defun write-string (string &optional (stream *standard-output*)
 908                             &key (start 0) (end nil))
 909   "Outputs the String to the given Stream."
 910   (let ((stream (sb-impl::out-synonym-of stream))
 911         (end (sb-impl::%check-vector-sequence-bounds string start end)))
 912     (etypecase stream
 913       (simple-stream
 914        (%write-string stream string start end)
 915        string)
 916       (ansi-stream
 917        (sb-impl::ansi-stream-write-string string stream start end))
 918       (fundamental-stream
 919        (sb-gray:stream-write-string stream string start end)))))
 920
 921 (defun write-line (string &optional (stream *standard-output*)
 922                           &key (start 0) end)
 923   (declare (type string string))
 924   (let ((stream (sb-impl::out-synonym-of stream))
 925         (end (sb-impl::%check-vector-sequence-bounds string start end)))
 926     (etypecase stream
 927       (simple-stream
 928        (%check stream :output)
 929        (with-stream-class (simple-stream stream)
 930          (funcall-stm-handler-2 j-write-chars string stream start end)
 931          (funcall-stm-handler-2 j-write-char #\Newline stream)))
 932       (ansi-stream
 933        (sb-impl::ansi-stream-write-string string stream start end)
 934        (funcall (sb-kernel:ansi-stream-out stream) stream #\Newline))
 935       (fundamental-stream
 936        (sb-gray:stream-write-string stream string start end)
 937        (sb-gray:stream-terpri stream))))
 938   string)
 939
 940 (defun write-sequence (seq stream &key (start 0) (end nil))
 941   "Write the elements of SEQ bounded by START and END to STREAM."
 942   (let ((stream (sb-impl::out-synonym-of stream))
 943         (end (or end (length seq))))
 944     (etypecase stream
 945       (simple-stream
 946        (%write-sequence stream seq start end))
 947       (ansi-stream
 948        (sb-impl::ansi-stream-write-sequence seq stream start end))
 949       (fundamental-stream
 950        (sb-gray:stream-write-sequence stream seq start end)))))
 951
 952 (defun terpri (&optional (stream *standard-output*))
 953   "Outputs a new line to the Stream."
 954   (let ((stream (sb-impl::out-synonym-of stream)))
 955     (etypecase stream
 956       (simple-stream
 957        (%check stream :output)
 958        (with-stream-class (simple-stream stream)
 959          (funcall-stm-handler-2 j-write-char #\Newline stream)))
 960       (ansi-stream
 961        (funcall (sb-kernel:ansi-stream-out stream) stream #\Newline))
 962       (fundamental-stream
 963        (sb-gray:stream-terpri stream))))
 964   nil)
 965
 966 (defun fresh-line (&optional (stream *standard-output*))
 967   "Outputs a new line to the Stream if it is not positioned at the beginning of
 968    a line.  Returns T if it output a new line, nil otherwise."
 969   (let ((stream (sb-impl::out-synonym-of stream)))
 970     (etypecase stream
 971       (simple-stream
 972        (%fresh-line stream))
 973       (ansi-stream
 974        (sb-impl::ansi-stream-fresh-line stream))
 975       (fundamental-stream
 976        (sb-gray:stream-fresh-line stream)))))
 977
 978 (defun finish-output (&optional (stream *standard-output*))
 979   "Attempts to ensure that all output sent to the Stream has reached its
 980    destination, and only then returns."
 981   (let ((stream (sb-impl::out-synonym-of stream)))
 982     (etypecase stream
 983       (simple-stream
 984        (%finish-output stream))
 985       (ansi-stream
 986        (funcall (sb-kernel:ansi-stream-misc stream) stream :finish-output))
 987       (fundamental-stream
 988        (sb-gray:stream-finish-output stream))))
 989   nil)
 990
 991 (defun force-output (&optional (stream *standard-output*))
 992   "Attempts to force any buffered output to be sent."
 993   (let ((stream (sb-impl::out-synonym-of stream)))
 994     (etypecase stream
 995       (simple-stream
 996        (%force-output stream))
 997       (ansi-stream
 998        (funcall (sb-kernel:ansi-stream-misc stream) stream :force-output))
 999       (fundamental-stream
1000        (sb-gray:stream-force-output stream))))
1001   nil)
1002
1003 (defun clear-output (&optional (stream *standard-output*))
1004   "Clears the given output Stream."
1005   (let ((stream (sb-impl::out-synonym-of stream)))
1006     (etypecase stream
1007       (simple-stream
1008        (%clear-output stream))
1009       (ansi-stream
1010        (funcall (sb-kernel:ansi-stream-misc stream) stream :clear-output))
1011       (fundamental-stream
1012        (sb-gray:stream-clear-output stream))))
1013   nil)
1014
1015
1016 (defun file-position (stream &optional position)
1017   "With one argument returns the current position within the file
1018    File-Stream is open to.  If the second argument is supplied, then
1019    this becomes the new file position.  The second argument may also
1020    be :start or :end for the start and end of the file, respectively."
1021   (declare (type (or sb-int:index (member nil :start :end)) position))
1022   (etypecase stream
1023     (simple-stream
1024      (%file-position stream position))
1025     (ansi-stream
1026      (sb-impl::ansi-stream-file-position stream position))))
1027
1028 (defun file-length (stream)
1029   "This function returns the length of the file that File-Stream is open to."
1030   (etypecase stream
1031     (simple-stream
1032      (%file-length stream))
1033     (ansi-stream
1034      (sb-impl::stream-must-be-associated-with-file stream)
1035      (funcall (sb-kernel:ansi-stream-misc stream) stream :file-length))))
1036
1037 (defun charpos (&optional (stream *standard-output*))
1038   "Returns the number of characters on the current line of output of the given
1039   Stream, or Nil if that information is not availible."
1040   (let ((stream (sb-impl::out-synonym-of stream)))
1041     (etypecase stream
1042       (simple-stream
1043        (with-stream-class (simple-stream stream)
1044          (%check stream :open)
1045          (sm charpos stream)))
1046       (ansi-stream
1047        (funcall (sb-kernel:ansi-stream-misc stream) stream :charpos))
1048       (fundamental-stream
1049        (sb-gray:stream-line-column stream)))))
1050
1051 (defun line-length (&optional (stream *standard-output*))
1052   "Returns the number of characters in a line of output of the given
1053   Stream, or Nil if that information is not availible."
1054   (let ((stream (sb-impl::out-synonym-of stream)))
1055     (etypecase stream
1056       (simple-stream
1057        (%check stream :output)
1058        ;; TODO (sat 2003-04-02): a way to specify a line length would
1059        ;; be good, I suppose.  Returning nil here means
1060        ;; sb-pretty::default-line-length is used.
1061        nil)
1062       (ansi-stream
1063        (funcall (sb-kernel:ansi-stream-misc stream) stream :line-length))
1064       (fundamental-stream
1065        (sb-gray:stream-line-length stream)))))
1066
1067 (defun wait-for-input-available (stream &optional timeout)
1068   "Waits for input to become available on the Stream and returns T.  If
1069   Timeout expires, Nil is returned."
1070   (let ((stream (sb-impl::in-synonym-of stream)))
1071     (etypecase stream
1072       (fixnum
1073        (sb-sys:wait-until-fd-usable stream :input timeout))
1074       (simple-stream
1075        (%check stream :input)
1076        (with-stream-class (simple-stream stream)
1077          (or (< (sm buffpos stream) (sm buffer-ptr stream))
1078              (wait-for-input-available (sm input-handle stream) timeout))))
1079       (two-way-stream
1080        (wait-for-input-available (two-way-stream-input-stream stream) timeout))
1081       (synonym-stream
1082        (wait-for-input-available (symbol-value (synonym-stream-symbol stream))
1083                                  timeout))
1084       (sb-sys:fd-stream
1085        (or (< (sb-impl::fd-stream-in-index stream)
1086               (length (sb-impl::fd-stream-in-buffer stream)))
1087            (wait-for-input-available (sb-sys:fd-stream-fd stream) timeout))))))
1088
1089 ;; Make PATHNAME and NAMESTRING work
1090 (defun sb-int:file-name (stream &optional new-name)
1091   (typecase stream
1092     (file-simple-stream
1093      (with-stream-class (file-simple-stream stream)
1094        (cond (new-name
1095               (%file-rename stream new-name))
1096              (t
1097               (%file-name stream)))))
1098     (sb-sys:fd-stream
1099      (cond (new-name
1100             (setf (sb-impl::fd-stream-pathname stream) new-name)
1101             (setf (sb-impl::fd-stream-file stream)
1102                   (file-namestring new-name))
1103             t)
1104            (t
1105             (sb-impl::fd-stream-pathname stream))))))