glib/gobject.foreign-gobject-subclassing.lisp

   1 (in-package :gobject)
   2
   3 (defvar *registered-types* (make-hash-table :test 'equal))
   4
   5 (defstruct object-type name class parent interfaces properties)
   6
   7 (defun instance-init (instance class)
   8   (log-for :subclass "(instance-init ~A ~A)~%" instance class)
   9   (log-for :subclass "Initializing instance ~A for type ~A (creating ~A)~%" instance (g-type-name (foreign-slot-value class 'g-type-class :type)) *current-creating-object*)
  10   (unless (or *current-creating-object*
  11               *currently-making-object-p*
  12               (gethash (pointer-address instance) *foreign-gobjects-strong*)
  13               (gethash (pointer-address instance) *foreign-gobjects-weak*))
  14     (log-for :subclass "Proceeding with initialization...~%")
  15     (let* ((g-type (foreign-slot-value class 'g-type-class :type))
  16            (type-name (g-type-name g-type))
  17            (lisp-type-info (gethash type-name *registered-types*))
  18            (lisp-class (object-type-class lisp-type-info)))
  19       (make-instance lisp-class :pointer instance))))
  20
  21 (defcallback c-instance-init :void ((instance :pointer) (class :pointer))
  22   (instance-init instance class))
  23
  24 (defcallback c-class-init :void ((class :pointer) (data :pointer))
  25   (class-init class data))
  26
  27 (defun minimum-foreign-integer (type &optional (signed t))
  28   (if signed
  29       (- (ash 1 (1- (* 8 (foreign-type-size type)))))
  30       0))
  31
  32 (defun maximum-foreign-integer (type &optional (signed t))
  33   (if signed
  34       (1- (ash 1 (1- (* 8 (foreign-type-size type)))))
  35       (1- (ash 1 (* 8 (foreign-type-size type))))))
  36
  37 (defun property->param-spec (property)
  38   (destructuring-bind (property-name property-type accessor property-get-fn property-set-fn) property
  39     (declare (ignore accessor))
  40     (let ((property-g-type (ensure-g-type property-type))
  41           (flags (append (when property-get-fn (list :readable))
  42                          (when property-set-fn (list :writable)))))
  43       (ev-case (g-type-fundamental property-g-type)
  44         (+g-type-invalid+ (error "GValue is of invalid type ~A (~A)" property-g-type (g-type-name property-g-type)))
  45         (+g-type-void+ nil)
  46         (+g-type-char+ (g-param-spec-char property-name property-name property-name (minimum-foreign-integer :char) (maximum-foreign-integer :char) 0 flags))
  47         (+g-type-uchar+ (g-param-spec-uchar property-name property-name property-name (minimum-foreign-integer :uchar nil) (maximum-foreign-integer :uchar nil) 0 flags))
  48         (+g-type-boolean+ (g-param-spec-boolean property-name property-name property-name nil flags))
  49         (+g-type-int+ (g-param-spec-int property-name property-name property-name (minimum-foreign-integer :int) (maximum-foreign-integer :int) 0 flags))
  50         (+g-type-uint+ (g-param-spec-uint property-name property-name property-name (minimum-foreign-integer :uint nil) (maximum-foreign-integer :uint nil) 0 flags))
  51         (+g-type-long+ (g-param-spec-long property-name property-name property-name (minimum-foreign-integer :long) (maximum-foreign-integer :long) 0 flags))
  52         (+g-type-ulong+ (g-param-spec-ulong property-name property-name property-name (minimum-foreign-integer :ulong nil) (maximum-foreign-integer :ulong nil) 0 flags))
  53         (+g-type-int64+ (g-param-spec-int64 property-name property-name property-name (minimum-foreign-integer :int64) (maximum-foreign-integer :int64) 0 flags))
  54         (+g-type-uint64+ (g-param-spec-uint64 property-name property-name property-name (minimum-foreign-integer :uint64 nil) (maximum-foreign-integer :uint64 t) 0 flags))
  55         (+g-type-enum+ (g-param-spec-enum property-name property-name property-name property-g-type (enum-item-value (first (get-enum-items property-g-type))) flags))
  56         (+g-type-flags+ (g-param-spec-enum property-name property-name property-name property-g-type (flags-item-value (first (get-flags-items property-g-type))) flags))
  57         (+g-type-float+ (g-param-spec-float property-name property-name property-name most-negative-single-float most-positive-single-float 0.0 flags))
  58         (+g-type-double+ (g-param-spec-double property-name property-name property-name most-negative-double-float most-positive-double-float 0.0d0 flags))
  59         (+g-type-string+ (g-param-spec-string property-name property-name property-name "" flags))
  60         (+g-type-pointer+ (g-param-spec-pointer property-name property-name property-name flags))
  61         (+g-type-boxed+ (g-param-spec-boxed property-name property-name property-name property-g-type flags))
  62                                         ;(+g-type-param+ (parse-g-value-param gvalue))
  63         (+g-type-object+ (g-param-spec-object property-name property-name property-name property-g-type flags))
  64                                         ;(+g-type-interface+ )
  65         (t (error "Unknown type: ~A (~A)" property-g-type (g-type-name property-g-type)))))))
  66
  67 (defun install-properties (class)
  68   (let* ((name (g-type-name (foreign-slot-value class 'g-type-class :type)))
  69          (lisp-type-info (gethash name *registered-types*)))
  70     (iter (for property in (object-type-properties lisp-type-info))
  71           (for param-spec = (property->param-spec property))
  72           (for property-id from 123)
  73           (log-for :subclass "installing property ~A~%" property)
  74           (g-object-class-install-property class property-id param-spec))))
  75
  76 (defun vtable-item->cstruct-item (item)
  77   (if (eq :skip (first item))
  78       (rest item)
  79       (list (first item) :pointer)))
  80
  81 (defstruct vtable-method-info slot-name name return-type args callback-name)
  82
  83 (defmethod make-load-form ((object vtable-method-info) &optional environment)
  84   (declare (ignore environment))
  85   `(make-vtable-method-info :slot-name ',(vtable-method-info-slot-name object)
  86                             :name ',(vtable-method-info-name object)
  87                             :return-type ',(vtable-method-info-return-type object)
  88                             :args ',(vtable-method-info-args object)
  89                             :callback-name ',(vtable-method-info-callback-name object)))
  90
  91 (defun vtable-methods (iface-name items)
  92   (iter (for item in items)
  93         (when (eq :skip (first item)) (next-iteration))
  94         (destructuring-bind (name return-type &rest args) item
  95           (for method-name = (intern (format nil "~A-~A-IMPL" (symbol-name iface-name) (symbol-name name))))
  96           (for callback-name = (intern (format nil "~A-~A-CALLBACK" (symbol-name iface-name) (symbol-name name))))
  97           (collect (make-vtable-method-info :slot-name name
  98                                             :name method-name
  99                                             :return-type return-type
 100                                             :args args
 101                                             :callback-name callback-name)))))
 102
 103 (defvar *vtables* (make-hash-table :test 'equal))
 104
 105 (defstruct vtable-description type-name cstruct-name methods)
 106
 107 (defmacro define-vtable ((type-name name) &body items)
 108   (let ((cstruct-name (intern (format nil "~A-VTABLE" (symbol-name name))))
 109         (methods (vtable-methods name items)))
 110     `(progn
 111        (defcstruct ,cstruct-name ,@(mapcar #'vtable-item->cstruct-item items))
 112        (setf (gethash ,type-name *vtables*)
 113              (make-vtable-description :type-name ,type-name
 114                                       :cstruct-name ',cstruct-name
 115                                       :methods (list ,@(mapcar #'make-load-form methods))))
 116        ,@(iter (for method in methods)
 117                (collect `(defgeneric ,(vtable-method-info-name method)
 118                              (,@(mapcar #'first (vtable-method-info-args method)))))
 119                (collect `(glib-defcallback ,(vtable-method-info-callback-name method)
 120                              ,(vtable-method-info-return-type method)
 121                              (,@(vtable-method-info-args method))
 122                            (restart-case
 123                                (,(vtable-method-info-name method) ,@(mapcar #'first (vtable-method-info-args method)))
 124                              (return-from-interface-method-implementation (v)
 125                                :interactive (lambda () (list (eval (read)))) v))))))))
 126
 127 (defun interface-init (iface data)
 128   (destructuring-bind (class-name interface-name) (prog1 (get-stable-pointer-value data) (free-stable-pointer data))
 129     (declare (ignorable class-name))
 130     (let* ((vtable (gethash interface-name *vtables*))
 131            (vtable-cstruct (vtable-description-cstruct-name vtable)))
 132       (log-for :subclass "interface-init for class ~A and interface ~A~%" class-name interface-name)
 133       (iter (for method in (vtable-description-methods vtable))
 134             (for cb = (get-callback (vtable-method-info-callback-name method)))
 135             (for slot-name = (vtable-method-info-slot-name method))
 136             (log-for :subclass "->setting method ~A to ~A~%" method cb)
 137             (setf (foreign-slot-value iface vtable-cstruct slot-name) cb)))))
 138
 139 (defcallback c-interface-init :void ((iface :pointer) (data :pointer))
 140   (interface-init iface data))
 141
 142 (defun add-interface (name interface)
 143   (let* ((interface-info (list name interface))
 144          (interface-info-ptr (allocate-stable-pointer interface-info)))
 145     (with-foreign-object (info 'g-interface-info)
 146       (setf (foreign-slot-value info 'g-interface-info :interface-init) (callback c-interface-init)
 147             (foreign-slot-value info 'g-interface-info :interface-data) interface-info-ptr)
 148       (g-type-add-interface-static (g-type-from-name name) (ensure-g-type interface) info))))
 149
 150 (defun add-interfaces (name)
 151   (let* ((lisp-type-info (gethash name *registered-types*))
 152          (interfaces (object-type-interfaces lisp-type-info)))
 153     (iter (for interface in interfaces)
 154           (add-interface name interface))))
 155
 156 (defun class-init (class data)
 157   (declare (ignore data))
 158   (log-for :subclass "class-init for ~A~%" (g-type-name (g-type-from-class class)))
 159   (setf (foreign-slot-value class 'g-object-class :get-property)
 160         (callback c-object-property-get)
 161         (foreign-slot-value class 'g-object-class :set-property)
 162         (callback c-object-property-set))
 163
 164   (install-properties class))
 165
 166 (defun object-property-get (object property-id g-value pspec)
 167   (declare (ignore property-id))
 168   (let* ((lisp-object (or (gethash (pointer-address object) *foreign-gobjects-strong*)
 169                           (gethash (pointer-address object) *foreign-gobjects-weak*)))
 170          (property-name (foreign-slot-value pspec 'g-param-spec :name))
 171          (property-type (foreign-slot-value pspec 'g-param-spec :value-type))
 172          (type-name (g-type-name (foreign-slot-value pspec 'g-param-spec :owner-type)))
 173          (lisp-type-info (gethash type-name *registered-types*))
 174          (property-info (find property-name (object-type-properties lisp-type-info) :test 'string= :key 'first))
 175          (property-get-fn (fourth property-info)))
 176     (log-for :subclass "get(~A,'~A')~%" lisp-object property-name)
 177     (let ((value (restart-case
 178                      (funcall property-get-fn lisp-object)
 179                    (return-from-property-getter (value) :interactive (lambda () (format t "Enter new value: ") (list (eval (read)))) value))))
 180       (set-g-value g-value value property-type))))
 181
 182 (defcallback c-object-property-get :void ((object :pointer) (property-id :uint) (value :pointer) (pspec :pointer))
 183   (object-property-get object property-id value pspec))
 184
 185 (defun object-property-set (object property-id value pspec)
 186   (declare (ignore property-id))
 187   (let* ((lisp-object (or (gethash (pointer-address object) *foreign-gobjects-strong*)
 188                           (gethash (pointer-address object) *foreign-gobjects-weak*)))
 189          (property-name (foreign-slot-value pspec 'g-param-spec :name))
 190          (type-name (g-type-name (foreign-slot-value pspec 'g-param-spec :owner-type)))
 191          (lisp-type-info (gethash type-name *registered-types*))
 192          (property-info (find property-name (object-type-properties lisp-type-info) :test 'string= :key 'first))
 193          (property-set-fn (fifth property-info))
 194          (new-value (parse-g-value value)))
 195     (log-for :subclass "set(~A,'~A',~A)~%" lisp-object property-name new-value)
 196     (restart-case
 197         (funcall property-set-fn new-value lisp-object)
 198       (return-without-error-from-property-setter () nil))))
 199
 200 (defcallback c-object-property-set :void ((object :pointer) (property-id :uint) (value :pointer) (pspec :pointer))
 201   (object-property-set object property-id value pspec))
 202
 203 (defmacro register-object-type-implementation (name class parent interfaces properties)
 204   (unless (stringp parent)
 205     (setf parent (g-type-name (ensure-g-type parent))))
 206   `(progn
 207      (setf (gethash ,name *registered-types*) (make-object-type :name ,name :class ',class :parent ,parent :interfaces ',interfaces :properties ',properties))
 208      (at-init (',class)
 209        (log-for :subclass "Registering GObject type implementation ~A for type ~A~%" ',class ,name)
 210        (with-foreign-object (query 'g-type-query)
 211          (g-type-query (g-type-from-name ,parent) query)
 212          (g-type-register-static-simple (g-type-from-name ,parent)
 213                                         ,name
 214                                         (foreign-slot-value query 'g-type-query :class-size)
 215                                         (callback c-class-init)
 216                                         (foreign-slot-value query 'g-type-query :instance-size)
 217                                         (callback c-instance-init) nil))
 218        (add-interfaces ,name))
 219      (defmethod initialize-instance :before ((object ,class) &key pointer)
 220        (log-for :subclass "(initialize-instance ~A :pointer ~A) :before~%" object pointer)
 221        (unless (or pointer (and (slot-boundp object 'gobject::pointer)
 222                                 (gobject::pointer object)))
 223          (log-for :subclass "calling g-object-constructor~%")
 224          (setf (gobject::pointer object) (gobject::g-object-call-constructor ,name nil nil)
 225                (gobject::g-object-has-reference object) t)))
 226      (progn
 227        ,@(iter (for (prop-name prop-type prop-accessor prop-reader prop-writer) in properties)
 228                (declare (ignorable prop-type))
 229                (when prop-reader
 230                  (collect `(defun ,prop-accessor (object) (g-object-call-get-property object ,prop-name))))
 231                (when prop-writer
 232                  (collect `(defun (setf ,prop-accessor) (new-value object) (g-object-call-set-property object ,prop-name new-value))))))
 233      ,name))