ecmalisp.lisp

   1 ;;; ecmalisp.lisp ---
   2
   3 ;; Copyright (C) 2012, 2013 David Vazquez
   4 ;; Copyright (C) 2012 Raimon Grau
   5
   6 ;; This program is free software: you can redistribute it and/or
   7 ;; modify it under the terms of the GNU General Public License as
   8 ;; published by the Free Software Foundation, either version 3 of the
   9 ;; License, or (at your option) any later version.
  10 ;;
  11 ;; This program is distributed in the hope that it will be useful, but
  12 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;; General Public License for more details.
  15 ;;
  16 ;; You should have received a copy of the GNU General Public License
  17 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;; This code is executed when ecmalisp compiles this file
  20 ;;; itself. The compiler provides compilation of some special forms,
  21 ;;; as well as funcalls and macroexpansion, but no functions. So, we
  22 ;;; define the Lisp world from scratch. This code has to define enough
  23 ;;; language to the compiler to be able to run.
  24
  25 #+ecmalisp
  26 (progn
  27   (eval-when-compile
  28     (%compile-defmacro 'defmacro
  29                        '(lambda (name args &rest body)
  30                          `(eval-when-compile
  31                             (%compile-defmacro ',name
  32                                                '(lambda ,(mapcar (lambda (x)
  33                                                                    (if (eq x '&body)
  34                                                                        '&rest
  35                                                                        x))
  36                                                                  args)
  37                                                  ,@body))))))
  38
  39   (setq nil 'nil)
  40   (setq t 't)
  41
  42   (defmacro when (condition &body body)
  43     `(if ,condition (progn ,@body) nil))
  44
  45   (defmacro unless (condition &body body)
  46     `(if ,condition nil (progn ,@body)))
  47
  48   (defmacro defvar (name value &optional docstring)
  49     `(progn
  50        (unless (boundp ',name)
  51          (setq ,name ,value))
  52        ,@(when (stringp docstring) `((oset ',name "vardoc" ,docstring)))
  53        ',name))
  54
  55   (defmacro defparameter (name value &optional docstring)
  56     `(progn
  57        (setq ,name ,value)
  58        ,@(when (stringp docstring) `((oset ',name "vardoc" ,docstring)))
  59        ',name))
  60
  61   (defmacro named-lambda (name args &rest body)
  62     (let ((x (gensym "FN")))
  63       `(let ((,x (lambda ,args ,@body)))
  64          (oset ,x "fname" ,name)
  65          ,x)))
  66
  67   (defmacro defun (name args &rest body)
  68     `(progn
  69        (fset ',name
  70              (named-lambda ,(symbol-name name) ,args
  71                ,@(if (and (stringp (car body)) (not (null (cdr body))))
  72                      `(,(car body) (block ,name ,@(cdr body)))
  73                      `((block ,name ,@body)))))
  74        ',name))
  75
  76   (defvar *package* (new))
  77
  78   (defun null (x)
  79     (eq x nil))
  80
  81   (defmacro return (&optional value)
  82     `(return-from nil ,value))
  83
  84   (defmacro while (condition &body body)
  85     `(block nil (%while ,condition ,@body)))
  86
  87   (defun internp (name)
  88     (in name *package*))
  89
  90   (defun intern (name)
  91     (if (internp name)
  92         (oget *package* name)
  93         (oset *package* name (make-symbol name))))
  94
  95   (defun find-symbol (name)
  96     (oget *package* name))
  97
  98   (defvar *gensym-counter* 0)
  99   (defun gensym (&optional (prefix "G"))
 100     (setq *gensym-counter* (+ *gensym-counter* 1))
 101     (make-symbol (concat-two prefix (integer-to-string *gensym-counter*))))
 102
 103   (defun boundp (x)
 104     (boundp x))
 105
 106   ;; Basic functions
 107   (defun = (x y) (= x y))
 108   (defun + (x y) (+ x y))
 109   (defun - (x y) (- x y))
 110   (defun * (x y) (* x y))
 111   (defun / (x y) (/ x y))
 112   (defun 1+ (x) (+ x 1))
 113   (defun 1- (x) (- x 1))
 114   (defun zerop (x) (= x 0))
 115   (defun truncate (x y) (floor (/ x y)))
 116
 117   (defun eql (x y) (eq x y))
 118
 119   (defun not (x) (if x nil t))
 120
 121   (defun cons (x y ) (cons x y))
 122   (defun consp (x) (consp x))
 123
 124   (defun car (x)
 125     "Return the CAR part of a cons, or NIL if X is null."
 126     (car x))
 127
 128   (defun cdr (x) (cdr x))
 129   (defun caar (x) (car (car x)))
 130   (defun cadr (x) (car (cdr x)))
 131   (defun cdar (x) (cdr (car x)))
 132   (defun cddr (x) (cdr (cdr x)))
 133   (defun caddr (x) (car (cdr (cdr x))))
 134   (defun cdddr (x) (cdr (cdr (cdr x))))
 135   (defun cadddr (x) (car (cdr (cdr (cdr x)))))
 136   (defun first (x) (car x))
 137   (defun second (x) (cadr x))
 138   (defun third (x) (caddr x))
 139   (defun fourth (x) (cadddr x))
 140
 141   (defun list (&rest args) args)
 142   (defun atom (x)
 143     (not (consp x)))
 144
 145   ;; Basic macros
 146
 147   (defmacro incf (x &optional (delta 1))
 148     `(setq ,x (+ ,x ,delta)))
 149
 150   (defmacro decf (x &optional (delta 1))
 151     `(setq ,x (- ,x ,delta)))
 152
 153   (defmacro push (x place)
 154     `(setq ,place (cons ,x ,place)))
 155
 156   (defmacro dolist (iter &body body)
 157     (let ((var (first iter))
 158           (g!list (gensym)))
 159       `(block nil
 160          (let ((,g!list ,(second iter))
 161                (,var nil))
 162            (%while ,g!list
 163                    (setq ,var (car ,g!list))
 164                    (tagbody ,@body)
 165                    (setq ,g!list (cdr ,g!list)))
 166            ,(third iter)))))
 167
 168   (defmacro dotimes (iter &body body)
 169     (let ((g!to (gensym))
 170           (var (first iter))
 171           (to (second iter))
 172           (result (third iter)))
 173       `(block nil
 174          (let ((,var 0)
 175                (,g!to ,to))
 176            (%while (< ,var ,g!to)
 177                    (tagbody ,@body)
 178                    (incf ,var))
 179            ,result))))
 180
 181   (defmacro cond (&rest clausules)
 182     (if (null clausules)
 183         nil
 184         (if (eq (caar clausules) t)
 185             `(progn ,@(cdar clausules))
 186             `(if ,(caar clausules)
 187                  (progn ,@(cdar clausules))
 188                  (cond ,@(cdr clausules))))))
 189
 190   (defmacro case (form &rest clausules)
 191     (let ((!form (gensym)))
 192       `(let ((,!form ,form))
 193          (cond
 194            ,@(mapcar (lambda (clausule)
 195                        (if (eq (car clausule) t)
 196                            clausule
 197                            `((eql ,!form ',(car clausule))
 198                              ,@(cdr clausule))))
 199                      clausules)))))
 200
 201   (defmacro ecase (form &rest clausules)
 202     `(case ,form
 203        ,@(append
 204           clausules
 205           `((t
 206              (error "ECASE expression failed."))))))
 207
 208   (defmacro and (&rest forms)
 209     (cond
 210       ((null forms)
 211        t)
 212       ((null (cdr forms))
 213        (car forms))
 214       (t
 215        `(if ,(car forms)
 216             (and ,@(cdr forms))
 217             nil))))
 218
 219   (defmacro or (&rest forms)
 220     (cond
 221       ((null forms)
 222        nil)
 223       ((null (cdr forms))
 224        (car forms))
 225       (t
 226        (let ((g (gensym)))
 227          `(let ((,g ,(car forms)))
 228             (if ,g ,g (or ,@(cdr forms))))))))
 229
 230   (defmacro prog1 (form &body body)
 231     (let ((value (gensym)))
 232       `(let ((,value ,form))
 233          ,@body
 234          ,value)))
 235
 236   (defmacro prog2 (form1 result &body body)
 237     `(prog1 (progn ,form1 ,result) ,@body)))
 238
 239
 240
 241 ;;; This couple of helper functions will be defined in both Common
 242 ;;; Lisp and in Ecmalisp.
 243 (defun ensure-list (x)
 244   (if (listp x)
 245       x
 246       (list x)))
 247
 248 (defun !reduce (func list initial)
 249   (if (null list)
 250       initial
 251       (!reduce func
 252                (cdr list)
 253                (funcall func initial (car list)))))
 254
 255 ;;; Go on growing the Lisp language in Ecmalisp, with more high
 256 ;;; level utilities as well as correct versions of other
 257 ;;; constructions.
 258 #+ecmalisp
 259 (progn
 260   (defun append-two (list1 list2)
 261     (if (null list1)
 262         list2
 263         (cons (car list1)
 264               (append (cdr list1) list2))))
 265
 266   (defun append (&rest lists)
 267     (!reduce #'append-two lists '()))
 268
 269   (defun revappend (list1 list2)
 270     (while list1
 271       (push (car list1) list2)
 272       (setq list1 (cdr list1)))
 273     list2)
 274
 275   (defun reverse (list)
 276     (revappend list '()))
 277
 278   (defun list-length (list)
 279     (let ((l 0))
 280       (while (not (null list))
 281         (incf l)
 282         (setq list (cdr list)))
 283       l))
 284
 285   (defun length (seq)
 286     (if (stringp seq)
 287         (string-length seq)
 288         (list-length seq)))
 289
 290   (defun concat-two (s1 s2)
 291     (concat-two s1 s2))
 292
 293   (defun mapcar (func list)
 294     (if (null list)
 295         '()
 296         (cons (funcall func (car list))
 297               (mapcar func (cdr list)))))
 298
 299   (defun identity (x) x)
 300
 301   (defun copy-list (x)
 302     (mapcar #'identity x))
 303
 304   (defun code-char (x) x)
 305   (defun char-code (x) x)
 306   (defun char= (x y) (= x y))
 307
 308   (defun integerp (x)
 309     (and (numberp x) (= (floor x) x)))
 310
 311   (defun plusp (x) (< 0 x))
 312   (defun minusp (x) (< x 0))
 313
 314   (defun listp (x)
 315     (or (consp x) (null x)))
 316
 317   (defun nthcdr (n list)
 318     (while (and (plusp n) list)
 319       (setq n (1- n))
 320       (setq list (cdr list)))
 321     list)
 322
 323   (defun nth (n list)
 324     (car (nthcdr n list)))
 325
 326   (defun last (x)
 327     (while (consp (cdr x))
 328       (setq x (cdr x)))
 329     x)
 330
 331   (defun butlast (x)
 332     (and (consp (cdr x))
 333          (cons (car x) (butlast (cdr x)))))
 334
 335   (defun member (x list)
 336     (while list
 337       (when (eql x (car list))
 338         (return list))
 339       (setq list (cdr list))))
 340
 341   (defun remove (x list)
 342     (cond
 343       ((null list)
 344        nil)
 345       ((eql x (car list))
 346        (remove x (cdr list)))
 347       (t
 348        (cons (car list) (remove x (cdr list))))))
 349
 350   (defun remove-if (func list)
 351     (cond
 352       ((null list)
 353        nil)
 354       ((funcall func (car list))
 355        (remove-if func (cdr list)))
 356       (t
 357        (cons (car list) (remove-if func (cdr list))))))
 358
 359   (defun remove-if-not (func list)
 360     (cond
 361       ((null list)
 362        nil)
 363       ((funcall func (car list))
 364        (cons (car list) (remove-if-not func (cdr list))))
 365       (t
 366        (remove-if-not func (cdr list)))))
 367
 368   (defun digit-char-p (x)
 369     (if (and (<= #\0 x) (<= x #\9))
 370         (- x #\0)
 371         nil))
 372
 373   (defun subseq (seq a &optional b)
 374     (cond
 375       ((stringp seq)
 376        (if b
 377            (slice seq a b)
 378            (slice seq a)))
 379       (t
 380        (error "Unsupported argument."))))
 381
 382   (defun parse-integer (string)
 383     (let ((value 0)
 384           (index 0)
 385           (size (length string)))
 386       (while (< index size)
 387         (setq value (+ (* value 10) (digit-char-p (char string index))))
 388         (incf index))
 389       value))
 390
 391   (defun some (function seq)
 392     (cond
 393       ((stringp seq)
 394        (let ((index 0)
 395              (size (length seq)))
 396          (while (< index size)
 397            (when (funcall function (char seq index))
 398              (return-from some t))
 399            (incf index))
 400          nil))
 401       ((listp seq)
 402        (dolist (x seq nil)
 403          (when (funcall function x)
 404            (return t))))
 405       (t
 406        (error "Unknown sequence."))))
 407
 408   (defun every (function seq)
 409     (cond
 410       ((stringp seq)
 411        (let ((index 0)
 412              (size (length seq)))
 413          (while (< index size)
 414            (unless (funcall function (char seq index))
 415              (return-from every nil))
 416            (incf index))
 417          t))
 418       ((listp seq)
 419        (dolist (x seq t)
 420          (unless (funcall function x)
 421            (return))))
 422       (t
 423        (error "Unknown sequence."))))
 424
 425   (defun assoc (x alist)
 426     (while alist
 427       (if (eql x (caar alist))
 428           (return)
 429           (setq alist (cdr alist))))
 430     (car alist))
 431
 432   (defun string= (s1 s2)
 433     (equal s1 s2))
 434
 435   (defun fdefinition (x)
 436     (cond
 437       ((functionp x)
 438        x)
 439       ((symbolp x)
 440        (symbol-function x))
 441       (t
 442        (error "Invalid function"))))
 443
 444   (defun disassemble (function)
 445     (write-line (lambda-code (fdefinition function)))
 446     nil)
 447
 448   (defun documentation (x type)
 449     "Return the documentation of X. TYPE must be the symbol VARIABLE or FUNCTION."
 450     (ecase type
 451       (function
 452        (let ((func (fdefinition x)))
 453          (oget func "docstring")))
 454       (variable
 455        (unless (symbolp x)
 456          (error "Wrong argument type! it should be a symbol"))
 457        (oget x "vardoc"))))
 458   )
 459
 460 ;;; The compiler offers some primitives and special forms which are
 461 ;;; not found in Common Lisp, for instance, while. So, we grow Common
 462 ;;; Lisp a bit to it can execute the rest of the file.
 463 #+common-lisp
 464 (progn
 465   (defmacro while (condition &body body)
 466     `(do ()
 467          ((not ,condition))
 468        ,@body))
 469
 470   (defmacro eval-when-compile (&body body)
 471     `(eval-when (:compile-toplevel :load-toplevel :execute)
 472        ,@body))
 473
 474   (defun concat-two (s1 s2)
 475     (concatenate 'string s1 s2))
 476
 477   (defun setcar (cons new)
 478     (setf (car cons) new))
 479   (defun setcdr (cons new)
 480     (setf (cdr cons) new)))
 481
 482 ;;; At this point, no matter if Common Lisp or ecmalisp is compiling
 483 ;;; from here, this code will compile on both. We define some helper
 484 ;;; functions now for string manipulation and so on. They will be
 485 ;;; useful in the compiler, mostly.
 486
 487 (defvar *newline* (string (code-char 10)))
 488
 489 (defun concat (&rest strs)
 490   (!reduce #'concat-two strs ""))
 491
 492 (defmacro concatf (variable &body form)
 493   `(setq ,variable (concat ,variable (progn ,@form))))
 494
 495 ;;; Concatenate a list of strings, with a separator
 496 (defun join (list &optional (separator ""))
 497   (cond
 498     ((null list)
 499      "")
 500     ((null (cdr list))
 501      (car list))
 502     (t
 503      (concat (car list)
 504              separator
 505              (join (cdr list) separator)))))
 506
 507 (defun join-trailing (list &optional (separator ""))
 508   (if (null list)
 509       ""
 510       (concat (car list) separator (join-trailing (cdr list) separator))))
 511
 512 (defun mapconcat (func list)
 513   (join (mapcar func list)))
 514
 515 ;;; Like CONCAT, but prefix each line with four spaces. Two versions
 516 ;;; of this function are available, because the Ecmalisp version is
 517 ;;; very slow and bootstraping was annoying.
 518
 519 #+ecmalisp
 520 (defun indent (&rest string)
 521   (let ((input (join string)))
 522     (let ((output "")
 523           (index 0)
 524           (size (length input)))
 525       (when (plusp (length input)) (concatf output "    "))
 526       (while (< index size)
 527         (let ((str
 528                (if (and (char= (char input index) #\newline)
 529                         (< index (1- size))
 530                         (not (char= (char input (1+ index)) #\newline)))
 531                    (concat (string #\newline) "    ")
 532                    (string (char input index)))))
 533           (concatf output str))
 534         (incf index))
 535       output)))
 536
 537 #+common-lisp
 538 (defun indent (&rest string)
 539   (with-output-to-string (*standard-output*)
 540     (with-input-from-string (input (join string))
 541       (loop
 542          for line = (read-line input nil)
 543          while line
 544          do (write-string "    ")
 545          do (write-line line)))))
 546
 547
 548 (defun integer-to-string (x)
 549   (cond
 550     ((zerop x)
 551      "0")
 552     ((minusp x)
 553      (concat "-" (integer-to-string (- 0 x))))
 554     (t
 555      (let ((digits nil))
 556        (while (not (zerop x))
 557          (push (mod x 10) digits)
 558          (setq x (truncate x 10)))
 559        (join (mapcar (lambda (d) (string (char "0123456789" d)))
 560                      digits))))))
 561
 562
 563 ;;; Wrap X with a Javascript code to convert the result from
 564 ;;; Javascript generalized booleans to T or NIL.
 565 (defun js!bool (x)
 566   (concat "(" x "?" (ls-compile t) ": " (ls-compile nil) ")"))
 567
 568 ;;; Concatenate the arguments and wrap them with a self-calling
 569 ;;; Javascript anonymous function. It is used to make some Javascript
 570 ;;; statements valid expressions and provide a private scope as well.
 571 ;;; It could be defined as function, but we could do some
 572 ;;; preprocessing in the future.
 573 (defmacro js!selfcall (&body body)
 574   `(concat "(function(){" *newline* (indent ,@body) "})()"))
 575
 576
 577 ;;; Printer
 578
 579 #+ecmalisp
 580 (progn
 581   (defun prin1-to-string (form)
 582     (cond
 583       ((symbolp form) (symbol-name form))
 584       ((integerp form) (integer-to-string form))
 585       ((stringp form) (concat "\"" (escape-string form) "\""))
 586       ((functionp form)
 587        (let ((name (oget form "fname")))
 588          (if name
 589              (concat "#<FUNCTION " name ">")
 590              (concat "#<FUNCTION>"))))
 591       ((listp form)
 592        (concat "("
 593                (join-trailing (mapcar #'prin1-to-string (butlast form)) " ")
 594                (let ((last (last form)))
 595                  (if (null (cdr last))
 596                      (prin1-to-string (car last))
 597                      (concat (prin1-to-string (car last)) " . " (prin1-to-string (cdr last)))))
 598                ")"))))
 599
 600   (defun write-line (x)
 601     (write-string x)
 602     (write-string *newline*)
 603     x)
 604
 605   (defun warn (string)
 606     (write-string "WARNING: ")
 607     (write-line string))
 608
 609   (defun print (x)
 610     (write-line (prin1-to-string x))
 611     x))
 612
 613
 614 ;;;; Reader
 615
 616 ;;; The Lisp reader, parse strings and return Lisp objects. The main
 617 ;;; entry points are `ls-read' and `ls-read-from-string'.
 618
 619 (defun make-string-stream (string)
 620   (cons string 0))
 621
 622 (defun %peek-char (stream)
 623   (and (< (cdr stream) (length (car stream)))
 624        (char (car stream) (cdr stream))))
 625
 626 (defun %read-char (stream)
 627   (and (< (cdr stream) (length (car stream)))
 628        (prog1 (char (car stream) (cdr stream))
 629          (setcdr stream (1+ (cdr stream))))))
 630
 631 (defun whitespacep (ch)
 632   (or (char= ch #\space) (char= ch #\newline) (char= ch #\tab)))
 633
 634 (defun skip-whitespaces (stream)
 635   (let (ch)
 636     (setq ch (%peek-char stream))
 637     (while (and ch (whitespacep ch))
 638       (%read-char stream)
 639       (setq ch (%peek-char stream)))))
 640
 641 (defun terminalp (ch)
 642   (or (null ch) (whitespacep ch) (char= #\) ch) (char= #\( ch)))
 643
 644 (defun read-until (stream func)
 645   (let ((string "")
 646         (ch))
 647     (setq ch (%peek-char stream))
 648     (while (and ch (not (funcall func ch)))
 649       (setq string (concat string (string ch)))
 650       (%read-char stream)
 651       (setq ch (%peek-char stream)))
 652     string))
 653
 654 (defun skip-whitespaces-and-comments (stream)
 655   (let (ch)
 656     (skip-whitespaces stream)
 657     (setq ch (%peek-char stream))
 658     (while (and ch (char= ch #\;))
 659       (read-until stream (lambda (x) (char= x #\newline)))
 660       (skip-whitespaces stream)
 661       (setq ch (%peek-char stream)))))
 662
 663 (defun %read-list (stream)
 664   (skip-whitespaces-and-comments stream)
 665   (let ((ch (%peek-char stream)))
 666     (cond
 667       ((null ch)
 668        (error "Unspected EOF"))
 669       ((char= ch #\))
 670        (%read-char stream)
 671        nil)
 672       ((char= ch #\.)
 673        (%read-char stream)
 674        (prog1 (ls-read stream)
 675          (skip-whitespaces-and-comments stream)
 676          (unless (char= (%read-char stream) #\))
 677            (error "')' was expected."))))
 678       (t
 679        (cons (ls-read stream) (%read-list stream))))))
 680
 681 (defun read-string (stream)
 682   (let ((string "")
 683         (ch nil))
 684     (setq ch (%read-char stream))
 685     (while (not (eql ch #\"))
 686       (when (null ch)
 687         (error "Unexpected EOF"))
 688       (when (eql ch #\\)
 689         (setq ch (%read-char stream)))
 690       (setq string (concat string (string ch)))
 691       (setq ch (%read-char stream)))
 692     string))
 693
 694 (defun read-sharp (stream)
 695   (%read-char stream)
 696   (ecase (%read-char stream)
 697     (#\'
 698      (list 'function (ls-read stream)))
 699     (#\\
 700      (let ((cname
 701             (concat (string (%read-char stream))
 702                     (read-until stream #'terminalp))))
 703        (cond
 704          ((string= cname "space") (char-code #\space))
 705          ((string= cname "tab") (char-code #\tab))
 706          ((string= cname "newline") (char-code #\newline))
 707          (t (char-code (char cname 0))))))
 708     (#\+
 709      (let ((feature (read-until stream #'terminalp)))
 710        (cond
 711          ((string= feature "common-lisp")
 712           (ls-read stream)              ;ignore
 713           (ls-read stream))
 714          ((string= feature "ecmalisp")
 715           (ls-read stream))
 716          (t
 717           (error "Unknown reader form.")))))))
 718
 719 (defvar *eof* (make-symbol "EOF"))
 720 (defun ls-read (stream)
 721   (skip-whitespaces-and-comments stream)
 722   (let ((ch (%peek-char stream)))
 723     (cond
 724       ((null ch)
 725        *eof*)
 726       ((char= ch #\()
 727        (%read-char stream)
 728        (%read-list stream))
 729       ((char= ch #\')
 730        (%read-char stream)
 731        (list 'quote (ls-read stream)))
 732       ((char= ch #\`)
 733        (%read-char stream)
 734        (list 'backquote (ls-read stream)))
 735       ((char= ch #\")
 736        (%read-char stream)
 737        (read-string stream))
 738       ((char= ch #\,)
 739        (%read-char stream)
 740        (if (eql (%peek-char stream) #\@)
 741            (progn (%read-char stream) (list 'unquote-splicing (ls-read stream)))
 742            (list 'unquote (ls-read stream))))
 743       ((char= ch #\#)
 744        (read-sharp stream))
 745       (t
 746        (let ((string (read-until stream #'terminalp)))
 747          (if (every #'digit-char-p string)
 748              (parse-integer string)
 749              (intern (string-upcase string))))))))
 750
 751 (defun ls-read-from-string (string)
 752   (ls-read (make-string-stream string)))
 753
 754
 755 ;;;; Compiler
 756
 757 ;;; Translate the Lisp code to Javascript. It will compile the special
 758 ;;; forms. Some primitive functions are compiled as special forms
 759 ;;; too. The respective real functions are defined in the target (see
 760 ;;; the beginning of this file) as well as some primitive functions.
 761
 762 (defvar *compilation-unit-checks* '())
 763
 764 (defun make-binding (name type translation declared)
 765   (list name type translation declared))
 766
 767 (defun binding-name (b) (first b))
 768 (defun binding-type (b) (second b))
 769 (defun binding-value (b) (third b))
 770 (defun set-binding-value (b value)
 771   (setcar (cdr (cdr b)) value))
 772
 773 (defun binding-declared (b)
 774   (and b (fourth b)))
 775 (defun mark-binding-as-declared (b)
 776   (setcar (cdddr b) t))
 777
 778 (defun make-lexenv ()
 779   (list nil nil nil nil))
 780
 781 (defun copy-lexenv (lexenv)
 782   (copy-list lexenv))
 783
 784 (defun push-to-lexenv (binding lexenv namespace)
 785   (ecase namespace
 786     (variable   (setcar        lexenv  (cons binding (car lexenv))))
 787     (function   (setcar   (cdr lexenv) (cons binding (cadr lexenv))))
 788     (block      (setcar  (cddr lexenv) (cons binding (caddr lexenv))))
 789     (gotag      (setcar (cdddr lexenv) (cons binding (cadddr lexenv))))))
 790
 791 (defun extend-lexenv (bindings lexenv namespace)
 792   (let ((env (copy-lexenv lexenv)))
 793     (dolist (binding (reverse bindings) env)
 794       (push-to-lexenv binding env namespace))))
 795
 796 (defun lookup-in-lexenv (name lexenv namespace)
 797   (assoc name (ecase namespace
 798                 (variable (first lexenv))
 799                 (function (second lexenv))
 800                 (block (third lexenv))
 801                 (gotag (fourth lexenv)))))
 802
 803 (defvar *global-environment* (make-lexenv))
 804 (defvar *environment* (make-lexenv))
 805
 806 (defun clear-undeclared-global-bindings ()
 807   (setq *environment*
 808         (mapcar (lambda (namespace)
 809                   (remove-if-not #'binding-declared namespace))
 810                 *environment*)))
 811
 812
 813 (defvar *variable-counter* 0)
 814 (defun gvarname (symbol)
 815   (concat "v" (integer-to-string (incf *variable-counter*))))
 816
 817 (defun translate-variable (symbol)
 818   (binding-value (lookup-in-lexenv symbol *environment* 'variable)))
 819
 820 (defun extend-local-env (args)
 821   (let ((new (copy-lexenv *environment*)))
 822     (dolist (symbol args new)
 823       (let ((b (make-binding symbol 'lexical-variable (gvarname symbol) t)))
 824         (push-to-lexenv b new 'variable)))))
 825
 826 ;;; Toplevel compilations
 827 (defvar *toplevel-compilations* nil)
 828
 829 (defun toplevel-compilation (string)
 830   (push string *toplevel-compilations*))
 831
 832 (defun null-or-empty-p (x)
 833   (zerop (length x)))
 834
 835 (defun get-toplevel-compilations ()
 836   (reverse (remove-if #'null-or-empty-p *toplevel-compilations*)))
 837
 838 (defun %compile-defmacro (name lambda)
 839   (toplevel-compilation (ls-compile `',name))
 840   (push-to-lexenv (make-binding name 'macro lambda t) *environment* 'function))
 841
 842 (defvar *compilations* nil)
 843
 844 (defun ls-compile-block (sexps &optional return-last-p)
 845   (if return-last-p
 846       (concat (ls-compile-block (butlast sexps))
 847               "return " (ls-compile (car (last sexps))) ";")
 848       (join-trailing
 849        (remove-if #'null-or-empty-p (mapcar #'ls-compile sexps))
 850        (concat ";" *newline*))))
 851
 852 (defmacro define-compilation (name args &body body)
 853   ;; Creates a new primitive `name' with parameters args and
 854   ;; @body. The body can access to the local environment through the
 855   ;; variable *ENVIRONMENT*.
 856   `(push (list ',name (lambda ,args (block ,name ,@body)))
 857          *compilations*))
 858
 859 (define-compilation if (condition true false)
 860   (concat "(" (ls-compile condition) " !== " (ls-compile nil)
 861           " ? " (ls-compile true)
 862           " : " (ls-compile false)
 863           ")"))
 864
 865 (defvar *lambda-list-keywords* '(&optional &rest))
 866
 867 (defun list-until-keyword (list)
 868   (if (or (null list) (member (car list) *lambda-list-keywords*))
 869       nil
 870       (cons (car list) (list-until-keyword (cdr list)))))
 871
 872 (defun lambda-list-required-arguments (lambda-list)
 873   (list-until-keyword lambda-list))
 874
 875 (defun lambda-list-optional-arguments-with-default (lambda-list)
 876   (mapcar #'ensure-list (list-until-keyword (cdr (member '&optional lambda-list)))))
 877
 878 (defun lambda-list-optional-arguments (lambda-list)
 879   (mapcar #'car (lambda-list-optional-arguments-with-default lambda-list)))
 880
 881 (defun lambda-list-rest-argument (lambda-list)
 882   (let ((rest (list-until-keyword (cdr (member '&rest lambda-list)))))
 883     (when (cdr rest)
 884       (error "Bad lambda-list"))
 885     (car rest)))
 886
 887
 888 (defun lambda-docstring-wrapper (docstring &rest strs)
 889   (if docstring
 890       (js!selfcall
 891         "var func = " (join strs) ";" *newline*
 892         "func.docstring = '" docstring "';" *newline*
 893         "return func;" *newline*)
 894       (join strs)))
 895
 896 (define-compilation lambda (lambda-list &rest body)
 897   (let ((required-arguments (lambda-list-required-arguments lambda-list))
 898         (optional-arguments (lambda-list-optional-arguments lambda-list))
 899         (rest-argument (lambda-list-rest-argument lambda-list))
 900         documentation)
 901     ;; Get the documentation string for the lambda function
 902     (when (and (stringp (car body))
 903                (not (null (cdr body))))
 904       (setq documentation (car body))
 905       (setq body (cdr body)))
 906     (let ((n-required-arguments (length required-arguments))
 907           (n-optional-arguments (length optional-arguments))
 908           (*environment* (extend-local-env
 909                           (append (ensure-list rest-argument)
 910                                   required-arguments
 911                                   optional-arguments))))
 912       (lambda-docstring-wrapper
 913        documentation
 914        "(function ("
 915        (join (mapcar #'translate-variable
 916                      (append required-arguments optional-arguments))
 917              ",")
 918        "){" *newline*
 919        ;; Check number of arguments
 920        (indent
 921         (if required-arguments
 922             (concat "if (arguments.length < " (integer-to-string n-required-arguments)
 923                     ") throw 'too few arguments';" *newline*)
 924             "")
 925         (if (not rest-argument)
 926             (concat "if (arguments.length > "
 927                     (integer-to-string (+ n-required-arguments n-optional-arguments))
 928                     ") throw 'too many arguments';" *newline*)
 929             "")
 930         ;; Optional arguments
 931         (if optional-arguments
 932             (concat "switch(arguments.length){" *newline*
 933                     (let ((optional-and-defaults
 934                            (lambda-list-optional-arguments-with-default lambda-list))
 935                           (cases nil)
 936                           (idx 0))
 937                       (progn
 938                         (while (< idx n-optional-arguments)
 939                           (let ((arg (nth idx optional-and-defaults)))
 940                             (push (concat "case "
 941                                           (integer-to-string (+ idx n-required-arguments)) ":" *newline*
 942                                           (translate-variable (car arg))
 943                                           "="
 944                                           (ls-compile (cadr arg))
 945                                           ";" *newline*)
 946                                   cases)
 947                             (incf idx)))
 948                         (push (concat "default: break;" *newline*) cases)
 949                         (join (reverse cases))))
 950                     "}" *newline*)
 951             "")
 952         ;; &rest/&body argument
 953         (if rest-argument
 954             (let ((js!rest (translate-variable rest-argument)))
 955               (concat "var " js!rest "= " (ls-compile nil) ";" *newline*
 956                       "for (var i = arguments.length-1; i>="
 957                       (integer-to-string (+ n-required-arguments n-optional-arguments))
 958                       "; i--)" *newline*
 959                       (indent js!rest " = "
 960                               "{car: arguments[i], cdr: ") js!rest "};"
 961                       *newline*))
 962             "")
 963         ;; Body
 964         (ls-compile-block body t)) *newline*
 965        "})"))))
 966
 967 (define-compilation setq (var val)
 968   (let ((b (lookup-in-lexenv var *environment* 'variable)))
 969     (if (eq (binding-type b) 'lexical-variable)
 970         (concat (binding-value b) " = " (ls-compile val))
 971         (ls-compile `(set ',var ,val)))))
 972
 973 ;;; FFI Variable accessors
 974 (define-compilation js-vref (var)
 975   var)
 976
 977 (define-compilation js-vset (var val)
 978   (concat "(" var " = " (ls-compile val) ")"))
 979
 980
 981 ;;; Literals
 982 (defun escape-string (string)
 983   (let ((output "")
 984         (index 0)
 985         (size (length string)))
 986     (while (< index size)
 987       (let ((ch (char string index)))
 988         (when (or (char= ch #\") (char= ch #\\))
 989           (setq output (concat output "\\")))
 990         (when (or (char= ch #\newline))
 991           (setq output (concat output "\\"))
 992           (setq ch #\n))
 993         (setq output (concat output (string ch))))
 994       (incf index))
 995     output))
 996
 997
 998 (defvar *literal-symbols* nil)
 999 (defvar *literal-counter* 0)
1000
1001 (defun genlit ()
1002   (concat "l" (integer-to-string (incf *literal-counter*))))
1003
1004 (defun literal (sexp &optional recursive)
1005   (cond
1006     ((integerp sexp) (integer-to-string sexp))
1007     ((stringp sexp) (concat "\"" (escape-string sexp) "\""))
1008     ((symbolp sexp)
1009      (or (cdr (assoc sexp *literal-symbols*))
1010          (let ((v (genlit))
1011                (s #+common-lisp (concat "{name: \"" (escape-string (symbol-name sexp)) "\"}")
1012                   #+ecmalisp (ls-compile `(intern ,(symbol-name sexp)))))
1013            (push (cons sexp v) *literal-symbols*)
1014            (toplevel-compilation (concat "var " v " = " s))
1015            v)))
1016     ((consp sexp)
1017      (let ((c (concat "{car: " (literal (car sexp) t) ", "
1018                       "cdr: " (literal (cdr sexp) t) "}")))
1019        (if recursive
1020            c
1021            (let ((v (genlit)))
1022              (toplevel-compilation (concat "var " v " = " c))
1023              v))))))
1024
1025 (define-compilation quote (sexp)
1026   (literal sexp))
1027
1028 (define-compilation %while (pred &rest body)
1029   (js!selfcall
1030     "while(" (ls-compile pred) " !== " (ls-compile nil) "){" *newline*
1031     (indent (ls-compile-block body))
1032     "}"
1033     "return " (ls-compile nil) ";" *newline*))
1034
1035 (define-compilation function (x)
1036   (cond
1037     ((and (listp x) (eq (car x) 'lambda))
1038      (ls-compile x))
1039     ((symbolp x)
1040      (ls-compile `(symbol-function ',x)))))
1041
1042 (define-compilation eval-when-compile (&rest body)
1043   (eval (cons 'progn body))
1044   nil)
1045
1046 (defmacro define-transformation (name args form)
1047   `(define-compilation ,name ,args
1048      (ls-compile ,form)))
1049
1050 (define-compilation progn (&rest body)
1051   (js!selfcall (ls-compile-block body t)))
1052
1053 (defun dynamic-binding-wrapper (bindings body)
1054   (if (null bindings)
1055       body
1056       (concat
1057        "try {" *newline*
1058        (indent
1059         "var tmp;" *newline*
1060         (join
1061          (mapcar (lambda (b)
1062                    (let ((s (ls-compile `(quote ,(car b)))))
1063                      (concat "tmp = " s ".value;" *newline*
1064                              s ".value = " (cdr b) ";" *newline*
1065                              (cdr b) " = tmp;" *newline*)))
1066                  bindings))
1067         body)
1068        "}" *newline*
1069        "finally {"  *newline*
1070        (indent
1071         (join-trailing
1072          (mapcar (lambda (b)
1073                    (let ((s (ls-compile `(quote ,(car b)))))
1074                      (concat s ".value" " = " (cdr b))))
1075                  bindings)
1076          (concat ";" *newline*)))
1077        "}" *newline*)))
1078
1079
1080 (define-compilation let (bindings &rest body)
1081   (let ((bindings (mapcar #'ensure-list bindings)))
1082     (let ((variables (mapcar #'first bindings))
1083           (values    (mapcar #'second bindings)))
1084       (let ((cvalues (mapcar #'ls-compile values))
1085             (*environment* (extend-local-env (remove-if #'boundp variables)))
1086             (dynamic-bindings))
1087         (concat "(function("
1088                 (join (mapcar (lambda (x)
1089                                 (if (boundp x)
1090                                     (let ((v (gvarname x)))
1091                                       (push (cons x v) dynamic-bindings)
1092                                       v)
1093                                     (translate-variable x)))
1094                               variables)
1095                       ",")
1096                 "){" *newline*
1097                 (let ((body (ls-compile-block body t)))
1098                   (indent (dynamic-binding-wrapper dynamic-bindings body)))
1099                 "})(" (join cvalues ",") ")")))))
1100
1101
1102 (defvar *block-counter* 0)
1103
1104 (define-compilation block (name &rest body)
1105   (let ((tr (integer-to-string (incf *block-counter*))))
1106     (let ((b (make-binding name 'block tr t)))
1107       (js!selfcall
1108         "try {" *newline*
1109         (let ((*environment* (extend-lexenv (list b) *environment* 'block)))
1110           (indent "return " (ls-compile `(progn ,@body)) ";" *newline*))
1111         "}" *newline*
1112         "catch (cf){" *newline*
1113         "    if (cf.type == 'block' && cf.id == " tr ")" *newline*
1114         "        return cf.value;" *newline*
1115         "    else" *newline*
1116         "        throw cf;" *newline*
1117         "}" *newline*))))
1118
1119 (define-compilation return-from (name &optional value)
1120   (let ((b (lookup-in-lexenv name *environment* 'block)))
1121     (if b
1122         (js!selfcall
1123           "throw ({"
1124           "type: 'block', "
1125           "id: " (binding-value b) ", "
1126           "value: " (ls-compile value) ", "
1127           "message: 'Return from unknown block " (symbol-name name) ".'"
1128           "})")
1129         (error (concat "Unknown block `" (symbol-name name) "'.")))))
1130
1131
1132 (define-compilation catch (id &rest body)
1133   (js!selfcall
1134     "var id = " (ls-compile id) ";" *newline*
1135     "try {" *newline*
1136     (indent "return " (ls-compile `(progn ,@body))
1137             ";" *newline*)
1138     "}" *newline*
1139     "catch (cf){" *newline*
1140     "    if (cf.type == 'catch' && cf.id == id)" *newline*
1141     "        return cf.value;" *newline*
1142     "    else" *newline*
1143     "        throw cf;" *newline*
1144     "}" *newline*))
1145
1146 (define-compilation throw (id &optional value)
1147   (js!selfcall
1148     "throw ({"
1149     "type: 'catch', "
1150     "id: " (ls-compile id) ", "
1151     "value: " (ls-compile value) ", "
1152     "message: 'Throw uncatched.'"
1153     "})"))
1154
1155
1156 (defvar *tagbody-counter* 0)
1157 (defvar *go-tag-counter* 0)
1158
1159 (defun go-tag-p (x)
1160   (or (integerp x) (symbolp x)))
1161
1162 (defun declare-tagbody-tags (tbidx body)
1163   (let ((bindings
1164          (mapcar (lambda (label)
1165                    (let ((tagidx (integer-to-string (incf *go-tag-counter*))))
1166                      (make-binding label 'gotag (list tbidx tagidx) t)))
1167                  (remove-if-not #'go-tag-p body))))
1168     (extend-lexenv bindings *environment* 'gotag)))
1169
1170 (define-compilation tagbody (&rest body)
1171   ;; Ignore the tagbody if it does not contain any go-tag. We do this
1172   ;; because 1) it is easy and 2) many built-in forms expand to a
1173   ;; implicit tagbody, so we save some space.
1174   (unless (some #'go-tag-p body)
1175     (return-from tagbody (ls-compile `(progn ,@body nil))))
1176   ;; The translation assumes the first form in BODY is a label
1177   (unless (go-tag-p (car body))
1178     (push (gensym "START") body))
1179   ;; Tagbody compilation
1180   (let ((tbidx (integer-to-string *tagbody-counter*)))
1181     (let ((*environment* (declare-tagbody-tags tbidx body))
1182           initag)
1183       (let ((b (lookup-in-lexenv (first body) *environment* 'gotag)))
1184         (setq initag (second (binding-value b))))
1185       (js!selfcall
1186         "var tagbody_" tbidx " = " initag ";" *newline*
1187         "tbloop:" *newline*
1188         "while (true) {" *newline*
1189         (indent "try {" *newline*
1190                 (indent (let ((content ""))
1191                           (concat "switch(tagbody_" tbidx "){" *newline*
1192                                   "case " initag ":" *newline*
1193                                   (dolist (form (cdr body) content)
1194                                     (concatf content
1195                                       (if (not (go-tag-p form))
1196                                           (indent (ls-compile form) ";" *newline*)
1197                                           (let ((b (lookup-in-lexenv form *environment* 'gotag)))
1198                                             (concat "case " (second (binding-value b)) ":" *newline*)))))
1199                                   "default:" *newline*
1200                                   "    break tbloop;" *newline*
1201                                   "}" *newline*)))
1202                 "}" *newline*
1203                 "catch (jump) {" *newline*
1204                 "    if (jump.type == 'tagbody' && jump.id == " tbidx ")" *newline*
1205                 "        tagbody_" tbidx " = jump.label;" *newline*
1206                 "    else" *newline*
1207                 "        throw(jump);" *newline*
1208                 "}" *newline*)
1209         "}" *newline*
1210         "return " (ls-compile nil) ";" *newline*))))
1211
1212 (define-compilation go (label)
1213   (let ((b (lookup-in-lexenv label *environment* 'gotag))
1214         (n (cond
1215              ((symbolp label) (symbol-name label))
1216              ((integerp label) (integer-to-string label)))))
1217     (if b
1218         (js!selfcall
1219           "throw ({"
1220           "type: 'tagbody', "
1221           "id: " (first (binding-value b)) ", "
1222           "label: " (second (binding-value b)) ", "
1223           "message: 'Attempt to GO to non-existing tag " n "'"
1224           "})" *newline*)
1225         (error (concat "Unknown tag `" n "'.")))))
1226
1227
1228 (define-compilation unwind-protect (form &rest clean-up)
1229   (js!selfcall
1230     "var ret = " (ls-compile nil) ";" *newline*
1231     "try {" *newline*
1232     (indent "ret = " (ls-compile form) ";" *newline*)
1233     "} finally {" *newline*
1234     (indent (ls-compile-block clean-up))
1235     "}" *newline*
1236     "return ret;" *newline*))
1237
1238
1239 ;;; A little backquote implementation without optimizations of any
1240 ;;; kind for ecmalisp.
1241 (defun backquote-expand-1 (form)
1242   (cond
1243     ((symbolp form)
1244      (list 'quote form))
1245     ((atom form)
1246      form)
1247     ((eq (car form) 'unquote)
1248      (car form))
1249     ((eq (car form) 'backquote)
1250      (backquote-expand-1 (backquote-expand-1 (cadr form))))
1251     (t
1252      (cons 'append
1253            (mapcar (lambda (s)
1254                      (cond
1255                        ((and (listp s) (eq (car s) 'unquote))
1256                         (list 'list (cadr s)))
1257                        ((and (listp s) (eq (car s) 'unquote-splicing))
1258                         (cadr s))
1259                        (t
1260                         (list 'list (backquote-expand-1 s)))))
1261                    form)))))
1262
1263 (defun backquote-expand (form)
1264   (if (and (listp form) (eq (car form) 'backquote))
1265       (backquote-expand-1 (cadr form))
1266       form))
1267
1268 (defmacro backquote (form)
1269   (backquote-expand-1 form))
1270
1271 (define-transformation backquote (form)
1272   (backquote-expand-1 form))
1273
1274 ;;; Primitives
1275
1276 (defmacro define-builtin (name args &body body)
1277   `(progn
1278      (define-compilation ,name ,args
1279        (let ,(mapcar (lambda (arg) `(,arg (ls-compile ,arg))) args)
1280          ,@body))))
1281
1282 ;;; DECLS is a list of (JSVARNAME TYPE LISPFORM) declarations.
1283 (defmacro type-check (decls &body body)
1284   `(js!selfcall
1285      ,@(mapcar (lambda (decl)
1286                    `(concat "var " ,(first decl) " = " ,(third decl) ";" *newline*))
1287                  decls)
1288      ,@(mapcar (lambda (decl)
1289                  `(concat "if (typeof " ,(first decl) " != '" ,(second decl) "')" *newline*
1290                           (indent "throw 'The value ' + "
1291                                   ,(first decl)
1292                                   " + ' is not a type "
1293                                   ,(second decl)
1294                                   ".';"
1295                                   *newline*)))
1296                decls)
1297      (concat "return " (progn ,@body) ";" *newline*)))
1298
1299 (defun num-op-num (x op y)
1300   (type-check (("x" "number" x) ("y" "number" y))
1301     (concat "x" op "y")))
1302
1303 (define-builtin + (x y) (num-op-num x "+" y))
1304 (define-builtin - (x y) (num-op-num x "-" y))
1305 (define-builtin * (x y) (num-op-num x "*" y))
1306 (define-builtin / (x y) (num-op-num x "/" y))
1307
1308 (define-builtin mod (x y) (num-op-num x "%" y))
1309
1310 (define-builtin < (x y)  (js!bool (num-op-num x "<" y)))
1311 (define-builtin > (x y)  (js!bool (num-op-num x ">" y)))
1312 (define-builtin = (x y)  (js!bool (num-op-num x "==" y)))
1313 (define-builtin <= (x y) (js!bool (num-op-num x "<=" y)))
1314 (define-builtin >= (x y) (js!bool (num-op-num x ">=" y)))
1315
1316 (define-builtin numberp (x)
1317   (js!bool (concat "(typeof (" x ") == \"number\")")))
1318
1319 (define-builtin floor (x)
1320   (type-check (("x" "number" x))
1321     "Math.floor(x)"))
1322
1323 (define-builtin cons (x y)
1324   (concat "({car: " x ", cdr: " y "})"))
1325
1326 (define-builtin consp (x)
1327   (js!bool
1328    (js!selfcall
1329      "var tmp = " x ";" *newline*
1330      "return (typeof tmp == 'object' && 'car' in tmp);" *newline*)))
1331
1332 (define-builtin car (x)
1333   (js!selfcall
1334     "var tmp = " x ";" *newline*
1335     "return tmp === " (ls-compile nil)
1336     "? " (ls-compile nil)
1337     ": tmp.car;" *newline*))
1338
1339 (define-builtin cdr (x)
1340   (js!selfcall
1341     "var tmp = " x ";" *newline*
1342     "return tmp === " (ls-compile nil) "? "
1343     (ls-compile nil)
1344     ": tmp.cdr;" *newline*))
1345
1346 (define-builtin setcar (x new)
1347   (type-check (("x" "object" x))
1348     (concat "(x.car = " new ")")))
1349
1350 (define-builtin setcdr (x new)
1351   (type-check (("x" "object" x))
1352     (concat "(x.cdr = " new ")")))
1353
1354 (define-builtin symbolp (x)
1355   (js!bool
1356    (js!selfcall
1357      "var tmp = " x ";" *newline*
1358      "return (typeof tmp == 'object' && 'name' in tmp);" *newline*)))
1359
1360 (define-builtin make-symbol (name)
1361   (type-check (("name" "string" name))
1362     "({name: name})"))
1363
1364 (define-builtin symbol-name (x)
1365   (concat "(" x ").name"))
1366
1367 (define-builtin set (symbol value)
1368   (concat "(" symbol ").value = " value))
1369
1370 (define-builtin fset (symbol value)
1371   (concat "(" symbol ").function = " value))
1372
1373 (define-builtin boundp (x)
1374   (js!bool (concat "(" x ".value !== undefined)")))
1375
1376 (define-builtin symbol-value (x)
1377   (js!selfcall
1378     "var symbol = " x ";" *newline*
1379     "var value = symbol.value;" *newline*
1380     "if (value === undefined) throw \"Variable `\" + symbol.name + \"' is unbound.\";" *newline*
1381     "return value;" *newline*))
1382
1383 (define-builtin symbol-function (x)
1384   (js!selfcall
1385     "var symbol = " x ";" *newline*
1386     "var func = symbol.function;" *newline*
1387     "if (func === undefined) throw \"Function `\" + symbol.name + \"' is undefined.\";" *newline*
1388     "return func;" *newline*))
1389
1390 (define-builtin symbol-plist (x)
1391   (concat "((" x ").plist || " (ls-compile nil) ")"))
1392
1393 (define-builtin lambda-code (x)
1394   (concat "(" x ").toString()"))
1395
1396
1397 (define-builtin eq    (x y) (js!bool (concat "(" x " === " y ")")))
1398 (define-builtin equal (x y) (js!bool (concat "(" x  " == " y ")")))
1399
1400 (define-builtin string (x)
1401   (type-check (("x" "number" x))
1402     "String.fromCharCode(x)"))
1403
1404 (define-builtin stringp (x)
1405   (js!bool (concat "(typeof(" x ") == \"string\")")))
1406
1407 (define-builtin string-upcase (x)
1408   (type-check (("x" "string" x))
1409     "x.toUpperCase()"))
1410
1411 (define-builtin string-length (x)
1412   (type-check (("x" "string" x))
1413     "x.length"))
1414
1415 (define-compilation slice (string a &optional b)
1416   (js!selfcall
1417     "var str = " (ls-compile string) ";" *newline*
1418     "var a = " (ls-compile a) ";" *newline*
1419     "var b;" *newline*
1420     (if b
1421         (concat "b = " (ls-compile b) ";" *newline*)
1422         "")
1423     "return str.slice(a,b);" *newline*))
1424
1425 (define-builtin char (string index)
1426   (type-check (("string" "string" string)
1427                ("index" "number" index))
1428     "string.charCodeAt(index)"))
1429
1430 (define-builtin concat-two (string1 string2)
1431   (type-check (("string1" "string" string1)
1432                ("string2" "string" string2))
1433     "string1.concat(string2)"))
1434
1435 (define-compilation funcall (func &rest args)
1436   (concat "(" (ls-compile func) ")("
1437           (join (mapcar #'ls-compile args)
1438                 ", ")
1439           ")"))
1440
1441 (define-compilation apply (func &rest args)
1442   (if (null args)
1443       (concat "(" (ls-compile func) ")()")
1444       (let ((args (butlast args))
1445             (last (car (last args))))
1446         (js!selfcall
1447           "var f = " (ls-compile func) ";" *newline*
1448           "var args = [" (join (mapcar #'ls-compile args)
1449                                ", ")
1450           "];" *newline*
1451           "var tail = (" (ls-compile last) ");" *newline*
1452           "while (tail != " (ls-compile nil) "){" *newline*
1453           "    args.push(tail.car);" *newline*
1454           "    tail = tail.cdr;" *newline*
1455           "}" *newline*
1456           "return f.apply(this, args);" *newline*))))
1457
1458 (define-builtin js-eval (string)
1459   (type-check (("string" "string" string))
1460     "eval.apply(window, [string])"))
1461
1462 (define-builtin error (string)
1463   (js!selfcall "throw " string ";" *newline*))
1464
1465 (define-builtin new () "{}")
1466
1467 (define-builtin oget (object key)
1468   (js!selfcall
1469     "var tmp = " "(" object ")[" key "];" *newline*
1470     "return tmp == undefined? " (ls-compile nil) ": tmp ;" *newline*))
1471
1472 (define-builtin oset (object key value)
1473   (concat "((" object ")[" key "] = " value ")"))
1474
1475 (define-builtin in (key object)
1476   (js!bool (concat "((" key ") in (" object "))")))
1477
1478 (define-builtin functionp (x)
1479   (js!bool (concat "(typeof " x " == 'function')")))
1480
1481 (define-builtin write-string (x)
1482   (type-check (("x" "string" x))
1483     "lisp.write(x)"))
1484
1485 (defun macro (x)
1486   (and (symbolp x)
1487        (let ((b (lookup-in-lexenv x *environment* 'function)))
1488          (and (eq (binding-type b) 'macro)
1489               b))))
1490
1491 (defun ls-macroexpand-1 (form)
1492   (let ((macro-binding (macro (car form))))
1493     (if macro-binding
1494         (let ((expander (binding-value macro-binding)))
1495           (when (listp expander)
1496             (let ((compiled (eval expander)))
1497               ;; The list representation are useful while
1498               ;; bootstrapping, as we can dump the definition of the
1499               ;; macros easily, but they are slow because we have to
1500               ;; evaluate them and compile them now and again. So, let
1501               ;; us replace the list representation version of the
1502               ;; function with the compiled one.
1503               ;;
1504               #+ecmalisp (set-binding-value macro-binding compiled)
1505               (setq expander compiled)))
1506           (apply expander (cdr form)))
1507         form)))
1508
1509 (defun compile-funcall (function args)
1510   (concat (ls-compile `#',function) "("
1511           (join (mapcar #'ls-compile args)
1512                 ", ")
1513           ")"))
1514
1515 (defun ls-compile (sexp)
1516   (cond
1517     ((symbolp sexp)
1518      (let ((b (lookup-in-lexenv sexp *environment* 'variable)))
1519        (if (eq (binding-type b) 'lexical-variable)
1520            (binding-value b)
1521            (ls-compile `(symbol-value ',sexp)))))
1522     ((integerp sexp) (integer-to-string sexp))
1523     ((stringp sexp) (concat "\"" (escape-string sexp) "\""))
1524     ((listp sexp)
1525      (if (assoc (car sexp) *compilations*)
1526          (let ((comp (second (assoc (car sexp) *compilations*))))
1527            (apply comp (cdr sexp)))
1528          (if (macro (car sexp))
1529              (ls-compile (ls-macroexpand-1 sexp))
1530              (compile-funcall (car sexp) (cdr sexp)))))))
1531
1532 (defun ls-compile-toplevel (sexp)
1533   (let ((*toplevel-compilations* nil))
1534     (cond
1535       ((and (consp sexp) (eq (car sexp) 'progn))
1536        (let ((subs (mapcar #'ls-compile-toplevel (cdr sexp))))
1537          (join (remove-if #'null-or-empty-p subs))))
1538       (t
1539        (let ((code (ls-compile sexp)))
1540          (concat (join-trailing (get-toplevel-compilations)
1541                                 (concat ";" *newline*))
1542                  (if code
1543                      (concat code ";" *newline*)
1544                      "")))))))
1545
1546
1547 ;;; Once we have the compiler, we define the runtime environment and
1548 ;;; interactive development (eval), which works calling the compiler
1549 ;;; and evaluating the Javascript result globally.
1550
1551 #+ecmalisp
1552 (progn
1553   (defmacro with-compilation-unit (&body body)
1554     `(prog1
1555          (progn
1556            (setq *compilation-unit-checks* nil)
1557            (clear-undeclared-global-bindings)
1558            ,@body)
1559        (dolist (check *compilation-unit-checks*)
1560          (funcall check))))
1561
1562   (defun eval (x)
1563     (let ((code
1564            (with-compilation-unit
1565                (ls-compile-toplevel x))))
1566       (js-eval code)))
1567
1568   (js-eval "var lisp")
1569   (js-vset "lisp" (new))
1570   (js-vset "lisp.read" #'ls-read-from-string)
1571   (js-vset "lisp.print" #'prin1-to-string)
1572   (js-vset "lisp.eval" #'eval)
1573   (js-vset "lisp.compile" #'ls-compile-toplevel)
1574   (js-vset "lisp.evalString" (lambda (str) (eval (ls-read-from-string str))))
1575   (js-vset "lisp.compileString" (lambda (str) (ls-compile-toplevel (ls-read-from-string str))))
1576
1577   ;; Set the initial global environment to be equal to the host global
1578   ;; environment at this point of the compilation.
1579   (eval-when-compile
1580     (toplevel-compilation
1581      (ls-compile
1582       `(progn
1583          ,@(mapcar (lambda (s)
1584                      `(oset *package* ,(symbol-name (car s))
1585                             (js-vref ,(cdr s))))
1586                    *literal-symbols*)
1587          (setq *literal-symbols* ',*literal-symbols*)
1588          (setq *environment* ',*environment*)
1589          (setq *variable-counter* ,*variable-counter*)
1590          (setq *gensym-counter* ,*gensym-counter*)
1591          (setq *block-counter* ,*block-counter*)))))
1592
1593   (eval-when-compile
1594     (toplevel-compilation
1595      (ls-compile
1596       `(setq *literal-counter* ,*literal-counter*)))))
1597
1598
1599 ;;; Finally, we provide a couple of functions to easily bootstrap
1600 ;;; this. It just calls the compiler with this file as input.
1601
1602 #+common-lisp
1603 (progn
1604   (defun read-whole-file (filename)
1605     (with-open-file (in filename)
1606       (let ((seq (make-array (file-length in) :element-type 'character)))
1607         (read-sequence seq in)
1608         seq)))
1609
1610   (defun ls-compile-file (filename output)
1611     (setq *compilation-unit-checks* nil)
1612     (with-open-file (out output :direction :output :if-exists :supersede)
1613       (let* ((source (read-whole-file filename))
1614              (in (make-string-stream source)))
1615         (loop
1616            for x = (ls-read in)
1617            until (eq x *eof*)
1618            for compilation = (ls-compile-toplevel x)
1619            when (plusp (length compilation))
1620            do (write-string compilation out))
1621         (dolist (check *compilation-unit-checks*)
1622           (funcall check))
1623         (setq *compilation-unit-checks* nil))))
1624
1625   (defun bootstrap ()
1626     (setq *environment* (make-lexenv))
1627     (setq *literal-symbols* nil)
1628     (setq *variable-counter* 0
1629           *gensym-counter* 0
1630           *literal-counter* 0
1631           *block-counter* 0)
1632     (ls-compile-file "ecmalisp.lisp" "ecmalisp.js")))