contrib/sb-sprof/sb-sprof.lisp

   1 ;;; Copyright (C) 2003 Gerd Moellmann <gerd.moellmann@t-online.de>
   2 ;;; All rights reserved.
   3 ;;;
   4 ;;; Redistribution and use in source and binary forms, with or without
   5 ;;; modification, are permitted provided that the following conditions
   6 ;;; are met:
   7 ;;;
   8 ;;; 1. Redistributions of source code must retain the above copyright
   9 ;;;    notice, this list of conditions and the following disclaimer.
  10 ;;; 2. Redistributions in binary form must reproduce the above copyright
  11 ;;;    notice, this list of conditions and the following disclaimer in the
  12 ;;;    documentation and/or other materials provided with the distribution.
  13 ;;; 3. The name of the author may not be used to endorse or promote
  14 ;;;    products derived from this software without specific prior written
  15 ;;;    permission.
  16 ;;;
  17 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS
  18 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  19 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE
  21 ;;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22 ;;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT
  23 ;;; OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  24 ;;; BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  25 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 ;;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
  27 ;;; USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
  28 ;;; DAMAGE.
  29
  30 ;;; Statistical profiler.
  31
  32 ;;; Overview:
  33 ;;;
  34 ;;; This profiler arranges for SIGPROF interrupts to interrupt a
  35 ;;; running program at regular intervals.  Each time a SIGPROF occurs,
  36 ;;; the current program counter and return address is recorded in a
  37 ;;; vector, until a configurable maximum number of samples have been
  38 ;;; taken.
  39 ;;;
  40 ;;; A profiling report is generated from the samples array by
  41 ;;; determining the Lisp functions corresponding to the recorded
  42 ;;; addresses.  Each program counter/return address pair forms one
  43 ;;; edge in a call graph.
  44
  45 ;;; Problems:
  46 ;;;
  47 ;;; The code being generated on x86 makes determining callers reliably
  48 ;;; something between extremely difficult and impossible.  Example:
  49 ;;;
  50 ;;; 10979F00:       .entry eval::eval-stack-args(arg-count)
  51 ;;;       18:       pop     dword ptr [ebp-8]
  52 ;;;       1B:       lea     esp, [ebp-32]
  53 ;;;       1E:       mov     edi, edx
  54 ;;;
  55 ;;;       20:       cmp     ecx, 4
  56 ;;;       23:       jne     L4
  57 ;;;       29:       mov     [ebp-12], edi
  58 ;;;       2C:       mov     dword ptr [ebp-16], #x28F0000B ; nil
  59 ;;;                                              ; No-arg-parsing entry point
  60 ;;;       33:       mov     dword ptr [ebp-20], 0
  61 ;;;       3A:       jmp     L3
  62 ;;;       3C: L0:   mov     edx, esp
  63 ;;;       3E:       sub     esp, 12
  64 ;;;       41:       mov     eax, [#x10979EF8]    ; #<FDEFINITION object for eval::eval-stack-pop>
  65 ;;;       47:       xor     ecx, ecx
  66 ;;;       49:       mov     [edx-4], ebp
  67 ;;;       4C:       mov     ebp, edx
  68 ;;;       4E:       call    dword ptr [eax+5]
  69 ;;;       51:       mov     esp, ebx
  70 ;;;
  71 ;;; Suppose this function is interrupted by SIGPROF at 4E.  At that
  72 ;;; point, the frame pointer EBP has been modified so that the
  73 ;;; original return address of the caller of eval-stack-args is no
  74 ;;; longer where it can be found by x86-call-context, and the new
  75 ;;; return address, for the call to eval-stack-pop, is not yet on the
  76 ;;; stack.  The effect is that x86-call-context returns something
  77 ;;; bogus, which leads to wrong edges in the call graph.
  78 ;;;
  79 ;;; One thing that one might try is filtering cases where the program
  80 ;;; is interrupted at a call instruction.  But since the above example
  81 ;;; of an interrupt at a call instruction isn't the only case where
  82 ;;; the stack is something x86-call-context can't really cope with,
  83 ;;; this is not a general solution.
  84 ;;;
  85 ;;; Random ideas for implementation:
  86 ;;;
  87 ;;; * Space profiler.  Sample when new pages are allocated instead of
  88 ;;; at SIGPROF.
  89 ;;;
  90 ;;; * Record a configurable number of callers up the stack.  That
  91 ;;; could give a more complete graph when there are many small
  92 ;;; functions.
  93 ;;;
  94 ;;; * Print help strings for reports, include hints to the problem
  95 ;;; explained above.
  96 ;;;
  97 ;;; * Make flat report the default since call-graph isn't that
  98 ;;; reliable?
  99
 100 (defpackage #:sb-sprof
 101   (:use #:cl #:sb-ext #:sb-unix #:sb-alien #:sb-sys)
 102   (:export #:*sample-interval* #:*max-samples*
 103            #:start-sampling #:stop-sampling #:with-sampling
 104            #:with-profiling #:start-profiling #:stop-profiling
 105            #:reset #:report))
 106
 107 (in-package #:sb-sprof)
 108
 109 \f
 110 ;;;; Graph Utilities
 111
 112 (defstruct (vertex (:constructor make-vertex)
 113                    (:constructor make-scc (scc-vertices edges)))
 114   (visited     nil :type boolean)
 115   (root        nil :type (or null vertex))
 116   (dfn           0 :type fixnum)
 117   (edges        () :type list)
 118   (scc-vertices () :type list))
 119
 120 (defstruct edge
 121   (vertex (sb-impl::missing-arg) :type vertex))
 122
 123 (defstruct graph
 124   (vertices () :type list))
 125
 126 (declaim (inline scc-p))
 127 (defun scc-p (vertex)
 128   (not (null (vertex-scc-vertices vertex))))
 129
 130 (defmacro do-vertices ((vertex graph) &body body)
 131   `(dolist (,vertex (graph-vertices ,graph))
 132      ,@body))
 133
 134 (defmacro do-edges ((edge edge-to vertex) &body body)
 135   `(dolist (,edge (vertex-edges ,vertex))
 136      (let ((,edge-to (edge-vertex ,edge)))
 137        ,@body)))
 138
 139 (defun self-cycle-p (vertex)
 140   (do-edges (e to vertex)
 141     (when (eq to vertex)
 142       (return t))))
 143
 144 (defun map-vertices (fn vertices)
 145   (dolist (v vertices)
 146     (setf (vertex-visited v) nil))
 147   (dolist (v vertices)
 148     (unless (vertex-visited v)
 149       (funcall fn v))))
 150
 151 ;;; Eeko Nuutila, Eljas Soisalon-Soininen, around 1992.  Improves on
 152 ;;; Tarjan's original algorithm by not using the stack when processing
 153 ;;; trivial components.  Trivial components should appear frequently
 154 ;;; in a call-graph such as ours, I think.  Same complexity O(V+E) as
 155 ;;; Tarjan.
 156 (defun strong-components (vertices)
 157   (let ((in-component (make-array (length vertices)
 158                                   :element-type 'boolean
 159                                   :initial-element nil))
 160         (stack ())
 161         (components ())
 162         (dfn -1))
 163     (labels ((min-root (x y)
 164                (let ((rx (vertex-root x))
 165                      (ry (vertex-root y)))
 166                  (if (< (vertex-dfn rx) (vertex-dfn ry))
 167                      rx
 168                      ry)))
 169              (in-component (v)
 170                (aref in-component (vertex-dfn v)))
 171              ((setf in-component) (in v)
 172                (setf (aref in-component (vertex-dfn v)) in))
 173              (vertex-> (x y)
 174                (> (vertex-dfn x) (vertex-dfn y)))
 175              (visit (v)
 176                (setf (vertex-dfn v) (incf dfn)
 177                      (in-component v) nil
 178                      (vertex-root v) v
 179                      (vertex-visited v) t)
 180                (do-edges (e w v)
 181                  (unless (vertex-visited w)
 182                    (visit w))
 183                  (unless (in-component w)
 184                    (setf (vertex-root v) (min-root v w))))
 185                (if (eq v (vertex-root v))
 186                    (loop while (and stack (vertex-> (car stack) v))
 187                          as w = (pop stack)
 188                          collect w into this-component
 189                          do (setf (in-component w) t)
 190                          finally
 191                            (setf (in-component v) t)
 192                            (push (cons v this-component) components))
 193                    (push v stack))))
 194       (map-vertices #'visit vertices)
 195       components)))
 196
 197 ;;; Given a dag as a list of vertices, return the list sorted
 198 ;;; topologically, children first.
 199 (defun topological-sort (dag)
 200   (let ((sorted ())
 201         (dfn -1))
 202     (labels ((rec-sort (v)
 203                (setf (vertex-visited v) t)
 204                (setf (vertex-dfn v) (incf dfn))
 205                (dolist (e (vertex-edges v))
 206                  (unless (vertex-visited (edge-vertex e))
 207                    (rec-sort (edge-vertex e))))
 208                (push v sorted)))
 209       (map-vertices #'rec-sort dag)
 210       (nreverse sorted))))
 211
 212 ;;; Reduce graph G to a dag by coalescing strongly connected components
 213 ;;; into vertices.  Sort the result topologically.
 214 (defun reduce-graph (graph &optional (scc-constructor #'make-scc))
 215   (sb-int:collect ((sccs) (trivial))
 216     (dolist (c (strong-components (graph-vertices graph)))
 217       (if (or (cdr c) (self-cycle-p (car c)))
 218           (sb-int:collect ((outgoing))
 219             (dolist (v c)
 220               (do-edges (e w v)
 221                 (unless (member w c)
 222                   (outgoing e))))
 223             (sccs (funcall scc-constructor c (outgoing))))
 224           (trivial (car c))))
 225     (dolist (scc (sccs))
 226       (dolist (v (trivial))
 227         (do-edges (e w v)
 228           (when (member w (vertex-scc-vertices scc))
 229             (setf (edge-vertex e) scc)))))
 230     (setf (graph-vertices graph)
 231           (topological-sort (nconc (sccs) (trivial))))))
 232
 233 \f
 234 ;;;; AA Trees
 235
 236 ;;; An AA tree is a red-black tree with the extra condition that left
 237 ;;; children may not be red.  This condition simplifies the red-black
 238 ;;; algorithm.  It eliminates half of the restructuring cases, and
 239 ;;; simplifies the delete algorithm.
 240
 241 (defstruct (aa-node (:conc-name aa-))
 242   (left  nil :type (or null aa-node))
 243   (right nil :type (or null aa-node))
 244   (level   0 :type integer)
 245   (data  nil :type t))
 246
 247 (defvar *null-node*
 248   (let ((node (make-aa-node)))
 249     (setf (aa-left node) node)
 250     (setf (aa-right node) node)
 251     node))
 252
 253 (defstruct aa-tree
 254   (root *null-node* :type aa-node))
 255
 256 (declaim (inline skew split rotate-with-left-child rotate-with-right-child))
 257
 258 (defun rotate-with-left-child (k2)
 259   (let ((k1 (aa-left k2)))
 260     (setf (aa-left k2) (aa-right k1))
 261     (setf (aa-right k1) k2)
 262     k1))
 263
 264 (defun rotate-with-right-child (k1)
 265   (let ((k2 (aa-right k1)))
 266     (setf (aa-right k1) (aa-left k2))
 267     (setf (aa-left k2) k1)
 268     k2))
 269
 270 (defun skew (aa)
 271   (if (= (aa-level (aa-left aa)) (aa-level aa))
 272       (rotate-with-left-child aa)
 273       aa))
 274
 275 (defun split (aa)
 276   (when (= (aa-level (aa-right (aa-right aa)))
 277            (aa-level aa))
 278     (setq aa (rotate-with-right-child aa))
 279     (incf (aa-level aa)))
 280   aa)
 281
 282 (macrolet ((def (name () &body body)
 283              (let ((name (sb-int::symbolicate 'aa- name)))
 284                `(defun ,name (item tree &key
 285                               (test-< #'<) (test-= #'=)
 286                               (node-key #'identity) (item-key #'identity))
 287                   (let ((.item-key. (funcall item-key item)))
 288                     (flet ((item-< (node)
 289                              (funcall test-< .item-key.
 290                                       (funcall node-key (aa-data node))))
 291                            (item-= (node)
 292                              (funcall test-= .item-key.
 293                                       (funcall node-key (aa-data node)))))
 294                       (declare (inline item-< item-=))
 295                       ,@body))))))
 296
 297   (def insert ()
 298     (labels ((insert-into (aa)
 299                (cond ((eq aa *null-node*)
 300                       (setq aa (make-aa-node :data item
 301                                              :left *null-node*
 302                                              :right *null-node*)))
 303                      ((item-= aa)
 304                       (return-from insert-into aa))
 305                      ((item-< aa)
 306                       (setf (aa-left aa) (insert-into (aa-left aa))))
 307                      (t
 308                       (setf (aa-right aa) (insert-into (aa-right aa)))))
 309                (split (skew aa))))
 310       (setf (aa-tree-root tree)
 311             (insert-into (aa-tree-root tree)))))
 312
 313   (def delete ()
 314     (let ((deleted-node *null-node*)
 315           (last-node nil))
 316       (labels ((remove-from (aa)
 317                  (unless (eq aa *null-node*)
 318                    (setq last-node aa)
 319                    (if (item-< aa)
 320                        (setf (aa-left aa) (remove-from (aa-left aa)))
 321                        (progn
 322                          (setq deleted-node aa)
 323                          (setf (aa-right aa) (remove-from (aa-right aa)))))
 324                    (cond ((eq aa last-node)
 325                           ;;
 326                           ;; If at the bottom of the tree, and item
 327                           ;; is present, delete it.
 328                           (when (and (not (eq deleted-node *null-node*))
 329                                      (item-= deleted-node))
 330                             (setf (aa-data deleted-node) (aa-data aa))
 331                             (setq deleted-node *null-node*)
 332                             (setq aa (aa-right aa))))
 333                          ;;
 334                          ;; Otherwise not at bottom of tree; rebalance.
 335                          ((or (< (aa-level (aa-left aa))
 336                                  (1- (aa-level aa)))
 337                               (< (aa-level (aa-right aa))
 338                                  (1- (aa-level aa))))
 339                           (decf (aa-level aa))
 340                           (when (> (aa-level (aa-right aa)) (aa-level aa))
 341                             (setf (aa-level (aa-right aa)) (aa-level aa)))
 342                           (setq aa (skew aa))
 343                           (setf (aa-right aa) (skew (aa-right aa)))
 344                           (setf (aa-right (aa-right aa))
 345                                 (skew (aa-right (aa-right aa))))
 346                           (setq aa (split aa))
 347                           (setf (aa-right aa) (split (aa-right aa))))))
 348                  aa))
 349         (setf (aa-tree-root tree)
 350               (remove-from (aa-tree-root tree))))))
 351
 352   (def find ()
 353     (let ((current (aa-tree-root tree)))
 354       (setf (aa-data *null-node*) item)
 355       (loop
 356          (cond ((eq current *null-node*)
 357                 (return (values nil nil)))
 358                ((item-= current)
 359                 (return (values (aa-data current) t)))
 360                ((item-< current)
 361                 (setq current (aa-left current)))
 362                (t
 363                 (setq current (aa-right current))))))))
 364
 365 \f
 366 ;;;; Other Utilities
 367
 368 ;;; Sort the subsequence of Vec in the interval [From To] using
 369 ;;; comparison function Test.  Assume each element to sort consists of
 370 ;;; Element-Size array slots, and that the slot Key-Offset contains
 371 ;;; the sort key.
 372 (defun qsort (vec &key (element-size 1) (key-offset 0)
 373               (from 0) (to (- (length vec) element-size)))
 374   (declare (type fixnum to from element-size key-offset))
 375   (declare (type (simple-array address) vec))
 376   (labels ((rotate (i j)
 377              (declare (fixnum i j))
 378              (loop repeat element-size
 379                    for i from i and j from j do
 380                      (rotatef (aref vec i) (aref vec j))))
 381            (key (i)
 382              (aref vec (+ i key-offset)))
 383            (rec-sort (from to)
 384              (declare (fixnum to from))
 385              (when (> to from)
 386                (let* ((mid (* element-size
 387                               (round (+ (/ from element-size)
 388                                         (/ to element-size))
 389                                      2)))
 390                       (i from)
 391                       (j (+ to element-size))
 392                       (p (key mid)))
 393                  (declare (fixnum mid i j))
 394                  (rotate mid from)
 395                  (loop
 396                     (loop do (incf i element-size)
 397                           until (or (> i to)
 398                                     ;; QSORT used to take a test
 399                                     ;; parameter which was funcalled
 400                                     ;; here. This caused some consing,
 401                                     ;; which is problematic since
 402                                     ;; QSORT is indirectly called in
 403                                     ;; an after-gc-hook. So just
 404                                     ;; hardcode >, which would've been
 405                                     ;; used for the test anyway.
 406                                     ;; --JES, 2004-07-09
 407                                     (> p (key i))))
 408                     (loop do (decf j element-size)
 409                           until (or (<= j from)
 410                                     ;; As above.
 411                                     (> (key j) p)))
 412                     (when (< j i) (return))
 413                     (rotate i j))
 414                  (rotate from j)
 415                  (rec-sort from (- j element-size))
 416                  (rec-sort i to)))))
 417     (rec-sort from to)
 418     vec))
 419
 420 \f
 421 ;;;; The Profiler
 422
 423 (deftype address ()
 424   "Type used for addresses, for instance, program counters,
 425    code start/end locations etc."
 426   '(unsigned-byte #.sb-vm::n-machine-word-bits))
 427
 428 (defconstant +unknown-address+ 0
 429   "Constant representing an address that cannot be determined.")
 430
 431 ;;; A call graph.  Vertices are NODE structures, edges are CALL
 432 ;;; structures.
 433 (defstruct (call-graph (:include graph)
 434                        (:constructor %make-call-graph))
 435   ;; the value of *Sample-Interval* at the time the graph was created
 436   (sample-interval (sb-impl::missing-arg) :type number)
 437   ;; number of samples taken
 438   (nsamples (sb-impl::missing-arg) :type sb-impl::index)
 439   ;; sample count for samples not in any function
 440   (elsewhere-count (sb-impl::missing-arg) :type sb-impl::index)
 441   ;; a flat list of NODEs, sorted by sample count
 442   (flat-nodes () :type list))
 443
 444 ;;; A node in a call graph, representing a function that has been
 445 ;;; sampled.  The edges of a node are CALL structures that represent
 446 ;;; functions called from a given node.
 447 (defstruct (node (:include vertex)
 448                  (:constructor %make-node))
 449   ;; A numeric label for the node.  The most frequently called function
 450   ;; gets label 1.  This is just for identification purposes in the
 451   ;; profiling report.
 452   (index 0 :type fixnum)
 453   ;; start and end address of the function's code
 454   (start-pc 0 :type address)
 455   (end-pc 0 :type address)
 456   ;; the name of the function
 457   (name nil :type t)
 458   ;; sample count for this function
 459   (count 0 :type fixnum)
 460   ;; count including time spent in functions called from this one
 461   (accrued-count 0 :type fixnum)
 462   ;; list of NODEs for functions calling this one
 463   (callers () :type list))
 464
 465 ;;; A cycle in a call graph.  The functions forming the cycle are
 466 ;;; found in the SCC-VERTICES slot of the VERTEX structure.
 467 (defstruct (cycle (:include node)))
 468
 469 ;;; An edge in a call graph.  EDGE-VERTEX is the function being
 470 ;;; called.
 471 (defstruct (call (:include edge)
 472                  (:constructor make-call (vertex)))
 473   ;; number of times the call was sampled
 474   (count 1 :type sb-impl::index))
 475
 476 ;;; Info about a function in dynamic-space.  This is used to track
 477 ;;; address changes of functions during GC.
 478 (defstruct (dyninfo (:constructor make-dyninfo (code start end)))
 479   ;; component this info is for
 480   (code (sb-impl::missing-arg) :type sb-kernel::code-component)
 481   ;; current start and end address of the component
 482   (start (sb-impl::missing-arg) :type address)
 483   (end (sb-impl::missing-arg) :type address)
 484   ;; new start address of the component, after GC.
 485   (new-start 0 :type address))
 486
 487 (defmethod print-object ((call-graph call-graph) stream)
 488   (print-unreadable-object (call-graph stream :type t :identity t)
 489     (format stream "~d samples" (call-graph-nsamples call-graph))))
 490
 491 (defmethod print-object ((node node) stream)
 492   (print-unreadable-object (node stream :type t :identity t)
 493     (format stream "~s [~d]" (node-name node) (node-index node))))
 494
 495 (defmethod print-object ((call call) stream)
 496   (print-unreadable-object (call stream :type t :identity t)
 497     (format stream "~s [~d]" (node-name (call-vertex call))
 498             (node-index (call-vertex call)))))
 499
 500 (deftype report-type ()
 501   '(member nil :flat :graph))
 502
 503 (defvar *sample-interval* 0.01
 504   "Default number of seconds between samples.")
 505 (declaim (number *sample-interval*))
 506
 507 (defvar *max-samples* 50000
 508   "Default number of samples taken.")
 509 (declaim (type sb-impl::index *max-samples*))
 510
 511 (defconstant +sample-size+
 512   #+(or x86 x86-64) 8
 513   #-(or x86 x86-64) 2)
 514
 515 (defvar *samples* nil)
 516 (declaim (type (or null (vector address)) *samples*))
 517
 518 (defvar *samples-index* 0)
 519 (declaim (type sb-impl::index *samples-index*))
 520
 521 (defvar *profiling* nil)
 522 (defvar *sampling* nil)
 523 (declaim (type boolean *profiling* *sampling*))
 524
 525 (defvar *dynamic-space-code-info* ())
 526 (declaim (type list *dynamic-space-code-info*))
 527
 528 (defvar *show-progress* nil)
 529
 530 (defvar *old-sampling* nil)
 531
 532 (defun turn-off-sampling ()
 533   (setq *old-sampling* *sampling*)
 534   (setq *sampling* nil))
 535
 536 (defun turn-on-sampling ()
 537   (setq *sampling* *old-sampling*))
 538
 539 (defun show-progress (format-string &rest args)
 540   (when *show-progress*
 541     (apply #'format t format-string args)
 542     (finish-output)))
 543
 544 (defun start-sampling ()
 545   "Switch on statistical sampling."
 546   (setq *sampling* t))
 547
 548 (defun stop-sampling ()
 549   "Switch off statistical sampling."
 550   (setq *sampling* nil))
 551
 552 (defmacro with-sampling ((&optional (on t)) &body body)
 553   "Evaluate body with statistical sampling turned on or off."
 554   `(let ((*sampling* ,on))
 555      ,@body))
 556
 557 (defun sort-samples (key-offset)
 558   "Sort *Samples* using comparison Test.  Key must be one of
 559    :Pc or :Return-Pc for sorting by pc or return pc."
 560   (when (plusp *samples-index*)
 561     (qsort *samples*
 562            :from 0
 563            :to (- *samples-index* +sample-size+)
 564            :element-size +sample-size+
 565            :key-offset key-offset)))
 566
 567 (defun record (pc)
 568   (declare (type address pc))
 569   (setf (aref *samples* *samples-index*) pc)
 570   (incf *samples-index*))
 571
 572 ;;; SIGPROF handler.  Record current PC and return address in
 573 ;;; *SAMPLES*.
 574 #+(or x86 x86-64)
 575 (defun sigprof-handler (signal code scp)
 576   (declare (ignore signal code) (type system-area-pointer scp))
 577   (when (and *sampling*
 578              (< *samples-index* (length *samples*)))
 579     (sb-sys:without-gcing
 580         (locally (declare (optimize (inhibit-warnings 2)))
 581           (with-alien ((scp (* os-context-t) :local scp))
 582             ;; For some reason completely bogus small values for the
 583             ;; frame pointer are returned every now and then, leading
 584             ;; to segfaults. Try to avoid these cases.
 585             ;;
 586             ;; FIXME: Do a more thorough sanity check on ebp, or figure
 587             ;; out why this is happening.
 588             ;; -- JES, 2005-01-11
 589             (when (< (sb-vm::context-register scp #.sb-vm::ebp-offset)
 590                      4096)
 591               (dotimes (i +sample-size+)
 592                 (record 0))
 593               (return-from sigprof-handler nil))
 594             (let* ((pc-ptr (sb-vm:context-pc scp))
 595                    (fp (sb-vm::context-register scp #.sb-vm::ebp-offset)))
 596               (record (sap-int pc-ptr))
 597               (let ((fp (int-sap fp))
 598                     ra)
 599                 (dotimes (i (1- +sample-size+))
 600                   (cond (fp
 601                          (setf (values ra fp)
 602                                (sb-di::x86-call-context fp :depth i))
 603                          (record (if ra
 604                                      (sap-int ra)
 605                                      0)))
 606                         (t
 607                          (record 0)))))))))))
 608
 609 ;; FIXME: On non-x86 platforms we don't yet walk the call stack deeper
 610 ;; than one level.
 611 #-(or x86 x86-64)
 612 (defun sigprof-handler (signal code scp)
 613   (declare (ignore signal code))
 614   (when (and *sampling*
 615              (< *samples-index* (length *samples*)))
 616     (sb-sys:without-gcing
 617      (with-alien ((scp (* os-context-t) :local scp))
 618        (locally (declare (optimize (inhibit-warnings 2)))
 619          (let* ((pc-ptr (sb-vm:context-pc scp))
 620                 (fp (sb-vm::context-register scp #.sb-vm::cfp-offset))
 621                 (ra (sap-ref-word
 622                      (int-sap fp)
 623                      (* sb-vm::lra-save-offset sb-vm::n-word-bytes))))
 624            (record (sap-int pc-ptr))
 625            (record ra)))))))
 626
 627 ;;; Map function FN over code objects in dynamic-space.  FN is called
 628 ;;; with two arguments, the object and its size in bytes.
 629 (defun map-dynamic-space-code (fn)
 630   (flet ((call-if-code (obj obj-type size)
 631            (declare (ignore obj-type))
 632            (when (sb-kernel:code-component-p obj)
 633              (funcall fn obj size))))
 634     (sb-vm::map-allocated-objects #'call-if-code :dynamic)))
 635
 636 ;;; Return the start address of CODE.
 637 (defun code-start (code)
 638   (declare (type sb-kernel:code-component code))
 639   (sap-int (sb-kernel:code-instructions code)))
 640
 641 ;;; Return start and end address of CODE as multiple values.
 642 (defun code-bounds (code)
 643   (declare (type sb-kernel:code-component code))
 644   (let* ((start (code-start code))
 645          (end (+ start (sb-kernel:%code-code-size code))))
 646     (values start end)))
 647
 648 ;;; Record the addresses of dynamic-space code objects in
 649 ;;; *DYNAMIC-SPACE-CODE-INFO*.  Call this with GC disabled.
 650 (defun record-dyninfo ()
 651   (setf *dynamic-space-code-info* nil)
 652   (flet ((record-address (code size)
 653            (declare (ignore size))
 654            (multiple-value-bind (start end)
 655                (code-bounds code)
 656              (push (make-dyninfo code start end)
 657                    *dynamic-space-code-info*))))
 658     (map-dynamic-space-code #'record-address)))
 659
 660 (defun adjust-samples (offset)
 661   (sort-samples offset)
 662   (let ((sidx 0))
 663     (declare (type sb-impl::index sidx))
 664     (dolist (info *dynamic-space-code-info*)
 665       (unless (= (dyninfo-new-start info) (dyninfo-start info))
 666         (let ((pos (do ((i sidx (+ i +sample-size+)))
 667                        ((= i *samples-index*) nil)
 668                      (declare (type sb-impl::index i))
 669                      (when (<= (dyninfo-start info)
 670                                (aref *samples* (+ i offset))
 671                                (dyninfo-end info))
 672                        (return i)))))
 673           (when pos
 674             (setq sidx pos)
 675             (loop with delta = (- (dyninfo-new-start info)
 676                                   (dyninfo-start info))
 677                   for j from sidx below *samples-index* by +sample-size+
 678                   as pc = (aref *samples* (+ j offset))
 679                   while (<= (dyninfo-start info) pc (dyninfo-end info)) do
 680                     (incf (aref *samples* (+ j offset)) delta)
 681                     (incf sidx +sample-size+))))))))
 682
 683 ;;; This runs from *AFTER-GC-HOOKS*.  Adjust *SAMPLES* for address
 684 ;;; changes of dynamic-space code objects.
 685 (defun adjust-samples-for-address-changes ()
 686   (sb-sys:without-gcing
 687    (turn-off-sampling)
 688    (setq *dynamic-space-code-info*
 689          (sort *dynamic-space-code-info* #'> :key #'dyninfo-start))
 690    (dolist (info *dynamic-space-code-info*)
 691      (setf (dyninfo-new-start info)
 692            (code-start (dyninfo-code info))))
 693    (progn
 694      (dotimes (i +sample-size+)
 695        (adjust-samples i)))
 696    (dolist (info *dynamic-space-code-info*)
 697      (let ((size (- (dyninfo-end info) (dyninfo-start info))))
 698        (setf (dyninfo-start info) (dyninfo-new-start info))
 699        (setf (dyninfo-end info) (+ (dyninfo-new-start info) size))))
 700    (turn-on-sampling)))
 701
 702 (defmacro with-profiling ((&key (sample-interval '*sample-interval*)
 703                                 (max-samples '*max-samples*)
 704                                 (reset nil)
 705                                 show-progress
 706                                 (report nil report-p))
 707                           &body body)
 708   "Repeatedly evaluate Body with statistical profiling turned on.
 709    The following keyword args are recognized:
 710
 711    :Sample-Interval <seconds>
 712      Take a sample every <seconds> seconds.  Default is
 713      *Sample-Interval*.
 714
 715    :Max-Samples <max>
 716      Repeat evaluating body until <max> samples are taken.
 717      Default is *Max-Samples*.
 718
 719    :Report <type>
 720      If specified, call Report with :Type <type> at the end.
 721
 722    :Reset <bool>
 723      It true, call Reset at the beginning."
 724   (declare (type report-type report))
 725   `(let ((*sample-interval* ,sample-interval)
 726          (*max-samples* ,max-samples))
 727      ,@(when reset '((reset)))
 728      (start-profiling)
 729      (loop
 730         (when (>= *samples-index* (length *samples*))
 731           (return))
 732         ,@(when show-progress
 733             `((format t "~&===> ~d of ~d samples taken.~%"
 734                       (/ *samples-index* +sample-size+)
 735                       *max-samples*)))
 736         (let ((.last-index. *samples-index*))
 737           ,@body
 738           (when (= .last-index. *samples-index*)
 739             (warn "No sampling progress; possibly a profiler bug.")
 740             (return))))
 741      (stop-profiling)
 742      ,@(when report-p `((report :type ,report)))))
 743
 744 (defun start-profiling (&key (max-samples *max-samples*)
 745                         (sample-interval *sample-interval*)
 746                         (sampling t))
 747   "Start profiling statistically if not already profiling.
 748    The following keyword args are recognized:
 749
 750    :Sample-Interval <seconds>
 751      Take a sample every <seconds> seconds.  Default is
 752      *Sample-Interval*.
 753
 754    :Max-Samples <max>
 755      Maximum number of samples.  Default is *Max-Samples*.
 756
 757    :Sampling <bool>
 758      If true, the default, start sampling right away.
 759      If false, Start-Sampling can be used to turn sampling on."
 760   (unless *profiling*
 761     (multiple-value-bind (secs usecs)
 762         (multiple-value-bind (secs rest)
 763             (truncate sample-interval)
 764           (values secs (truncate (* rest 1000000))))
 765       (setq *samples* (make-array (* max-samples +sample-size+)
 766                                   :element-type 'address))
 767       (setq *samples-index* 0)
 768       (setq *sampling* sampling)
 769       ;; Disabled for now, since this was causing some problems with the
 770       ;; sampling getting turned off completely. --JES, 2004-06-19
 771       ;;
 772       ;; BEFORE-GC-HOOKS have exceedingly bad interactions with
 773       ;; threads.  -- CSR, 2004-06-21
 774       ;;
 775       ;; (pushnew 'turn-off-sampling *before-gc-hooks*)
 776       (pushnew 'adjust-samples-for-address-changes *after-gc-hooks*)
 777       (record-dyninfo)
 778       (sb-sys:enable-interrupt sb-unix::sigprof #'sigprof-handler)
 779       (unix-setitimer :profile secs usecs secs usecs)
 780       (setq *profiling* t)))
 781   (values))
 782
 783 (defun stop-profiling ()
 784   "Stop profiling if profiling."
 785   (when *profiling*
 786     (setq *after-gc-hooks*
 787           (delete 'adjust-samples-for-address-changes *after-gc-hooks*))
 788     (unix-setitimer :profile 0 0 0 0)
 789     (sb-sys:enable-interrupt sb-unix::sigprof :default)
 790     (setq *sampling* nil)
 791     (setq *profiling* nil))
 792   (values))
 793
 794 (defun reset ()
 795   "Reset the profiler."
 796   (stop-profiling)
 797   (setq *sampling* nil)
 798   (setq *dynamic-space-code-info* ())
 799   (setq *samples* nil)
 800   (setq *samples-index* 0)
 801   (values))
 802
 803 ;;; Make a NODE for debug-info INFO.
 804 (defun make-node (info)
 805   (typecase info
 806     (sb-kernel::code-component
 807      (multiple-value-bind (start end)
 808          (code-bounds info)
 809        (%make-node :name (or (sb-disassem::find-assembler-routine start)
 810                              (format nil "~a" info))
 811                    :start-pc start :end-pc end)))
 812     (sb-di::compiled-debug-fun
 813      (let* ((name (sb-di::debug-fun-name info))
 814             (cdf (sb-di::compiled-debug-fun-compiler-debug-fun info))
 815             (start-offset (sb-c::compiled-debug-fun-start-pc cdf))
 816             (end-offset (sb-c::compiled-debug-fun-elsewhere-pc cdf))
 817             (component (sb-di::compiled-debug-fun-component info))
 818             (start-pc (code-start component)))
 819        (%make-node :name name
 820                    :start-pc (+ start-pc start-offset)
 821                    :end-pc (+ start-pc end-offset))))
 822     (sb-di::debug-fun
 823      (%make-node :name (sb-di::debug-fun-name info)))
 824     (t
 825      (%make-node :name (coerce info 'string)))))
 826
 827 ;;; Return something serving as debug info for address PC.  If we can
 828 ;;; get something from SB-DI:DEBUG-FUNCTION-FROM-PC, return that.
 829 ;;; Otherwise, if we can determine a code component, return that.
 830 ;;; Otherwise return nil.
 831 (defun debug-info (pc)
 832   (declare (type address pc))
 833   (let ((ptr (sb-di::component-ptr-from-pc (int-sap pc))))
 834     (cond ((sap= ptr (int-sap 0))
 835            (let ((name (sap-foreign-symbol (int-sap pc))))
 836              (when name
 837                (format nil "foreign function ~a" name))))
 838           (t
 839            (let* ((code (sb-di::component-from-component-ptr ptr))
 840                   (code-header-len (* (sb-kernel:get-header-data code)
 841                                       sb-vm:n-word-bytes))
 842                   (pc-offset (- pc
 843                                 (- (sb-kernel:get-lisp-obj-address code)
 844                                    sb-vm:other-pointer-lowtag)
 845                                 code-header-len))
 846                   (df (ignore-errors (sb-di::debug-fun-from-pc code
 847                                                                pc-offset))))
 848              (or df
 849                  code))))))
 850
 851
 852 ;;; One function can have more than one COMPILED-DEBUG-FUNCTION with
 853 ;;; the same name.  Reduce the number of calls to Debug-Info by first
 854 ;;; looking for a given PC in a red-black tree.  If not found in the
 855 ;;; tree, get debug info, and look for a node in a hash-table by
 856 ;;; function name.  If not found in the hash-table, make a new node.
 857
 858 (defvar *node-tree*)
 859 (defvar *name->node*)
 860
 861 (defmacro with-lookup-tables (() &body body)
 862   `(let ((*node-tree* (make-aa-tree))
 863          (*name->node* (make-hash-table :test 'equal)))
 864      ,@body))
 865
 866 (defun tree-find (item)
 867   (flet ((pc/node-= (pc node)
 868            (<= (node-start-pc node) pc (node-end-pc node)))
 869          (pc/node-< (pc node)
 870            (< pc (node-start-pc node))))
 871     (aa-find item *node-tree* :test-= #'pc/node-= :test-< #'pc/node-<)))
 872
 873 (defun tree-insert (item)
 874   (flet ((node/node-= (x y)
 875            (<= (node-start-pc y) (node-start-pc x) (node-end-pc y)))
 876          (node/node-< (x y)
 877            (< (node-start-pc x) (node-start-pc y))))
 878     (aa-insert item *node-tree* :test-= #'node/node-= :test-< #'node/node-<)))
 879
 880 ;;; Find or make a new node for address PC.  Value is the NODE found
 881 ;;; or made; NIL if not enough information exists to make a NODE for
 882 ;;; PC.
 883 (defun lookup-node (pc)
 884   (declare (type address pc))
 885   (or (tree-find pc)
 886       (let ((info (debug-info pc)))
 887         (when info
 888           (let* ((new (make-node info))
 889                  (found (gethash (node-name new) *name->node*)))
 890             (cond (found
 891                    (setf (node-start-pc found)
 892                          (min (node-start-pc found) (node-start-pc new)))
 893                    (setf (node-end-pc found)
 894                          (max (node-end-pc found) (node-end-pc new)))
 895                    found)
 896                   (t
 897                    (setf (gethash (node-name new) *name->node*) new)
 898                    (tree-insert new)
 899                    new)))))))
 900
 901 ;;; Return a list of all nodes created by LOOKUP-NODE.
 902 (defun collect-nodes ()
 903   (loop for node being the hash-values of *name->node*
 904         collect node))
 905
 906 ;;; Value is a CALL-GRAPH for the current contents of *SAMPLES*.
 907 (defun make-call-graph-1 (depth)
 908   (let ((elsewhere-count 0)
 909         visited-nodes)
 910     (with-lookup-tables ()
 911       (loop for i below (1- *samples-index*) ;; by +sample-size+
 912             as pc = (aref *samples* i)
 913             as return-pc = (aref *samples* (1+ i))
 914             as callee = (lookup-node pc)
 915             as caller =
 916               (when (and callee (/= return-pc +unknown-address+))
 917                 (let ((caller (lookup-node return-pc)))
 918                   (when caller
 919                     caller)))
 920             do
 921             (when (and *show-progress* (plusp i))
 922               (cond ((zerop (mod i 1000))
 923                      (show-progress "~d" i))
 924                     ((zerop (mod i 100))
 925                      (show-progress "."))))
 926             (when (< (mod i +sample-size+) depth)
 927               (when (= (mod i +sample-size+) 0)
 928                 (setf visited-nodes nil)
 929                 (cond (callee
 930                        (incf (node-accrued-count callee))
 931                        (incf (node-count callee)))
 932                       (t
 933                        (incf elsewhere-count))))
 934               (when callee
 935                 (push callee visited-nodes))
 936               (when caller
 937                 (unless (member caller visited-nodes)
 938                   (incf (node-accrued-count caller)))
 939                 (when callee
 940                   (let ((call (find callee (node-edges caller)
 941                                     :key #'call-vertex)))
 942                     (pushnew caller (node-callers callee))
 943                     (if call
 944                         (unless (member caller visited-nodes)
 945                           (incf (call-count call)))
 946                         (push (make-call callee) (node-edges caller))))))))
 947       (let ((sorted-nodes (sort (collect-nodes) #'> :key #'node-count)))
 948         (loop for node in sorted-nodes and i from 1 do
 949                 (setf (node-index node) i))
 950         (%make-call-graph :nsamples (/ *samples-index* +sample-size+)
 951                           :sample-interval *sample-interval*
 952                           :elsewhere-count elsewhere-count
 953                           :vertices sorted-nodes)))))
 954
 955 ;;; Reduce CALL-GRAPH to a dag, creating CYCLE structures for call
 956 ;;; cycles.
 957 (defun reduce-call-graph (call-graph)
 958   (let ((cycle-no 0))
 959     (flet ((make-one-cycle (vertices edges)
 960              (let* ((name (format nil "<Cycle ~d>" (incf cycle-no)))
 961                     (count (loop for v in vertices sum (node-count v))))
 962                (make-cycle :name name
 963                            :index cycle-no
 964                            :count count
 965                            :scc-vertices vertices
 966                            :edges edges))))
 967       (reduce-graph call-graph #'make-one-cycle))))
 968
 969 ;;; For all nodes in CALL-GRAPH, compute times including the time
 970 ;;; spent in functions called from them.  Note that the call-graph
 971 ;;; vertices are in reverse topological order, children first, so we
 972 ;;; will have computed accrued counts of called functions before they
 973 ;;; are used to compute accrued counts for callers.
 974 (defun compute-accrued-counts (call-graph)
 975   (do-vertices (from call-graph)
 976     (setf (node-accrued-count from) (node-count from))
 977     (do-edges (call to from)
 978       (incf (node-accrued-count from)
 979             (round (* (/ (call-count call) (node-count to))
 980                       (node-accrued-count to)))))))
 981
 982 ;;; Return a CALL-GRAPH structure for the current contents of
 983 ;;; *SAMPLES*.  The result contain a list of nodes sorted by self-time
 984 ;;; in the FLAT-NODES slot, and a dag in VERTICES, with call cycles
 985 ;;; reduced to CYCLE structures.
 986 (defun make-call-graph (depth)
 987   (stop-profiling)
 988   (show-progress "~&Computing call graph ")
 989   (let ((call-graph (without-gcing (make-call-graph-1 depth))))
 990     (setf (call-graph-flat-nodes call-graph)
 991           (copy-list (graph-vertices call-graph)))
 992     (show-progress "~&Finding cycles")
 993     (reduce-call-graph call-graph)
 994     (show-progress "~&Propagating counts")
 995     #+nil (compute-accrued-counts call-graph)
 996     call-graph))
 997
 998 \f
 999 ;;;; Reporting
1000
1001 (defun print-separator (&key (length 72) (char #\-))
1002   (format t "~&~V,,,V<~>~%" length char))
1003
1004 (defun samples-percent (call-graph count)
1005   (* 100.0 (/ count (call-graph-nsamples call-graph))))
1006
1007 (defun print-call-graph-header (call-graph)
1008   (let ((nsamples (call-graph-nsamples call-graph))
1009         (interval (call-graph-sample-interval call-graph))
1010         (ncycles (loop for v in (graph-vertices call-graph)
1011                        count (scc-p v))))
1012     (format t "~2&Number of samples:   ~d~%~
1013                   Sample interval:     ~f seconds~%~
1014                   Total sampling time: ~f seconds~%~
1015                   Number of cycles:    ~d~2%"
1016             nsamples
1017             interval
1018             (* nsamples interval)
1019             ncycles)))
1020
1021 (defun print-flat (call-graph &key (stream *standard-output*) max
1022                    min-percent (print-header t))
1023   (let ((*standard-output* stream)
1024         (*print-pretty* nil)
1025         (total-count 0)
1026         (total-percent 0)
1027         (min-count (if min-percent
1028                        (round (* (/ min-percent 100.0)
1029                                  (call-graph-nsamples call-graph)))
1030                        0)))
1031     (when print-header
1032       (print-call-graph-header call-graph))
1033     (format t "~&           Self        Cumul        Total~%")
1034     (format t "~&  Nr  Count     %  Count     %  Count     % Function~%")
1035     (print-separator)
1036     (let ((elsewhere-count (call-graph-elsewhere-count call-graph))
1037           (i 0))
1038       (dolist (node (call-graph-flat-nodes call-graph))
1039         (when (or (and max (> (incf i) max))
1040                   (< (node-count node) min-count))
1041           (return))
1042         (let* ((count (node-count node))
1043                (percent (samples-percent call-graph count))
1044                (accrued-count (node-accrued-count node))
1045                (accrued-percent (samples-percent call-graph accrued-count)))
1046           (incf total-count count)
1047           (incf total-percent percent)
1048           (format t "~&~4d ~6d ~5,1f ~6d ~5,1f ~6d ~5,1f ~s~%"
1049                   (node-index node)
1050                   count
1051                   percent
1052                   accrued-count
1053                   accrued-percent
1054                   total-count
1055                   total-percent
1056                   (node-name node))
1057           (finish-output)))
1058       (print-separator)
1059       (format t "~&    ~6d ~5,1f              elsewhere~%"
1060               elsewhere-count
1061               (samples-percent call-graph elsewhere-count)))))
1062
1063 (defun print-cycles (call-graph)
1064   (when (some #'cycle-p (graph-vertices call-graph))
1065     (format t "~&                            Cycle~%")
1066     (format t "~& Count     %                   Parts~%")
1067     (do-vertices (node call-graph)
1068       (when (cycle-p node)
1069         (flet ((print-info (indent index count percent name)
1070                  (format t "~&~6d ~5,1f ~11@t ~V@t  ~s [~d]~%"
1071                          count percent indent name index)))
1072           (print-separator)
1073           (format t "~&~6d ~5,1f                ~a...~%"
1074                   (node-count node)
1075                   (samples-percent call-graph (cycle-count node))
1076                   (node-name node))
1077           (dolist (v (vertex-scc-vertices node))
1078             (print-info 4 (node-index v) (node-count v)
1079                         (samples-percent call-graph (node-count v))
1080                         (node-name v))))))
1081     (print-separator)
1082     (format t "~2%")))
1083
1084 (defun print-graph (call-graph &key (stream *standard-output*)
1085                     max min-percent)
1086   (let ((*standard-output* stream)
1087         (*print-pretty* nil))
1088     (print-call-graph-header call-graph)
1089     (print-cycles call-graph)
1090     (flet ((find-call (from to)
1091              (find to (node-edges from) :key #'call-vertex))
1092            (print-info (indent index count percent name)
1093              (format t "~&~6d ~5,1f ~11@t ~V@t  ~s [~d]~%"
1094                      count percent indent name index)))
1095       (format t "~&                               Callers~%")
1096       (format t "~&                 Cumul.     Function~%")
1097       (format t "~& Count     %  Count     %      Callees~%")
1098       (do-vertices (node call-graph)
1099         (print-separator)
1100         ;;
1101         ;; Print caller information.
1102         (dolist (caller (node-callers node))
1103           (let ((call (find-call caller node)))
1104             (print-info 4 (node-index caller)
1105                         (call-count call)
1106                         (samples-percent call-graph (call-count call))
1107                         (node-name caller))))
1108         ;; Print the node itself.
1109         (format t "~&~6d ~5,1f ~6d ~5,1f   ~s [~d]~%"
1110                 (node-count node)
1111                 (samples-percent call-graph (node-count node))
1112                 (node-accrued-count node)
1113                 (samples-percent call-graph (node-accrued-count node))
1114                 (node-name node)
1115                 (node-index node))
1116         ;; Print callees.
1117         (do-edges (call called node)
1118           (print-info 4 (node-index called)
1119                       (call-count call)
1120                       (samples-percent call-graph (call-count call))
1121                       (node-name called))))
1122       (print-separator)
1123       (format t "~2%")
1124       (print-flat call-graph :stream stream :max max
1125                   :min-percent min-percent :print-header nil))))
1126
1127 (defun report (&key (type :graph) max min-percent call-graph
1128                (stream *standard-output*) ((:show-progress *show-progress*)))
1129   "Report statistical profiling results.  The following keyword
1130    args are recognized:
1131
1132    :Type <type>
1133       Specifies the type of report to generate.  If :FLAT, show
1134       flat report, if :GRAPH show a call graph and a flat report.
1135       If nil, don't print out a report.
1136
1137    :Stream <stream>
1138       Specify a stream to print the report on.  Default is
1139       *Standard-Output*.
1140
1141    :Max <max>
1142       Don't show more than <max> entries in the flat report.
1143
1144    :Min-Percent <min-percent>
1145       Don't show functions taking less than <min-percent> of the
1146       total time in the flat report.
1147
1148    :Show-Progress <bool>
1149      If true, print progress messages while generating the call graph.
1150
1151    :Call-Graph <graph>
1152      Print a report from <graph> instead of the latest profiling
1153      results.
1154
1155    Value of this function is a Call-Graph object representing the
1156    resulting call-graph."
1157   (let ((graph (or call-graph (make-call-graph (1- +sample-size+)))))
1158     (ecase type
1159       (:flat
1160        (print-flat graph :stream stream :max max :min-percent min-percent))
1161       (:graph
1162        (print-graph graph :stream stream :max max :min-percent min-percent))
1163       ((nil)))
1164     graph))
1165
1166 ;;; Interface to DISASSEMBLE
1167
1168 (defun add-disassembly-profile-note (chunk stream dstate)
1169   (declare (ignore chunk stream))
1170   (unless (zerop *samples-index*)
1171     (let* ((location
1172             (+ (sb-disassem::seg-virtual-location
1173                 (sb-disassem:dstate-segment dstate))
1174                (sb-disassem::dstate-cur-offs dstate)))
1175            (samples (loop for x from 0 below *samples-index* by +sample-size+
1176                           summing (if (= (aref *samples* x) location)
1177                                       1
1178                                       0))))
1179       (unless (zerop samples)
1180         (sb-disassem::note (format nil "~A/~A samples"
1181                                    samples (/ *samples-index* +sample-size+))
1182                            dstate)))))
1183
1184 (pushnew 'add-disassembly-profile-note sb-disassem::*default-dstate-hooks*)
1185
1186 ;;; silly examples
1187
1188 (defun test-0 (n &optional (depth 0))
1189   (declare (optimize (debug 3)))
1190   (when (< depth n)
1191     (dotimes (i n)
1192       (test-0 n (1+ depth))
1193       (test-0 n (1+ depth)))))
1194
1195 (defun test ()
1196   (with-profiling (:reset t :max-samples 1000 :report :graph)
1197     (test-0 7)))
1198
1199
1200 ;;; provision
1201 (provide 'sb-sprof)
1202
1203 ;;; end of file