glib/gobject.foreign-gobject.lisp

   1 (in-package :gobject)
   2
   3 (defclass g-object ()
   4   ((pointer
   5     :type cffi:foreign-pointer
   6     :initarg :pointer
   7     :accessor pointer
   8     :initform nil)
   9    (has-reference
  10     :type boolean
  11     :accessor g-object-has-reference
  12     :initform nil))
  13   (:documentation
  14    "Base class for GObject classes hierarchy."))
  15
  16 (defvar *foreign-gobjects* (make-weak-hash-table :test 'equal :weakness :value))
  17 (defvar *foreign-gobjects-ref-count* (make-hash-table :test 'equal))
  18 (defvar *lisp-objects-pointers* (make-hash-table :test 'equal))
  19 (defvar *current-creating-object* nil)
  20
  21 (defcstruct g-object-struct
  22   (type-instance g-type-instance)
  23   (ref-count :uint)
  24   (qdata :pointer))
  25
  26 (defun ref-count (pointer)
  27   (foreign-slot-value (if (pointerp pointer) pointer (pointer pointer)) 'g-object-struct 'ref-count))
  28
  29 (defmethod initialize-instance :around ((obj g-object) &key)
  30   (let ((*current-creating-object* obj))
  31     (call-next-method)))
  32
  33 (defmethod initialize-instance :after ((obj g-object) &key &allow-other-keys)
  34   (unless (slot-boundp obj 'pointer)
  35     (error "Pointer slot is not initialized for ~A" obj))
  36   (let* ((pointer (pointer obj))
  37          (s (format nil "~A" obj)))
  38     (finalize obj
  39               (lambda ()
  40                 (handler-case
  41                     (g-object-dispose-carefully pointer)
  42                   (error (e) (format t "Error in finalizer for ~A: ~A~%" s e))))))
  43   (register-g-object obj)
  44   (activate-gc-hooks))
  45
  46 (defvar *gobject-gc-hooks-lock* (make-recursive-lock "gobject-gc-hooks-lock"))
  47 (defvar *gobject-gc-hooks* nil);;pointers to objects to be freed
  48
  49 (defun activate-gc-hooks ()
  50   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  51     (when *gobject-gc-hooks*
  52       (debugf "activating gc hooks for objects: ~A~%" *gobject-gc-hooks*)
  53       (loop
  54          for pointer in *gobject-gc-hooks*
  55          do (g-object-unref pointer))
  56       (setf *gobject-gc-hooks* nil))))
  57
  58 (defcallback g-idle-gc-hook :boolean ((data :pointer))
  59   (declare (ignore data))
  60   (activate-gc-hooks)
  61   nil)
  62
  63 (defun register-gobject-for-gc (pointer)
  64   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  65     (let ((locks-were-present (not (null *gobject-gc-hooks*))))
  66       (push pointer *gobject-gc-hooks*)
  67       (unless locks-were-present
  68         (debugf "adding idle-gc-hook to main loop~%")
  69         (glib::g-idle-add (callback g-idle-gc-hook) (null-pointer))))))
  70
  71 (defun g-object-dispose-carefully (pointer)
  72   (handler-case
  73       (register-gobject-for-gc pointer)
  74     (error (e) (format t "Error in dispose: ~A~%" e))))
  75
  76 (defcallback weak-notify-print :void ((data :pointer) (object-pointer :pointer))
  77   (declare (ignore data))
  78   (debugf "g-object has finalized ~A ~A~%" (g-type-name (g-type-from-object object-pointer)) object-pointer))
  79
  80 (defun erase-pointer (data object-pointer)
  81   (declare (ignore data))
  82   (remhash (pointer-address object-pointer) *lisp-objects-pointers*))
  83
  84 (defcallback weak-notify-erase-pointer :void ((data :pointer) (object-pointer :pointer))
  85   (erase-pointer data object-pointer))
  86
  87 (defun should-ref-sink-at-creation (object)
  88 ;;If object was not created from lisp-side, we should ref it
  89 ;;If an object is regular g-object, we should not ref-sink it
  90 ;;If an object is GInitiallyUnowned, then it is created with a floating reference, we should ref-sink it
  91 ;;A special case is GtkWindow: we should ref-sink it anyway
  92   (if (g-object-has-reference object)
  93       (let ((object-type (g-type-from-object (pointer object)))
  94             (initially-unowned-type (g-type-from-name "GInitiallyUnowned")))
  95         (g-type-is-a object-type initially-unowned-type))
  96       t))
  97
  98 (defun register-g-object (obj)
  99   (debugf "registered GObject ~A with gobject ref-count ~A ~A~%" (pointer obj) (ref-count obj) (if (g-object-is-floating (pointer obj)) "(floating)" ""))
 100   (when (should-ref-sink-at-creation obj)
 101     (debugf "g_object_ref_sink(~A)~%" (pointer obj))
 102     (g-object-ref-sink (pointer obj)))
 103   (g-object-weak-ref (pointer obj) (callback weak-notify-print) (null-pointer))
 104   (g-object-weak-ref (pointer obj) (callback weak-notify-erase-pointer) (null-pointer))
 105   (setf (g-object-has-reference obj) t)
 106   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects*)
 107         obj)
 108   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects-ref-count*) 1))
 109
 110 (defun g-object-dispose (pointer)
 111   (unless (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 112     (debugf "GObject ~A is already disposed, signalling error~%" pointer)
 113     (error "GObject ~A is already disposed" pointer))
 114   (debugf "g_object_unref(~A) (of type ~A, lisp-value ~A) (lisp ref-count ~A, gobject ref-count ~A)~%"
 115           pointer
 116           (g-type-name (g-type-from-object pointer))
 117           (gethash (pointer-address pointer) *foreign-gobjects*)
 118           (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 119           (ref-count pointer))
 120   (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 121     (when object
 122       (setf (pointer object) nil)
 123       (cancel-finalization object)))
 124   (remhash (pointer-address pointer) *foreign-gobjects*)
 125   (remhash (pointer-address pointer) *foreign-gobjects-ref-count*)
 126   (g-object-unref pointer))
 127
 128 (defmethod release ((object g-object))
 129   (debugf "Releasing object ~A (type ~A, lisp-value ~A)~%" (pointer object) (when (pointer object) (g-type-name (g-type-from-object (pointer object)))) object)
 130   (unless (and (pointer object) (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 131     (error "Object ~A already disposed of from lisp side" object))
 132   (decf (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 133   (when (zerop (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 134     (g-object-dispose (pointer object)))
 135   (activate-gc-hooks))
 136
 137 (defvar *registered-object-types* (make-hash-table :test 'equal))
 138 (defun register-object-type (name type)
 139   (setf (gethash name *registered-object-types*) type))
 140 (defun registered-object-type-by-name (name)
 141   (gethash name *registered-object-types*))
 142 (defun get-g-object-lisp-type (g-type)
 143   (setf g-type (ensure-g-type g-type))
 144   (loop
 145      while (not (zerop g-type))
 146      for lisp-type = (gethash (g-type-name g-type) *registered-object-types*)
 147      when lisp-type do (return lisp-type)
 148      do (setf g-type (ensure-g-type (g-type-parent g-type)))))
 149
 150 (defun make-g-object-from-pointer (pointer)
 151   (let* ((g-type (g-type-from-instance pointer))
 152          (lisp-type (get-g-object-lisp-type g-type)))
 153     (unless lisp-type
 154       (error "Type ~A is not registered with REGISTER-OBJECT-TYPE"
 155              (g-type-name g-type)))
 156     (g-object-ref pointer)
 157     (make-instance lisp-type :pointer pointer)))
 158
 159 (define-foreign-type foreign-g-object-type ()
 160   ((sub-type :reader sub-type :initarg :sub-type :initform 'g-object))
 161   (:actual-type :pointer))
 162
 163 (define-parse-method g-object (&optional (sub-type 'g-object))
 164   (make-instance 'foreign-g-object-type :sub-type sub-type))
 165
 166 (defmethod translate-to-foreign (object (type foreign-g-object-type))
 167   (cond
 168     ((null object)
 169      (null-pointer))
 170     ((pointerp object) object)
 171     ((null (pointer object))
 172      (error "Object ~A has been disposed" object))
 173     ((typep object 'g-object)
 174      (assert (typep object (sub-type type))
 175              nil
 176              "Object ~A is not a subtype of ~A" object (sub-type type))
 177      (pointer object))
 178     (t (error "Object ~A is not translatable as GObject*" object))))
 179
 180 (defun get-g-object-for-pointer (pointer)
 181   (unless (null-pointer-p pointer)
 182     (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 183       (if object
 184           (prog1 object
 185             (incf (gethash (pointer-address pointer) *foreign-gobjects-ref-count*))
 186             (debugf "increfering object ~A~%" pointer))
 187           (make-g-object-from-pointer pointer)))))
 188
 189 (defmethod translate-from-foreign (pointer (type foreign-g-object-type))
 190   (get-g-object-for-pointer pointer))
 191
 192 (register-object-type "GObject" 'g-object)
 193
 194 (defun ensure-g-type (type)
 195   "Returns the GType value for a given type. If type is an integer, it is returned. If type is a string, GType corresponding to this type name is looked up and returned.
 196 @arg[type]{a string or and integer}
 197 @return{integer equal to GType of @code{type}}"
 198   (etypecase type
 199     (integer type)
 200     (string (or (g-type-from-name type)
 201                 (error "Type ~A is invalid" type)))))
 202
 203 (defun ensure-object-pointer (object)
 204   (if (pointerp object)
 205       object
 206       (etypecase object
 207         (g-object (pointer object)))))
 208
 209 (define-condition property-access-error (error)
 210   ((property-name :initarg :property-name :reader property-access-error-property-name)
 211    (class-name :initarg :class-name :reader property-access-error-class-name)
 212    (message :initarg :message :reader property-access-error-message))
 213   (:report (lambda (condition stream)
 214              (format stream "Error accessing property '~A' on class '~A': ~A"
 215                      (property-access-error-property-name condition)
 216                      (property-access-error-class-name condition)
 217                      (property-access-error-message condition)))))
 218
 219 (define-condition property-unreadable-error (property-access-error)
 220   ()
 221   (:default-initargs :message "property is not readable"))
 222
 223 (define-condition property-unwritable-error (property-access-error)
 224   ()
 225   (:default-initargs :message "property is not writable"))
 226
 227 (defun g-param-spec-property-type (param-spec property-name object-type assert-readable assert-writable)
 228   (when (null-pointer-p param-spec)
 229            (error "Property ~A on type ~A is not found"
 230                   property-name
 231                   (g-type-name object-type)))
 232   (when (and assert-readable
 233              (not (member :readable
 234                           (foreign-slot-value param-spec
 235                                               'g-param-spec
 236                                               'flags))))
 237     (error 'property-unreadable-error
 238            :property-name property-name
 239            :class-name (g-type-name object-type)))
 240   (when (and assert-writable
 241              (not (member :writable
 242                           (foreign-slot-value param-spec
 243                                               'g-param-spec
 244                                               'flags))))
 245     (error 'property-unwritable-error
 246            :property-name property-name
 247            :class-name (g-type-name object-type)))
 248   (foreign-slot-value param-spec 'g-param-spec 'value-type))
 249
 250 (defun g-object-type-property-type (object-type property-name
 251                                     &key assert-readable assert-writable)
 252   (let* ((object-class (g-type-class-ref object-type))
 253          (param-spec (g-object-class-find-property object-class property-name)))
 254     (unwind-protect
 255          (g-param-spec-property-type param-spec property-name object-type assert-readable assert-writable)
 256       (g-type-class-unref object-class))))
 257
 258 (defun g-object-property-type (object property-name
 259                                &key assert-readable assert-writable)
 260   (g-object-type-property-type (g-type-from-object (ensure-object-pointer object))
 261                                property-name
 262                                :assert-readable assert-readable
 263                                :assert-writable assert-writable))
 264
 265 (defun g-object-call-constructor (object-type args-names args-values
 266                                   &optional args-types)
 267   (unless args-types
 268     (setf args-types
 269           (mapcar (lambda (name)
 270                     (g-object-type-property-type object-type name))
 271                   args-names)))
 272   (let ((args-count (length args-names)))
 273     (with-foreign-object (parameters 'g-parameter args-count)
 274       (loop
 275          for i from 0 below args-count
 276          for arg-name in args-names
 277          for arg-value in args-values
 278          for arg-type in args-types
 279          for arg-g-type = (if arg-type (ensure-g-type arg-type) (g-object-type-property-type object-type arg-name))
 280          for parameter = (mem-aref parameters 'g-parameter i)
 281          do (setf (foreign-slot-value parameter 'g-parameter 'name) arg-name)
 282          do (set-g-value (foreign-slot-value parameter 'g-parameter 'value)
 283                          arg-value arg-g-type
 284                          :zero-g-value t))
 285       (unwind-protect
 286            (g-object-newv object-type args-count parameters)
 287         (loop
 288            for i from 0 below args-count
 289            for parameter = (mem-aref parameters 'g-parameter i)
 290            do (foreign-free
 291                (mem-ref (foreign-slot-pointer parameter 'g-parameter 'name)
 292                         :pointer))
 293            do (g-value-unset
 294                (foreign-slot-pointer parameter 'g-parameter 'value)))))))
 295
 296 (defun g-object-call-get-property (object property-name &optional property-type)
 297   (restart-case
 298       (unless property-type
 299         (setf property-type
 300               (g-object-property-type object property-name :assert-readable t)))
 301     (return-nil () (return-from g-object-call-get-property nil)))
 302   (setf property-type (ensure-g-type property-type))
 303   (with-foreign-object (value 'g-value)
 304     (g-value-zero value)
 305     (g-value-init value property-type)
 306     (g-object-get-property (ensure-object-pointer object)
 307                            property-name value)
 308     (unwind-protect
 309          (parse-gvalue value)
 310       (g-value-unset value))))
 311
 312 (defun g-object-call-set-property (object property-name new-value
 313                                    &optional property-type)
 314   (unless property-type
 315     (setf property-type
 316           (g-object-property-type object property-name :assert-writable t)))
 317   (setf property-type (ensure-g-type property-type))
 318   (with-foreign-object (value 'g-value)
 319     (set-g-value value new-value property-type :zero-g-value t)
 320     (unwind-protect
 321          (g-object-set-property (ensure-object-pointer object)
 322                                 property-name value)
 323       (g-value-unset value))))