glib/gobject.foreign-gobject.lisp

   1 (in-package :gobject)
   2
   3 (defclass g-object ()
   4   ((pointer
   5     :type cffi:foreign-pointer
   6     :initarg :pointer
   7     :accessor pointer
   8     :initform nil)
   9    (has-reference
  10     :type boolean
  11     :accessor g-object-has-reference
  12     :initform nil)))
  13
  14 (defvar *foreign-gobjects* (make-weak-hash-table :test 'equal :weakness :value))
  15 (defvar *foreign-gobjects-ref-count* (make-hash-table :test 'equal))
  16 (defvar *lisp-objects-pointers* (make-hash-table :test 'equal))
  17 (defvar *current-creating-object* nil)
  18
  19 (defcstruct g-object-struct
  20   (type-instance g-type-instance)
  21   (ref-count :uint)
  22   (qdata :pointer))
  23
  24 (defun ref-count (pointer)
  25   (foreign-slot-value (if (pointerp pointer) pointer (pointer pointer)) 'g-object-struct 'ref-count))
  26
  27 (defmethod initialize-instance :around ((obj g-object) &key)
  28   (let ((*current-creating-object* obj))
  29     (call-next-method)))
  30
  31 (defmethod initialize-instance :after ((obj g-object) &key &allow-other-keys)
  32   (unless (slot-boundp obj 'pointer)
  33     (error "Pointer slot is not initialized for ~A" obj))
  34   (let* ((pointer (pointer obj))
  35          (s (format nil "~A" obj)))
  36     (finalize obj
  37               (lambda ()
  38                 (handler-case
  39                     (g-object-dispose-carefully pointer)
  40                   (error (e) (format t "Error in finalizer for ~A: ~A~%" s e))))))
  41   (register-g-object obj)
  42   (activate-gc-hooks))
  43
  44 (defvar *gobject-gc-hooks-lock* (make-recursive-lock "gobject-gc-hooks-lock"))
  45 (defvar *gobject-gc-hooks* nil);;pointers to objects to be freed
  46
  47 (defun activate-gc-hooks ()
  48   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  49     (when *gobject-gc-hooks*
  50       (debugf "activating gc hooks for objects: ~A~%" *gobject-gc-hooks*)
  51       (loop
  52          for pointer in *gobject-gc-hooks*
  53          do (g-object-unref pointer))
  54       (setf *gobject-gc-hooks* nil))))
  55
  56 (defcallback g-idle-gc-hook :boolean ((data :pointer))
  57   (declare (ignore data))
  58   (activate-gc-hooks)
  59   nil)
  60
  61 (defun register-gobject-for-gc (pointer)
  62   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  63     (let ((locks-were-present (not (null *gobject-gc-hooks*))))
  64       (push pointer *gobject-gc-hooks*)
  65       (unless locks-were-present
  66         (debugf "adding idle-gc-hook to main loop~%")
  67         (glib::g-idle-add (callback g-idle-gc-hook) (null-pointer))))))
  68
  69 (defun g-object-dispose-carefully (pointer)
  70   (handler-case
  71       (register-gobject-for-gc pointer)
  72     (error (e) (format t "Error in dispose: ~A~%" e))))
  73
  74 (defcallback weak-notify-print :void ((data :pointer) (object-pointer :pointer))
  75   (declare (ignore data))
  76   (debugf "g-object has finalized ~A ~A~%" (g-type-name (g-type-from-object object-pointer)) object-pointer))
  77
  78 (defun erase-pointer (data object-pointer)
  79   (declare (ignore data))
  80   (remhash (pointer-address object-pointer) *lisp-objects-pointers*))
  81
  82 (defcallback weak-notify-erase-pointer :void ((data :pointer) (object-pointer :pointer))
  83   (erase-pointer data object-pointer))
  84
  85 (defun should-ref-sink-at-creation (object)
  86 ;;If object was not created from lisp-side, we should ref it
  87 ;;If an object is regular g-object, we should not ref-sink it
  88 ;;If an object is GInitiallyUnowned, then it is created with a floating reference, we should ref-sink it
  89 ;;A special case is GtkWindow: we should ref-sink it anyway
  90   (if (g-object-has-reference object)
  91       (let ((object-type (g-type-from-object (pointer object)))
  92             (initially-unowned-type (g-type-from-name "GInitiallyUnowned")))
  93         (g-type-is-a object-type initially-unowned-type))
  94       t))
  95
  96 (defun register-g-object (obj)
  97   (debugf "registered GObject ~A with gobject ref-count ~A ~A~%" (pointer obj) (ref-count obj) (if (g-object-is-floating (pointer obj)) "(floating)" ""))
  98   (when (should-ref-sink-at-creation obj)
  99     (debugf "g_object_ref_sink(~A)~%" (pointer obj))
 100     (g-object-ref-sink (pointer obj)))
 101   (g-object-weak-ref (pointer obj) (callback weak-notify-print) (null-pointer))
 102   (g-object-weak-ref (pointer obj) (callback weak-notify-erase-pointer) (null-pointer))
 103   (setf (g-object-has-reference obj) t)
 104   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects*)
 105         obj)
 106   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects-ref-count*) 1))
 107
 108 (defun g-object-dispose (pointer)
 109   (unless (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 110     (debugf "GObject ~A is already disposed, signalling error~%" pointer)
 111     (error "GObject ~A is already disposed" pointer))
 112   (debugf "g_object_unref(~A) (of type ~A, lisp-value ~A) (lisp ref-count ~A, gobject ref-count ~A)~%"
 113           pointer
 114           (g-type-name (g-type-from-object pointer))
 115           (gethash (pointer-address pointer) *foreign-gobjects*)
 116           (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 117           (ref-count pointer))
 118   (awhen (gethash (pointer-address pointer) *foreign-gobjects*)
 119     (setf (pointer it) nil)
 120     (cancel-finalization it))
 121   (remhash (pointer-address pointer) *foreign-gobjects*)
 122   (remhash (pointer-address pointer) *foreign-gobjects-ref-count*)
 123   (g-object-unref pointer))
 124
 125 (defmethod release ((object g-object))
 126   (debugf "Releasing object ~A (type ~A, lisp-value ~A)~%" (pointer object) (when (pointer object) (g-type-name (g-type-from-object (pointer object)))) object)
 127   (unless (and (pointer object) (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 128     (error "Object ~A already disposed of from lisp side" object))
 129   (decf (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 130   (when (zerop (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 131     (g-object-dispose (pointer object)))
 132   (activate-gc-hooks))
 133
 134 (defvar *registered-object-types* (make-hash-table :test 'equal))
 135 (defun register-object-type (name type)
 136   (setf (gethash name *registered-object-types*) type))
 137 (defun registered-object-type-by-name (name)
 138   (gethash name *registered-object-types*))
 139 (defun get-g-object-lisp-type (g-type)
 140   (loop
 141      while (not (zerop g-type))
 142      for lisp-type = (gethash (g-type-name g-type) *registered-object-types*)
 143      when lisp-type do (return lisp-type)
 144      do (setf g-type (g-type-parent g-type))))
 145
 146 (defun make-g-object-from-pointer (pointer)
 147   (let* ((g-type (g-type-from-instance pointer))
 148          (lisp-type (get-g-object-lisp-type g-type)))
 149     (unless lisp-type
 150       (error "Type ~A is not registered with REGISTER-OBJECT-TYPE"
 151              (g-type-name g-type)))
 152     (make-instance lisp-type :pointer pointer)))
 153
 154 (define-foreign-type foreign-g-object-type ()
 155   ((sub-type :reader sub-type :initarg :sub-type :initform 'g-object))
 156   (:actual-type :pointer))
 157
 158 (define-parse-method g-object (&optional (sub-type 'g-object))
 159   (make-instance 'foreign-g-object-type :sub-type sub-type))
 160
 161 (defmethod translate-to-foreign (object (type foreign-g-object-type))
 162   (cond
 163     ((null (pointer object))
 164      (error "Object ~A has been disposed" object))
 165     ((typep object 'g-object)
 166      (assert (typep object (sub-type type))
 167              nil
 168              "Object ~A is not a subtype of ~A" object (sub-type type))
 169      (pointer object))
 170     ((pointerp object) object)
 171     (t (error "Object ~A is not translatable as GObject*" object))))
 172
 173 (defun get-g-object-for-pointer (pointer)
 174   (unless (null-pointer-p pointer)
 175     (aif (gethash (pointer-address pointer) *foreign-gobjects*)
 176          (prog1 it
 177            (incf (gethash (pointer-address pointer) *foreign-gobjects-ref-count*))
 178            (debugf "increfering object ~A~%" pointer))
 179          (make-g-object-from-pointer pointer))))
 180
 181 (defmethod translate-from-foreign (pointer (type foreign-g-object-type))
 182   (get-g-object-for-pointer pointer))
 183
 184 (register-object-type "GObject" 'g-object)
 185
 186 (defun ensure-g-type (type)
 187   (etypecase type
 188     (integer type)
 189     (string (or (g-type-from-name type)
 190                 (error "Type ~A is invalid" type)))))
 191
 192 (defun ensure-object-pointer (object)
 193   (if (pointerp object)
 194       object
 195       (etypecase object
 196         (g-object (pointer object)))))
 197
 198 (defun g-param-spec-property-type (param-spec property-name object-type assert-readable assert-writable)
 199   (when (null-pointer-p param-spec)
 200            (error "Property ~A on type ~A is not found"
 201                   property-name
 202                   (g-type-name object-type)))
 203   (when (and assert-readable
 204              (not (member :readable
 205                           (foreign-slot-value param-spec
 206                                               'g-param-spec
 207                                               'flags))))
 208     (error "Property ~A on type ~A is not readable"
 209            property-name
 210            (g-type-name object-type)))
 211   (when (and assert-writable
 212              (not (member :writable
 213                           (foreign-slot-value param-spec
 214                                               'g-param-spec
 215                                               'flags))))
 216     (error "Property ~A on type ~A is not writable"
 217            property-name
 218            (g-type-name object-type)))
 219   (foreign-slot-value param-spec 'g-param-spec 'value-type))
 220
 221 (defun g-object-type-property-type (object-type property-name
 222                                     &key assert-readable assert-writable)
 223   (let* ((object-class (g-type-class-ref object-type))
 224          (param-spec (g-object-class-find-property object-class property-name)))
 225     (unwind-protect
 226          (g-param-spec-property-type param-spec property-name object-type assert-readable assert-writable)
 227       (g-type-class-unref object-class))))
 228
 229 (defun g-object-property-type (object property-name
 230                                &key assert-readable assert-writable)
 231   (g-object-type-property-type (g-type-from-object (ensure-object-pointer object))
 232                                property-name
 233                                :assert-readable assert-readable
 234                                :assert-writable assert-writable))
 235
 236 (defun g-object-call-constructor (object-type args-names args-values
 237                                   &optional args-types)
 238   (setf object-type (ensure-g-type object-type))
 239   (unless args-types
 240     (setf args-types
 241           (mapcar (lambda (name)
 242                     (g-object-type-property-type object-type name))
 243                   args-names)))
 244   (let ((args-count (length args-names)))
 245     (with-foreign-object (parameters 'g-parameter args-count)
 246       (loop
 247          for i from 0 below args-count
 248          for arg-name in args-names
 249          for arg-value in args-values
 250          for arg-type in args-types
 251          for arg-g-type = (ensure-g-type arg-type)
 252          for parameter = (mem-aref parameters 'g-parameter i)
 253          do (setf (foreign-slot-value parameter 'g-parameter 'name) arg-name)
 254          do (set-g-value (foreign-slot-value parameter 'g-parameter 'value)
 255                          arg-value arg-g-type
 256                          :zero-g-value t))
 257       (unwind-protect
 258            (g-object-newv object-type args-count parameters)
 259         (loop
 260            for i from 0 below args-count
 261            for parameter = (mem-aref parameters 'g-parameter i)
 262            do (foreign-free
 263                (mem-ref (foreign-slot-pointer parameter 'g-parameter 'name)
 264                         :pointer))
 265            do (g-value-unset
 266                (foreign-slot-pointer parameter 'g-parameter 'value)))))))
 267
 268 (defun g-object-call-get-property (object property-name &optional property-type)
 269   (unless property-type
 270     (setf property-type
 271           (g-object-property-type object property-name :assert-readable t)))
 272   (setf property-type (ensure-g-type property-type))
 273   (with-foreign-object (value 'g-value)
 274     (g-value-zero value)
 275     (g-value-init value property-type)
 276     (g-object-get-property (ensure-object-pointer object)
 277                            property-name value)
 278     (unwind-protect
 279          (parse-gvalue value)
 280       (g-value-unset value))))
 281
 282 (defun g-object-call-set-property (object property-name new-value
 283                                    &optional property-type)
 284   (unless property-type
 285     (setf property-type
 286           (g-object-property-type object property-name :assert-writable t)))
 287   (setf property-type (ensure-g-type property-type))
 288   (with-foreign-object (value 'g-value)
 289     (set-g-value value new-value property-type :zero-g-value t)
 290     (unwind-protect
 291          (g-object-set-property (ensure-object-pointer object)
 292                                 property-name value)
 293       (g-value-unset value))))