glib/gobject.generating.lisp

   1 (in-package :gobject)
   2
   3 (defvar *lisp-name-package* (find-package :gobject)
   4   "For internal use (used by class definitions generator). Specifies the package in which symbols are interned.")
   5 (defvar *strip-prefix* "")
   6 (defvar *lisp-name-exceptions* nil)
   7 (defvar *generation-exclusions* nil)
   8 (defvar *known-interfaces* (make-hash-table :test 'equal))
   9 (defvar *additional-properties* nil)
  10
  11 (defun name->supplied-p (name)
  12   (make-symbol (format nil "~A-SUPPLIED-P" (symbol-name name))))
  13
  14 (defstruct property name accessor-name readable writable)
  15
  16 (defstruct (gobject-property (:include property)) gname type)
  17
  18 (defstruct (cffi-property (:include property)) type reader writer)
  19
  20 (defmethod make-load-form ((object gobject-property) &optional env)
  21   (declare (ignore env))
  22   `(make-gobject-property :name ',(property-name object)
  23                           :accessor-name ',(property-accessor-name object)
  24                           :readable ',(property-readable object)
  25                           :writable ',(property-writable object)
  26                           :gname ',(gobject-property-gname object)
  27                           :type ',(gobject-property-type object)))
  28
  29 (defmethod make-load-form ((object cffi-property) &optional env)
  30   (declare (ignore env))
  31   `(make-cffi-property :name ',(property-name object)
  32                        :accessor-name ',(property-accessor-name object)
  33                        :readable ',(property-readable object)
  34                        :writable ',(property-writable object)
  35                        :type ',(cffi-property-type object)
  36                        :reader ',(cffi-property-reader object)
  37                        :writer ',(cffi-property-writer object)))
  38
  39 (defun parse-gobject-property (spec)
  40   (destructuring-bind (name accessor-name gname type readable writable) spec
  41       (make-gobject-property :name name
  42                              :accessor-name accessor-name
  43                              :gname gname
  44                              :type type
  45                              :readable readable
  46                              :writable writable)))
  47
  48 (defun parse-cffi-property (spec)
  49   (destructuring-bind (name accessor-name type reader writer) spec
  50     (make-cffi-property :name name
  51                         :accessor-name accessor-name
  52                         :type type
  53                         :reader reader
  54                         :writer writer
  55                         :readable (not (null reader))
  56                         :writable (not (null writer)))))
  57
  58 (defun parse-property (spec)
  59   (cond
  60     ((eq (first spec) :cffi) (parse-cffi-property (rest spec)))
  61     (t (parse-gobject-property spec))))
  62
  63 (defun property->method-arg (property)
  64   (when (or (gobject-property-p property)
  65             (and (cffi-property-p property)
  66                  (property-writable property)))
  67     (let ((name (property-name property)))
  68       `(,name nil ,(name->supplied-p name)))))
  69
  70 (defun gobject-property->arg-push (property)
  71   (assert (typep property 'gobject-property))
  72   (with-slots (name type gname) property
  73     `(when ,(name->supplied-p name)
  74        (push ,gname arg-names)
  75        (push ,type arg-types)
  76        (push ,name arg-values))))
  77
  78 (defun cffi-property->initarg (property)
  79   (assert (typep property 'cffi-property))
  80   (when (property-writable property)
  81     (with-slots (accessor-name name type writer) property
  82       `(when ,(name->supplied-p name)
  83          (setf (,accessor-name object) ,name)))))
  84
  85 (defun accessor-name (class-name property-name)
  86   (intern (format nil "~A-~A" (symbol-name class-name)
  87                   (lispify-name property-name))
  88           *lisp-name-package*))
  89
  90 (defgeneric property->reader (class property))
  91 (defgeneric property->writer (class property))
  92
  93 (defmethod property->reader (class (property gobject-property))
  94   (with-slots (accessor-name type gname) property
  95    `(defmethod ,accessor-name ((object ,class))
  96       (g-object-call-get-property object ,gname ,type))))
  97
  98 (defmethod property->reader (class (property cffi-property))
  99   (with-slots (accessor-name type reader) property
 100     (etypecase reader
 101       (string `(defmethod ,accessor-name ((object ,class))
 102                  (foreign-funcall ,reader g-object object ,type)))
 103       (symbol `(defmethod ,accessor-name ((object ,class))
 104                  (funcall ',reader object))))))
 105
 106 (defmethod property->writer (class (property gobject-property))
 107   (with-slots (accessor-name type gname) property
 108     `(defmethod (setf ,accessor-name) (new-value (object ,class))
 109        (g-object-call-set-property object ,gname new-value ,type)
 110        new-value)))
 111
 112 (defmethod property->writer (class (property cffi-property))
 113   (with-slots (accessor-name type writer) property
 114     (etypecase writer
 115       (string `(defmethod (setf ,accessor-name) (new-value (object ,class))
 116                  (foreign-funcall ,writer g-object object ,type new-value :void)
 117                  new-value))
 118       (symbol `(defmethod (setf ,accessor-name) (new-value (object ,class))
 119                  (funcall ',writer object new-value)
 120                  new-value)))))
 121
 122 (defun property->accessors (class property export)
 123   (append (when (property-readable property)
 124             (list (property->reader class property)))
 125           (when (property-writable property)
 126             (list (property->writer class property)))
 127           (when export
 128             (list `(export ',(property-accessor-name property)
 129                            (find-package ,(package-name (symbol-package (property-accessor-name property)))))))))
 130
 131 (defun interface->lisp-class-name (interface)
 132   (etypecase interface
 133     (symbol interface)
 134     (string (or (gethash interface *known-interfaces*)
 135                 (error "Unknown interface ~A" interface)))))
 136
 137 (defun type-initializer-call (type-initializer)
 138   (etypecase type-initializer
 139     (string `(foreign-funcall ,type-initializer g-type))
 140     (symbol `(funcall ',type-initializer))))
 141
 142 (defun meta-property->slot (class-name property)
 143   `(,(property-name property)
 144      :allocation ,(if (gobject-property-p property) :gobject-property :gobject-fn)
 145      :g-property-type ,(if (gobject-property-p property) (gobject-property-type property) (cffi-property-type property))
 146      :accessor ,(intern (format nil "~A-~A" (symbol-name class-name) (property-name property)) (symbol-package class-name))
 147      :initarg ,(intern (string-upcase (property-name property)) (find-package :keyword))
 148      ,@(if (gobject-property-p property)
 149            `(:g-property-name ,(gobject-property-gname property))
 150            `(:g-getter ,(cffi-property-reader property)
 151                                 :g-setter ,(cffi-property-writer property)))))
 152
 153 (defmacro define-g-object-class (g-type-name name
 154                                  (&key (superclass 'g-object)
 155                                        (export t)
 156                                        interfaces
 157                                        type-initializer)
 158                                  (&rest properties))
 159   (setf properties (mapcar #'parse-property properties))
 160   `(progn
 161      (defclass ,name (,superclass ,@(mapcar #'interface->lisp-class-name interfaces))
 162        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 163        (:metaclass gobject-class)
 164        (:g-type-name . ,g-type-name)
 165        ,@(when type-initializer
 166                (list `(:g-type-initializer . ,type-initializer))))
 167      ,@(when export
 168              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 169                    (mapcar (lambda (property)
 170                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 171                                       (find-package ,(package-name (symbol-package name)))))
 172                            properties)))))
 173
 174 (defmacro define-g-interface (g-type-name name (&key (export t) type-initializer) &body properties)
 175   (setf properties (mapcar #'parse-property properties))
 176   `(progn
 177      (defclass ,name ()
 178        (,@(mapcar (lambda (property) (meta-property->slot name property)) properties))
 179        (:metaclass gobject-class)
 180        (:g-type-name . ,g-type-name)
 181        (:g-interface-p . t)
 182        ,@(when type-initializer
 183                (list `(:g-type-initializer . ,type-initializer))))
 184      ,@(when export
 185              (cons `(export ',name (find-package ,(package-name (symbol-package name))))
 186                    (mapcar (lambda (property)
 187                              `(export ',(intern (format nil "~A-~A" (symbol-name name) (property-name property)) (symbol-package name))
 188                                       (find-package ,(package-name (symbol-package name)))))
 189                            properties)))
 190      (eval-when (:compile-toplevel :load-toplevel :execute)
 191        (setf (gethash ,g-type-name *known-interfaces*) ',name))))
 192
 193 (defun starts-with (name prefix)
 194   (and prefix (> (length name) (length prefix)) (string= (subseq name 0 (length prefix)) prefix)))
 195
 196 (defun strip-start (name prefix)
 197   (if (starts-with name prefix)
 198       (subseq name (length prefix))
 199       name))
 200
 201 (defun lispify-name (name)
 202   (with-output-to-string (stream)
 203     (loop for c across (strip-start name *strip-prefix*)
 204        for firstp = t then nil
 205        do (when (and (not firstp) (upper-case-p c)) (write-char #\- stream))
 206        do (write-char (char-upcase c) stream))))
 207
 208 (defun g-name->name (name)
 209   (or (second (assoc name *lisp-name-exceptions* :test 'equal))
 210       (intern (string-upcase (lispify-name name)) *lisp-name-package*)))
 211
 212 (defun property->property-definition (class-name property)
 213   (let ((name (g-name->name (g-class-property-definition-name property)))
 214         (accessor-name (accessor-name class-name (g-class-property-definition-name property)))
 215         (g-name (g-class-property-definition-name property))
 216         (type (g-type-name (g-class-property-definition-type property)))
 217         (readable (g-class-property-definition-readable property))
 218         (writable (and (g-class-property-definition-writable property)
 219                        (not (g-class-property-definition-constructor-only property)))))
 220     `(,name ,accessor-name ,g-name ,type ,readable ,writable)))
 221
 222 (defun probable-type-init-name (type-name)
 223   (with-output-to-string (stream)
 224     (iter (for c in-string type-name)
 225           (for prev-c previous c)
 226           (when (and (not (first-iteration-p))
 227                      (upper-case-p c)
 228                      (not (upper-case-p prev-c))
 229                      (not (char= prev-c #\_)))
 230             (write-char #\_ stream))
 231           (write-char (char-downcase c) stream))
 232     (write-string "_get_type" stream)))
 233
 234 (defun get-g-class-definition (type)
 235   (let* ((g-type (ensure-g-type type))
 236          (g-name (g-type-name g-type))
 237          (name (g-name->name g-name))
 238          (superclass-g-type (g-type-parent g-type))
 239          (superclass-name (g-name->name (g-type-name superclass-g-type)))
 240          (interfaces (g-type-interfaces g-type))
 241          (properties (class-properties g-type))
 242          (type-init-name (probable-type-init-name g-name))
 243          (own-properties
 244           (remove-if-not (lambda (property)
 245                            (= g-type
 246                               (g-type-numeric (g-class-property-definition-owner-type property))))
 247                          properties)))
 248     `(define-g-object-class ,g-name ,name
 249          (:superclass ,superclass-name
 250                       :export t
 251                       :interfaces (,@(sort (mapcar #'g-type-name interfaces) 'string<))
 252                       ,@(when (and (foreign-symbol-pointer type-init-name)
 253                                    (not (null-pointer-p (foreign-symbol-pointer type-init-name))))
 254                               `(:type-initializer ,type-init-name)))
 255        (,@(mapcar (lambda (property)
 256                     (property->property-definition name property))
 257                   own-properties)
 258           ,@(cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 259
 260 (defun get-g-interface-definition (interface)
 261   (let* ((type (ensure-g-type interface))
 262          (g-name (g-type-name type))
 263          (name (g-name->name g-name))
 264          (properties (interface-properties type))
 265          (probable-type-initializer (probable-type-init-name g-name)))
 266     `(define-g-interface ,g-name ,name
 267          (:export t
 268                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 269                           `(:type-initializer ,probable-type-initializer)))
 270        ,@(append (mapcar (lambda (property)
 271                            (property->property-definition name property))
 272                          properties)
 273                  (cdr (find g-name *additional-properties* :key 'car :test 'string=))))))
 274
 275 (defun get-g-class-definitions-for-root-1 (type)
 276   (unless (member (ensure-g-type type) *generation-exclusions* :test '=)
 277     (cons (get-g-class-definition type)
 278           (reduce #'append
 279                   (mapcar #'get-g-class-definitions-for-root-1
 280                           (g-type-children type))))))
 281
 282 (defun get-g-class-definitions-for-root (type)
 283   (setf type (ensure-g-type type))
 284   (get-g-class-definitions-for-root-1 type))
 285
 286 (defvar *referenced-types*)
 287
 288 (defun class-or-interface-properties (type)
 289   (setf type (ensure-g-type type))
 290   (cond
 291     ((= (g-type-fundamental type) +g-type-object+) (class-properties type))
 292     ((= (g-type-fundamental type) +g-type-interface+) (interface-properties type))))
 293
 294 (defun get-shallow-referenced-types (type)
 295   (setf type (ensure-g-type type))
 296   (remove-duplicates (sort (loop
 297                               for property in (class-or-interface-properties type)
 298                               when (= type (g-class-property-definition-owner-type property))
 299                               collect (g-class-property-definition-type property))
 300                            #'<)
 301                      :test 'equal))
 302
 303 (defun get-referenced-types-1 (type)
 304   (setf type (ensure-g-type type))
 305   (loop
 306      for property-type in (get-shallow-referenced-types type)
 307      do (pushnew property-type *referenced-types* :test '=))
 308   (loop
 309      for type in (g-type-children type)
 310      do (get-referenced-types-1 type)))
 311
 312 (defun get-referenced-types (root-type)
 313   (let (*referenced-types*)
 314     (get-referenced-types-1 (ensure-g-type root-type))
 315     *referenced-types*))
 316
 317 (defun filter-types-by-prefix (types prefix)
 318   (remove-if-not
 319    (lambda (type)
 320      (starts-with (g-type-name (ensure-g-type type)) prefix))
 321    types))
 322
 323 (defun filter-types-by-fund-type (types fund-type)
 324   (setf fund-type (ensure-g-type fund-type))
 325   (remove-if-not
 326    (lambda (type)
 327      (equal (g-type-fundamental (ensure-g-type type)) fund-type))
 328    types))
 329
 330 (defmacro define-g-enum (g-name name (&key (export t) type-initializer) &body values)
 331   "Defines a GEnum type for enumeration. Generates corresponding CFFI definition.
 332
 333 Example:
 334 @begin{pre}
 335 \(define-g-enum \"GdkGrabStatus\" grab-status () :success :already-grabbed :invalid-time :not-viewable :frozen)
 336 \(define-g-enum \"GdkExtensionMode\" gdk-extension-mode (:export t :type-initializer \"gdk_extension_mode_get_type\")
 337   (:none 0) (:all 1) (:cursor 2))
 338 @end{pre}
 339 @arg[g-name]{a string. Specifies the GEnum name}
 340 @arg[name]{a symbol. Names the enumeration type.}
 341 @arg[export]{a boolean. If true, @code{name} will be exported.}
 342 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 343
 344 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 345 @arg[values]{values for enum. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of enumeration, and @code{integer-value} is an C integer for enumeration item. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 346   `(progn
 347      (defcenum ,name ,@values)
 348      (register-enum-type ,g-name ',name)
 349      ,@(when export
 350              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 351      ,@(when type-initializer
 352              (list `(at-init () ,(type-initializer-call type-initializer))))))
 353
 354 (defun enum-value->definition (enum-value)
 355   (let ((value-name (intern (lispify-name (enum-item-nick enum-value))
 356                             (find-package :keyword)))
 357         (numeric-value (enum-item-value enum-value)))
 358     `(,value-name ,numeric-value)))
 359
 360 (defun get-g-enum-definition (type)
 361   (let* ((g-type (ensure-g-type type))
 362          (g-name (g-type-name g-type))
 363          (name (g-name->name g-name))
 364          (items (get-enum-items g-type))
 365          (probable-type-initializer (probable-type-init-name g-name)))
 366     `(define-g-enum ,g-name ,name
 367          (:export t
 368                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 369                           (list :type-initializer
 370                                 probable-type-initializer)))
 371        ,@(mapcar #'enum-value->definition items))))
 372
 373 (defmacro define-g-flags (g-name name (&key (export t) type-initializer) &body values)
 374   "Defines a GFlags type for enumeration that can combine its values. Generates corresponding CFFI definition. Values of this type are lists of keywords that are combined.
 375
 376 Example:
 377 @begin{pre}
 378 \(define-g-flags \"GdkWindowState\" window-state ()
 379   (:withdrawn 1)
 380   (:iconified 2) (:maximized 4) (:sticky 8) (:fullscreen 16)
 381   (:above 32) (:below 64))
 382 @end{pre}
 383 @arg[g-name]{a string. Specifies the GEnum name}
 384 @arg[name]{a symbol. Names the enumeration type.}
 385 @arg[export]{a boolean. If true, @code{name} will be exported.}
 386 @arg[type-initializer]{a @code{NIL} or a string or a function designator.
 387
 388 If non-@code{NIL}, specifies the function that initializes the type: string specifies a C function that returns the GType value and function designator specifies the Lisp function.}
 389 @arg[values]{values for flags. Each value is a keyword or a list @code{(keyword integer-value)}. @code{keyword} corresponds to Lisp value of a flag, and @code{integer-value} is an C integer for flag. If @code{integer-value} is not specified, it is generated automatically (see CFFI manual)}"
 390   `(progn
 391      (defbitfield ,name ,@values)
 392      (register-flags-type ,g-name ',name)
 393      ,@(when export
 394              (list `(export ',name (find-package ,(package-name (symbol-package name))))))
 395      ,@(when type-initializer
 396              (list `(at-init () ,(type-initializer-call type-initializer))))))
 397
 398 (defun flags-value->definition (flags-value)
 399   (let ((value-name (intern (lispify-name (flags-item-nick flags-value))
 400                             (find-package :keyword)))
 401         (numeric-value (flags-item-value flags-value)))
 402     `(,value-name ,numeric-value)))
 403
 404 (defun get-g-flags-definition (type)
 405   (let* ((g-type (ensure-g-type type))
 406          (g-name (g-type-name g-type))
 407          (name (g-name->name g-name))
 408          (items (get-flags-items g-type))
 409          (probable-type-initializer (probable-type-init-name g-name)))
 410     `(define-g-flags ,g-name ,name
 411          (:export t
 412                   ,@(when (foreign-symbol-pointer probable-type-initializer)
 413                           (list :type-initializer
 414                                 probable-type-initializer)))
 415        ,@(mapcar #'flags-value->definition items))))
 416
 417 (defun generate-types-hierarchy-to-file (file root-type &key include-referenced prefix package exceptions prologue interfaces enums flags objects exclusions additional-properties)
 418   (if (not (streamp file))
 419       (with-open-file (stream file :direction :output :if-exists :supersede)
 420         (generate-types-hierarchy-to-file stream root-type
 421                                           :prefix prefix
 422                                           :package package
 423                                           :exceptions exceptions
 424                                           :prologue prologue
 425                                           :include-referenced include-referenced
 426                                           :interfaces interfaces
 427                                           :enums enums
 428                                           :flags flags
 429                                           :objects objects
 430                                           :exclusions exclusions
 431                                           :additional-properties additional-properties))
 432       (let* ((*generation-exclusions* (mapcar #'ensure-g-type exclusions))
 433              (*lisp-name-package* (or package *package*))
 434              (*package* *lisp-name-package*)
 435              (*strip-prefix* (or prefix ""))
 436              (*lisp-name-exceptions* exceptions)
 437              (*print-case* :downcase)
 438              (*additional-properties* additional-properties)
 439              (referenced-types (and include-referenced
 440                                     (filter-types-by-prefix
 441                                      (get-referenced-types root-type)
 442                                      prefix))))
 443         (setf exclusions (mapcar #'ensure-g-type exclusions))
 444         (when prologue
 445           (write-string prologue file)
 446           (terpri file))
 447         (when include-referenced
 448           (loop
 449              for interface in interfaces
 450              do (loop
 451                    for referenced-type in (get-shallow-referenced-types interface)
 452                    do (pushnew referenced-type referenced-types :test 'equal)))
 453           (loop
 454              for object in objects
 455              do (loop
 456                    for referenced-type in (get-shallow-referenced-types object)
 457                    do (pushnew referenced-type referenced-types :test 'equal)))
 458           (loop
 459              for enum-type in (filter-types-by-fund-type
 460                                referenced-types "GEnum")
 461              for def = (get-g-enum-definition enum-type)
 462              unless (member (ensure-g-type enum-type) exclusions :test '=)
 463              do (format file "~S~%~%" def))
 464
 465           (loop
 466              for flags-type in (filter-types-by-fund-type
 467                                 referenced-types "GFlags")
 468              for def = (get-g-flags-definition flags-type)
 469              unless (member (ensure-g-type flags-type) exclusions :test '=)
 470              do (format file "~S~%~%" def)))
 471         (loop
 472            with auto-enums = (and include-referenced
 473                                   (filter-types-by-fund-type
 474                                    referenced-types "GEnum"))
 475            for enum in enums
 476            for def = (get-g-enum-definition enum)
 477            unless (find (ensure-g-type enum) auto-enums :test 'equal)
 478            do (format file "~S~%~%" def))
 479         (loop
 480            with auto-flags = (and include-referenced
 481                                   (filter-types-by-fund-type
 482                                    referenced-types "GFlags"))
 483            for flags-type in flags
 484            for def = (get-g-flags-definition flags-type)
 485            unless (find (ensure-g-type flags-type) auto-flags :test 'equal)
 486            do (format file "~S~%~%" def))
 487         (loop
 488            for interface in interfaces
 489            for def = (get-g-interface-definition interface)
 490            do (format file "~S~%~%" def))
 491         (loop
 492            for def in (get-g-class-definitions-for-root root-type)
 493            do (format file "~S~%~%" def))
 494         (loop
 495            for object in objects
 496            for def = (get-g-class-definition object)
 497            do (format file "~S~%~%" def)))))