contrib/sb-simple-streams/internal.lisp

   1 ;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Package: STREAM -*-
   2
   3 ;;; **********************************************************************
   4 ;;; This code was written by Paul Foley and has been placed in the public
   5 ;;; domain.
   6 ;;;
   7
   8 ;;; Sbcl port by Rudi Schlatte.
   9
  10 (in-package "SB-SIMPLE-STREAMS")
  11
  12 ;;;
  13 ;;; **********************************************************************
  14 ;;;
  15 ;;; Various functions needed by simple-streams
  16 (declaim (inline buffer-sap bref (setf bref) buffer-copy
  17                  allocate-buffer free-buffer))
  18
  19 (defun buffer-sap (thing &optional offset)
  20   (declare (type simple-stream-buffer thing) (type (or fixnum null) offset)
  21            (optimize (speed 3) (space 2) (debug 0) (safety 0)
  22                      ;; Suppress the note about having to box up the return:
  23                      (sb-ext:inhibit-warnings 3)))
  24   (let ((sap (if (vectorp thing) (sb-sys:vector-sap thing) thing)))
  25     (if offset (sb-sys:sap+ sap offset) sap)))
  26
  27 (defun bref (buffer index)
  28   (declare (type simple-stream-buffer buffer)
  29            (type (integer 0 #.most-positive-fixnum) index))
  30   (if (vectorp buffer)
  31       (sb-sys:with-pinned-objects (buffer)
  32         (sb-sys:sap-ref-8 (sb-sys:vector-sap buffer) index))
  33       (sb-sys:sap-ref-8 buffer index)))
  34
  35 (defun (setf bref) (octet buffer index)
  36   (declare (type (unsigned-byte 8) octet)
  37            (type simple-stream-buffer buffer)
  38            (type (integer 0 #.most-positive-fixnum) index))
  39   (if (vectorp buffer)
  40       (sb-sys:with-pinned-objects (buffer)
  41         (setf (sb-sys:sap-ref-8 (sb-sys:vector-sap buffer) index) octet))
  42       (setf (sb-sys:sap-ref-8 buffer index) octet)))
  43
  44 (defun buffer-copy (src soff dst doff length)
  45   (declare (type simple-stream-buffer src dst)
  46            (type fixnum soff doff length))
  47   ;; FIXME: Should probably be with-pinned-objects
  48   (sb-sys:without-gcing
  49    (sb-kernel:system-area-ub8-copy (buffer-sap src) soff
  50                                    (buffer-sap dst) doff
  51                                    length)))
  52
  53 (defun allocate-buffer (size)
  54   (make-array size :element-type '(unsigned-byte 8)))
  55
  56 (defun free-buffer (buffer)
  57   (sb-int:aver (typep buffer '(simple-array (unsigned-byte 8) (*))))
  58   t)
  59
  60 (defun make-control-table (&rest inits)
  61   (let ((table (make-array 32 :initial-element nil)))
  62     (do* ((char (pop inits) (pop inits))
  63           (func (pop inits) (pop inits)))
  64          ((null char))
  65       (when (< (char-code char) 32)
  66         (setf (aref table (char-code char)) func)))
  67     table))
  68
  69 (defun std-newline-out-handler (stream character)
  70   (declare (ignore character))
  71   (with-stream-class (simple-stream stream)
  72     (setf (sm charpos stream) -1)
  73     nil))
  74
  75 (defun std-tab-out-handler (stream character)
  76   (declare (ignore character))
  77   (with-stream-class (simple-stream stream)
  78     (let ((col (sm charpos stream)))
  79       (when col
  80         (setf (sm charpos stream) (1- (* 8 (1+ (floor col 8)))))))
  81     nil))
  82
  83 (defun std-dc-newline-in-handler (stream character)
  84   (with-stream-class (dual-channel-simple-stream stream)
  85     ;; FIXME: Currently, -1 is wrong, since callers of CHARPOS expect
  86     ;; a result in (or null (and fixnum unsigned-byte)), so they must
  87     ;; never see this temporary value.  Note that in
  88     ;; STD-NEWLINE-OUT-HANDLER it is correct to use -1, since CHARPOS
  89     ;; is incremented to zero before WRITE-CHAR returns.  Perhaps the
  90     ;; same should happen for input?
  91     (setf (sm charpos stream) 0) ; was -1
  92     character))
  93
  94 (defvar *std-control-out-table*
  95   (make-control-table #\Newline #'std-newline-out-handler
  96                       #\Tab     #'std-tab-out-handler))
  97
  98 (defvar *default-external-format* :iso8859-1)
  99
 100 (defvar *external-formats* (make-hash-table))
 101 (defvar *external-format-aliases* (make-hash-table))
 102
 103 (defstruct (external-format
 104              (:conc-name ef-)
 105              (:print-function %print-external-format)
 106              (:constructor make-external-format (name octets-to-char
 107                                                       char-to-octets)))
 108   (name (sb-int:missing-arg) :type keyword :read-only t)
 109   (octets-to-char (sb-int:missing-arg) :type function :read-only t)
 110   (char-to-octets (sb-int:missing-arg) :type function :read-only t))
 111
 112 (defun %print-external-format (ef stream depth)
 113   (declare (ignore depth))
 114   (print-unreadable-object (ef stream :type t :identity t)
 115     (princ (ef-name ef) stream)))
 116
 117 (defmacro define-external-format (name octets-to-char char-to-octets)
 118   `(macrolet ((octets-to-char ((state input unput) &body body)
 119                 `(lambda (,state ,input ,unput)
 120                    (declare (type (function () (unsigned-byte 8)) ,input)
 121                             (type (function (sb-int:index) t) ,unput)
 122                             (ignorable ,state ,input ,unput)
 123                             (values character sb-int:index t))
 124                    ,@body))
 125               (char-to-octets ((char state output) &body body)
 126                 `(lambda (,char ,state ,output)
 127                    (declare (type character ,char)
 128                             (type (function ((unsigned-byte 8)) t) ,output)
 129                             (ignorable state ,output)
 130                             (values t))
 131                    ,@body)))
 132      (setf (gethash ,name *external-formats*)
 133            (make-external-format ,name ,octets-to-char ,char-to-octets))))
 134
 135 ;;; TODO: make this work
 136 (defun load-external-format-aliases ()
 137   (let ((*package* (find-package "KEYWORD")))
 138     (with-open-file (stm "ef:aliases" :if-does-not-exist nil)
 139       (when stm
 140         (do ((alias (read stm nil stm) (read stm nil stm))
 141              (value (read stm nil stm) (read stm nil stm)))
 142             ((or (eq alias stm) (eq value stm))
 143              (unless (eq alias stm)
 144                (warn "External-format aliases file ends early.")))
 145           (if (and (keywordp alias) (keywordp value))
 146               (setf (gethash alias *external-format-aliases*) value)
 147               (warn "Bad entry in external-format aliases file: ~S => ~S."
 148                     alias value)))))))
 149
 150 (defun find-external-format (name &optional (error-p t))
 151   (when (external-format-p name)
 152     (return-from find-external-format name))
 153
 154   (when (eq name :default)
 155     (setq name *default-external-format*))
 156
 157   ;; TODO: make this work
 158   #+nil
 159   (unless (ext:search-list-defined-p "ef:")
 160     (setf (ext:search-list "ef:") '("library:ef/")))
 161
 162   (when (zerop (hash-table-count *external-format-aliases*))
 163     (setf (gethash :latin1 *external-format-aliases*) :iso8859-1)
 164     (setf (gethash :latin-1 *external-format-aliases*) :iso8859-1)
 165     (setf (gethash :iso-8859-1 *external-format-aliases*) :iso8859-1)
 166     (load-external-format-aliases))
 167
 168   (do ((tmp (gethash name *external-format-aliases*)
 169             (gethash tmp *external-format-aliases*))
 170        (cnt 0 (1+ cnt)))
 171       ((or (null tmp) (= cnt 50))
 172        (unless (null tmp)
 173          (error "External-format aliasing depth exceeded.")))
 174     (setq name tmp))
 175
 176   (or (gethash name *external-formats*)
 177       (and (let ((*package* (find-package "SB-SIMPLE-STREAMS")))
 178              (load (format nil "ef:~(~A~)" name) :if-does-not-exist nil))
 179            (gethash name *external-formats*))
 180       (if error-p (error "External format ~S not found." name) nil)))
 181
 182 (define-condition void-external-format (error)
 183   ()
 184   (:report
 185     (lambda (condition stream)
 186       (declare (ignore condition))
 187       (format stream "Attempting I/O through void external-format."))))
 188
 189 (define-external-format :void
 190     (octets-to-char (state input unput)
 191       (declare (ignore state input unput))
 192       (error 'void-external-format))
 193   (char-to-octets (char state output)
 194     (declare (ignore char state output))
 195     (error 'void-external-format)))
 196
 197 (define-external-format :iso8859-1
 198     (octets-to-char (state input unput)
 199       (declare (optimize (speed 3) (space 0) (safety 0) (debug 0)))
 200       (values (code-char (funcall input)) 1 state))
 201   (char-to-octets (char state output)
 202     (declare (optimize (speed 3) (space 0) (safety 0) (debug 0)))
 203     (let ((code (char-code char)))
 204       #-(or)
 205       (funcall output code)
 206       #+(or)
 207       (if (< code 256)
 208           (funcall output code)
 209           (funcall output (char-code #\?))))
 210     state))
 211
 212 (defmacro octets-to-char (external-format state count input unput)
 213   (let ((tmp1 (gensym)) (tmp2 (gensym)) (tmp3 (gensym)))
 214     `(multiple-value-bind (,tmp1 ,tmp2 ,tmp3)
 215          (funcall (ef-octets-to-char ,external-format) ,state ,input ,unput)
 216        (setf ,state ,tmp3 ,count ,tmp2)
 217        ,tmp1)))
 218
 219 (defmacro char-to-octets (external-format char state output)
 220   `(progn
 221      (setf ,state (funcall (ef-char-to-octets ,external-format)
 222                            ,char ,state ,output))
 223      nil))
 224
 225 (defun string-to-octets (string &key (start 0) end (external-format :default))
 226   (declare (type string string)
 227            (type sb-int:index start)
 228            (type (or null sb-int:index) end))
 229   (let ((ef (find-external-format external-format))
 230         (buffer (make-array (length string) :element-type '(unsigned-byte 8)))
 231         (ptr 0)
 232         (state nil))
 233     (flet ((out (b)
 234              (setf (aref buffer ptr) b)
 235              (when (= (incf ptr) (length buffer))
 236                (setq buffer (adjust-array buffer (* 2 ptr))))))
 237       (dotimes (i (- (or end (length string)) start))
 238         (declare (type sb-int:index i))
 239         (char-to-octets ef (char string (+ start i)) state #'out))
 240       (sb-kernel:shrink-vector buffer ptr))))
 241
 242 (defun octets-to-string (octets &key (start 0) end (external-format :default))
 243   (declare (type vector octets)
 244            (type sb-int:index start)
 245            (type (or null sb-int:index) end))
 246   (let ((ef (find-external-format external-format))
 247         (end (1- (or end (length octets))))
 248         (string (make-string (length octets)))
 249         (ptr (1- start))
 250         (pos -1)
 251         (count 0)
 252         (state nil))
 253     (flet ((input ()
 254              (aref octets (incf ptr)))
 255            (unput (n)
 256              (decf ptr n)))
 257       (loop until (>= ptr end)
 258             do (setf (schar string (incf pos))
 259                  (octets-to-char ef state count #'input #'unput))))
 260     (sb-kernel:shrink-vector string (1+ pos))))
 261
 262 (defun vector-elt-width (vector)
 263   ;; Return octet-width of vector elements
 264   (etypecase vector
 265     ;; (simple-array fixnum (*)) not supported
 266     ;; (simple-array base-char (*)) treated specially; don't call this
 267     ((simple-array bit (*)) 1)
 268     ((simple-array (unsigned-byte 2) (*)) 1)
 269     ((simple-array (unsigned-byte 4) (*)) 1)
 270     ((simple-array (signed-byte 8) (*)) 1)
 271     ((simple-array (unsigned-byte 8) (*)) 1)
 272     ((simple-array (signed-byte 16) (*)) 2)
 273     ((simple-array (unsigned-byte 16) (*)) 2)
 274     ((simple-array (signed-byte 32) (*)) 4)
 275     ((simple-array (unsigned-byte 32) (*)) 4)
 276     ((simple-array single-float (*)) 4)
 277     ((simple-array double-float (*)) 8)
 278     ((simple-array (complex single-float) (*)) 8)
 279     ((simple-array (complex double-float) (*)) 16)))
 280
 281 #-(or big-endian little-endian)
 282 (eval-when (:compile-toplevel)
 283   (push sb-c::*backend-byte-order* *features*))
 284
 285 (defun endian-swap-value (vector endian-swap)
 286   #+big-endian (declare (ignore vector))
 287   (case endian-swap
 288     (:network-order #+big-endian 0
 289                     #+little-endian (1- (vector-elt-width vector)))
 290     (:byte-8 0)
 291     (:byte-16 1)
 292     (:byte-32 3)
 293     (:byte-64 7)
 294     (:byte-128 15)
 295     (otherwise endian-swap)))
 296
 297 #+(or)
 298 (defun %read-vector (vector stream start end endian-swap blocking)
 299   (declare (type (kernel:simple-unboxed-array (*)) vector)
 300            (type stream stream))
 301   ;; move code from read-vector
 302   )
 303
 304 #+(or)
 305 (defun %write-vector (... blocking)
 306   ;; implement me
 307   )
 308
 309 (defun read-octets (stream buffer start end blocking)
 310   (declare (type simple-stream stream)
 311            (type (or null simple-stream-buffer) buffer)
 312            (type fixnum start)
 313            (type (or null fixnum) end)
 314            (type blocking blocking)
 315            (optimize (speed 3) (space 2) (safety 0) (debug 0)))
 316   (with-stream-class (simple-stream stream)
 317     (let ((fd (sm input-handle stream))
 318           (end (or end (sm buf-len stream)))
 319           (buffer (or buffer (sm buffer stream))))
 320       (declare (fixnum end))
 321       (typecase fd
 322         (fixnum
 323          (let ((flag (sb-sys:wait-until-fd-usable fd :input
 324                                                   (if blocking nil 0))))
 325            (cond
 326              ((and (not blocking) (= start end)) (if flag -3 0))
 327              ((and (not blocking) (not flag)) 0)
 328              (t (block nil
 329                   (let ((count 0))
 330                     (declare (type fixnum count))
 331                     (tagbody
 332                      again
 333                        ;; Avoid CMUCL gengc write barrier
 334                        (do ((i start (+ i #.(sb-posix:getpagesize))))
 335                            ((>= i end))
 336                          (declare (type fixnum i))
 337                          (setf (bref buffer i) 0))
 338                        (setf (bref buffer (1- end)) 0)
 339                        (multiple-value-bind (bytes errno)
 340                            (sb-sys:with-pinned-objects (buffer)
 341                              (sb-unix:unix-read fd (buffer-sap buffer start)
 342                                                 (the fixnum (- end start))))
 343                          (declare (type (or null fixnum) bytes)
 344                                   (type (integer 0 100) errno))
 345                          (when bytes
 346                            (incf count bytes)
 347                            (incf start bytes))
 348                          (cond ((null bytes)
 349                                 (format *debug-io* "~&;; UNIX-READ: errno=~D~%" errno)
 350                                 (cond ((= errno sb-unix:eintr) (go again))
 351                                       ((and blocking
 352                                             (or (= errno ;;sb-unix:eagain
 353                                                    ;; TODO: move
 354                                                    ;; eagain into
 355                                                    ;; sb-unix
 356                                                    11)
 357                                                 (= errno sb-unix:ewouldblock)))
 358                                        (sb-sys:wait-until-fd-usable fd :input nil)
 359                                        (go again))
 360                                       (t (return (- -10 errno)))))
 361                                ((zerop count) (return -1))
 362                                (t (return count)))))))))))
 363         (t (%read-vector buffer fd start end :byte-8
 364                          (if blocking :bnb nil)))))))
 365
 366 (defun write-octets (stream buffer start end blocking)
 367   (declare (type simple-stream stream)
 368            (type simple-stream-buffer buffer)
 369            (type fixnum start)
 370            (type (or null fixnum) end))
 371   (with-stream-class (simple-stream stream)
 372     (when (sm handler stream)
 373       (do ()
 374           ((null (sm pending stream)))
 375         (sb-sys:serve-all-events)))
 376
 377     (let ((fd (sm output-handle stream))
 378           (end (or end (length buffer))))
 379       (typecase fd
 380         (fixnum
 381          (let ((flag (sb-sys:wait-until-fd-usable fd :output
 382                                                   (if blocking nil 0))))
 383            (cond
 384              ((and (not blocking) (= start end)) (if flag -3 0))
 385              ((and (not blocking) (not flag)) 0)
 386              (t
 387               (block nil
 388                 (let ((count 0))
 389                   (tagbody again
 390                      (multiple-value-bind (bytes errno)
 391                          (sb-sys:with-pinned-objects (buffer)
 392                            (sb-unix:unix-write fd (buffer-sap buffer) start
 393                                                (- end start)))
 394                        (when bytes
 395                          (incf count bytes)
 396                          (incf start bytes))
 397                        (cond ((null bytes)
 398                               (format *debug-io* "~&;; UNIX-WRITE: errno=~D~%" errno)
 399                               (cond ((= errno sb-unix:eintr) (go again))
 400                                     ;; don't block for subsequent chars
 401                                     (t (return (- -10 errno)))))
 402                              (t (return count)))))))))))
 403         (t (error "implement me"))))))
 404
 405 (defun do-some-output (stream)
 406   ;; Do some pending output; return T if completed, NIL if more to do
 407   (with-stream-class (simple-stream stream)
 408     (let ((fd (sm output-handle stream)))
 409       (loop
 410         (let ((list (pop (sm pending stream))))
 411           (unless list
 412             (sb-sys:remove-fd-handler (sm handler stream))
 413             (setf (sm handler stream) nil)
 414             (return t))
 415           (let* ((buffer (first list))
 416                  (start (second list))
 417                  (end (third list))
 418                  (len (- end start)))
 419             (declare (type simple-stream-buffer buffer)
 420                      (type sb-int:index start end len))
 421             (tagbody again
 422                (multiple-value-bind (bytes errno)
 423                    (sb-sys:with-pinned-objects (buffer)
 424                      (sb-unix:unix-write fd (buffer-sap buffer) start len))
 425                  (cond ((null bytes)
 426                         (if (= errno sb-unix:eintr)
 427                             (go again)
 428                             (progn (push list (sm pending stream))
 429                                    (return nil))))
 430                        ((< bytes len)
 431                         (setf (second list) (+ start bytes))
 432                         (push list (sm pending stream))
 433                         (return nil))
 434                        ((= bytes len)
 435                         (free-buffer buffer)))))))))))
 436
 437 (defun queue-write (stream buffer start end)
 438   ;; Queue a write; return T if buffer needs changing, NIL otherwise
 439   (declare (type simple-stream stream)
 440            (type simple-stream-buffer buffer)
 441            (type sb-int:index start end))
 442   (with-stream-class (simple-stream stream)
 443     (when (sm handler stream)
 444       (unless (do-some-output stream)
 445         (let ((last (last (sm pending stream))))
 446           (setf (cdr last) (list (list buffer start end)))
 447           (return-from queue-write t))))
 448     (let ((bytes (write-octets stream buffer start end nil)))
 449       (unless (or (= bytes (- end start)) ; completed
 450                   (= bytes -3)) ; empty buffer; shouldn't happen
 451         (setf (sm pending stream) (list (list buffer start end)))
 452         (setf (sm handler stream)
 453               (sb-sys:add-fd-handler (sm output-handle stream) :output
 454                                      (lambda (fd)
 455                                        (declare (ignore fd))
 456                                        (do-some-output stream))))
 457         t))))
 458
 459
 460
 461
 462 (defun %fd-open (pathname direction if-exists if-exists-given
 463                           if-does-not-exist if-does-not-exist-given)
 464   (declare (type pathname pathname)
 465            (type (member :input :output :io :probe) direction)
 466            (type (member :error :new-version :rename :rename-and-delete
 467                          :overwrite :append :supersede nil) if-exists)
 468            (type (member :error :create nil) if-does-not-exist))
 469   (multiple-value-bind (input output mask)
 470       (ecase direction
 471         (:input (values t nil sb-unix:o_rdonly))
 472         (:output (values nil t sb-unix:o_wronly))
 473         (:io (values t t sb-unix:o_rdwr))
 474         (:probe (values t nil sb-unix:o_rdonly)))
 475     (declare (type sb-int:index mask))
 476     (let* ((phys (sb-int:physicalize-pathname (merge-pathnames pathname)))
 477            (true (probe-file phys))
 478            (name (cond (true
 479                         (sb-ext:native-namestring true :as-file t))
 480                        ((or (not input)
 481                             (and input (eq if-does-not-exist :create))
 482                             (and (eq direction :io) (not if-does-not-exist-given)))
 483                         (sb-ext:native-namestring phys :as-file t)))))
 484       ;; Process if-exists argument if we are doing any output.
 485       (cond (output
 486              (unless if-exists-given
 487                (setf if-exists
 488                      (if (eq (pathname-version pathname) :newest)
 489                          :new-version
 490                          :error)))
 491              (case if-exists
 492                ((:error nil :new-version)
 493                 (setf mask (logior mask sb-unix:o_excl)))
 494                ((:rename :rename-and-delete)
 495                 (setf mask (logior mask sb-unix:o_creat)))
 496                ((:supersede)
 497                 (setf mask (logior mask sb-unix:o_trunc)))))
 498             (t
 499              (setf if-exists nil)))     ; :ignore-this-arg
 500       (unless if-does-not-exist-given
 501         (setf if-does-not-exist
 502               (cond ((eq direction :input) :error)
 503                     ((and output
 504                           (member if-exists '(:overwrite :append)))
 505                      :error)
 506                     ((eq direction :probe)
 507                      nil)
 508                     (t
 509                      :create))))
 510       (if (eq if-does-not-exist :create)
 511           (setf mask (logior mask sb-unix:o_creat)))
 512
 513       (let ((original (if (member if-exists
 514                                   '(:rename :rename-and-delete))
 515                           (sb-impl::pick-backup-name name)
 516                           nil))
 517             (delete-original (eq if-exists :rename-and-delete))
 518             (mode #o666))
 519         (when original
 520           ;; We are doing a :rename or :rename-and-delete.
 521           ;; Determine if the file already exists, make sure the original
 522           ;; file is not a directory and keep the mode
 523           (let ((exists
 524                  (and name
 525                       (multiple-value-bind
 526                             (okay err/dev inode orig-mode)
 527                           (sb-unix:unix-stat name)
 528                         (declare (ignore inode)
 529                                  (type (or sb-int:index null) orig-mode))
 530                         (cond
 531                           (okay
 532                            (when (and output (= (logand orig-mode #o170000)
 533                                                 #o40000))
 534                              (error 'sb-int:simple-file-error
 535                                  :pathname pathname
 536                                  :format-control
 537                                  "Cannot open ~S for output: Is a directory."
 538                                  :format-arguments (list name)))
 539                            (setf mode (logand orig-mode #o777))
 540                            t)
 541                           ((eql err/dev sb-unix:enoent)
 542                            nil)
 543                           (t
 544                            (error 'sb-int:simple-file-error
 545                                   :pathname pathname
 546                                   :format-control "Cannot find ~S: ~A"
 547                                   :format-arguments
 548                                     (list name
 549                                       (sb-int:strerror err/dev)))))))))
 550             (unless (and exists
 551                          (rename-file name original))
 552               (setf original nil)
 553               (setf delete-original nil)
 554               ;; In order to use SUPERSEDE instead, we have
 555               ;; to make sure unix:o_creat corresponds to
 556               ;; if-does-not-exist.  unix:o_creat was set
 557               ;; before because of if-exists being :rename.
 558               (unless (eq if-does-not-exist :create)
 559                 (setf mask (logior (logandc2 mask sb-unix:o_creat)
 560                                    sb-unix:o_trunc)))
 561               (setf if-exists :supersede))))
 562
 563         ;; Okay, now we can try the actual open.
 564         (loop
 565           (multiple-value-bind (fd errno)
 566               (if name
 567                   (sb-unix:unix-open name mask mode)
 568                   (values nil sb-unix:enoent))
 569             (cond ((sb-int:fixnump fd)
 570                    (when (eql if-exists :append)
 571                      (sb-unix:unix-lseek fd 0 sb-unix:l_xtnd))
 572                    (return (values fd name original delete-original)))
 573                   ((eql errno sb-unix:enoent)
 574                    (case if-does-not-exist
 575                      (:error
 576                        (cerror "Return NIL."
 577                                'sb-int:simple-file-error
 578                                :pathname pathname
 579                                :format-control "Error opening ~S, ~A."
 580                                :format-arguments
 581                                    (list pathname
 582                                          (sb-int:strerror errno))))
 583                      (:create
 584                       (cerror "Return NIL."
 585                                'sb-int:simple-file-error
 586                                :pathname pathname
 587                                :format-control
 588                                    "Error creating ~S, path does not exist."
 589                                :format-arguments (list pathname))))
 590                    (return nil))
 591                   ((eql errno sb-unix:eexist)
 592                    (unless (eq nil if-exists)
 593                      (cerror "Return NIL."
 594                              'sb-int:simple-file-error
 595                              :pathname pathname
 596                              :format-control "Error opening ~S, ~A."
 597                              :format-arguments
 598                                  (list pathname
 599                                        (sb-int:strerror errno))))
 600                    (return nil))
 601                   #+nil ; FIXME: reinstate this; error reporting is nice.
 602                   ((eql errno sb-unix:eacces)
 603                    (cerror "Try again."
 604                            'sb-int:simple-file-error
 605                            :pathname pathname
 606                            :format-control "Error opening ~S, ~A."
 607                            :format-arguments
 608                                (list pathname
 609                                      (sb-int:strerror errno))))
 610                   (t
 611                    (cerror "Return NIL."
 612                            'sb-int:simple-file-error
 613                            :pathname pathname
 614                            :format-control "Error opening ~S, ~A."
 615                            :format-arguments
 616                                (list pathname
 617                                      (sb-int:strerror errno)))
 618                    (return nil)))))))))
 619
 620 (defun open-fd-stream (pathname &key (direction :input)
 621                                 (element-type 'base-char)
 622                                 (if-exists nil if-exists-given)
 623                                 (if-does-not-exist nil if-does-not-exist-given)
 624                                 (external-format :default))
 625   (declare (type (or pathname string stream) pathname)
 626            (type (member :input :output :io :probe) direction)
 627            (type (member :error :new-version :rename :rename-and-delete
 628                          :overwrite :append :supersede nil) if-exists)
 629            (type (member :error :create nil) if-does-not-exist))
 630   (let ((filespec (merge-pathnames pathname)))
 631     (multiple-value-bind (fd namestring original delete-original)
 632         (%fd-open filespec direction if-exists if-exists-given
 633                   if-does-not-exist if-does-not-exist-given)
 634       (when fd
 635         (case direction
 636           ((:input :output :io)
 637            (sb-sys:make-fd-stream fd
 638                                   :input (member direction '(:input :io))
 639                                   :output (member direction '(:output :io))
 640                                   :element-type element-type
 641                                   :file namestring
 642                                   :original original
 643                                   :delete-original delete-original
 644                                   :pathname pathname
 645                                   :dual-channel-p nil
 646                                   :input-buffer-p t
 647                                   :auto-close t
 648                                   :external-format external-format))
 649           (:probe
 650            (let ((stream (sb-impl::%make-fd-stream :name namestring :fd fd
 651                                                    :pathname pathname
 652                                                    :element-type element-type)))
 653              (close stream)
 654              stream)))))))
 655
 656
 657 ;; Experimental "filespec" stuff
 658
 659 ;; sat: Hooks to parse URIs etc apparently go here
 660
 661 (defstruct (filespec-parser
 662              (:constructor make-filespec-parser (name priority function)))
 663   name
 664   priority
 665   function)
 666
 667 (defvar *filespec-parsers* ())
 668
 669 (defun add-filespec (name priority function)
 670   (let ((filespec (make-filespec-parser name priority function)))
 671     (setf *filespec-parsers*
 672           (stable-sort (cons filespec (delete name *filespec-parsers*
 673                                               :key #'filespec-parser-name))
 674                        #'>
 675                        :key #'filespec-parser-priority)))
 676   t)
 677
 678 (defmacro define-filespec (name lambda-list &body body)
 679   (let ((truename (if (consp name) (first name) name))
 680         (priority (if (consp name) (second name) 0)))
 681     `(add-filespec ',truename ,priority (lambda ,lambda-list
 682                                           (block ,truename
 683                                             ,@body)))))
 684
 685 (defun parse-filespec (string &optional (errorp t))
 686   (dolist (i *filespec-parsers* (when errorp
 687                                   (error "~S not recognised." string)))
 688     (let ((result (ignore-errors
 689                     (funcall (filespec-parser-function i) string))))
 690       (when result (return result)))))
 691
 692 (define-filespec pathname (string)
 693   (pathname string))