glib/gobject.generating.lisp

   1 (in-package :gobject)
   2
   3 (defvar *lisp-name-package* nil
   4   "For internal use (used by class definitions generator). Specifies the package in which symbols are interned.")
   5 (defvar *strip-prefix* "")
   6 (defvar *lisp-name-exceptions* nil)
   7 (defvar *generation-exclusions* nil)
   8 (defvar *known-interfaces* (make-hash-table :test 'equal))
   9 (defvar *additional-properties* nil)
  10
  11 (defun name->supplied-p (name)
  12   (make-symbol (format nil "~A-SUPPLIED-P" (symbol-name name))))
  13
  14 (defstruct property name accessor-name readable writable)
  15
  16 (defstruct (gobject-property (:include property)) gname type)
  17
  18 (defstruct (cffi-property (:include property)) type reader writer)
  19
  20 (defmethod make-load-form ((object gobject-property) &optional env)
  21   (declare (ignore env))
  22   `(make-gobject-property :name ',(property-name object)
  23                           :accessor-name ',(property-accessor-name object)
  24                           :readable ',(property-readable object)
  25                           :writable ',(property-writable object)
  26                           :gname ',(gobject-property-gname object)
  27                           :type ',(gobject-property-type object)))
  28
  29 (defmethod make-load-form ((object cffi-property) &optional env)
  30   (declare (ignore env))
  31   `(make-cffi-property :name ',(property-name object)
  32                        :accessor-name ',(property-accessor-name object)
  33                        :readable ',(property-readable object)
  34                        :writable ',(property-writable object)
  35                        :type ',(cffi-property-type object)
  36                        :reader ',(cffi-property-reader object)
  37                        :writer ',(cffi-property-writer object)))
  38
  39 (defun parse-gobject-property (spec)
  40   (destructuring-bind (name accessor-name gname type readable writable) spec
  41       (make-gobject-property :name name
  42                              :accessor-name accessor-name
  43                              :gname gname
  44                              :type type
  45                              :readable readable
  46                              :writable writable)))
  47
  48 (defun parse-cffi-property (spec)
  49   (destructuring-bind (name accessor-name type reader writer) spec
  50     (make-cffi-property :name name
  51                         :accessor-name accessor-name
  52                         :type type
  53                         :reader reader
  54                         :writer writer
  55                         :readable (not (null reader))
  56                         :writable (not (null writer)))))
  57
  58 (defun parse-property (spec)
  59   (cond
  60     ((eq (first spec) :cffi) (parse-cffi-property (rest spec)))
  61     (t (parse-gobject-property spec))))
  62
  63 (defun property->method-arg (property)
  64   (when (or (gobject-property-p property)
  65             (and (cffi-property-p property)
  66                  (property-writable property)))
  67     (let ((name (property-name property)))
  68       `(,name nil ,(name->supplied-p name)))))
  69
  70 (defun gobject-property->arg-push (property)
  71   (assert (typep property 'gobject-property))
  72   (with-slots (name type gname) property
  73     `(when ,(name->supplied-p name)
  74        (push ,gname arg-names)
  75        (push ,type arg-types)
  76        (push ,name arg-values))))
  77
  78 (defun cffi-property->initarg (property)
  79   (assert (typep property 'cffi-property))
  80   (when (property-writable property)
  81     (with-slots (accessor-name name type writer) property
  82       `(when ,(name->supplied-p name)
  83          (setf (,accessor-name object) ,name)))))
  84
  85 (defun accessor-name (class-name property-name)
  86   (intern (format nil "~A-~A" (symbol-name class-name)
  87                   (lispify-name property-name))
  88           *lisp-name-package*))
  89
  90 (defgeneric property->reader (class property))
  91 (defgeneric property->writer (class property))
  92
  93 (defmethod property->reader (class (property gobject-property))
  94   (with-slots (accessor-name type gname) property
  95    `(defmethod ,accessor-name ((object ,class))
  96       (g-object-call-get-property object ,gname ,type))))
  97
  98 (defmethod property->reader (class (property cffi-property))
  99   (with-slots (accessor-name type reader) property
 100     (etypecase reader
 101       (string `(defmethod ,accessor-name ((object ,class))
 102                  (foreign-funcall ,reader g-object object ,type)))
 103       (symbol `(defmethod ,accessor-name ((object ,class))
 104                  (funcall ',reader object))))))
 105
 106 (defmethod property->writer (class (property gobject-property))
 107   (with-slots (accessor-name type gname) property
 108     `(defmethod (setf ,accessor-name) (new-value (object ,class))
 109        (g-object-call-set-property object ,gname new-value ,type)
 110        new-value)))
 111
 112 (defmethod property->writer (class (property cffi-property))
 113   (with-slots (accessor-name type writer) property
 114     (etypecase writer
 115       (string `(defmethod (setf ,accessor-name) (new-value (object ,class))
 116                  (foreign-funcall ,writer g-object object ,type new-value :void)
 117                  new-value))
 118       (symbol `(defmethod (setf ,accessor-name) (new-value (object ,class))
 119                  (funcall ',writer object new-value)
 120                  new-value)))))
 121
 122 (defun property->accessors (class property export)
 123   (append (when (property-readable property)
 124             (list (property->reader class property)))
 125           (when (property-writable property)
 126             (list (property->writer class property)))
 127           (when export
 128             (list `(export ',(property-accessor-name property)
 129                            (find-package ,(package-name (symbol-package (property-accessor-name property)))))))))
 130
 131 (defun interface->lisp-class-name (interface)
 132   (etypecase interface
 133     (symbol interface)
 134     (string (or (gethash interface *known-interfaces*)
 135                 (error "Unknown interface ~A" interface)))))
 136
 137 (defun type-initializer-call (type-initializer)
 138   (etypecase type-initializer
 139     (string `(foreign-funcall ,type-initializer g-type))
 140     (symbol `(funcall ',type-initializer))))
 141
 142 (defun meta-property->slot (class-name property)
 143   `(,(property-name property)
 144      :allocation ,(if (gobject-property-p property) :gobject-property :gobject-fn)
 145      :g-property-type ,(if (gobject-property-p property) (gobject-property-type property) (cffi-property-type property))
 146      :accessor ,(intern (format nil "~A-~A" (symbol-name class-name) (property-name property)) (symbol-package class-name))
 147      :initarg ,(intern (string-upcase (property-name property)) (find-package :keyword))
 148      ,@(if (gobject-property-p property)
 149            `(:g-property-name ,(gobject-property-gname property))
 150            `(:g-getter ,(cffi-property-reader property)
 151                                 :g-setter ,(cffi-property-writer property)))))
 152
 153 (defmacro define-g-object-class (g-type-name name
 154                                  (&key (superclass 'g-object)
 155                                        (export t)
 156                                        interfaces
 157                                        type-initializer)
 158                                  (&rest properties))
 159   (setf properties (mapcar #'parse-property properties))
 160   `(progn
 161      (defclass ,name (,superclass ,@(mapcar #'interface->lisp-class-name interfaces))
 162        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 163        (:metaclass gobject-class)
 164        (:g-type-name . ,g-type-name)
 165        ,@(when type-initializer
 166                (list `(:g-type-initializer . ,type-initializer))))
 167      ,@(when export
 168              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 169                    (mapcar (lambda (property)
 170                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 171                                       (find-package ,(package-name (symbol-package name)))))
 172                            properties)))))
 173
 174 (defmacro define-g-interface (g-type-name name (&key (export t) type-initializer) &body properties)
 175   (setf properties (mapcar #'parse-property properties))
 176   `(progn
 177      (defclass ,name ()
 178        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 179        (:metaclass gobject-class)
 180        (:g-type-name . ,g-type-name)
 181        (:g-interface-p . t)
 182        ,@(when type-initializer
 183                (list `(:g-type-initializer . ,type-initializer))))
 184      ,@(when export
 185              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 186                    (mapcar (lambda (property)
 187                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 188                                       (find-package ,(package-name (symbol-package name)))))
 189                            properties)))
 190      (eval-when (:compile-toplevel :load-toplevel :execute)
 191        (setf (gethash ,g-type-name *known-interfaces*) ',name))))
 192
 193 (defun starts-with (name prefix)
 194   (and prefix (> (length name) (length prefix)) (string= (subseq name 0 (length prefix)) prefix)))
 195
 196 (defun strip-start (name prefix)
 197   (if (starts-with name prefix)
 198       (subseq name (length prefix))
 199       name))
 200
 201 (defun lispify-name (name)
 202   (with-output-to-string (stream)
 203     (loop for c across (strip-start name *strip-prefix*)
 204        for firstp = t then nil
 205        do (when (and (not firstp) (upper-case-p c)) (write-char #\- stream))
 206        do (write-char (char-upcase c) stream))))
 207
 208 (defun g-name->name (name)
 209   (or (second (assoc name *lisp-name-exceptions* :test 'equal))
 210       (intern (string-upcase (lispify-name name)) *lisp-name-package*)))
 211
 212 (defun property->property-definition (class-name property)
 213   (let ((name (g-name->name (g-class-property-definition-name property)))
 214         (accessor-name (accessor-name class-name (g-class-property-definition-name property)))
 215         (g-name (g-class-property-definition-name property))
 216         (type (g-type-name (g-class-property-definition-type property)))
 217         (readable (g-class-property-definition-readable property))
 218         (writable (and (g-class-property-definition-writable property)
 219                        (not (g-class-property-definition-constructor-only property)))))
 220     `(,name ,accessor-name ,g-name ,type ,readable ,writable)))
 221
 222 (defun probable-type-init-name (type-name)
 223   (with-output-to-string (stream)
 224     (iter (for c in-string type-name)
 225           (for prev-c previous c)
 226           (when (and (not (first-iteration-p))
 227                      (upper-case-p c)
 228                      (not (upper-case-p prev-c))
 229                      (not (char= prev-c #\_)))
 230             (write-char #\_ stream))
 231           (write-char (char-downcase c) stream))
 232     (write-string "_get_type" stream)))
 233
 234 (defun get-g-class-definition (type &optional lisp-name-package)
 235   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 236          (g-type (ensure-g-type type))
 237          (g-name (g-type-name g-type))
 238          (name (g-name->name g-name))
 239          (superclass-g-type (g-type-parent g-type))
 240          (superclass-name (g-name->name (g-type-name superclass-g-type)))
 241          (interfaces (g-type-interfaces g-type))
 242          (properties (class-properties g-type))
 243          (type-init-name (probable-type-init-name g-name))
 244          (own-properties
 245           (remove-if-not (lambda (property)
 246                            (= g-type
 247                               (g-type-numeric (g-class-property-definition-owner-type property))))
 248                          properties)))
 249     `(define-g-object-class ,g-name ,name
 250          (:superclass ,superclass-name
 251                       :export t
 252                       :interfaces (,@(sort (mapcar #'g-type-name interfaces) 'string<))
 253                       ,@(when (and (foreign-symbol-pointer type-init-name)
 254                                    (not (null-pointer-p (foreign-symbol-pointer type-init-name))))
 255                               `(:type-initializer ,type-init-name)))
 256        (,@(mapcar (lambda (property)
 257                     (property->property-definition name property))
 258                   own-properties)
 259           ,@(cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 260
 261 (defun get-g-interface-definition (interface &optional lisp-name-package)
 262   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 263          (type (ensure-g-type interface))
 264          (g-name (g-type-name type))
 265          (name (g-name->name g-name))
 266          (properties (interface-properties type))
 267          (probable-type-initializer (probable-type-init-name g-name)))
 268     `(define-g-interface ,g-name ,name
 269          (:export t
 270                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 271                           `(:type-initializer ,probable-type-initializer)))
 272        ,@(append (mapcar (lambda (property)
 273                            (property->property-definition name property))
 274                          properties)
 275                  (cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 276
 277 (defun get-g-class-definitions-for-root-1 (type)
 278   (unless (member (ensure-g-type type) *generation-exclusions* :test '=)
 279     (cons (get-g-class-definition type)
 280           (reduce #'append
 281                   (mapcar #'get-g-class-definitions-for-root-1
 282                           (g-type-children type))))))
 283
 284 (defun get-g-class-definitions-for-root (type)
 285   (setf type (ensure-g-type type))
 286   (get-g-class-definitions-for-root-1 type))
 287
 288 (defvar *referenced-types*)
 289
 290 (defun class-or-interface-properties (type)
 291   (setf type (ensure-g-type type))
 292   (cond
 293     ((= (g-type-numeric (g-type-fundamental type)) +g-type-object+) (class-properties type))
 294     ((= (g-type-numeric (g-type-fundamental type)) +g-type-interface+) (interface-properties type))))
 295
 296 (defun get-shallow-referenced-types (type)
 297   (setf type (ensure-g-type type))
 298   (remove-duplicates (sort (loop
 299                               for property in (class-or-interface-properties type)
 300                               when (= (g-type-numeric type) (g-type-numeric (g-class-property-definition-owner-type property)))
 301                               collect (g-class-property-definition-type property))
 302                            #'<)
 303                      :test 'equal))
 304
 305 (defun get-referenced-types-1 (type)
 306   (setf type (ensure-g-type type))
 307   (loop
 308      for property-type in (get-shallow-referenced-types type)
 309      do (pushnew property-type *referenced-types* :test '=))
 310   (loop
 311      for type in (g-type-children type)
 312      do (get-referenced-types-1 type)))
 313
 314 (defun get-referenced-types (root-type)
 315   (let (*referenced-types*)
 316     (get-referenced-types-1 (ensure-g-type root-type))
 317     *referenced-types*))
 318
 319 (defun filter-types-by-prefix (types prefix)
 320   (remove-if-not
 321    (lambda (type)
 322      (starts-with (g-type-name (ensure-g-type type)) prefix))
 323    types))
 324
 325 (defun filter-types-by-fund-type (types fund-type)
 326   (setf fund-type (ensure-g-type fund-type))
 327   (remove-if-not
 328    (lambda (type)
 329      (equal (g-type-fundamental (ensure-g-type type)) fund-type))
 330    types))
 331
 332 (defmacro define-g-enum (g-name name (&key (export t) type-initializer) &body values)
 333   "Defines a GEnum type for enumeration. Generates corresponding CFFI definition.
 334
 335 Example:
 336 @begin{pre}
 337 \(define-g-enum \"GdkGrabStatus\" grab-status () :success :already-grabbed :invalid-time :not-viewable :frozen)
 338 \(define-g-enum \"GdkExtensionMode\" gdk-extension-mode (:export t :type-initializer \"gdk_extension_mode_get_type\")
 339   (:none 0) (:all 1) (:cursor 2))
 340 @end{pre}
 341 @arg[g-name]{a string. Specifies the GEnum name}
 342 @arg[name]{a symbol. Names the enumeration type.}
 343 @arg[export]{a boolean. If true, @code{name} will be exported.}
 344 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 345
 346 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 347 @arg[values]{values for enum. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of enumeration, and @code{integer-value} is an C integer for enumeration item. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 348   `(progn
 349      (defcenum ,name ,@values)
 350      (register-enum-type ,g-name ',name)
 351      ,@(when export
 352              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 353      ,@(when type-initializer
 354              (list `(at-init () ,(type-initializer-call type-initializer))))))
 355
 356 (defun enum-value->definition (enum-value)
 357   (let ((value-name (intern (lispify-name (enum-item-nick enum-value))
 358                             (find-package :keyword)))
 359         (numeric-value (enum-item-value enum-value)))
 360     `(,value-name ,numeric-value)))
 361
 362 (defun get-g-enum-definition (type &optional lisp-name-package)
 363   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 364          (g-type (ensure-g-type type))
 365          (g-name (g-type-name g-type))
 366          (name (g-name->name g-name))
 367          (items (get-enum-items g-type))
 368          (probable-type-initializer (probable-type-init-name g-name)))
 369     `(define-g-enum ,g-name ,name
 370          (:export t
 371                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 372                           (list :type-initializer
 373                                 probable-type-initializer)))
 374        ,@(mapcar #'enum-value->definition items))))
 375
 376 (defmacro define-g-flags (g-name name (&key (export t) type-initializer) &body values)
 377   "Defines a GFlags type for enumeration that can combine its values. Generates corresponding CFFI definition. Values of this type are lists of keywords that are combined.
 378
 379 Example:
 380 @begin{pre}
 381 \(define-g-flags \"GdkWindowState\" window-state ()
 382   (:withdrawn 1)
 383   (:iconified 2) (:maximized 4) (:sticky 8) (:fullscreen 16)
 384   (:above 32) (:below 64))
 385 @end{pre}
 386 @arg[g-name]{a string. Specifies the GEnum name}
 387 @arg[name]{a symbol. Names the enumeration type.}
 388 @arg[export]{a boolean. If true, @code{name} will be exported.}
 389 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 390
 391 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 392 @arg[values]{values for flags. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of a flag, and @code{integer-value} is an C integer for flag. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 393   `(progn
 394      (defbitfield ,name ,@values)
 395      (register-flags-type ,g-name ',name)
 396      ,@(when export
 397              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 398      ,@(when type-initializer
 399              (list `(at-init () ,(type-initializer-call type-initializer))))))
 400
 401 (defun flags-value->definition (flags-value)
 402   (let ((value-name (intern (lispify-name (flags-item-nick flags-value))
 403                             (find-package :keyword)))
 404         (numeric-value (flags-item-value flags-value)))
 405     `(,value-name ,numeric-value)))
 406
 407 (defun get-g-flags-definition (type &optional lisp-name-package)
 408   (let* ((*lisp-name-package* (or lisp-name-package *lisp-name-package* *package*))
 409          (g-type (ensure-g-type type))
 410          (g-name (g-type-name g-type))
 411          (name (g-name->name g-name))
 412          (items (get-flags-items g-type))
 413          (probable-type-initializer (probable-type-init-name g-name)))
 414     `(define-g-flags ,g-name ,name
 415          (:export t
 416                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 417                           (list :type-initializer
 418                                 probable-type-initializer)))
 419        ,@(mapcar #'flags-value->definition items))))
 420
 421 (defun generate-types-hierarchy-to-file (file root-type &key include-referenced prefix package exceptions prologue interfaces enums flags objects exclusions additional-properties)
 422   (if (not (streamp file))
 423       (with-open-file (stream file :direction :output :if-exists :supersede)
 424         (generate-types-hierarchy-to-file stream root-type
 425                                           :prefix prefix
 426                                           :package package
 427                                           :exceptions exceptions
 428                                           :prologue prologue
 429                                           :include-referenced include-referenced
 430                                           :interfaces interfaces
 431                                           :enums enums
 432                                           :flags flags
 433                                           :objects objects
 434                                           :exclusions exclusions
 435                                           :additional-properties additional-properties))
 436       (let* ((*generation-exclusions* (mapcar #'ensure-g-type exclusions))
 437              (*lisp-name-package* (or package *package*))
 438              (*package* *lisp-name-package*)
 439              (*strip-prefix* (or prefix ""))
 440              (*lisp-name-exceptions* exceptions)
 441              (*print-case* :downcase)
 442              (*additional-properties* additional-properties)
 443              (referenced-types (and include-referenced
 444                                     (filter-types-by-prefix
 445                                      (get-referenced-types root-type)
 446                                      prefix))))
 447         (setf exclusions (mapcar #'ensure-g-type exclusions))
 448         (when prologue
 449           (write-string prologue file)
 450           (terpri file))
 451         (when include-referenced
 452           (loop
 453              for interface in interfaces
 454              do (loop
 455                    for referenced-type in (get-shallow-referenced-types interface)
 456                    do (pushnew referenced-type referenced-types :test 'equal)))
 457           (loop
 458              for object in objects
 459              do (loop
 460                    for referenced-type in (get-shallow-referenced-types object)
 461                    do (pushnew referenced-type referenced-types :test 'equal)))
 462           (loop
 463              for enum-type in (filter-types-by-fund-type
 464                                referenced-types "GEnum")
 465              for def = (get-g-enum-definition enum-type)
 466              unless (member (ensure-g-type enum-type) exclusions :test '=)
 467              do (format file "~S~%~%" def))
 468
 469           (loop
 470              for flags-type in (filter-types-by-fund-type
 471                                 referenced-types "GFlags")
 472              for def = (get-g-flags-definition flags-type)
 473              unless (member (ensure-g-type flags-type) exclusions :test '=)
 474              do (format file "~S~%~%" def)))
 475         (loop
 476            with auto-enums = (and include-referenced
 477                                   (filter-types-by-fund-type
 478                                    referenced-types "GEnum"))
 479            for enum in enums
 480            for def = (get-g-enum-definition enum)
 481            unless (find (ensure-g-type enum) auto-enums :test 'equal)
 482            do (format file "~S~%~%" def))
 483         (loop
 484            with auto-flags = (and include-referenced
 485                                   (filter-types-by-fund-type
 486                                    referenced-types "GFlags"))
 487            for flags-type in flags
 488            for def = (get-g-flags-definition flags-type)
 489            unless (find (ensure-g-type flags-type) auto-flags :test 'equal)
 490            do (format file "~S~%~%" def))
 491         (loop
 492            for interface in interfaces
 493            for def = (get-g-interface-definition interface)
 494            do (format file "~S~%~%" def))
 495         (loop
 496            for def in (get-g-class-definitions-for-root root-type)
 497            do (format file "~S~%~%" def))
 498         (loop
 499            for object in objects
 500            for def = (get-g-class-definition object)
 501            do (format file "~S~%~%" def)))))