glib/gobject.generating.lisp

   1 (in-package :gobject)
   2
   3 (defvar *lisp-name-package* (find-package :gobject))
   4 (defvar *strip-prefix* "")
   5 (defvar *lisp-name-exceptions* nil)
   6 (defvar *generation-exclusions* nil)
   7 (defvar *known-interfaces* (make-hash-table :test 'equal))
   8 (defvar *additional-properties* nil)
   9
  10 (defun name->supplied-p (name)
  11   (intern (format nil "~A-SUPPLIED-P" (symbol-name name))
  12           *lisp-name-package*))
  13
  14 (defstruct property name accessor-name readable writable)
  15
  16 (defstruct (gobject-property (:include property)) gname type)
  17
  18 (defstruct (cffi-property (:include property)) type reader writer)
  19
  20 (defmethod make-load-form ((object gobject-property) &optional env)
  21   (declare (ignore env))
  22   `(make-gobject-property :name ',(property-name object)
  23                           :accessor-name ',(property-accessor-name object)
  24                           :readable ',(property-readable object)
  25                           :writable ',(property-writable object)
  26                           :gname ',(gobject-property-gname object)
  27                           :type ',(gobject-property-type object)))
  28
  29 (defmethod make-load-form ((object cffi-property) &optional env)
  30   (declare (ignore env))
  31   `(make-cffi-property :name ',(property-name object)
  32                        :accessor-name ',(property-accessor-name object)
  33                        :readable ',(property-readable object)
  34                        :writable ',(property-writable object)
  35                        :type ',(cffi-property-type object)
  36                        :reader ',(cffi-property-reader object)
  37                        :writer ',(cffi-property-writer object)))
  38
  39 (defun parse-gobject-property (spec)
  40   (destructuring-bind (name accessor-name gname type readable writable) spec
  41       (make-gobject-property :name name
  42                              :accessor-name accessor-name
  43                              :gname gname
  44                              :type type
  45                              :readable readable
  46                              :writable writable)))
  47
  48 (defun parse-cffi-property (spec)
  49   (destructuring-bind (name accessor-name type reader writer) spec
  50     (make-cffi-property :name name
  51                         :accessor-name accessor-name
  52                         :type type
  53                         :reader reader
  54                         :writer writer
  55                         :readable (not (null reader))
  56                         :writable (not (null writer)))))
  57
  58 (defun parse-property (spec)
  59   (cond
  60     ((eq (first spec) :cffi) (parse-cffi-property (rest spec)))
  61     (t (parse-gobject-property spec))))
  62
  63 (defun property->method-arg (property)
  64   (when (or (gobject-property-p property)
  65             (and (cffi-property-p property)
  66                  (property-writable property)))
  67     (let ((name (property-name property)))
  68       `(,name nil ,(name->supplied-p name)))))
  69
  70 (defun gobject-property->arg-push (property)
  71   (assert (typep property 'gobject-property))
  72   (with-slots (name type gname) property
  73     `(when ,(name->supplied-p name)
  74        (push ,gname arg-names)
  75        (push ,type arg-types)
  76        (push ,name arg-values))))
  77
  78 (defun cffi-property->initarg (property)
  79   (assert (typep property 'cffi-property))
  80   (when (property-writable property)
  81     (with-slots (accessor-name name type writer) property
  82       `(when ,(name->supplied-p name)
  83          (setf (,accessor-name object) ,name)))))
  84
  85 (defun accessor-name (class-name property-name)
  86   (intern (format nil "~A-~A" (symbol-name class-name)
  87                   (lispify-name property-name))
  88           *lisp-name-package*))
  89
  90 (defgeneric property->reader (class property))
  91 (defgeneric property->writer (class property))
  92
  93 (defmethod property->reader (class (property gobject-property))
  94   (with-slots (accessor-name type gname) property
  95    `(defmethod ,accessor-name ((object ,class))
  96       (g-object-call-get-property object ,gname ,type))))
  97
  98 (defmethod property->reader (class (property cffi-property))
  99   (with-slots (accessor-name type reader) property
 100     (etypecase reader
 101       (string `(defmethod ,accessor-name ((object ,class))
 102                  (foreign-funcall ,reader g-object object ,type)))
 103       (symbol `(defmethod ,accessor-name ((object ,class))
 104                  (funcall ',reader object))))))
 105
 106 (defmethod property->writer (class (property gobject-property))
 107   (with-slots (accessor-name type gname) property
 108     `(defmethod (setf ,accessor-name) (new-value (object ,class))
 109        (g-object-call-set-property object ,gname new-value ,type)
 110        new-value)))
 111
 112 (defmethod property->writer (class (property cffi-property))
 113   (with-slots (accessor-name type writer) property
 114     (etypecase writer
 115       (string `(defmethod (setf ,accessor-name) (new-value (object ,class))
 116                  (foreign-funcall ,writer g-object object ,type new-value :void)
 117                  new-value))
 118       (symbol `(defmethod (setf ,accessor-name) (new-value (object ,class))
 119                  (funcall ',writer object new-value)
 120                  new-value)))))
 121
 122 (defun property->accessors (class property export)
 123   (append (when (property-readable property)
 124             (list (property->reader class property)))
 125           (when (property-writable property)
 126             (list (property->writer class property)))
 127           (when export
 128             (list `(export ',(property-accessor-name property)
 129                            (find-package ,(package-name (symbol-package (property-accessor-name property)))))))))
 130
 131 (defun interface->lisp-class-name (interface)
 132   (etypecase interface
 133     (symbol interface)
 134     (string (or (gethash interface *known-interfaces*)
 135                 (error "Unknown interface ~A" interface)))))
 136
 137 (defun type-initializer-call (type-initializer)
 138   (etypecase type-initializer
 139     (string `(foreign-funcall ,type-initializer g-type))
 140     (symbol `(funcall ',type-initializer))))
 141
 142 (defmacro define-g-object-class (g-type-name name
 143                                  (&key (superclass 'g-object)
 144                                        (export t)
 145                                        interfaces
 146                                        type-initializer)
 147                                  (&rest properties))
 148   (setf properties (mapcar #'parse-property properties))
 149   (let* ((superclass-properties (get superclass 'properties))
 150          (combined-properties (append superclass-properties properties)))
 151     `(progn
 152        (defclass ,name (,superclass ,@(mapcar #'interface->lisp-class-name interfaces)) ())
 153        (register-object-type ,g-type-name ',name)
 154        ,@(when type-initializer
 155                (list (type-initializer-call type-initializer)))
 156        ,@(when export
 157                (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 158        (defmethod initialize-instance :before
 159            ((object ,name) &key pointer
 160             ,@(remove nil (mapcar #'property->method-arg
 161                                   combined-properties)))
 162          (unless (or pointer (and (slot-boundp object 'pointer)
 163                                   (not (null-pointer-p (pointer object)))))
 164            (let (arg-names arg-values arg-types)
 165              ,@(mapcar #'gobject-property->arg-push (remove-if-not #'gobject-property-p combined-properties))
 166              (setf (pointer object)
 167                    (g-object-call-constructor ,g-type-name
 168                                               arg-names
 169                                               arg-values
 170                                               arg-types)
 171                    (g-object-has-reference object) t)
 172              ,@(mapcar #'cffi-property->initarg (remove-if-not #'cffi-property-p combined-properties)))))
 173        ,@(loop
 174             for property in properties
 175             append (property->accessors name property export))
 176
 177        (eval-when (:compile-toplevel :load-toplevel :execute)
 178          (setf (get ',name 'superclass) ',superclass
 179                (get ',name 'properties) ',combined-properties)))))
 180
 181 (defmacro define-g-interface (g-name name (&key (export t) type-initializer) &body properties)
 182   (setf properties (mapcar #'parse-property properties))
 183   `(progn
 184      (defclass ,name () ())
 185      ,@(when export
 186              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 187      ,@(when type-initializer
 188              (list (type-initializer-call type-initializer)))
 189      ,@(loop
 190           for property in properties
 191           append (property->accessors name property export))
 192      (eval-when (:compile-toplevel :load-toplevel :execute)
 193        (setf (get ',name 'properties) ',properties)
 194        (setf (gethash ,g-name *known-interfaces*) ',name))))
 195
 196 (defun starts-with (name prefix)
 197   (and prefix (> (length name) (length prefix)) (string= (subseq name 0 (length prefix)) prefix)))
 198
 199 (defun strip-start (name prefix)
 200   (if (starts-with name prefix)
 201       (subseq name (length prefix))
 202       name))
 203
 204 (defun lispify-name (name)
 205   (with-output-to-string (stream)
 206     (loop for c across (strip-start name *strip-prefix*)
 207        for firstp = t then nil
 208        do (when (and (not firstp) (upper-case-p c)) (write-char #\- stream))
 209        do (write-char (char-upcase c) stream))))
 210
 211 (defun g-name->name (name)
 212   (or (second (assoc name *lisp-name-exceptions* :test 'equal))
 213       (intern (string-upcase (lispify-name name)) *lisp-name-package*)))
 214
 215 (defun property->property-definition (class-name property)
 216   (let ((name (g-name->name (g-class-property-definition-name property)))
 217         (accessor-name (accessor-name class-name (g-class-property-definition-name property)))
 218         (g-name (g-class-property-definition-name property))
 219         (type (g-type-name (g-class-property-definition-type property)))
 220         (readable (g-class-property-definition-readable property))
 221         (writable (and (g-class-property-definition-writable property)
 222                        (not (g-class-property-definition-constructor-only property)))))
 223     `(,name ,accessor-name ,g-name ,type ,readable ,writable)))
 224
 225 (defun probable-type-init-name (type-name)
 226   (with-output-to-string (stream)
 227     (iter (for c in-string type-name)
 228           (for prev-c previous c)
 229           (when (and (not (first-iteration-p))
 230                      (upper-case-p c)
 231                      (not (upper-case-p prev-c))
 232                      (not (char= prev-c #\_)))
 233             (write-char #\_ stream))
 234           (write-char (char-downcase c) stream))
 235     (write-string "_get_type" stream)))
 236
 237 (defun get-g-class-definition (type)
 238   (let* ((g-type (ensure-g-type type))
 239          (g-name (g-type-name g-type))
 240          (name (g-name->name g-name))
 241          (superclass-g-type (g-type-parent g-type))
 242          (superclass-name (g-name->name (g-type-name superclass-g-type)))
 243          (interfaces (g-type-interfaces g-type))
 244          (properties (class-properties g-type))
 245          (type-init-name (probable-type-init-name g-name))
 246          (own-properties
 247           (remove-if-not (lambda (property)
 248                            (= g-type
 249                               (g-class-property-definition-owner-type property)))
 250                          properties)))
 251     `(define-g-object-class ,g-name ,name
 252          (:superclass ,superclass-name
 253                       :export t
 254                       :interfaces (,@(sort (mapcar #'g-type-name interfaces) 'string<))
 255                       ,@(when (and (foreign-symbol-pointer type-init-name)
 256                                    (not (null-pointer-p (foreign-symbol-pointer type-init-name))))
 257                               `(:type-initializer ,type-init-name)))
 258        (,@(mapcar (lambda (property)
 259                     (property->property-definition name property))
 260                   own-properties)
 261           ,@(cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 262
 263 (defun get-g-interface-definition (interface)
 264   (let* ((type (ensure-g-type interface))
 265          (g-name (g-type-name type))
 266          (name (g-name->name g-name))
 267          (properties (interface-properties type))
 268          (probable-type-initializer (probable-type-init-name g-name)))
 269     `(define-g-interface ,g-name ,name
 270          (:export t
 271                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 272                           `(:type-initializer ,probable-type-initializer)))
 273        ,@(mapcar (lambda (property)
 274                    (property->property-definition name property))
 275                  properties))))
 276
 277 (defun get-g-class-definitions-for-root-1 (type)
 278   (unless (member (ensure-g-type type) *generation-exclusions* :test '=)
 279     (cons (get-g-class-definition type)
 280           (reduce #'append
 281                   (mapcar #'get-g-class-definitions-for-root-1
 282                           (g-type-children type))))))
 283
 284 (defun get-g-class-definitions-for-root (type)
 285   (setf type (ensure-g-type type))
 286   (get-g-class-definitions-for-root-1 type))
 287
 288 (defvar *referenced-types*)
 289
 290 (defun class-or-interface-properties (type)
 291   (setf type (ensure-g-type type))
 292   (cond
 293     ((= (g-type-fundamental type) +g-type-object+) (class-properties type))
 294     ((= (g-type-fundamental type) +g-type-interface+) (interface-properties type))))
 295
 296 (defun get-shallow-referenced-types (type)
 297   (setf type (ensure-g-type type))
 298   (remove-duplicates (sort (loop
 299                               for property in (class-or-interface-properties type)
 300                               when (= type (g-class-property-definition-owner-type property))
 301                               collect (g-class-property-definition-type property))
 302                            #'<)
 303                      :test 'equal))
 304
 305 (defun get-referenced-types-1 (type)
 306   (setf type (ensure-g-type type))
 307   (loop
 308      for property-type in (get-shallow-referenced-types type)
 309      do (pushnew property-type *referenced-types* :test '=))
 310   (loop
 311      for type in (g-type-children type)
 312      do (get-referenced-types-1 type)))
 313
 314 (defun get-referenced-types (root-type)
 315   (let (*referenced-types*)
 316     (get-referenced-types-1 (ensure-g-type root-type))
 317     *referenced-types*))
 318
 319 (defun filter-types-by-prefix (types prefix)
 320   (remove-if-not
 321    (lambda (type)
 322      (starts-with (g-type-name (ensure-g-type type)) prefix))
 323    types))
 324
 325 (defun filter-types-by-fund-type (types fund-type)
 326   (setf fund-type (ensure-g-type fund-type))
 327   (remove-if-not
 328    (lambda (type)
 329      (equal (g-type-fundamental (ensure-g-type type)) fund-type))
 330    types))
 331
 332 (defmacro define-g-enum (g-name name (&key (export t) type-initializer)  &body values)
 333   `(progn
 334      (defcenum ,name ,@values)
 335      (register-enum-type ,g-name ',name)
 336      ,@(when export
 337              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 338      ,@(when type-initializer
 339              (list (type-initializer-call type-initializer)))))
 340
 341 (defun enum-value->definition (enum-value)
 342   (let ((value-name (intern (lispify-name (enum-item-nick enum-value))
 343                             (find-package :keyword)))
 344         (numeric-value (enum-item-value enum-value)))
 345     `(,value-name ,numeric-value)))
 346
 347 (defun get-g-enum-definition (type)
 348   (let* ((g-type (ensure-g-type type))
 349          (g-name (g-type-name g-type))
 350          (name (g-name->name g-name))
 351          (items (get-enum-items g-type))
 352          (probable-type-initializer (probable-type-init-name g-name)))
 353     `(define-g-enum ,g-name ,name
 354          (:export t
 355                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 356                           (list :type-initializer
 357                                 probable-type-initializer)))
 358        ,@(mapcar #'enum-value->definition items))))
 359
 360 (defmacro define-g-flags (g-name name (&key (export t) type-initializer) &body values)
 361   `(progn
 362      (defbitfield ,name ,@values)
 363      (register-enum-type ,g-name ',name)
 364      ,@(when export
 365              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 366      ,@(when type-initializer
 367              (list (type-initializer-call type-initializer)))))
 368
 369 (defun flags-value->definition (flags-value)
 370   (let ((value-name (intern (lispify-name (flags-item-nick flags-value))
 371                             (find-package :keyword)))
 372         (numeric-value (flags-item-value flags-value)))
 373     `(,value-name ,numeric-value)))
 374
 375 (defun get-g-flags-definition (type)
 376   (let* ((g-type (ensure-g-type type))
 377          (g-name (g-type-name g-type))
 378          (name (g-name->name g-name))
 379          (items (get-flags-items g-type))
 380          (probable-type-initializer (probable-type-init-name g-name)))
 381     `(define-g-flags ,g-name ,name
 382          (:export t
 383                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 384                           (list :type-initializer
 385                                 probable-type-initializer)))
 386        ,@(mapcar #'flags-value->definition items))))
 387
 388 (defun generate-types-hierarchy-to-file (file root-type &key include-referenced prefix package exceptions prologue interfaces enums flags objects exclusions additional-properties)
 389   (if (not (streamp file))
 390       (with-open-file (stream file :direction :output :if-exists :supersede)
 391         (generate-types-hierarchy-to-file stream root-type
 392                                           :prefix prefix
 393                                           :package package
 394                                           :exceptions exceptions
 395                                           :prologue prologue
 396                                           :include-referenced include-referenced
 397                                           :interfaces interfaces
 398                                           :enums enums
 399                                           :flags flags
 400                                           :objects objects
 401                                           :exclusions exclusions
 402                                           :additional-properties additional-properties))
 403       (let* ((*generation-exclusions* (mapcar #'ensure-g-type exclusions))
 404              (*lisp-name-package* (or package *package*))
 405              (*package* *lisp-name-package*)
 406              (*strip-prefix* (or prefix ""))
 407              (*lisp-name-exceptions* exceptions)
 408              (*print-case* :downcase)
 409              (*additional-properties* additional-properties)
 410              (referenced-types (and include-referenced
 411                                     (filter-types-by-prefix
 412                                      (get-referenced-types root-type)
 413                                      prefix))))
 414         (setf exclusions (mapcar #'ensure-g-type exclusions))
 415         (when prologue
 416           (write-string prologue file)
 417           (terpri file))
 418         (when include-referenced
 419           (loop
 420              for interface in interfaces
 421              do (loop
 422                    for referenced-type in (get-shallow-referenced-types interface)
 423                    do (pushnew referenced-type referenced-types :test 'equal)))
 424           (loop
 425              for object in objects
 426              do (loop
 427                    for referenced-type in (get-shallow-referenced-types object)
 428                    do (pushnew referenced-type referenced-types :test 'equal)))
 429           (loop
 430              for enum-type in (filter-types-by-fund-type
 431                                referenced-types "GEnum")
 432              for def = (get-g-enum-definition enum-type)
 433              unless (member (ensure-g-type enum-type) exclusions :test '=)
 434              do (format file "~S~%~%" def))
 435
 436           (loop
 437              for flags-type in (filter-types-by-fund-type
 438                                 referenced-types "GFlags")
 439              for def = (get-g-flags-definition flags-type)
 440              unless (member (ensure-g-type flags-type) exclusions :test '=)
 441              do (format file "~S~%~%" def)))
 442         (loop
 443            with auto-enums = (and include-referenced
 444                                   (filter-types-by-fund-type
 445                                    referenced-types "GEnum"))
 446            for enum in enums
 447            for def = (get-g-enum-definition enum)
 448            unless (find (ensure-g-type enum) auto-enums :test 'equal)
 449            do (format file "~S~%~%" def))
 450         (loop
 451            with auto-flags = (and include-referenced
 452                                   (filter-types-by-fund-type
 453                                    referenced-types "GFlags"))
 454            for flags-type in flags
 455            for def = (get-g-flags-definition flags-type)
 456            unless (find (ensure-g-type flags-type) auto-flags :test 'equal)
 457            do (format file "~S~%~%" def))
 458         (loop
 459            for interface in interfaces
 460            for def = (get-g-interface-definition interface)
 461            do (format file "~S~%~%" def))
 462         (loop
 463            for def in (get-g-class-definitions-for-root root-type)
 464            do (format file "~S~%~%" def))
 465         (loop
 466            for object in objects
 467            for def = (get-g-class-definition object)
 468            do (format file "~S~%~%" def)))))