glib/gobject.generating.lisp

   1 (in-package :gobject)
   2
   3 (defvar *lisp-name-package* nil
   4   "For internal use (used by class definitions generator). Specifies the package in which symbols are interned.")
   5 (defvar *strip-prefix* "")
   6 (defvar *lisp-name-exceptions* nil)
   7 (defvar *generation-exclusions* nil)
   8 (defvar *known-interfaces* (make-hash-table :test 'equal))
   9 (defvar *additional-properties* nil)
  10
  11 (defun name->supplied-p (name)
  12   (make-symbol (format nil "~A-SUPPLIED-P" (symbol-name name))))
  13
  14 (defstruct property name accessor-name readable writable)
  15
  16 (defstruct (gobject-property (:include property)) gname type)
  17
  18 (defstruct (cffi-property (:include property)) type reader writer)
  19
  20 (defmethod make-load-form ((object gobject-property) &optional env)
  21   (declare (ignore env))
  22   `(make-gobject-property :name ',(property-name object)
  23                           :accessor-name ',(property-accessor-name object)
  24                           :readable ',(property-readable object)
  25                           :writable ',(property-writable object)
  26                           :gname ',(gobject-property-gname object)
  27                           :type ',(gobject-property-type object)))
  28
  29 (defmethod make-load-form ((object cffi-property) &optional env)
  30   (declare (ignore env))
  31   `(make-cffi-property :name ',(property-name object)
  32                        :accessor-name ',(property-accessor-name object)
  33                        :readable ',(property-readable object)
  34                        :writable ',(property-writable object)
  35                        :type ',(cffi-property-type object)
  36                        :reader ',(cffi-property-reader object)
  37                        :writer ',(cffi-property-writer object)))
  38
  39 (defun parse-gobject-property (spec)
  40   (destructuring-bind (name accessor-name gname type readable writable) spec
  41       (make-gobject-property :name name
  42                              :accessor-name accessor-name
  43                              :gname gname
  44                              :type type
  45                              :readable readable
  46                              :writable writable)))
  47
  48 (defun parse-cffi-property (spec)
  49   (destructuring-bind (name accessor-name type reader writer) spec
  50     (make-cffi-property :name name
  51                         :accessor-name accessor-name
  52                         :type type
  53                         :reader reader
  54                         :writer writer
  55                         :readable (not (null reader))
  56                         :writable (not (null writer)))))
  57
  58 (defun parse-property (spec)
  59   (cond
  60     ((eq (first spec) :cffi) (parse-cffi-property (rest spec)))
  61     (t (parse-gobject-property spec))))
  62
  63 (defun property->method-arg (property)
  64   (when (or (gobject-property-p property)
  65             (and (cffi-property-p property)
  66                  (property-writable property)))
  67     (let ((name (property-name property)))
  68       `(,name nil ,(name->supplied-p name)))))
  69
  70 (defun gobject-property->arg-push (property)
  71   (assert (typep property 'gobject-property))
  72   (with-slots (name type gname) property
  73     `(when ,(name->supplied-p name)
  74        (push ,gname arg-names)
  75        (push ,type arg-types)
  76        (push ,name arg-values))))
  77
  78 (defun cffi-property->initarg (property)
  79   (assert (typep property 'cffi-property))
  80   (when (property-writable property)
  81     (with-slots (accessor-name name type writer) property
  82       `(when ,(name->supplied-p name)
  83          (setf (,accessor-name object) ,name)))))
  84
  85 (defun accessor-name (class-name property-name)
  86   (intern (format nil "~A-~A" (symbol-name class-name)
  87                   (lispify-name property-name))
  88           *lisp-name-package*))
  89
  90 (defgeneric property->reader (class property))
  91 (defgeneric property->writer (class property))
  92
  93 (defmethod property->reader (class (property gobject-property))
  94   (with-slots (accessor-name type gname) property
  95    `(defmethod ,accessor-name ((object ,class))
  96       (g-object-call-get-property object ,gname ,type))))
  97
  98 (defmethod property->reader (class (property cffi-property))
  99   (with-slots (accessor-name type reader) property
 100     (etypecase reader
 101       (string `(defmethod ,accessor-name ((object ,class))
 102                  (foreign-funcall ,reader g-object object ,type)))
 103       (symbol `(defmethod ,accessor-name ((object ,class))
 104                  (funcall ',reader object))))))
 105
 106 (defmethod property->writer (class (property gobject-property))
 107   (with-slots (accessor-name type gname) property
 108     `(defmethod (setf ,accessor-name) (new-value (object ,class))
 109        (g-object-call-set-property object ,gname new-value ,type)
 110        new-value)))
 111
 112 (defmethod property->writer (class (property cffi-property))
 113   (with-slots (accessor-name type writer) property
 114     (etypecase writer
 115       (string `(defmethod (setf ,accessor-name) (new-value (object ,class))
 116                  (foreign-funcall ,writer g-object object ,type new-value :void)
 117                  new-value))
 118       (symbol `(defmethod (setf ,accessor-name) (new-value (object ,class))
 119                  (funcall ',writer object new-value)
 120                  new-value)))))
 121
 122 (defun property->accessors (class property export)
 123   (append (when (property-readable property)
 124             (list (property->reader class property)))
 125           (when (property-writable property)
 126             (list (property->writer class property)))
 127           (when export
 128             (list `(export ',(property-accessor-name property)
 129                            (find-package ,(package-name (symbol-package (property-accessor-name property)))))))))
 130
 131 (defun interface->lisp-class-name (interface)
 132   (etypecase interface
 133     (symbol interface)
 134     (string (or (gethash interface *known-interfaces*)
 135                 (error "Unknown interface ~A" interface)))))
 136
 137 (defun type-initializer-call (type-initializer)
 138   (etypecase type-initializer
 139     (string `(if (foreign-symbol-pointer ,type-initializer)
 140                  (foreign-funcall ,type-initializer g-type)
 141                  (warn "Type initializer '~A' is not available" ,type-initializer)))
 142     (symbol `(funcall ',type-initializer))))
 143
 144 (defun meta-property->slot (class-name property)
 145   `(,(property-name property)
 146      :allocation ,(if (gobject-property-p property) :gobject-property :gobject-fn)
 147      :g-property-type ,(if (gobject-property-p property) (gobject-property-type property) (cffi-property-type property))
 148      :accessor ,(intern (format nil "~A-~A" (symbol-name class-name) (property-name property)) (symbol-package class-name))
 149      :initarg ,(intern (string-upcase (property-name property)) (find-package :keyword))
 150      ,@(if (gobject-property-p property)
 151            `(:g-property-name ,(gobject-property-gname property))
 152            `(:g-getter ,(cffi-property-reader property)
 153                                 :g-setter ,(cffi-property-writer property)))))
 154
 155 (defmacro define-g-object-class (g-type-name name
 156                                  (&key (superclass 'g-object)
 157                                        (export t)
 158                                        interfaces
 159                                        type-initializer)
 160                                  (&rest properties))
 161   (setf properties (mapcar #'parse-property properties))
 162   `(progn
 163      (defclass ,name (,superclass ,@(mapcar #'interface->lisp-class-name interfaces))
 164        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 165        (:metaclass gobject-class)
 166        (:g-type-name . ,g-type-name)
 167        ,@(when type-initializer
 168                (list `(:g-type-initializer . ,type-initializer))))
 169      ,@(when export
 170              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 171                    (mapcar (lambda (property)
 172                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 173                                       (find-package ,(package-name (symbol-package name)))))
 174                            properties)))))
 175
 176 (defmacro define-g-interface (g-type-name name (&key (export t) type-initializer) &body properties)
 177   (setf properties (mapcar #'parse-property properties))
 178   `(progn
 179      (defclass ,name ()
 180        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 181        (:metaclass gobject-class)
 182        (:g-type-name . ,g-type-name)
 183        (:g-interface-p . t)
 184        ,@(when type-initializer
 185                (list `(:g-type-initializer . ,type-initializer))))
 186      ,@(when export
 187              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 188                    (mapcar (lambda (property)
 189                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 190                                       (find-package ,(package-name (symbol-package name)))))
 191                            properties)))
 192      (eval-when (:compile-toplevel :load-toplevel :execute)
 193        (setf (gethash ,g-type-name *known-interfaces*) ',name))))
 194
 195 (defun starts-with (name prefix)
 196   (and prefix (> (length name) (length prefix)) (string= (subseq name 0 (length prefix)) prefix)))
 197
 198 (defun strip-start (name prefix)
 199   (if (starts-with name prefix)
 200       (subseq name (length prefix))
 201       name))
 202
 203 (defun lispify-name (name)
 204   (with-output-to-string (stream)
 205     (loop for c across (strip-start name *strip-prefix*)
 206        for firstp = t then nil
 207        do (when (and (not firstp) (upper-case-p c)) (write-char #\- stream))
 208        do (write-char (char-upcase c) stream))))
 209
 210 (defun g-name->name (name)
 211   (or (second (assoc name *lisp-name-exceptions* :test 'equal))
 212       (intern (string-upcase (lispify-name name)) *lisp-name-package*)))
 213
 214 (defun property->property-definition (class-name property)
 215   (let ((name (g-name->name (g-class-property-definition-name property)))
 216         (accessor-name (accessor-name class-name (g-class-property-definition-name property)))
 217         (g-name (g-class-property-definition-name property))
 218         (type (g-type-name (g-class-property-definition-type property)))
 219         (readable (g-class-property-definition-readable property))
 220         (writable (and (g-class-property-definition-writable property)
 221                        (not (g-class-property-definition-constructor-only property)))))
 222     `(,name ,accessor-name ,g-name ,type ,readable ,writable)))
 223
 224 (defun probable-type-init-name (type-name)
 225   (with-output-to-string (stream)
 226     (iter (for c in-string type-name)
 227           (for prev-c previous c)
 228           (when (and (not (first-iteration-p))
 229                      (upper-case-p c)
 230                      (not (upper-case-p prev-c))
 231                      (not (char= prev-c #\_)))
 232             (write-char #\_ stream))
 233           (write-char (char-downcase c) stream))
 234     (write-string "_get_type" stream)))
 235
 236 (defun get-g-class-definition (type &optional lisp-name-package)
 237   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 238          (g-type (ensure-g-type type))
 239          (g-name (g-type-name g-type))
 240          (name (g-name->name g-name))
 241          (superclass-g-type (g-type-parent g-type))
 242          (superclass-name (g-name->name (g-type-name superclass-g-type)))
 243          (interfaces (g-type-interfaces g-type))
 244          (properties (class-properties g-type))
 245          (type-init-name (probable-type-init-name g-name))
 246          (own-properties
 247           (remove-if-not (lambda (property)
 248                            (g-type= g-type (g-class-property-definition-owner-type property)))
 249                          properties)))
 250     `(define-g-object-class ,g-name ,name
 251          (:superclass ,superclass-name
 252                       :export t
 253                       :interfaces (,@(sort (mapcar #'g-type-name interfaces) 'string<))
 254                       ,@(when (and (foreign-symbol-pointer type-init-name)
 255                                    (not (null-pointer-p (foreign-symbol-pointer type-init-name))))
 256                               `(:type-initializer ,type-init-name)))
 257        (,@(mapcar (lambda (property)
 258                     (property->property-definition name property))
 259                   own-properties)
 260           ,@(cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 261
 262 (defun get-g-interface-definition (interface &optional lisp-name-package)
 263   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 264          (type (ensure-g-type interface))
 265          (g-name (g-type-name type))
 266          (name (g-name->name g-name))
 267          (properties (interface-properties type))
 268          (probable-type-initializer (probable-type-init-name g-name)))
 269     `(define-g-interface ,g-name ,name
 270          (:export t
 271                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 272                           `(:type-initializer ,probable-type-initializer)))
 273        ,@(append (mapcar (lambda (property)
 274                            (property->property-definition name property))
 275                          properties)
 276                  (cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 277
 278 (defun get-g-class-definitions-for-root-1 (type)
 279   (unless (member type *generation-exclusions* :test 'g-type=)
 280     (cons (get-g-class-definition type)
 281           (reduce #'append
 282                   (mapcar #'get-g-class-definitions-for-root-1
 283                           (g-type-children type))))))
 284
 285 (defun get-g-class-definitions-for-root (type)
 286   (setf type (ensure-g-type type))
 287   (get-g-class-definitions-for-root-1 type))
 288
 289 (defvar *referenced-types*)
 290
 291 (defun class-or-interface-properties (type)
 292   (setf type (ensure-g-type type))
 293   (cond
 294     ((g-type= (g-type-fundamental type) +g-type-object+) (class-properties type))
 295     ((g-type= (g-type-fundamental type) +g-type-interface+) (interface-properties type))))
 296
 297 (defun get-shallow-referenced-types (type)
 298   (setf type (ensure-g-type type))
 299   (remove-duplicates (sort (loop
 300                               for property in (class-or-interface-properties type)
 301                               when (g-type= type (g-class-property-definition-owner-type property))
 302                               collect (g-class-property-definition-type property))
 303                            #'<
 304                            :key #'g-type-numeric)
 305                      :test 'equal))
 306
 307 (defun get-referenced-types-1 (type)
 308   (setf type (ensure-g-type type))
 309   (loop
 310      for property-type in (get-shallow-referenced-types type)
 311      do (pushnew property-type *referenced-types* :test 'g-type=))
 312   (loop
 313      for type in (g-type-children type)
 314      do (get-referenced-types-1 type)))
 315
 316 (defun get-referenced-types (root-type)
 317   (let (*referenced-types*)
 318     (get-referenced-types-1 (ensure-g-type root-type))
 319     *referenced-types*))
 320
 321 (defun filter-types-by-prefix (types prefix)
 322   (remove-if-not
 323    (lambda (type)
 324      (starts-with (g-type-name (ensure-g-type type)) prefix))
 325    types))
 326
 327 (defun filter-types-by-fund-type (types fund-type)
 328   (setf fund-type (ensure-g-type fund-type))
 329   (remove-if-not
 330    (lambda (type)
 331      (equal (g-type-fundamental (ensure-g-type type)) fund-type))
 332    types))
 333
 334 (defmacro define-g-enum (g-name name (&key (export t) type-initializer) &body values)
 335   "Defines a GEnum type for enumeration. Generates corresponding CFFI definition.
 336
 337 Example:
 338 @begin{pre}
 339 \(define-g-enum \"GdkGrabStatus\" grab-status () :success :already-grabbed :invalid-time :not-viewable :frozen)
 340 \(define-g-enum \"GdkExtensionMode\" gdk-extension-mode (:export t :type-initializer \"gdk_extension_mode_get_type\")
 341   (:none 0) (:all 1) (:cursor 2))
 342 @end{pre}
 343 @arg[g-name]{a string. Specifies the GEnum name}
 344 @arg[name]{a symbol. Names the enumeration type.}
 345 @arg[export]{a boolean. If true, @code{name} will be exported.}
 346 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 347
 348 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 349 @arg[values]{values for enum. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of enumeration, and @code{integer-value} is an C integer for enumeration item. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 350   `(progn
 351      (defcenum ,name ,@values)
 352      (register-enum-type ,g-name ',name)
 353      ,@(when export
 354              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 355      ,@(when type-initializer
 356              (list `(at-init () ,(type-initializer-call type-initializer))))))
 357
 358 (defun enum-value->definition (enum-value)
 359   (let ((value-name (intern (lispify-name (enum-item-nick enum-value))
 360                             (find-package :keyword)))
 361         (numeric-value (enum-item-value enum-value)))
 362     `(,value-name ,numeric-value)))
 363
 364 (defun get-g-enum-definition (type &optional lisp-name-package)
 365   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 366          (g-type (ensure-g-type type))
 367          (g-name (g-type-name g-type))
 368          (name (g-name->name g-name))
 369          (items (get-enum-items g-type))
 370          (probable-type-initializer (probable-type-init-name g-name)))
 371     `(define-g-enum ,g-name ,name
 372          (:export t
 373                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 374                           (list :type-initializer
 375                                 probable-type-initializer)))
 376        ,@(mapcar #'enum-value->definition items))))
 377
 378 (defmacro define-g-flags (g-name name (&key (export t) type-initializer) &body values)
 379   "Defines a GFlags type for enumeration that can combine its values. Generates corresponding CFFI definition. Values of this type are lists of keywords that are combined.
 380
 381 Example:
 382 @begin{pre}
 383 \(define-g-flags \"GdkWindowState\" window-state ()
 384   (:withdrawn 1)
 385   (:iconified 2) (:maximized 4) (:sticky 8) (:fullscreen 16)
 386   (:above 32) (:below 64))
 387 @end{pre}
 388 @arg[g-name]{a string. Specifies the GEnum name}
 389 @arg[name]{a symbol. Names the enumeration type.}
 390 @arg[export]{a boolean. If true, @code{name} will be exported.}
 391 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 392
 393 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 394 @arg[values]{values for flags. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of a flag, and @code{integer-value} is an C integer for flag. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 395   `(progn
 396      (defbitfield ,name ,@values)
 397      (register-flags-type ,g-name ',name)
 398      ,@(when export
 399              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 400      ,@(when type-initializer
 401              (list `(at-init () ,(type-initializer-call type-initializer))))))
 402
 403 (defun flags-value->definition (flags-value)
 404   (let ((value-name (intern (lispify-name (flags-item-nick flags-value))
 405                             (find-package :keyword)))
 406         (numeric-value (flags-item-value flags-value)))
 407     `(,value-name ,numeric-value)))
 408
 409 (defun get-g-flags-definition (type &optional lisp-name-package)
 410   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 411          (g-type (ensure-g-type type))
 412          (g-name (g-type-name g-type))
 413          (name (g-name->name g-name))
 414          (items (get-flags-items g-type))
 415          (probable-type-initializer (probable-type-init-name g-name)))
 416     `(define-g-flags ,g-name ,name
 417          (:export t
 418                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 419                           (list :type-initializer
 420                                 probable-type-initializer)))
 421        ,@(mapcar #'flags-value->definition items))))
 422
 423 (defun generate-types-hierarchy-to-file (file root-type &key include-referenced prefix package exceptions prologue interfaces enums flags objects exclusions additional-properties)
 424   (if (not (streamp file))
 425       (with-open-file (stream file :direction :output :if-exists :supersede)
 426         (generate-types-hierarchy-to-file stream root-type
 427                                           :prefix prefix
 428                                           :package package
 429                                           :exceptions exceptions
 430                                           :prologue prologue
 431                                           :include-referenced include-referenced
 432                                           :interfaces interfaces
 433                                           :enums enums
 434                                           :flags flags
 435                                           :objects objects
 436                                           :exclusions exclusions
 437                                           :additional-properties additional-properties))
 438       (let* ((*generation-exclusions* (mapcar #'ensure-g-type exclusions))
 439              (*lisp-name-package* (or package *package*))
 440              (*package* *lisp-name-package*)
 441              (*strip-prefix* (or prefix ""))
 442              (*lisp-name-exceptions* exceptions)
 443              (*print-case* :downcase)
 444              (*additional-properties* additional-properties)
 445              (referenced-types (and include-referenced
 446                                     (filter-types-by-prefix
 447                                      (get-referenced-types root-type)
 448                                      prefix))))
 449         (setf exclusions (mapcar #'ensure-g-type exclusions))
 450         (when prologue
 451           (write-string prologue file)
 452           (terpri file))
 453         (when include-referenced
 454           (loop
 455              for interface in interfaces
 456              do (loop
 457                    for referenced-type in (get-shallow-referenced-types interface)
 458                    do (pushnew referenced-type referenced-types :test 'g-type=)))
 459           (loop
 460              for object in objects
 461              do (loop
 462                    for referenced-type in (get-shallow-referenced-types object)
 463                    do (pushnew referenced-type referenced-types :test 'g-type=)))
 464           (loop
 465              for enum-type in (filter-types-by-fund-type
 466                                referenced-types "GEnum")
 467              for def = (get-g-enum-definition enum-type)
 468              unless (member enum-type exclusions :test 'g-type=)
 469              do (format file "~S~%~%" def))
 470
 471           (loop
 472              for flags-type in (filter-types-by-fund-type
 473                                 referenced-types "GFlags")
 474              for def = (get-g-flags-definition flags-type)
 475              unless (member flags-type exclusions :test 'g-type=)
 476              do (format file "~S~%~%" def)))
 477         (loop
 478            with auto-enums = (and include-referenced
 479                                   (filter-types-by-fund-type
 480                                    referenced-types "GEnum"))
 481            for enum in enums
 482            for def = (get-g-enum-definition enum)
 483            unless (find enum auto-enums :test 'g-type=)
 484            do (format file "~S~%~%" def))
 485         (loop
 486            with auto-flags = (and include-referenced
 487                                   (filter-types-by-fund-type
 488                                    referenced-types "GFlags"))
 489            for flags-type in flags
 490            for def = (get-g-flags-definition flags-type)
 491            unless (find flags-type auto-flags :test 'g-type=)
 492            do (format file "~S~%~%" def))
 493         (loop
 494            for interface in interfaces
 495            for def = (get-g-interface-definition interface)
 496            do (format file "~S~%~%" def))
 497         (loop
 498            for def in (get-g-class-definitions-for-root root-type)
 499            do (format file "~S~%~%" def))
 500         (loop
 501            for object in objects
 502            for def = (get-g-class-definition object)
 503            do (format file "~S~%~%" def)))))