experimental/compiler.lisp

   1 ;;; compiler.lisp ---
   2
   3 ;; Copyright (C) 2013 David Vazquez
   4
   5 ;; JSCL is free software: you can redistribute it and/or
   6 ;; modify it under the terms of the GNU General Public License as
   7 ;; published by the Free Software Foundation, either version 3 of the
   8 ;; License, or (at your option) any later version.
   9 ;;
  10 ;; JSCL is distributed in the hope that it will be useful, but
  11 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;; General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public License
  16 ;; along with JSCL.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 (defpackage :jscl
  19   (:use :cl))
  20
  21 (in-package :jscl)
  22
  23 ;;;; Utilities
  24 ;;;;
  25 ;;;; Random Common Lisp code useful to use here and there.
  26
  27 (defmacro with-gensyms ((&rest vars) &body body)
  28   `(let ,(mapcar (lambda (var) `(,var (gensym ,(concatenate 'string (string var) "-")))) vars)
  29      ,@body))
  30
  31 (defun singlep (x)
  32   (and (consp x) (null (cdr x))))
  33
  34 (defun unlist (x)
  35   (assert (singlep x))
  36   (first x))
  37
  38 (defun generic-printer (x stream)
  39   (print-unreadable-object (x stream :type t :identity t)))
  40
  41 ;;; A generic counter mechanism. IDs are used generally for debugging
  42 ;;; purposes. You can bind *counter-alist* to NIL to reset the
  43 ;;; counters in a dynamic extent.
  44 (defvar *counter-alist* nil)
  45 (defun generate-id (class)
  46   (let ((e (assoc class *counter-alist*)))
  47     (if e
  48         (incf (cdr e))
  49         (prog1 1
  50           (push (cons class 1) *counter-alist*)))))
  51
  52
  53 ;;;; Intermediate representation structures
  54 ;;;;
  55 ;;;; This intermediate representation (IR) is a simplified version of
  56 ;;;; the first intermediate representation what you will find if you
  57 ;;;; have a look to the source code of SBCL. Some terminology is also
  58 ;;;; used, but other is changed, so be careful if you assume you know
  59 ;;;; what it is because you know the name.
  60 ;;;;
  61 ;;;; Computations are represented by `node'.  Nodes are grouped
  62 ;;;; sequencially into `basic-block'. It is a plain representation
  63 ;;;; rather than a nested one. Computations take data and produce a
  64 ;;;; value. Both data transfer are represented by `lvar'.
  65
  66 (defstruct leaf)
  67
  68 ;;; A (lexical) variable. Special variables has not a special
  69 ;;; representation in the IR. They are handled by the primitive
  70 ;;; functions `%symbol-function' and `%symbol-value'.
  71 (defstruct (var (:include leaf))
  72   ;; The symbol which names this variable in the source code.
  73   name)
  74
  75 ;;; A literal Lisp object. It usually comes from a quoted expression.
  76 (defstruct (constant (:include leaf))
  77   ;; The object itself.
  78   value)
  79
  80 ;;; A lambda expression. Why do we name it `functional'? Well,
  81 ;;; function is reserved by the ANSI, isn't it?
  82 (defstruct (functional (:include leaf) (:print-object generic-printer))
  83   ;; The symbol which names this function in the source code or null
  84   ;; if we do not know or it is an anonymous function.
  85   name
  86   arguments
  87   return-lvar
  88   component)
  89
  90 ;;; An abstract place where the result of a computation is stored and
  91 ;;; it can be referenced from other nodes, so lvars are responsible
  92 ;;; for keeping the necessary information of the nested structure of
  93 ;;; the code in this plain representation.
  94 (defstruct lvar
  95   (id (generate-id 'lvar)))
  96
  97 ;;; A base structure for every single computation. Most of the
  98 ;;; computations are valued.
  99 (defstruct (node (:print-object generic-printer))
 100   ;; The next and the prev slots are the next nodes and the previous
 101   ;; node in the basic block sequence respectively.
 102   next prev
 103   ;; Lvar which stands for the result of the computation of this node.
 104   lvar)
 105
 106 ;;; Sentinel nodes in the basic block sequence of nodes.
 107 (defstruct (block-entry (:include node)))
 108 (defstruct (block-exit (:include node)))
 109
 110 ;;; A reference to a leaf (variable, constant and functions). The
 111 ;;; meaning of this node is leaving the leaf into the lvar of the
 112 ;;; node.
 113 (defstruct (ref (:include node))
 114   leaf)
 115
 116 ;;; An assignation of the LVAR VALUE into the var VARIABLE.
 117 (defstruct (assignment (:include node))
 118   variable
 119   value)
 120
 121 ;;; A base node to function calls with a list of lvar as ARGUMENTS.
 122 (defstruct (combination (:include node) (:constructor))
 123   arguments)
 124
 125 ;;; A function call to the ordinary Lisp function in the lvar FUNCTION.
 126 (defstruct (call (:include combination))
 127   function)
 128
 129 ;;; A function call to the primitive FUNCTION.
 130 (defstruct (primitive-call (:include combination))
 131   function)
 132
 133
 134 ;;; A conditional branch. If the LVAR is not NIL, then we will jump to
 135 ;;; the basic block CONSEQUENT, jumping to ALTERNATIVE otherwise. By
 136 ;;; definition, a conditional must appear at the end of a basic block.
 137 (defstruct (conditional (:include node))
 138   test
 139   consequent
 140   alternative)
 141
 142
 143 ;;;; Components
 144 ;;;;
 145 ;;;; Components are connected pieces of the control flow graph of
 146 ;;;; basic blocks with some additional information. Components have
 147 ;;;; well-defined entry and exit nodes. It is the toplevel
 148 ;;;; organizational entity in the compiler. The IR translation result
 149 ;;;; is accumulated into components incrementally.
 150 (defstruct (component (:print-object generic-printer))
 151   (id (generate-id 'component))
 152   name
 153   entry
 154   exit
 155   functions
 156   blocks)
 157
 158 ;;; The current component. We accumulate the results of the IR
 159 ;;; conversion in this component.
 160 (defvar *component*)
 161
 162 ;;; Create a new component with an empty basic block, ready to start
 163 ;;; conversion to IR. It returns the component and the basic block as
 164 ;;; multiple values.
 165 (defun make-empty-component (&optional name)
 166   (let ((*component* (make-component :name name)))
 167     (let ((entry (make-component-entry))
 168           (block (make-empty-block))
 169           (exit (make-component-exit)))
 170       (setf (block-succ entry) (list block)
 171             (block-pred exit)  (list block)
 172             (block-succ block) (list exit)
 173             (block-pred block) (list entry)
 174             (component-entry *component*) entry
 175             (component-exit  *component*) exit)
 176       (values *component* block))))
 177
 178 ;;; Prepare a new component with a current empty block ready to start
 179 ;;; IR conversion bound in the current cursor. BODY is evaluated and
 180 ;;; the value of the last form is returned.
 181 (defmacro with-component-compilation ((&optional name) &body body)
 182   (with-gensyms (block)
 183     `(multiple-value-bind (*component* ,block)
 184          (make-empty-component ,name)
 185        (let ((*cursor* (cursor :block ,block)))
 186          ,@body))))
 187
 188 ;;; Call function for each block in component in post-order.
 189 (defun map-postorder-blocks (function component)
 190   (let ((seen nil))
 191     (labels ((compute-from (block)
 192                (unless (or (component-exit-p block) (find block seen))
 193                  (push block seen)
 194                  (dolist (successor (block-succ block))
 195                    (unless (component-exit-p block)
 196                      (compute-from successor)))
 197                  (funcall function block))))
 198       (compute-from (unlist (block-succ (component-entry component))))
 199       nil)))
 200
 201 ;;; Iterate across different blocks in COMPONENT.
 202 (defmacro do-blocks ((block component &optional result) &body body)
 203   `(dolist (,block (or (component-blocks ,component)
 204                        (error "Component is not normalized."))
 205              ,result)
 206      ,@body))
 207
 208 (defmacro do-blocks-backward ((block component &optional result) &body body)
 209   `(dolist (,block (or (reverse (component-blocks ,component))
 210                        (error "component is not normalized."))
 211              ,result)
 212      ,@body))
 213
 214 ;;; A few consistency checks in the IR useful for catching bugs.
 215 (defun check-ir-consistency (&optional (component *component*))
 216   (with-simple-restart (continue "Continue execution")
 217     (do-blocks (block component)
 218       (dolist (succ (block-succ block))
 219         (unless (find block (block-pred succ))
 220           (error "The block `~S' does not belong to the predecessors list of the its successor `~S'"
 221                  (block-id block)
 222                  (block-id succ)))
 223         (unless (or (boundary-block-p succ) (find succ (component-blocks component)))
 224           (error "Block `~S' is reachable but it is not in the component `~S'" succ component)))
 225       (dolist (pred (block-pred block))
 226         (unless (find block (block-succ pred))
 227           (error "The block `~S' does not belong to the successors' list of its predecessor `~S'"
 228                  (block-id block)
 229                  (block-id pred)))
 230         (unless (or (boundary-block-p pred) (find pred (component-blocks component)))
 231           (error "Block `~S' is reachable but it is not in the component `~S'" pred component))))))
 232
 233
 234 ;;; Blocks are `basic block`. Basic blocks are organized as a control
 235 ;;; flow graph with some more information in omponents.
 236 (defstruct (basic-block
 237              (:conc-name "BLOCK-")
 238              (:constructor make-block)
 239              (:predicate block-p)
 240              (:print-object generic-printer))
 241   (id (generate-id 'basic-block))
 242   ;; List of successors and predecessors of this basic block.
 243   succ pred
 244   ;; The sentinel nodes of the sequence.
 245   entry exit
 246   ;; The component where this block belongs
 247   (component *component*)
 248   (dominators%))
 249
 250 ;;; Sentinel nodes in the control flow graph of basic blocks.
 251 (defstruct (component-entry (:include basic-block)))
 252 (defstruct (component-exit (:include basic-block)))
 253
 254 ;;; Return a fresh empty basic block.
 255 (defun make-empty-block ()
 256   (let ((entry (make-block-entry))
 257         (exit (make-block-exit)))
 258     (setf (node-next entry) exit
 259           (node-prev exit) entry)
 260     (make-block :entry entry :exit exit)))
 261
 262 ;;; Return T if B is an empty basic block and NIL otherwise.
 263 (defun empty-block-p (b)
 264   (block-exit-p (node-next (block-entry b))))
 265
 266 (defun boundary-block-p (block)
 267   (or (component-entry-p block)
 268       (component-exit-p block)))
 269
 270 ;;; Iterate across the nodes in a basic block forward.
 271 (defmacro do-nodes
 272     ((node block &optional result &key include-sentinel-p) &body body)
 273   `(do ((,node ,(if include-sentinel-p
 274                     `(block-entry ,block)
 275                     `(node-next (block-entry ,block)))
 276                (node-next ,node)))
 277        (,(if include-sentinel-p
 278              `(null ,node)
 279              `(block-exit-p ,node))
 280         ,result)
 281      ,@body))
 282
 283 ;;; Iterate across the nodes in a basic block backward.
 284 (defmacro do-nodes-backward
 285     ((node block &optional result &key include-sentinel-p) &body body)
 286   `(do ((,node ,(if include-sentinel-p
 287                     `(block-exit ,block)
 288                     `(node-prev (block-entry ,block)))
 289                (node-prev ,node)))
 290        (,(if include-sentinel-p
 291              `(null ,node)
 292              `(block-entry-p ,node))
 293         ,result)
 294      ,@body))
 295
 296 ;;; Link FROM and TO nodes together. FROM and TO must belong to the
 297 ;;; same basic block and appear in such order. The nodes between FROM
 298 ;;; and TO are discarded.
 299 (defun link-nodes (from to)
 300   (setf (node-next from) to
 301         (node-prev to) from)
 302   (values))
 303
 304
 305
 306 ;;;; Cursors
 307 ;;;;
 308 ;;;; A cursor is a point between two nodes in some basic block in the
 309 ;;;; IR representation where manipulations can take place, similarly
 310 ;;;; to the cursors in text editing.
 311 ;;;;
 312 ;;;; Cursors cannot point to special component's entry and exit basic
 313 ;;;; blocks or after a conditional node. Conveniently, the `cursor'
 314 ;;;; function will signal an error if the cursor is not positioned
 315 ;;;; correctly, so the rest of the code does not need to check once
 316 ;;;; and again.
 317
 318 (defstruct cursor
 319   block next)
 320
 321 ;;; The current cursor. It is the default cursor for many functions
 322 ;;; which work on cursors.
 323 (defvar *cursor*)
 324
 325 ;;; Return the current basic block. It is to say, the basic block
 326 ;;; where the current cursor is pointint.
 327 (defun current-block ()
 328   (cursor-block *cursor*))
 329
 330 ;;; Create a cursor which points to the basic block BLOCK. If omitted,
 331 ;;; then the current block is used.
 332 ;;;
 333 ;;; The keywords AFTER and BEFORE specify the cursor will point after (or
 334 ;;; before) that node respectively. If none is specified, the cursor is
 335 ;;; created before the exit node in BLOCK. An error is signaled if both
 336 ;;; keywords are specified inconsistently, or if the nodes do not belong
 337 ;;; to BLOCK.
 338 ;;;
 339 ;;; AFTER and BEFORE could also be the special values :ENTRY and :EXIT,
 340 ;;; which stand for the entry and exit nodes of the block respectively.
 341 (defun cursor (&key (block (current-block))
 342                  (before nil before-p)
 343                  (after nil after-p))
 344   (when (boundary-block-p block)
 345     (error "Invalid cursor on special entry/exit basic block."))
 346   ;; Handle special values :ENTRY and :EXIT.
 347   (flet ((node-designator (x)
 348            (case x
 349              (:entry (block-entry block))
 350              (:exit  (block-exit block))
 351              (t x))))
 352     (setq before (node-designator before))
 353     (setq after  (node-designator after)))
 354   (let* ((next (or before (and after (node-next after)) (block-exit block)))
 355          (cursor (make-cursor :block block :next next)))
 356     (flet ((out-of-range-cursor ()
 357              (error "Out of range cursor."))
 358            (ambiguous-cursor ()
 359              (error "Ambiguous cursor specified between two non-adjacent nodes.")))
 360       (when (conditional-p (node-prev next))
 361         (error "Invalid cursor after conditional node."))
 362       (when (or (null next) (block-entry-p next))
 363         (out-of-range-cursor))
 364       (when (and before-p after-p (not (eq after before)))
 365         (ambiguous-cursor))
 366       (do-nodes-backward (node block (out-of-range-cursor) :include-sentinel-p t)
 367         (when (eq next node) (return))))
 368     cursor))
 369
 370 ;;; Accept a cursor specification just as described in `cursor'
 371 ;;; describing a position in the IR and modify destructively the
 372 ;;; current cursor to point there.
 373 (defun set-cursor (&rest cursor-spec)
 374   (let ((newcursor (apply #'cursor cursor-spec)))
 375     (setf (cursor-block *cursor*) (cursor-block newcursor))
 376     (setf (cursor-next *cursor*) (cursor-next newcursor))
 377     *cursor*))
 378
 379 ;;; Insert NODE at cursor.
 380 (defun insert-node (node &optional (cursor *cursor*))
 381   (link-nodes (node-prev (cursor-next cursor)) node)
 382   (link-nodes node (cursor-next cursor))
 383   t)
 384
 385 ;;; Split the block at CURSOR. The cursor will point to the end of the
 386 ;;; first basic block. Return the three basic blocks as multiple
 387 ;;; values.
 388 (defun split-block (&optional (cursor *cursor*))
 389   ;; <aaaaa|zzzzz>  ==>  <aaaaa|>--<zzzzz>
 390   (let* ((block (cursor-block cursor))
 391          (newexit (make-block-exit))
 392          (newentry (make-block-entry))
 393          (exit (block-exit block))
 394          (newblock (make-block :entry newentry
 395                                :exit exit
 396                                :pred (list block)
 397                                :succ (block-succ block))))
 398     (insert-node newexit)
 399     (insert-node newentry)
 400     (setf (node-next newexit)  nil)
 401     (setf (node-prev newentry) nil)
 402     (setf (block-exit block) newexit)
 403     (setf (block-succ block) (list newblock))
 404     (dolist (succ (block-succ newblock))
 405       (setf (block-pred succ) (substitute newblock block (block-pred succ))))
 406     (set-cursor :block block :before newexit)
 407     newblock))
 408
 409 ;;; Split the block at CURSOR if it is in the middle of it. The cursor
 410 ;;; will point to the end of the first basic block. Return the three
 411 ;;; basic blocks as multiple values.
 412 (defun maybe-split-block (&optional (cursor *cursor*))
 413   ;; If we are converting IR into the end of the basic block, it's
 414   ;; fine, we don't need to do anything.
 415   (unless (block-exit-p (cursor-next cursor))
 416     (split-block cursor)))
 417
 418
 419
 420 ;;;; Lexical environment
 421 ;;;;
 422 ;;;; It keeps an association between names and the IR entities. It is
 423 ;;;; used to guide the translation from the Lisp source code to the
 424 ;;;; intermediate representation.
 425
 426 (defstruct binding
 427   name namespace type value)
 428
 429 (defvar *lexenv* nil)
 430
 431 (defun find-binding (name namespace)
 432   (find-if (lambda (b)
 433              (and (eq (binding-name b) name)
 434                   (eq (binding-namespace b) namespace)))
 435            *lexenv*))
 436
 437 (defun push-binding (name namespace value &optional type)
 438   (push (make-binding :name name
 439                       :namespace namespace
 440                       :type type
 441                       :value value)
 442         *lexenv*))
 443
 444
 445 ;;;; IR Translation
 446 ;;;;
 447 ;;;; This code covers the translation from Lisp source code to the
 448 ;;;; intermediate representation. The main entry point function to do
 449 ;;;; that is the `ir-convert' function, which dispatches to IR
 450 ;;;; translators. This function ss intended to do the initial
 451 ;;;; conversion as well as insert new IR code during optimizations.
 452 ;;;;
 453 ;;;; The function `ir-normalize' will coalesce basic blocks in a
 454 ;;;; component to generate proper maximal basic blocks, as well as
 455 ;;;; compute reverse depth first ordering on the blocks.
 456
 457 ;;; A alist of IR translator functions.
 458 (defvar *ir-translator* nil)
 459
 460 ;;; Define a IR translator for NAME. LAMBDA-LIST is used to
 461 ;;; destructure the arguments of the form. Calling the local function
 462 ;;; `result-lvar' you can get the LVAR where the compilation of the
 463 ;;; expression should store the result of the evaluation.
 464 ;;;
 465 ;;; The cursor is granted to be at the end of a basic block with a
 466 ;;; unique successor, and so it should be when the translator returns.
 467 (defmacro define-ir-translator (name lambda-list &body body)
 468   (check-type name symbol)
 469   (let ((fname (intern (format nil "IR-CONVERT-~a" (string name)))))
 470     (with-gensyms (result form)
 471       `(progn
 472          (defun ,fname (,form ,result)
 473            (flet ((result-lvar () ,result))
 474              (declare (ignorable (function result-lvar)))
 475              (destructuring-bind ,lambda-list ,form
 476                ,@body)))
 477          (push (cons ',name #',fname) *ir-translator*)))))
 478
 479 ;;; Return the unique successor of the current block. If it is not
 480 ;;; unique signal an error.
 481 (defun next-block ()
 482   (unlist (block-succ (current-block))))
 483
 484 ;;; Set the next block of the current one.
 485 (defun (setf next-block) (new-value)
 486   (let ((block (current-block)))
 487     (dolist (succ (block-succ block))
 488       (setf (block-pred succ) (remove block (block-pred succ))))
 489     (setf (block-succ block) (list new-value))
 490     (push block (block-pred new-value))
 491     new-value))
 492
 493 (defun ir-convert-constant (form result)
 494   (let* ((leaf (make-constant :value form)))
 495     (insert-node (make-ref :leaf leaf :lvar result))))
 496
 497 (define-ir-translator quote (form)
 498   (ir-convert-constant form (result-lvar)))
 499
 500 (define-ir-translator setq (variable value)
 501   (let ((b (find-binding variable 'variable)))
 502     (cond
 503       (b
 504        (let ((var (make-var :name variable))
 505              (value-lvar (make-lvar)))
 506          (ir-convert value value-lvar)
 507          (let ((assign (make-assignment :variable var :value value-lvar :lvar (result-lvar))))
 508            (insert-node assign))))
 509       (t
 510        (ir-convert `(set ',variable ,value) (result-lvar))))))
 511
 512 (define-ir-translator progn (&body body)
 513   (mapc #'ir-convert (butlast body))
 514   (ir-convert (car (last body)) (result-lvar)))
 515
 516 (define-ir-translator if (test then &optional else)
 517   ;; It is the schema of how the basic blocks will look like
 518   ;;
 519   ;;              / ..then.. \
 520   ;;  <aaaaXX> --<            >-- <|> -- <zzzz>
 521   ;;              \ ..else.. /
 522   ;;
 523   ;; Note that is important to leave the cursor in an empty basic
 524   ;; block, as zzz could be the exit basic block of the component,
 525   ;; which is an invalid position for a cursor.
 526   (let ((test-lvar (make-lvar))
 527         (then-block (make-empty-block))
 528         (else-block (make-empty-block))
 529         (join-block (make-empty-block)))
 530     (ir-convert test test-lvar)
 531     (insert-node (make-conditional :test test-lvar :consequent then-block :alternative else-block))
 532     (let* ((block (current-block))
 533            (tail-block (next-block)))
 534       ;; Link together the different created basic blocks.
 535       (setf (block-succ block)      (list else-block then-block)
 536             (block-pred else-block) (list block)
 537             (block-pred then-block) (list block)
 538             (block-succ then-block) (list join-block)
 539             (block-succ else-block) (list join-block)
 540             (block-pred join-block) (list else-block then-block)
 541             (block-succ join-block) (list tail-block)
 542             (block-pred tail-block) (substitute join-block block (block-pred tail-block))))
 543     ;; Convert he consequent and alternative forms and update cursor.
 544     (ir-convert then (result-lvar) (cursor :block then-block))
 545     (ir-convert else (result-lvar) (cursor :block else-block))
 546     (set-cursor :block join-block)))
 547
 548 (define-ir-translator block (name &body body)
 549   (let ((new (split-block)))
 550     (push-binding name 'block (cons (next-block) (result-lvar)))
 551     (ir-convert `(progn ,@body) (result-lvar))
 552     (set-cursor :block new)))
 553
 554 (define-ir-translator return-from (name &optional value)
 555   (let ((binding
 556          (or (find-binding name 'block)
 557              (error "Tried to return from unknown block `~S' name" name))))
 558     (destructuring-bind (jump-block . lvar)
 559         (binding-value binding)
 560       (ir-convert value lvar)
 561       (setf (next-block) jump-block)
 562       ;; This block is really unreachable, even if the following code
 563       ;; is labelled in a tagbody, as tagbody will create a new block
 564       ;; for each label. However, we have to leave the cursor
 565       ;; somewhere to convert new input.
 566       (let ((dummy (make-empty-block)))
 567         (set-cursor :block dummy)))))
 568
 569 (define-ir-translator tagbody (&rest statements)
 570   (flet ((go-tag-p (x)
 571            (or (integerp x) (symbolp x))))
 572     (let* ((tags (remove-if-not #'go-tag-p statements))
 573            (tag-blocks nil))
 574       ;; Create a chain of basic blocks for the tags, recording each
 575       ;; block in a alist in TAG-BLOCKS.
 576       (let ((*cursor* *cursor*))
 577         (dolist (tag tags)
 578           (setq *cursor* (cursor :block (split-block)))
 579           (push-binding tag 'tag (current-block))
 580           (if (assoc tag tag-blocks)
 581               (error "Duplicated tag `~S' in tagbody." tag)
 582               (push (cons tag (current-block)) tag-blocks))))
 583       ;; Convert the statements into the correct block.
 584       (dolist (stmt statements)
 585         (if (go-tag-p stmt)
 586             (set-cursor :block (cdr (assoc stmt tag-blocks)))
 587             (ir-convert stmt))))))
 588
 589 (define-ir-translator go (label)
 590   (let ((tag-binding
 591          (or (find-binding label 'tag)
 592              (error "Unable to jump to the label `~S'" label))))
 593     (setf (next-block) (binding-value tag-binding))
 594     ;; Unreachable block.
 595     (let ((dummy (make-empty-block)))
 596       (set-cursor :block dummy))))
 597
 598
 599 (defun ir-convert-functoid (result name arguments &rest body)
 600   (let ((component)
 601         (return-lvar (make-lvar)))
 602     (with-component-compilation (name)
 603       (ir-convert `(progn ,@body) return-lvar)
 604       (ir-normalize)
 605       (setq component *component*))
 606     (let ((functional
 607            (make-functional
 608             :name name
 609             :arguments arguments
 610             :component component
 611             :return-lvar return-lvar)))
 612       (push functional (component-functions *component*))
 613       (insert-node (make-ref :leaf functional :lvar result)))))
 614
 615 (define-ir-translator function (name)
 616   (if (atom name)
 617       (ir-convert `(symbol-function ,name) (result-lvar))
 618       (ecase (car name)
 619         ((lambda named-lambda)
 620          (let ((desc (cdr name)))
 621            (when (eq 'lambda (car name))
 622              (push nil desc))
 623            (apply #'ir-convert-functoid (result-lvar) desc)))
 624         (setf))))
 625
 626 (defun ir-convert-var (form result)
 627   (let ((binds (find-binding form 'variable)))
 628     (if binds
 629         (insert-node (make-ref :leaf (binding-value binds) :lvar result))
 630         (ir-convert `(symbol-value ',form) result))))
 631
 632 (defun ir-convert-call (form result)
 633   (destructuring-bind (function &rest args) form
 634     (let ((func-lvar (make-lvar))
 635           (args-lvars nil))
 636       ;; Argument list
 637       (dolist (arg args)
 638         (let ((arg-lvar (make-lvar)))
 639           (push arg-lvar args-lvars)
 640           (ir-convert arg arg-lvar)))
 641       (setq args-lvars (reverse args-lvars))
 642       ;; Funcall
 643       (if (find-primitive function)
 644           (insert-node (make-primitive-call
 645                         :function (find-primitive function)
 646                         :arguments args-lvars
 647                         :lvar result))
 648           (progn
 649             (ir-convert `(symbol-function ,function) func-lvar)
 650             (insert-node (make-call :function func-lvar
 651                                     :arguments args-lvars
 652                                     :lvar result)))))))
 653
 654 ;;; Convert the Lisp expression FORM, it may create new basic
 655 ;;; blocks. RESULT is the lvar representing the result of the
 656 ;;; computation or null if the value should be discarded. The IR is
 657 ;;; inserted at *CURSOR*.
 658 (defun ir-convert (form &optional result (*cursor* *cursor*))
 659   ;; Rebinding the lexical environment here we make sure that the
 660   ;; lexical information introduced by FORM is just available for
 661   ;; subforms.
 662   (let ((*lexenv* *lexenv*))
 663     ;; Possibly create additional blocks in order to make sure the
 664     ;; cursor is at end the end of a basic block.
 665     (maybe-split-block)
 666     (cond
 667       ((atom form)
 668        (cond
 669          ((symbolp form)
 670           (ir-convert-var form result))
 671          (t
 672           (ir-convert-constant form result))))
 673       (t
 674        (destructuring-bind (op &rest args) form
 675          (let ((translator (cdr (assoc op *ir-translator*))))
 676            (if translator
 677                (funcall translator args result)
 678                (ir-convert-call form result))))))
 679     (values)))
 680
 681
 682 ;;; Change all the predecessors of BLOCK to precede NEW-BLOCK instead.
 683 (defun replace-block (block new-block)
 684   (let ((predecessors (block-pred block)))
 685     (setf (block-pred new-block) (union (block-pred new-block) predecessors))
 686     (dolist (pred predecessors)
 687       (setf (block-succ pred) (substitute new-block block (block-succ pred)))
 688       (unless (component-entry-p pred)
 689         (let ((last-node (node-prev (block-exit pred))))
 690           (when (conditional-p last-node)
 691             (macrolet ((replacef (place)
 692                          `(setf ,place (if (eq block ,place) new-block ,place))))
 693               (replacef (conditional-consequent last-node))
 694               (replacef (conditional-alternative last-node)))))))))
 695
 696 (defun delete-block (block)
 697   (when (boundary-block-p block)
 698     (error "Cannot delete entry or exit basic blocks."))
 699   (unless (singlep (block-succ block))
 700     (error "Cannot delete a basic block with multiple successors."))
 701   (replace-block block (unlist (block-succ block))))
 702
 703 ;;; Try to coalesce BLOCK with the successor if it is unique and block
 704 ;;; is its unique predecessor.
 705 (defun maybe-coalesce-block (block)
 706   (when (singlep (block-succ block))
 707     (let ((succ (first (block-succ block))))
 708       (when (and (not (component-exit-p succ)) (singlep (block-pred succ)))
 709         (link-nodes (node-prev (block-exit block))
 710                     (node-next (block-entry succ)))
 711         (setf (block-succ block) (block-succ succ))
 712         (dolist (next (block-succ succ))
 713           (setf (block-pred next) (substitute block succ (block-pred next))))
 714         t))))
 715
 716 ;;; Normalize a component. This function must be called after a batch
 717 ;;; of modifications to the flowgraph of the component to make sure it
 718 ;;; is a valid input for the possible optimizations and the backend.
 719 (defun ir-normalize (&optional (component *component*))
 720   (flet ((clean-and-coallesce (block)
 721            (maybe-coalesce-block block)
 722            (when (empty-block-p block)
 723              (delete-block block)))
 724          (add-to-list (block)
 725            (push block (component-blocks *component*))))
 726     (map-postorder-blocks #'clean-and-coallesce component)
 727     (map-postorder-blocks #'add-to-list component)
 728     (check-ir-consistency)))
 729
 730
 731 ;;; IR Debugging
 732
 733 (defun format-block-name (block)
 734   (cond
 735     ((eq block (unlist (block-succ (component-entry (block-component block)))))
 736      (format nil "ENTRY-~a" (component-id (block-component block))))
 737     ((component-exit-p block)
 738      (format nil "EXIT-~a" (component-id (block-component block))))
 739     (t
 740      (format nil "BLOCK ~a" (block-id block)))))
 741
 742 (defun print-node (node)
 743   (when (node-lvar node)
 744     (format t "$~a = " (lvar-id (node-lvar node))))
 745   (cond
 746     ((ref-p node)
 747      (let ((leaf (ref-leaf node)))
 748        (cond
 749          ((var-p leaf)
 750           (format t "~a" (var-name leaf)))
 751          ((constant-p leaf)
 752           (format t "'~s" (constant-value leaf)))
 753          ((functional-p leaf)
 754           (format t "#<function ~a>" (functional-name leaf))))))
 755     ((assignment-p node)
 756      (format t "set ~a $~a"
 757              (var-name (assignment-variable node))
 758              (lvar-id (assignment-value node))))
 759     ((primitive-call-p node)
 760      (format t "primitive ~a" (primitive-name (primitive-call-function node)))
 761      (dolist (arg (primitive-call-arguments node))
 762        (format t " $~a" (lvar-id arg))))
 763     ((call-p node)
 764      (format t "call $~a" (lvar-id (call-function node)))
 765      (dolist (arg (call-arguments node))
 766        (format t " $~a" (lvar-id arg))))
 767     ((conditional-p node)
 768      (format t "if $~a then ~a else ~a~%"
 769              (lvar-id (conditional-test node))
 770              (format-block-name (conditional-consequent node))
 771              (format-block-name (conditional-alternative node))))
 772     (t
 773      (error "`print-node' does not support printing ~S as a node." node)))
 774   (terpri))
 775
 776 (defun print-block (block)
 777   (write-line (format-block-name block))
 778   (do-nodes (node block)
 779     (print-node node))
 780   (when (singlep (block-succ block))
 781     (format t "GO ~a~%~%" (format-block-name (unlist (block-succ block))))))
 782
 783 (defun /print (component &optional (stream *standard-output*))
 784   (format t ";;; COMPONENT ~a (~a) ~%~%" (component-name component) (component-id component))
 785   (let ((*standard-output* stream))
 786     (do-blocks (block component)
 787       (print-block block)))
 788   (format t ";;; END COMPONENT ~a ~%~%" (component-name component))
 789   (let ((*standard-output* stream))
 790     (dolist (func (component-functions component))
 791       (/print (functional-component func)))))
 792
 793 ;;; Translate FORM into IR and print a textual repreresentation of the
 794 ;;; component.
 795 (defun convert-toplevel-and-print (form)
 796   (let ((*counter-alist* nil))
 797     (with-component-compilation ('toplevel)
 798       (ir-convert form (make-lvar :id "out"))
 799       (ir-normalize)
 800       (/print *component*)
 801       *component*)))
 802
 803 (defmacro /ir (form)
 804   `(convert-toplevel-and-print ',form))
 805
 806
 807
 808 ;;;; Dominators
 809
 810 (defun compute-dominators (component)
 811   ;; Initialize the dominators of the entry to the component to be
 812   ;; empty and the power set of the set of blocks for proper basic
 813   ;; blocks in the component.
 814   (let ((n (length (component-blocks component))))
 815     ;; The component entry special block has not predecessors in the
 816     ;; set of (proper) basic blocks.
 817     (setf (block-dominators% (component-entry component))
 818           (make-array n :element-type 'bit :initial-element 0))
 819     (do-blocks (block component)
 820       (setf (block-dominators% block) (make-array n :element-type 'bit :initial-element 1))))
 821   ;; Iterate across the blocks in the component removing non domintors
 822   ;; until it reaches a fixed point.tpn
 823   (do ((i 0 0)
 824        (changes t))
 825       ((not changes))
 826     (setf changes nil)
 827     (do-blocks (block component)
 828       (format t "Processing ~a~%" (format-block-name block))
 829       (let ((new (reduce #'bit-and (mapcar #'block-dominators% (block-pred block)))))
 830         (setf (aref new i) 1)
 831         (setf changes (or changes (not (equal new (block-dominators% block)))))
 832         (setf (block-dominators% block) new)
 833         (incf i)))))
 834
 835
 836
 837 ;;;; Primitives
 838 ;;;;
 839 ;;;; Primitive functions are a set of functions provided by the
 840 ;;;; compiler. They cannot usually be written in terms of other
 841 ;;;; functions. When the compiler tries to compile a function call, it
 842 ;;;; looks for a primitive function firstly, and if it is found and
 843 ;;;; the declarations allow it, a primitive call is inserted in the
 844 ;;;; IR. The back-end of the compiler knows how to compile primitive
 845 ;;;; calls.
 846 ;;;;
 847
 848 (defvar *primitive-function-table* nil)
 849
 850 (defstruct primitive
 851   name)
 852
 853 (defmacro define-primitive (name args &body body)
 854   (declare (ignore args body))
 855   `(push (make-primitive :name ',name)
 856          *primitive-function-table*))
 857
 858 (defun find-primitive (name)
 859   (find name *primitive-function-table* :key #'primitive-name))
 860
 861 (define-primitive symbol-function (symbol))
 862 (define-primitive symbol-value (symbol))
 863 (define-primitive set (symbol value))
 864 (define-primitive fset (symbol value))
 865
 866 (define-primitive + (&rest numbers))
 867 (define-primitive - (number &rest other-numbers))
 868
 869 (define-primitive consp (x))
 870 (define-primitive cons (x y))
 871 (define-primitive car (x))
 872 (define-primitive cdr (x))
 873
 874
 875 ;;; compiler.lisp ends here