glib/gobject.foreign-gboxed.lisp

   1 (in-package :gobject)
   2
   3 (defun ensure-list (thing)
   4   (if (listp thing) thing (list thing)))
   5
   6 (defun slot->cstruct-slot (slot)
   7   (destructuring-bind (name type &key &allow-other-keys) slot
   8     `(,name ,type)))
   9
  10 (defun slot->slot-name (slot)
  11   (destructuring-bind (name type &key &allow-other-keys) slot
  12     (declare (ignore type))
  13     name))
  14
  15 (defun cstruct-definition (name slots)
  16   `(defcstruct ,name ,@(mapcar #'slot->cstruct-slot slots)))
  17
  18 (defun maybe-unlist (thing)
  19   (if (or (not (listp thing)) (cdr thing))
  20       thing
  21       (car thing)))
  22
  23 (defun slot->struct-slot (slot)
  24   (destructuring-bind (name type &key initform &allow-other-keys) slot
  25     (declare (ignore type))
  26     (maybe-unlist `(,name ,@(when initform (list initform))))))
  27
  28 (defun struct-definition (name superclass slots)
  29   `(defstruct ,@(if superclass
  30                     (list `(,name (:include ,superclass)))
  31                     (list name))
  32      ,@(mapcar #'slot->struct-slot slots)))
  33
  34 (define-foreign-type g-boxed-pointer-type ()
  35   ((name :accessor g-boxed-pointer-type-name :initarg :name)
  36    (outp :accessor g-boxed-pointer-type-outp :initarg :outp)))
  37
  38 (define-parse-method g-boxed-ptr (name &optional (type :in))
  39   (make-instance 'g-boxed-pointer-type :name name :actual-type :pointer :outp (ecase type
  40                                                                                 (:in nil)
  41                                                                                 (:in-out t))))
  42
  43 (defmethod translate-from-foreign (value (type g-boxed-pointer-type))
  44   (unless (null-pointer-p value)
  45     (parse-g-boxed value (g-boxed-pointer-type-name type))))
  46
  47 (defmethod translate-to-foreign (value (type g-boxed-pointer-type))
  48   (let ((ptr (foreign-alloc (boxed-c-structure-name (g-boxed-pointer-type-name type)))))
  49     (real-unparse-g-boxed ptr value)
  50     (values ptr value)))
  51
  52 (defmethod free-translated-object (ptr (type g-boxed-pointer-type) param)
  53   (when (g-boxed-pointer-type-outp type)
  54     (let ((original-object param)
  55           (new-real-name (g-boxed-real-name ptr (g-boxed-pointer-type-name type))))
  56       (if (eq new-real-name (type-of original-object))
  57           (real-parse-g-boxed ptr original-object)
  58           (error "Type has changed!"))))
  59   (foreign-free ptr))
  60
  61 (defmethod expand-to-foreign-dyn (value var body (type g-boxed-pointer-type))
  62   (let ((value-var (gensym)))
  63     `(with-foreign-object (,var ',(boxed-c-structure-name (g-boxed-pointer-type-name type)))
  64        (let ((,value-var ,value))
  65          (real-unparse-g-boxed ,var ,value-var)
  66          ,@body
  67          ,@(when (g-boxed-pointer-type-outp type)
  68                  (list `(let ((new-real-name (g-boxed-real-name ,var ',(g-boxed-pointer-type-name type))))
  69                           (if (eq new-real-name (type-of ,value-var))
  70                               (real-parse-g-boxed ,var ,value-var)
  71                               (error "Type has changed from ~A to ~A" (type-of ,value-var) new-real-name)))))))))
  72
  73 (define-foreign-type g-boxed-inline-type ()
  74   ((name :accessor g-boxed-inline-type :initarg :name)))
  75
  76 (define-parse-method g-boxed-inline (name)
  77   (make-instance 'g-boxed-inline-type :name name :actual-type name))
  78
  79 (defgeneric real-parse-g-boxed (pointer object))
  80 (defgeneric real-unparse-g-boxed (pointer object))
  81
  82 (defun parse-g-boxed (pointer name)
  83   (let* ((real-name (g-boxed-real-name pointer name))
  84          (object (make-instance real-name)))
  85     (real-parse-g-boxed pointer object)
  86     object))
  87
  88 (defun g-boxed->cstruct (object)
  89   (let ((pointer (foreign-alloc (type-of object))))
  90     (real-unparse-g-boxed pointer object)
  91     pointer))
  92
  93 (defun g-boxed-real-name (pointer name)
  94   (or (loop
  95          for (sub-name slot values) in (get name 'boxed-dispatch)
  96          do (debugf "Checking ~A ~A ~A against ~A.~A = ~A~%" sub-name slot values name slot (foreign-slot-value pointer name slot))
  97          when (member (foreign-slot-value pointer name slot) values :test 'equalp)
  98          return (g-boxed-real-name pointer sub-name))
  99       name))
 100
 101 (defun slot->slot-parser (class-name pointer-var slot)
 102   (bind (((slot-name slot-type &key parser &allow-other-keys) slot))
 103     (cond
 104       (parser
 105        `(setf ,slot-name (funcall ,parser ',class-name ,pointer-var)))
 106       ((and (listp slot-type) (eq 'g-boxed-inline (first slot-type)))
 107        `(setf ,slot-name (parse-g-boxed (foreign-slot-pointer ,pointer-var ',class-name ',slot-name) ',(second slot-type))))
 108       (t
 109        `(setf ,slot-name (foreign-slot-value ,pointer-var ',class-name ',slot-name))))))
 110
 111 (defun parse-method-definition (name slots)
 112   (let ((slot-names (mapcar #'slot->slot-name slots)))
 113     `(defmethod real-parse-g-boxed (pointer (object ,name))
 114        (with-slots (,@slot-names) object
 115          ,@(mapcar (lambda (slot) (slot->slot-parser name 'pointer slot)) slots)))))
 116
 117 (defun slot->slot-unparser (class-name pointer-var slot object)
 118   (bind (((slot-name slot-type &key unparser &allow-other-keys) slot))
 119     (cond
 120       (unparser
 121        `(funcall ,unparser ',class-name ,pointer-var ,object))
 122       ((and (listp slot-type) (eq 'g-boxed-inline (first slot-type)))
 123        `(real-unparse-g-boxed (foreign-slot-pointer ,pointer-var ',class-name ',slot-name) ,slot-name))
 124       (t
 125        `(setf (foreign-slot-value ,pointer-var ',class-name ',slot-name) ,slot-name)))))
 126
 127 (defun unparse-method-definition (name slots)
 128   (let ((slot-names (mapcar #'slot->slot-name slots)))
 129     `(defmethod real-unparse-g-boxed (pointer (object ,name))
 130        (with-slots (,@slot-names) object
 131          ,@(mapcar (lambda (slot) (slot->slot-unparser name 'pointer slot 'object)) slots)))))
 132
 133 (defun slot->export-accessor (class-name slot)
 134   (destructuring-bind (slot-name slot-type &key &allow-other-keys) slot
 135     (declare (ignore slot-type))
 136     (let ((accessor-name (intern (format nil "~A-~A" (symbol-name class-name) (symbol-name slot-name))
 137                                  (symbol-package class-name))))
 138       `(export ',accessor-name (symbol-package ',accessor-name)))))
 139
 140 (defun struct-constructor-name (name)
 141   (intern (format nil "MAKE-~A" (symbol-name name)) (symbol-package name)))
 142
 143 (defun get-g-boxed-direct-subclasses (name)
 144   (mapcar (lambda (spec) (bind (((name slot values) spec))
 145                            (declare (ignore slot values))
 146                            name))
 147           (get name 'boxed-dispatch)))
 148
 149 (defun map-append (f &rest lists)
 150   (reduce #'append (apply #'mapcar f lists)))
 151
 152 (defun get-g-boxed-all-subclasses (name)
 153   (cons name
 154         (map-append #'get-g-boxed-all-subclasses (get-g-boxed-direct-subclasses name))))
 155
 156 (defun get-g-boxed-completed-c-definition (name union-name)
 157   `(defcunion ,union-name
 158      ,@(mapcar (lambda (sub-name)
 159                  `(,sub-name ,sub-name))
 160                (get-g-boxed-all-subclasses name))))
 161
 162 (defun g-boxed-root (name)
 163   (if (get name 'superclass)
 164       (g-boxed-root (get name 'superclass))
 165       name))
 166
 167 (defmacro update-g-boxed-root-c-class (name)
 168   (when (get name 'c-name)
 169     (get-g-boxed-completed-c-definition (g-boxed-root name) (get name 'c-name))))
 170
 171 (defmacro define-g-boxed-class (g-name-and-c-name name (&optional superclass-and-dispatch (export t)) &body slots)
 172   (bind (((&optional g-name c-name) (ensure-list g-name-and-c-name))
 173          ((&optional superclass dispatch-slot dispatch-values) superclass-and-dispatch)
 174          (superclass-slots (get superclass 'boxed-combined-slots))
 175          (combined-slots (append superclass-slots slots)))
 176     (setf c-name (or c-name (gensym "C-UNION-")))
 177     `(progn ,(cstruct-definition name combined-slots)
 178             ,(struct-definition name superclass slots)
 179             ,(parse-method-definition name combined-slots)
 180             ,(unparse-method-definition name combined-slots)
 181             (eval-when (:load-toplevel :compile-toplevel :execute)
 182               (setf (get ',name 'boxed-slots) ',slots
 183                     (get ',name 'boxed-combined-slots) ',combined-slots
 184                     (get ',name 'superclass) ',superclass
 185                     (get ',name 'c-name) (or (get ',name 'c-name) ',c-name))
 186               ,@(when superclass
 187                       (list `(pushnew '(,name ,dispatch-slot ,(ensure-list dispatch-values)) (get ',superclass 'boxed-dispatch) :test 'equalp))))
 188             (update-g-boxed-root-c-class ,name)
 189             ,@(when g-name
 190                     (list `(register-boxed-type ,g-name ',name)))
 191             ,@(when export
 192                     (append (list `(export ',name (symbol-package ',name))
 193                                   `(export ',(struct-constructor-name name) (symbol-package ',(struct-constructor-name name))))
 194                             (mapcar (lambda (slot) (slot->export-accessor name slot)) slots))))))
 195
 196 (defun boxed-c-structure-name (name)
 197   (get (g-boxed-root name) 'c-name))
 198
 199 (defclass g-boxed-ref () ((pointer :accessor pointer :initarg :pointer)))
 200
 201 (defvar *g-boxed-gc-lock* (make-recursive-lock "g-boxed-gc-lock"))
 202 (defvar *known-boxed-refs* (tg:make-weak-hash-table :test 'equal :weakness :value))
 203 (defvar *boxed-ref-count* (make-hash-table :test 'equal))
 204 (defvar *boxed-ref-owner* (make-hash-table :test 'equal))
 205
 206 (defun boxed-ref-free-function (name)
 207   (or (get name 'free-function)
 208       (error "g-boxed-ref class ~A has no free-function" name)))
 209
 210 (defun disown-boxed-ref (object)
 211   (setf (gethash (pointer-address (pointer object)) *boxed-ref-owner*) :foreign))
 212
 213 (defun dispose-boxed-ref (type pointer)
 214   (debugf "disposing g-boxed-ref ~A~%" pointer)
 215
 216   (unless (gethash (pointer-address pointer) *boxed-ref-count*)
 217     (error "g-boxed-ref ~A is already disposed from lisp-side" pointer))
 218   (with-recursive-lock-held (*g-boxed-gc-lock*)
 219     (awhen (gethash (pointer-address pointer) *known-boxed-refs*)
 220       (debugf "Removing finalization from ~A for pointer ~A~%" it pointer)
 221       (tg:cancel-finalization it))
 222     (when (eq :lisp (gethash (pointer-address pointer) *boxed-ref-owner*))
 223       (funcall (boxed-ref-free-function type) pointer))
 224     (remhash (pointer-address pointer) *known-boxed-refs*)
 225     (remhash (pointer-address pointer) *boxed-ref-count*)
 226     (remhash (pointer-address pointer) *boxed-ref-owner*)
 227     (debugf "Disposed of g-boxed-ref ~A (object ~A)~%"
 228             pointer
 229             (gethash (pointer-address pointer) *known-boxed-refs*))))
 230
 231 (defmethod initialize-instance :after ((object g-boxed-ref) &key)
 232   (with-recursive-lock-held (*g-boxed-gc-lock*)
 233     (let ((address (pointer-address (pointer object))))
 234       (awhen (gethash address *known-boxed-refs*)
 235         (tg:cancel-finalization it))
 236       (setf (gethash address *known-boxed-refs*) object)
 237       (setf (gethash address *boxed-ref-count*) 1)
 238       (setf (gethash address *boxed-ref-owner*)
 239             (gethash address *boxed-ref-owner* :foreign)))
 240     (debugf "setting g-boxed-ref-count of ~A (for ptr ~A) to 1~%" object (pointer object))
 241     (let ((p (pointer object))
 242           (type (type-of object))
 243           (s (format nil "~A" object)))
 244       (tg:finalize object (lambda ()
 245                             (handler-case
 246                                 (dispose-boxed-ref type p)
 247                               (error (e) (format t "Error ~A for ~A~%" e s))))))))
 248
 249 (defmethod release ((object g-boxed-ref))
 250   (debugf "releasing g-boxed-ref ~A~%" (pointer object))
 251   (unless (gethash (pointer-address (pointer object)) *boxed-ref-count*)
 252     (error "g-boxed-ref ~A is already disposed from lisp-side" (pointer object)))
 253   (decf (gethash (pointer-address (pointer object)) *boxed-ref-count*))
 254   (when (zerop (gethash (pointer-address (pointer object)) *boxed-ref-count*))
 255     (dispose-boxed-ref (type-of object) (pointer object))))
 256
 257 (define-foreign-type g-boxed-ref-type ()
 258   ((class-name :reader g-boxed-ref-class-name :initarg :class-name)
 259    (owner :reader g-boxed-ref-owner :initarg :owner :initform nil))
 260   (:actual-type :pointer))
 261
 262 (define-parse-method g-boxed-ref (class-name &key (owner :foreign))
 263   (unless (get class-name 'is-g-boxed-ref)
 264     (error "~A is not a subtype of G-BOXED-REF (~A: ~S)" class-name class-name (symbol-plist class-name)))
 265   (make-instance 'g-boxed-ref-type :class-name class-name :owner owner))
 266
 267 (defmethod translate-to-foreign (value (type g-boxed-ref-type))
 268   (if value
 269       (pointer value)
 270       (null-pointer)))
 271
 272 (defun convert-g-boxed-ref-from-pointer (pointer name type)
 273   (unless (null-pointer-p pointer)
 274     (with-recursive-lock-held (*g-boxed-gc-lock*)
 275      (or (aprog1 (gethash (pointer-address pointer) *known-boxed-refs*)
 276            (when it (debugf "Boxed-ref for ~A is found (~A)~%" pointer it))
 277            (when it (incf (gethash (pointer-address pointer) *boxed-ref-count*)))
 278            it)
 279          (aprog1 (make-instance name :pointer pointer)
 280            (setf (gethash (pointer-address pointer) *boxed-ref-owner*) (g-boxed-ref-owner type))
 281            (debugf "Boxed-ref for ~A is created (~A) with owner ~A~%" pointer it
 282                    (gethash (pointer-address pointer) *boxed-ref-owner*))
 283            it)))))
 284
 285 (defmethod translate-from-foreign (value (type g-boxed-ref-type))
 286   (let ((owner (or (gethash (pointer-address value) *boxed-ref-owner*) (g-boxed-ref-owner type)))) ;;This is needed to prevent changing ownership of already created
 287     (prog1
 288         (convert-g-boxed-ref-from-pointer value (g-boxed-ref-class-name type) type)
 289       (setf (gethash (pointer-address value) *boxed-ref-owner*) owner))))
 290
 291 (defun g-boxed-ref-slot->methods (class slot)
 292   (bind (((slot-name &key reader writer type (accessor slot-name)) slot))
 293     `(progn ,@(when reader
 294                     (list `(defmethod ,accessor ((object ,class))
 295                              ,(if (stringp reader)
 296                                   `(foreign-funcall ,reader :pointer (pointer object) ,type)
 297                                   `(,reader object)))))
 298             ,@(when writer
 299                     (list `(defmethod (setf ,accessor) (new-value (object ,class))
 300                              ,(if (stringp writer)
 301                                   `(foreign-funcall ,writer :pointer (pointer object) ,type new-value)
 302                                   `(,writer new-value object))))))))
 303
 304 (defmacro define-g-boxed-ref (gobject-name name &rest properties)
 305   (let ((free-fn (second (find :free-function properties :key 'first)))
 306         (alloc-fn (second (find :alloc-function properties :key 'first)))
 307         (slots (rest (find :slots properties :key 'first))))
 308     (unless (and free-fn alloc-fn) (error "All of :free-function, :alloc-function must be specified"))
 309     `(progn (defclass ,name (g-boxed-ref) ())
 310             (defmethod initialize-instance :before ((object ,name) &key pointer)
 311               (unless (or pointer (slot-boundp object 'pointer))
 312                 (setf (pointer object) (,alloc-fn)
 313                       (gethash (pointer-address (pointer object)) *boxed-ref-owner*) :lisp)))
 314             (setf (get ',name 'free-function) ',free-fn)
 315             (eval-when (:compile-toplevel :load-toplevel :execute)
 316               (setf (get ',name 'is-g-boxed-ref) t))
 317             ,@(mapcar (lambda (slot)
 318                         (g-boxed-ref-slot->methods name slot))
 319                       slots)
 320             (register-boxed-type ,gobject-name ',name))))
 321
 322 (define-foreign-type fixed-array ()
 323   ((element-type :reader fixed-array-element-type :initarg :element-type :initform (error "Element type must be specified"))
 324    (array-size :reader fixed-array-array-size :initarg :array-size :initform (error "Array size must be specified")))
 325   (:actual-type :pointer))
 326
 327 (define-parse-method fixed-array (element-type array-size)
 328   (make-instance 'fixed-array :element-type element-type :array-size array-size))
 329
 330 (defmethod translate-from-foreign (ptr (type fixed-array))
 331   (when (not (null-pointer-p ptr))
 332     (let ((result (make-array (fixed-array-array-size type)))
 333           (el-type (fixed-array-element-type type)))
 334       (loop
 335          for i from 0 below (fixed-array-array-size type)
 336          do (setf (aref result i) (mem-aref ptr el-type i)))
 337       result)))
 338
 339 (defvar *registered-boxed-types* (make-hash-table :test 'equal))
 340 (defun register-boxed-type (name type)
 341   (setf (gethash name *registered-boxed-types*) type))
 342 (defun get-registered-boxed-type (name)
 343   (gethash name *registered-boxed-types*))
 344
 345 (defun set-gvalue-boxed (gvalue value)
 346   (if value
 347       (progn
 348         (unless (typep value 'g-boxed-ref) (error "Can only set g-boxed-ref!"))
 349         (g-value-set-boxed gvalue (pointer value)))
 350       (g-value-set-boxed gvalue (null-pointer))))
 351
 352 (defun parse-gvalue-boxed (gvalue)
 353   (let* ((g-type (gvalue-type gvalue))
 354          (type-name (g-type-name g-type))
 355          (boxed-type (get-registered-boxed-type type-name)))
 356     (unless boxed-type
 357       (warn t "Type ~A is a not registered GBoxed~%" type-name)
 358       (return-from parse-gvalue-boxed nil))
 359     (unless (null-pointer-p (g-value-get-boxed gvalue))
 360       (cond
 361         ((subtypep boxed-type 'g-boxed-ref) (convert-g-boxed-ref-from-pointer (g-value-get-boxed gvalue) boxed-type (make-instance 'g-boxed-ref-type :class-name boxed-type :owner :foreign)))
 362         (t (parse-g-boxed (g-value-get-boxed gvalue) boxed-type))))))