glib/gobject.object.high.lisp

   1 (in-package :gobject)
   2
   3 (defclass g-object ()
   4   ((pointer
   5     :type cffi:foreign-pointer
   6     :initarg :pointer
   7     :accessor pointer
   8     :initform nil)
   9    (has-reference
  10     :type boolean
  11     :accessor g-object-has-reference
  12     :initform nil))
  13   (:documentation
  14    "Base class for GObject classes hierarchy."))
  15
  16 (defvar *foreign-gobjects* (make-weak-hash-table :test 'equal :weakness :value))
  17 (defvar *foreign-gobjects-ref-count* (make-hash-table :test 'equal))
  18 (defvar *lisp-objects-pointers* (make-hash-table :test 'equal))
  19 (defvar *current-creating-object* nil)
  20
  21 (defun ref-count (pointer)
  22   (foreign-slot-value (if (pointerp pointer) pointer (pointer pointer)) 'g-object-struct :ref-count))
  23
  24 (defmethod initialize-instance :around ((obj g-object) &key)
  25   (let ((*current-creating-object* obj))
  26     (call-next-method)))
  27
  28 (defmethod initialize-instance :after ((obj g-object) &key &allow-other-keys)
  29   (unless (slot-boundp obj 'pointer)
  30     (error "Pointer slot is not initialized for ~A" obj))
  31   (let* ((pointer (pointer obj))
  32          (s (format nil "~A" obj)))
  33     (finalize obj
  34               (lambda ()
  35                 (handler-case
  36                     (g-object-dispose-carefully pointer)
  37                   (error (e) (format t "Error in finalizer for ~A: ~A~%" s e))))))
  38   (register-g-object obj)
  39   (activate-gc-hooks))
  40
  41 (defvar *gobject-gc-hooks-lock* (make-recursive-lock "gobject-gc-hooks-lock"))
  42 (defvar *gobject-gc-hooks* nil);;pointers to objects to be freed
  43
  44 (defun activate-gc-hooks ()
  45   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  46     (when *gobject-gc-hooks*
  47       (debugf "activating gc hooks for objects: ~A~%" *gobject-gc-hooks*)
  48       (loop
  49          for pointer in *gobject-gc-hooks*
  50          do (g-object-unref pointer))
  51       (setf *gobject-gc-hooks* nil))))
  52
  53 (defcallback g-idle-gc-hook :boolean ((data :pointer))
  54   (declare (ignore data))
  55   (activate-gc-hooks)
  56   nil)
  57
  58 (defun register-gobject-for-gc (pointer)
  59   (with-recursive-lock-held (*gobject-gc-hooks-lock*)
  60     (let ((locks-were-present (not (null *gobject-gc-hooks*))))
  61       (push pointer *gobject-gc-hooks*)
  62       (unless locks-were-present
  63         (debugf "adding idle-gc-hook to main loop~%")
  64         (g-idle-add (callback g-idle-gc-hook) (null-pointer))))))
  65
  66 (defun g-object-dispose-carefully (pointer)
  67   (handler-case
  68       (register-gobject-for-gc pointer)
  69     (error (e) (format t "Error in dispose: ~A~%" e))))
  70
  71 (defcallback weak-notify-print :void ((data :pointer) (object-pointer :pointer))
  72   (declare (ignore data)
  73            (ignorable object-pointer))
  74   (debugf "g-object has finalized ~A ~A~%" (g-type-name (g-type-from-object object-pointer)) object-pointer))
  75
  76 (defun erase-pointer (data object-pointer)
  77   (declare (ignore data))
  78   (remhash (pointer-address object-pointer) *lisp-objects-pointers*))
  79
  80 (defcallback weak-notify-erase-pointer :void ((data :pointer) (object-pointer :pointer))
  81   (erase-pointer data object-pointer))
  82
  83 (defun should-ref-sink-at-creation (object)
  84 ;;If object was not created from lisp-side, we should ref it
  85 ;;If an object is regular g-object, we should not ref-sink it
  86 ;;If an object is GInitiallyUnowned, then it is created with a floating reference, we should ref-sink it
  87 ;;A special case is GtkWindow: we should ref-sink it anyway
  88   (if (g-object-has-reference object)
  89       (let ((object-type (g-type-from-object (pointer object)))
  90             (initially-unowned-type (g-type-from-name "GInitiallyUnowned")))
  91         (g-type-is-a object-type initially-unowned-type))
  92       t))
  93
  94 (defun register-g-object (obj)
  95   (debugf "registered GObject ~A with gobject ref-count ~A ~A~%" (pointer obj) (ref-count obj) (if (g-object-is-floating (pointer obj)) "(floating)" ""))
  96   (when (should-ref-sink-at-creation obj)
  97     (debugf "g_object_ref_sink(~A)~%" (pointer obj))
  98     (g-object-ref-sink (pointer obj)))
  99   (g-object-weak-ref (pointer obj) (callback weak-notify-print) (null-pointer))
 100   (g-object-weak-ref (pointer obj) (callback weak-notify-erase-pointer) (null-pointer))
 101   (setf (g-object-has-reference obj) t)
 102   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects*)
 103         obj)
 104   (setf (gethash (pointer-address (pointer obj)) *foreign-gobjects-ref-count*) 1))
 105
 106 (defun g-object-dispose (pointer)
 107   (unless (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 108     (debugf "GObject ~A is already disposed, signalling error~%" pointer)
 109     (error "GObject ~A is already disposed" pointer))
 110   (debugf "g_object_unref(~A) (of type ~A, lisp-value ~A) (lisp ref-count ~A, gobject ref-count ~A)~%"
 111           pointer
 112           (g-type-name (g-type-from-object pointer))
 113           (gethash (pointer-address pointer) *foreign-gobjects*)
 114           (gethash (pointer-address pointer) *foreign-gobjects-ref-count*)
 115           (ref-count pointer))
 116   (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 117     (when object
 118       (setf (pointer object) nil)
 119       (cancel-finalization object)))
 120   (remhash (pointer-address pointer) *foreign-gobjects*)
 121   (remhash (pointer-address pointer) *foreign-gobjects-ref-count*)
 122   (g-object-unref pointer))
 123
 124 (defmethod release ((object g-object))
 125   (debugf "Releasing object ~A (type ~A, lisp-value ~A)~%" (pointer object) (when (pointer object) (g-type-name (g-type-from-object (pointer object)))) object)
 126   (unless (and (pointer object) (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 127     (error "Object ~A already disposed of from lisp side" object))
 128   (decf (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 129   (when (zerop (gethash (pointer-address (pointer object)) *foreign-gobjects-ref-count*))
 130     (g-object-dispose (pointer object)))
 131   (activate-gc-hooks))
 132
 133 (defvar *registered-object-types* (make-hash-table :test 'equal))
 134 (defun register-object-type (name type)
 135   (setf (gethash name *registered-object-types*) type))
 136 (defun registered-object-type-by-name (name)
 137   (gethash name *registered-object-types*))
 138 (defun get-g-object-lisp-type (g-type)
 139   (setf g-type (ensure-g-type g-type))
 140   (loop
 141      while (not (zerop g-type))
 142      for lisp-type = (gethash (g-type-name g-type) *registered-object-types*)
 143      when lisp-type do (return lisp-type)
 144      do (setf g-type (ensure-g-type (g-type-parent g-type)))))
 145
 146 (defun make-g-object-from-pointer (pointer)
 147   (let* ((g-type (g-type-from-instance pointer))
 148          (lisp-type (get-g-object-lisp-type g-type)))
 149     (unless lisp-type
 150       (error "Type ~A is not registered with REGISTER-OBJECT-TYPE"
 151              (g-type-name g-type)))
 152     (g-object-ref pointer)
 153     (make-instance lisp-type :pointer pointer)))
 154
 155 (define-foreign-type foreign-g-object-type ()
 156   ((sub-type :reader sub-type :initarg :sub-type :initform 'g-object))
 157   (:actual-type :pointer))
 158
 159 (define-parse-method g-object (&optional (sub-type 'g-object))
 160   (make-instance 'foreign-g-object-type :sub-type sub-type))
 161
 162 (defmethod translate-to-foreign (object (type foreign-g-object-type))
 163   (cond
 164     ((null object)
 165      (null-pointer))
 166     ((pointerp object) object)
 167     ((null (pointer object))
 168      (error "Object ~A has been disposed" object))
 169     ((typep object 'g-object)
 170      (assert (typep object (sub-type type))
 171              nil
 172              "Object ~A is not a subtype of ~A" object (sub-type type))
 173      (pointer object))
 174     (t (error "Object ~A is not translatable as GObject*" object))))
 175
 176 (defun get-g-object-for-pointer (pointer)
 177   (unless (null-pointer-p pointer)
 178     (let ((object (gethash (pointer-address pointer) *foreign-gobjects*)))
 179       (if object
 180           (prog1 object
 181             (incf (gethash (pointer-address pointer) *foreign-gobjects-ref-count*))
 182             (debugf "increfering object ~A~%" pointer))
 183           (make-g-object-from-pointer pointer)))))
 184
 185 (defmethod translate-from-foreign (pointer (type foreign-g-object-type))
 186   (get-g-object-for-pointer pointer))
 187
 188 (register-object-type "GObject" 'g-object)
 189
 190 (defun ensure-g-type (type)
 191   "Returns the GType value for a given type. If type is an integer, it is returned. If type is a string, GType corresponding to this type name is looked up and returned.
 192 @arg[type]{a string or and integer}
 193 @return{integer equal to GType of @code{type}}"
 194   (etypecase type
 195     (integer type)
 196     (string (or (g-type-from-name type)
 197                 (error "Type ~A is invalid" type)))))
 198
 199 (defun ensure-object-pointer (object)
 200   (if (pointerp object)
 201       object
 202       (etypecase object
 203         (g-object (pointer object)))))
 204
 205 (defun parse-g-value-object (gvalue)
 206   (get-g-object-for-pointer (g-value-get-object gvalue)))
 207
 208 (defun set-gvalue-object (gvalue value)
 209   (g-value-set-object gvalue (if value (pointer value) (null-pointer))))
 210
 211 (defmethod parse-g-value-for-type (gvalue-ptr (type-numeric (eql +g-type-object+)) parse-kind)
 212   (declare (ignore parse-kind))
 213   (parse-g-value-object gvalue-ptr))
 214
 215 (defmethod parse-g-value-for-type (gvalue-ptr (type-numeric (eql +g-type-interface+)) parse-kind)
 216   (declare (ignore parse-kind))
 217   (parse-g-value-object gvalue-ptr))
 218
 219 (defmethod set-gvalue-for-type (gvalue-ptr (type-numeric (eql +g-type-object+)) value)
 220   (set-gvalue-object gvalue-ptr value))
 221
 222 (defmethod set-gvalue-for-type (gvalue-ptr (type-numeric (eql +g-type-interface+)) value)
 223   (set-gvalue-object gvalue-ptr value))
 224
 225 (defun g-signal-connect (object signal handler &key after)
 226   "Deprecated alias for @fun{connect-signal}"
 227   (connect-signal object signal handler :after after))
 228
 229 (defun connect-signal (object signal handler &key after)
 230   "Connects the function to a signal for a particular object.
 231 If @code{after} is true, then the function will be called after the default handler of the signal.
 232
 233 @arg[object]{an instance of @class{gobject}}
 234 @arg[signal]{a string; names the signal}
 235 @arg[handler]{a function; handles the signal. Number (and type) of arguments and return value type depends on the signal}
 236 @arg[after]{a boolean}"
 237   (g-signal-connect-closure (ensure-object-pointer object)
 238                             signal
 239                             (create-g-closure handler)
 240                             after))
 241
 242 (defun emit-signal (object signal-name &rest args)
 243   "Emits the signal.
 244 @arg[object]{an instance of @class{g-object}. Signal is emitted on this object}
 245 @arg[signal-name]{a string specifying the signal}
 246 @arg[args]{arguments for the signal}
 247 @return{none}"
 248   (let* ((object-type (g-type-from-object (pointer object)))
 249          (signal-info (parse-signal-name object-type signal-name)))
 250     (unless signal-info
 251       (error "Signal ~A not found on object ~A" signal-name object))
 252     (let ((params-count (length (signal-info-param-types signal-info))))
 253       (with-foreign-object (params 'g-value (1+ params-count))
 254         (set-g-value (mem-aref params 'g-value 0) object object-type :zero-g-value t)
 255         (iter (for i from 0 below params-count)
 256               (for arg in args)
 257               (for type in (signal-info-param-types signal-info))
 258               (set-g-value (mem-aref params 'g-value (1+ i)) arg type :zero-g-value t))
 259         (prog1
 260             (if (g-type= (signal-info-return-type signal-info) +g-type-void+)
 261                 (g-signal-emitv params (signal-info-id signal-info) signal-name (null-pointer))
 262                 (with-foreign-object (return-value 'g-value)
 263                   (g-value-zero return-value)
 264                   (g-value-init return-value (signal-info-return-type signal-info))
 265                   (prog1 (parse-g-value return-value)
 266                     (g-value-unset return-value))))
 267           (iter (for i from 0 below (1+ params-count))
 268                 (g-value-unset (mem-aref params 'g-value i))))))))