glib/gobject.object.high.lisp

   1 (in-package :gobject)
   2
   3 (defclass g-object ()
   4   ((pointer
   5     :type cffi:foreign-pointer
   6     :initarg :pointer
   7     :accessor pointer
   8     :initform nil)
   9    (has-reference
  10     :type boolean
  11     :accessor g-object-has-reference
  12     :initform nil)
  13    (signal-handlers
  14     :type (array t *)
  15     :initform (make-array 0 :adjustable t :fill-pointer t)
  16     :reader g-object-signal-handlers))
  17   (:documentation
  18    "Base class for GObject classes hierarchy."))
  19
  20 (defvar *foreign-gobjects-weak* (make-weak-hash-table :test 'equal :weakness :value))
  21 (defvar *foreign-gobjects-strong* (make-hash-table :test 'equal))
  22 (defvar *current-creating-object* nil)
  23 (defvar *current-object-from-pointer* nil)
  24 (defvar *currently-making-object-p* nil)
  25
  26 (defun ref-count (pointer)
  27   (foreign-slot-value (if (pointerp pointer) pointer (pointer pointer)) 'g-object-struct :ref-count))
  28
  29 (defmethod initialize-instance :around ((obj g-object) &key)
  30   (when *currently-making-object-p*
  31     (setf *currently-making-object-p* t))
  32   (let ((*current-creating-object* obj))
  33     (log-for :subclass "initialize-instance :around; *current-creating-object* = ~A~%" obj)
  34     (call-next-method)))
  35
  36 (defmethod initialize-instance :after ((obj g-object) &key &allow-other-keys)
  37   (unless (slot-boundp obj 'pointer)
  38     (error "Pointer slot is not initialized for ~A" obj))
  39   (let* ((pointer (pointer obj))
  40          (s (format nil "~A" obj)))
  41     (finalize obj
  42               (lambda ()
  43                 (log-for :gc "~A ~A is queued for GC (having ~A refs)~%"
  44                          (g-type-from-object pointer) pointer (ref-count pointer))
  45                 (handler-case
  46                     (g-object-dispose-carefully pointer)
  47                   (error (e)
  48                     (log-for :gc "Error in finalizer for ~A: ~A~%" s e)
  49                     (format t "Error in finalizer for ~A: ~A~%" s e))))))
  50   (register-g-object obj)
  51   (activate-gc-hooks))
  52
  53 (defvar *gobject-gc-hooks-lock* (make-recursive-lock "gobject-gc-hooks-lock"))
  54 (defvar *gobject-gc-hooks* nil);;pointers to objects to be freed
  55
  56 (defun activate-gc-hooks ()
  57   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  58     (when *gobject-gc-hooks*
  59       (log-for :gc "activating gc hooks for objects: ~A~%" *gobject-gc-hooks*)
  60       (loop
  61          for pointer in *gobject-gc-hooks*
  62          do (g-object-remove-toggle-ref pointer (callback gobject-toggle-ref-toggled) (null-pointer)))
  63       (setf *gobject-gc-hooks* nil))))
  64
  65 (defcallback g-idle-gc-hook :boolean ((data :pointer))
  66   (declare (ignore data))
  67   (activate-gc-hooks)
  68   nil)
  69
  70 (defun register-gobject-for-gc (pointer)
  71   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  72     (let ((locks-were-present (not (null *gobject-gc-hooks*))))
  73       (push pointer *gobject-gc-hooks*)
  74       (unless locks-were-present
  75         (log-for :gc "adding idle-gc-hook to main loop~%")
  76         (g-idle-add (callback g-idle-gc-hook) (null-pointer))))))
  77
  78 (defun g-object-dispose-carefully (pointer)
  79   (handler-case
  80       (register-gobject-for-gc pointer)
  81     (error (e)
  82       (log-for :gc  "Error in dispose: ~A~%" e)
  83       (format t "Error in dispose: ~A~%" e))))
  84
  85 (defun should-ref-sink-at-creation (object)
  86 ;;If object was not created from lisp-side, we should ref it
  87 ;;If an object is regular g-object, we should not ref-sink it
  88 ;;If an object is GInitiallyUnowned, then it is created with a floating reference, we should ref-sink it
  89 ;;A special case is GtkWindow: we should ref-sink it anyway
  90   (let ((r (cond
  91              ((equal *current-object-from-pointer* (pointer object))
  92               (log-for :gc "*cur-obj-from-ptr* ")
  93               t)  ;; not new objects should be ref_sunk
  94              ((eq object *current-creating-object*) ;; g_object_new returns objects with ref = 1, we should save _this_ ref
  95               (typep object 'g-initially-unowned)) ;; but GInitiallyUnowned objects should be ref_sunk
  96              (t t))))
  97     (log-for :gc "(should-ref-sink-at-creation ~A) => ~A~%" object r)
  98     r))
  99
 100 (defcallback gobject-toggle-ref-toggled :void
 101     ((data :pointer) (pointer :pointer) (is-last-ref :boolean))
 102   (declare (ignore data))
 103   (log-for :gc "~A is now ~A with ~A refs~%" pointer (if is-last-ref "weak pointer" "strong pointer") (ref-count pointer))
 104   (log-for :gc "obj: ~A~%" (or (gethash (pointer-address pointer) *foreign-gobjects-strong*)
 105                             (gethash (pointer-address pointer) *foreign-gobjects-weak*)))
 106   (if is-last-ref
 107       (let ((obj (gethash (pointer-address pointer) *foreign-gobjects-strong*)))
 108         (if obj
 109             (progn
 110               (remhash (pointer-address pointer) *foreign-gobjects-strong*)
 111               (setf (gethash (pointer-address pointer) *foreign-gobjects-weak*) obj))
 112             (progn
 113               (log-for :gc "GObject at ~A has no lisp-side (strong) reference" pointer)
 114               (warn "GObject at ~A has no lisp-side (strong) reference" pointer))))
 115       (let ((obj (gethash (pointer-address pointer) *foreign-gobjects-weak*)))
 116         (unless obj
 117           (log-for :gc "GObject at ~A has no lisp-side (weak) reference" pointer)
 118           (warn "GObject at ~A has no lisp-side (weak) reference" pointer))
 119         (remhash (pointer-address pointer) *foreign-gobjects-weak*)
 120         (setf (gethash (pointer-address pointer) *foreign-gobjects-strong*) obj))))
 121
 122 (defcallback gobject-weak-ref-finalized :void
 123     ((data :pointer) (pointer :pointer))
 124   (declare (ignore data))
 125   (log-for :gc "~A is weak-ref-finalized with ~A refs~%" pointer (ref-count pointer))
 126   (remhash (pointer-address pointer) *foreign-gobjects-weak*)
 127   (when (gethash (pointer-address pointer) *foreign-gobjects-strong*)
 128     (warn "GObject at ~A was weak-ref-finalized while still holding lisp-side strong reference to it" pointer)
 129     (log-for :gc "GObject at ~A was weak-ref-finalized while still holding lisp-side strong reference to it" pointer))
 130   (remhash (pointer-address pointer) *foreign-gobjects-strong*))
 131
 132 (defun register-g-object (obj)
 133   (log-for :gc "registered GObject ~A (~A) with initial ref-count ~A ~A~%"
 134            (pointer obj) obj
 135            (ref-count obj) (if (g-object-is-floating (pointer obj)) "(floating)" ""))
 136   (when (should-ref-sink-at-creation obj)
 137     (log-for :gc "g_object_ref_sink(~A)~%" (pointer obj))
 138     (g-object-ref-sink (pointer obj)))
 139   (setf (g-object-has-reference obj) t)
 140   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects-strong*) obj)
 141   (g-object-add-toggle-ref (pointer obj) (callback gobject-toggle-ref-toggled) (null-pointer))
 142   (g-object-unref (pointer obj)))
 143
 144 (defvar *registered-object-types* (make-hash-table :test 'equal))
 145 (defun register-object-type (name type)
 146   (setf (gethash name *registered-object-types*) type))
 147 (defun registered-object-type-by-name (name)
 148   (gethash name *registered-object-types*))
 149 (defun get-g-object-lisp-type (g-type)
 150   (setf g-type (ensure-g-type g-type))
 151   (loop
 152      while (not (zerop g-type))
 153      for lisp-type = (gethash (g-type-name g-type) *registered-object-types*)
 154      when lisp-type do (return lisp-type)
 155      do (setf g-type (ensure-g-type (g-type-parent g-type)))))
 156
 157 (defun make-g-object-from-pointer (pointer)
 158   (let* ((g-type (g-type-from-instance pointer))
 159          (lisp-type (get-g-object-lisp-type g-type)))
 160     (unless lisp-type
 161       (error "Type ~A is not registered with REGISTER-OBJECT-TYPE"
 162              (g-type-name g-type)))
 163     (let ((*current-object-from-pointer* pointer))
 164       (make-instance lisp-type :pointer pointer))))
 165
 166 (define-foreign-type foreign-g-object-type ()
 167   ((sub-type :reader sub-type :initarg :sub-type :initform 'g-object)
 168    (already-referenced :reader foreign-g-object-type-already-referenced :initarg :already-referenced :initform nil))
 169   (:actual-type :pointer))
 170
 171 (define-parse-method g-object (&rest args)
 172   (let* ((sub-type (first (remove-if #'keywordp args)))
 173          (flags (remove-if-not #'keywordp args))
 174          (already-referenced (not (null (find :already-referenced flags)))))
 175     (make-instance 'foreign-g-object-type :sub-type sub-type :already-referenced already-referenced)))
 176
 177 (defmethod translate-to-foreign (object (type foreign-g-object-type))
 178   (cond
 179     ((null object)
 180      (null-pointer))
 181     ((pointerp object) object)
 182     ((null (pointer object))
 183      (error "Object ~A has been disposed" object))
 184     ((typep object 'g-object)
 185      (when (sub-type type)
 186        (assert (typep object (sub-type type))
 187                nil
 188                "Object ~A is not a subtype of ~A" object (sub-type type)))
 189      (pointer object))
 190     (t (error "Object ~A is not translatable as GObject*" object))))
 191
 192 (defun get-g-object-for-pointer (pointer)
 193   (unless (null-pointer-p pointer)
 194     (or (gethash (pointer-address pointer) *foreign-gobjects-strong*)
 195         (gethash (pointer-address pointer) *foreign-gobjects-weak*)
 196         (progn (log-for :gc "Now creating object for ~A~%" pointer)
 197                (make-g-object-from-pointer pointer)))))
 198
 199 (defmethod translate-from-foreign (pointer (type foreign-g-object-type))
 200   (let ((object (get-g-object-for-pointer pointer)))
 201     (when (foreign-g-object-type-already-referenced type)
 202       (g-object-unref (pointer object)))
 203     object))
 204
 205 (register-object-type "GObject" 'g-object)
 206
 207 (defun ensure-g-type (type)
 208   "Returns the GType value for a given type. If type is an integer, it is returned. If type is a string, GType corresponding to this type name is looked up and returned.
 209 @arg[type]{a string or and integer}
 210 @return{integer equal to GType of @code{type}}"
 211   (etypecase type
 212     (integer type)
 213     (string (or (g-type-from-name type)
 214                 (error "Type ~A is invalid" type)))))
 215
 216 (defun ensure-object-pointer (object)
 217   (if (pointerp object)
 218       object
 219       (etypecase object
 220         (g-object (pointer object)))))
 221
 222 (defun parse-g-value-object (gvalue)
 223   (get-g-object-for-pointer (g-value-get-object gvalue)))
 224
 225 (defun set-gvalue-object (gvalue value)
 226   (g-value-set-object gvalue (if value (pointer value) (null-pointer))))
 227
 228 (defmethod parse-g-value-for-type (gvalue-ptr (type-numeric (eql +g-type-object+)) parse-kind)
 229   (declare (ignore parse-kind))
 230   (parse-g-value-object gvalue-ptr))
 231
 232 (defmethod parse-g-value-for-type (gvalue-ptr (type-numeric (eql +g-type-interface+)) parse-kind)
 233   (declare (ignore parse-kind))
 234   (parse-g-value-object gvalue-ptr))
 235
 236 (defmethod set-gvalue-for-type (gvalue-ptr (type-numeric (eql +g-type-object+)) value)
 237   (set-gvalue-object gvalue-ptr value))
 238
 239 (defmethod set-gvalue-for-type (gvalue-ptr (type-numeric (eql +g-type-interface+)) value)
 240   (set-gvalue-object gvalue-ptr value))