glib/gobject.foreign-gobject.lisp

   1 (in-package :gobject)
   2
   3 (defclass g-object ()
   4   ((pointer
   5     :type cffi:foreign-pointer
   6     :initarg :pointer
   7     :accessor pointer
   8     :initform nil)
   9    (has-reference
  10     :type boolean
  11     :accessor g-object-has-reference
  12     :initform nil)))
  13
  14 (defvar *foreign-gobjects* (make-weak-hash-table :test 'equal :weakness :value))
  15 (defvar *foreign-gobjects-ref-count* (make-hash-table :test 'equal))
  16 (defvar *lisp-objects-pointers* (make-hash-table :test 'equal))
  17 (defvar *current-creating-object* nil)
  18
  19 (defcstruct g-object-struct
  20   (type-instance g-type-instance)
  21   (ref-count :uint)
  22   (qdata :pointer))
  23
  24 (defun ref-count (pointer)
  25   (foreign-slot-value (if (pointerp pointer) pointer (pointer pointer)) 'g-object-struct 'ref-count))
  26
  27 (defmethod initialize-instance :around ((obj g-object) &key)
  28   (let ((*current-creating-object* obj))
  29     (call-next-method)))
  30
  31 (defmethod initialize-instance :after ((obj g-object) &key &allow-other-keys)
  32   (unless (slot-boundp obj 'pointer)
  33     (error "Pointer slot is not initialized for ~A" obj))
  34   (let* ((pointer (pointer obj))
  35          (s (format nil "~A" obj)))
  36     (finalize obj
  37               (lambda ()
  38                 (handler-case
  39                     (g-object-dispose-carefully pointer)
  40                   (error (e) (format t "Error in finalizer for ~A: ~A~%" s e))))))
  41   (register-g-object obj)
  42   (activate-gc-hooks))
  43
  44 (defvar *gobject-gc-hooks-lock* (make-recursive-lock "gobject-gc-hooks-lock"))
  45 (defvar *gobject-gc-hooks* nil);;pointers to objects to be freed
  46
  47 (defun activate-gc-hooks ()
  48   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  49     (when *gobject-gc-hooks*
  50       (debugf "activating gc hooks for objects: ~A~%" *gobject-gc-hooks*)
  51       (loop
  52          for pointer in *gobject-gc-hooks*
  53          do (g-object-unref pointer))
  54       (setf *gobject-gc-hooks* nil))))
  55
  56 (defcallback g-idle-gc-hook :boolean ((data :pointer))
  57   (declare (ignore data))
  58   (activate-gc-hooks)
  59   nil)
  60
  61 (defun register-gobject-for-gc (pointer)
  62   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  63     (let ((locks-were-present (not (null *gobject-gc-hooks*))))
  64       (push pointer *gobject-gc-hooks*)
  65       (unless locks-were-present
  66         (debugf "adding idle-gc-hook to main loop~%")
  67         (glib::g-idle-add (callback g-idle-gc-hook) (null-pointer))))))
  68
  69 (defun g-object-dispose-carefully (pointer)
  70   (handler-case
  71       (register-gobject-for-gc pointer)
  72     (error (e) (format t "Error in dispose: ~A~%" e))))
  73
  74 (defcallback weak-notify-print :void ((data :pointer) (object-pointer :pointer))
  75   (declare (ignore data))
  76   (debugf "g-object has finalized ~A ~A~%" (g-type-name (g-type-from-object object-pointer)) object-pointer))
  77
  78 (defun erase-pointer (data object-pointer)
  79   (declare (ignore data))
  80   (remhash (pointer-address object-pointer) *lisp-objects-pointers*))
  81
  82 (defcallback weak-notify-erase-pointer :void ((data :pointer) (object-pointer :pointer))
  83   (erase-pointer data object-pointer))
  84
  85 (defun should-ref-sink-at-creation (object)
  86 ;;If object was not created from lisp-side, we should ref it
  87 ;;If an object is regular g-object, we should not ref-sink it
  88 ;;If an object is GInitiallyUnowned, then it is created with a floating reference, we should ref-sink it
  89 ;;A special case is GtkWindow: we should ref-sink it anyway
  90   (if (g-object-has-reference object)
  91       (let ((object-type (g-type-from-object (pointer object)))
  92             (initially-unowned-type (g-type-from-name "GInitiallyUnowned")))
  93         (g-type-is-a object-type initially-unowned-type))
  94       t))
  95
  96 (defun register-g-object (obj)
  97   (debugf "registered GObject ~A with gobject ref-count ~A ~A~%" (pointer obj) (ref-count obj) (if (g-object-is-floating (pointer obj)) "(floating)" ""))
  98   (when (should-ref-sink-at-creation obj)
  99     (debugf "g_object_ref_sink(~A)~%" (pointer obj))
 100     (g-object-ref-sink (pointer obj)))
 101   (g-object-weak-ref (pointer obj) (callback weak-notify-print) (null-pointer))
 102   (g-object-weak-ref (pointer obj) (callback weak-notify-erase-pointer) (null-pointer))
 103   (setf (g-object-has-reference obj) t)
 104   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects*)
 105         obj)
 106   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects-ref-count*) 1))
 107
 108 (defun g-object-dispose (pointer)
 109   (unless (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 110     (debugf "GObject ~A is already disposed, signalling error~%" pointer)
 111     (error "GObject ~A is already disposed" pointer))
 112   (debugf "g_object_unref(~A) (of type ~A, lisp-value ~A) (lisp ref-count ~A, gobject ref-count ~A)~%"
 113           pointer
 114           (g-type-name (g-type-from-object pointer))
 115           (gethash (pointer-address pointer) *foreign-gobjects*)
 116           (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 117           (ref-count pointer))
 118   (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 119     (when object
 120       (setf (pointer object) nil)
 121       (cancel-finalization object)))
 122   (remhash (pointer-address pointer) *foreign-gobjects*)
 123   (remhash (pointer-address pointer) *foreign-gobjects-ref-count*)
 124   (g-object-unref pointer))
 125
 126 (defmethod release ((object g-object))
 127   (debugf "Releasing object ~A (type ~A, lisp-value ~A)~%" (pointer object) (when (pointer object) (g-type-name (g-type-from-object (pointer object)))) object)
 128   (unless (and (pointer object) (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 129     (error "Object ~A already disposed of from lisp side" object))
 130   (decf (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 131   (when (zerop (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 132     (g-object-dispose (pointer object)))
 133   (activate-gc-hooks))
 134
 135 (defvar *registered-object-types* (make-hash-table :test 'equal))
 136 (defun register-object-type (name type)
 137   (setf (gethash name *registered-object-types*) type))
 138 (defun registered-object-type-by-name (name)
 139   (gethash name *registered-object-types*))
 140 (defun get-g-object-lisp-type (g-type)
 141   (loop
 142      while (not (zerop g-type))
 143      for lisp-type = (gethash (g-type-name g-type) *registered-object-types*)
 144      when lisp-type do (return lisp-type)
 145      do (setf g-type (g-type-parent g-type))))
 146
 147 (defun make-g-object-from-pointer (pointer)
 148   (let* ((g-type (g-type-from-instance pointer))
 149          (lisp-type (get-g-object-lisp-type g-type)))
 150     (unless lisp-type
 151       (error "Type ~A is not registered with REGISTER-OBJECT-TYPE"
 152              (g-type-name g-type)))
 153     (g-object-ref pointer)
 154     (make-instance lisp-type :pointer pointer)))
 155
 156 (define-foreign-type foreign-g-object-type ()
 157   ((sub-type :reader sub-type :initarg :sub-type :initform 'g-object))
 158   (:actual-type :pointer))
 159
 160 (define-parse-method g-object (&optional (sub-type 'g-object))
 161   (make-instance 'foreign-g-object-type :sub-type sub-type))
 162
 163 (defmethod translate-to-foreign (object (type foreign-g-object-type))
 164   (cond
 165     ((null object)
 166      (null-pointer))
 167     ((pointerp object) object)
 168     ((null (pointer object))
 169      (error "Object ~A has been disposed" object))
 170     ((typep object 'g-object)
 171      (assert (typep object (sub-type type))
 172              nil
 173              "Object ~A is not a subtype of ~A" object (sub-type type))
 174      (pointer object))
 175     (t (error "Object ~A is not translatable as GObject*" object))))
 176
 177 (defun get-g-object-for-pointer (pointer)
 178   (unless (null-pointer-p pointer)
 179     (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 180       (if object
 181           (prog1 object
 182             (incf (gethash (pointer-address pointer) *foreign-gobjects-ref-count*))
 183             (debugf "increfering object ~A~%" pointer))
 184           (make-g-object-from-pointer pointer)))))
 185
 186 (defmethod translate-from-foreign (pointer (type foreign-g-object-type))
 187   (get-g-object-for-pointer pointer))
 188
 189 (register-object-type "GObject" 'g-object)
 190
 191 (defun ensure-g-type (type)
 192   (etypecase type
 193     (integer type)
 194     (string (or (g-type-from-name type)
 195                 (error "Type ~A is invalid" type)))))
 196
 197 (defun ensure-object-pointer (object)
 198   (if (pointerp object)
 199       object
 200       (etypecase object
 201         (g-object (pointer object)))))
 202
 203 (define-condition property-access-error (error)
 204   ((property-name :initarg :property-name :reader property-access-error-property-name)
 205    (class-name :initarg :class-name :reader property-access-error-class-name)
 206    (message :initarg :message :reader property-access-error-message))
 207   (:report (lambda (condition stream)
 208              (format stream "Error accessing property '~A' on class '~A': ~A"
 209                      (property-access-error-property-name condition)
 210                      (property-access-error-class-name condition)
 211                      (property-access-error-message condition)))))
 212
 213 (define-condition property-unreadable-error (property-access-error)
 214   ()
 215   (:default-initargs :message "property is not readable"))
 216
 217 (define-condition property-unwritable-error (property-access-error)
 218   ()
 219   (:default-initargs :message "property is not writable"))
 220
 221 (defun g-param-spec-property-type (param-spec property-name object-type assert-readable assert-writable)
 222   (when (null-pointer-p param-spec)
 223            (error "Property ~A on type ~A is not found"
 224                   property-name
 225                   (g-type-name object-type)))
 226   (when (and assert-readable
 227              (not (member :readable
 228                           (foreign-slot-value param-spec
 229                                               'g-param-spec
 230                                               'flags))))
 231     (error 'property-unreadable-error
 232            :property-name property-name
 233            :class-name (g-type-name object-type)))
 234   (when (and assert-writable
 235              (not (member :writable
 236                           (foreign-slot-value param-spec
 237                                               'g-param-spec
 238                                               'flags))))
 239     (error 'property-unwritable-error
 240            :property-name property-name
 241            :class-name (g-type-name object-type)))
 242   (foreign-slot-value param-spec 'g-param-spec 'value-type))
 243
 244 (defun g-object-type-property-type (object-type property-name
 245                                     &key assert-readable assert-writable)
 246   (let* ((object-class (g-type-class-ref object-type))
 247          (param-spec (g-object-class-find-property object-class property-name)))
 248     (unwind-protect
 249          (g-param-spec-property-type param-spec property-name object-type assert-readable assert-writable)
 250       (g-type-class-unref object-class))))
 251
 252 (defun g-object-property-type (object property-name
 253                                &key assert-readable assert-writable)
 254   (g-object-type-property-type (g-type-from-object (ensure-object-pointer object))
 255                                property-name
 256                                :assert-readable assert-readable
 257                                :assert-writable assert-writable))
 258
 259 (defun g-object-call-constructor (object-type args-names args-values
 260                                   &optional args-types)
 261   (setf object-type (ensure-g-type object-type))
 262   (unless args-types
 263     (setf args-types
 264           (mapcar (lambda (name)
 265                     (g-object-type-property-type object-type name))
 266                   args-names)))
 267   (let ((args-count (length args-names)))
 268     (with-foreign-object (parameters 'g-parameter args-count)
 269       (loop
 270          for i from 0 below args-count
 271          for arg-name in args-names
 272          for arg-value in args-values
 273          for arg-type in args-types
 274          for arg-g-type = (if arg-type (ensure-g-type arg-type) (g-object-type-property-type object-type arg-name))
 275          for parameter = (mem-aref parameters 'g-parameter i)
 276          do (setf (foreign-slot-value parameter 'g-parameter 'name) arg-name)
 277          do (set-g-value (foreign-slot-value parameter 'g-parameter 'value)
 278                          arg-value arg-g-type
 279                          :zero-g-value t))
 280       (unwind-protect
 281            (g-object-newv object-type args-count parameters)
 282         (loop
 283            for i from 0 below args-count
 284            for parameter = (mem-aref parameters 'g-parameter i)
 285            do (foreign-free
 286                (mem-ref (foreign-slot-pointer parameter 'g-parameter 'name)
 287                         :pointer))
 288            do (g-value-unset
 289                (foreign-slot-pointer parameter 'g-parameter 'value)))))))
 290
 291 (defun g-object-call-get-property (object property-name &optional property-type)
 292   (restart-case
 293       (unless property-type
 294         (setf property-type
 295               (g-object-property-type object property-name :assert-readable t)))
 296     (return-nil () (return-from g-object-call-get-property nil)))
 297   (setf property-type (ensure-g-type property-type))
 298   (with-foreign-object (value 'g-value)
 299     (g-value-zero value)
 300     (g-value-init value property-type)
 301     (g-object-get-property (ensure-object-pointer object)
 302                            property-name value)
 303     (unwind-protect
 304          (parse-gvalue value)
 305       (g-value-unset value))))
 306
 307 (defun g-object-call-set-property (object property-name new-value
 308                                    &optional property-type)
 309   (unless property-type
 310     (setf property-type
 311           (g-object-property-type object property-name :assert-writable t)))
 312   (setf property-type (ensure-g-type property-type))
 313   (with-foreign-object (value 'g-value)
 314     (set-g-value value new-value property-type :zero-g-value t)
 315     (unwind-protect
 316          (g-object-set-property (ensure-object-pointer object)
 317                                 property-name value)
 318       (g-value-unset value))))