gtk/gtk.tree-model.lisp

   1 (in-package :gtk)
   2
   3 (define-vtable ("GtkTreeModel" tree-model)
   4   (:skip parent-instance g-type-interface)
   5   ;;some signals
   6   (:skip tree-model-row-changed :pointer)
   7   (:skip tree-model-row-inserted :pointer)
   8   (:skip tree-model-row-has-child-toggled :pointer)
   9   (:skip tree-model-row-deleted :pointer)
  10   (:skip tree-model-rows-reordered :pointer)
  11   ;;methods
  12   (get-flags (tree-model-flags (tree-model g-object)))
  13   (get-n-columns (:int (tree-model g-object)))
  14   (get-column-type (g-type-designator
  15                     (tree-model g-object)
  16                     (index :int)))
  17   (get-iter (:boolean
  18              (tree-model g-object)
  19              (iter (g-boxed-foreign tree-iter))
  20              (path (g-boxed-foreign tree-path))))
  21   (get-path ((g-boxed-foreign tree-path :return)
  22              (tree-model g-object)
  23              (iter (g-boxed-foreign tree-iter))))
  24   (get-value (:void
  25               (tree-model g-object)
  26               (iter (g-boxed-foreign tree-iter))
  27               (n :int)
  28               (value (:pointer g-value)))
  29              :impl-call
  30              ((tree-model iter n)
  31               (multiple-value-bind (v type) (tree-model-get-value-impl tree-model iter n)
  32                 (set-g-value value v type))))
  33   (iter-next (:boolean
  34               (tree-model g-object)
  35               (iter (g-boxed-foreign tree-iter))))
  36   (iter-children (:boolean
  37                   (tree-model g-object)
  38                   (iter (g-boxed-foreign tree-iter))
  39                   (parent (g-boxed-foreign tree-iter))))
  40   (iter-has-child (:boolean
  41                    (tree-model g-object)
  42                    (iter (g-boxed-foreign tree-iter))))
  43   (iter-n-children (:int
  44                     (tree-model g-object)
  45                     (iter (g-boxed-foreign tree-iter))))
  46   (iter-nth-child (:boolean
  47                    (tree-model g-object)
  48                    (iter (g-boxed-foreign tree-iter))
  49                    (parent (g-boxed-foreign tree-iter))
  50                    (n :int)))
  51   (iter-parent (:boolean
  52                 (tree-model g-object)
  53                 (iter (g-boxed-foreign tree-iter))
  54                 (child (g-boxed-foreign tree-iter))))
  55   (ref-node (:void
  56              (tree-model g-object)
  57              (iter (g-boxed-foreign tree-iter))))
  58   (unref-node (:void
  59                (tree-model g-object)
  60                (iter (g-boxed-foreign tree-iter)))))
  61
  62 (define-vtable ("GtkTreeSortable" tree-sortable)
  63   (:skip parent-instance g-type-interface)
  64   ;; signal
  65   (:skip sort-columns-changed :pointer)
  66   ;; methods
  67   (get-sort-column-id
  68    (:boolean (sortable (g-object tree-sortable))
  69              (sort-column-id (:pointer :int))
  70              (order (:pointer sort-type)))
  71    :impl-call ((sortable)
  72                (multiple-value-bind (sorted-p r-sort-column-id r-order) (tree-sortable-get-sort-column-id-impl sortable)
  73                  (unless (null-pointer-p sort-column-id)
  74                    (setf (mem-ref sort-column-id :int) r-sort-column-id))
  75                  (unless (null-pointer-p order)
  76                    (setf (mem-ref order 'sort-type) r-order))
  77                  sorted-p)))
  78   (set-sort-column-id (:void (sortable (g-object tree-sortable)) (sort-column-id :int) (order sort-type)))
  79   (set-sort-func (:void (sortable (g-object tree-sortable)) (sort-column-id :int) (func :pointer) (data :pointer) (destroy-notify :pointer)))
  80   (set-default-sort-func (:void (sortable (g-object tree-sortable)) (func :pointer) (data :pointer) (destroy-notify :pointer)))
  81   (has-default-sort-func (:boolean (sortable (g-object tree-sortable)))))
  82
  83 ; TODO: GtkTreeModelSort
  84
  85 ; TODO: GtkTreeModelFilter
  86
  87 (defclass array-list-store (tree-model)
  88   ((items :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-items)
  89    (columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-getters)
  90    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-types))
  91   (:metaclass gobject-class)
  92   (:g-type-name . "LispArrayListStore"))
  93
  94 (export 'array-list-store)
  95
  96 (register-object-type-implementation "LispArrayListStore" array-list-store "GObject" ("GtkTreeModel") nil)
  97
  98 (defun store-items-count (store)
  99   (length (store-items store)))
 100
 101 (export 'store-items-count)
 102
 103 (defun store-item (store index)
 104   (aref (store-items store) index))
 105
 106 (export 'store-item)
 107
 108 (defun store-add-item (store item)
 109   (vector-push-extend item (store-items store))
 110   (let* ((path (make-instance 'tree-path))
 111          (iter (make-tree-iter)))
 112     (setf (tree-path-indices path) (list (1- (length (store-items store)))))
 113     (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (1- (length (store-items store))))
 114     (emit-signal store "row-inserted" path iter)))
 115
 116 (export 'store-add-item)
 117
 118 (defun store-remove-item (store item &key (test 'eq))
 119   (with-slots (items) store
 120     (let ((index (position item items :test test)))
 121       (unless index (error "No such item~%~A~%in list-store~%~A" item store))
 122       (setf items (delete item items :test test))
 123       (let ((path (make-instance 'tree-path)))
 124         (setf (tree-path-indices path) (list index))
 125         (emit-signal store "row-deleted" path)))))
 126
 127 (export 'store-remove-item)
 128
 129 (defun store-add-column (store type getter)
 130   (vector-push-extend type (store-types store))
 131   (vector-push-extend getter (store-getters store))
 132   (1- (length (store-types store))))
 133
 134 (export 'store-add-column)
 135
 136 (defmethod tree-model-get-flags-impl ((model array-list-store))
 137   '(:list-only))
 138
 139 (defmethod tree-model-get-n-columns-impl ((model array-list-store))
 140   (length (store-types model)))
 141
 142 (defmethod tree-model-get-column-type-impl ((tree-model array-list-store) index)
 143   (aref (store-types tree-model) index))
 144
 145 (defmethod tree-model-get-iter-impl ((model array-list-store) iter path)
 146   (let ((indices (tree-path-indices path)))
 147     (when (and (= 1 (length indices))
 148                (< (first indices) (length (store-items model))))
 149       (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (first indices))
 150       t)))
 151
 152 (defmethod tree-model-ref-node-impl ((model array-list-store) iter)
 153   (declare (ignorable model iter)))
 154 (defmethod tree-model-unref-node-impl ((model array-list-store) iter)
 155   (declare (ignorable model iter)))
 156
 157 (defmethod tree-model-iter-next-impl ((model array-list-store) iter)
 158   (let ((n (tree-iter-user-data iter)))
 159     (when (< n (1- (length (store-items model))))
 160       (setf (tree-iter-user-data iter) (1+ n))
 161       t)))
 162
 163 (defmethod tree-model-iter-nth-child-impl ((model array-list-store) iter parent n)
 164   (declare (ignorable parent))
 165   (setf (tree-iter-stamp iter) 0
 166         (tree-iter-user-data iter) n)
 167   t)
 168
 169 (defmethod tree-model-iter-children-impl ((model array-list-store) iter parent)
 170   (declare (ignore iter parent))
 171   nil)
 172
 173 (defmethod tree-model-iter-n-children-impl ((model array-list-store) iter)
 174   (if (null iter)
 175       (length (store-items model))
 176       0))
 177
 178 (defmethod tree-model-get-path-impl ((model array-list-store) iter)
 179   (let ((path (make-instance 'tree-path)))
 180     (setf (tree-path-indices path) (list (tree-iter-user-data iter)))
 181     path))
 182
 183 (defmethod tree-model-iter-has-child-impl ((model array-list-store) iter)
 184   (declare (ignorable iter))
 185   nil)
 186
 187 (defgeneric tree-model-item (model iter-or-path))
 188
 189 (defmethod tree-model-item ((model array-list-store) (iter tree-iter))
 190   (let ((n-row (tree-iter-user-data iter)))
 191     (aref (store-items model) n-row)))
 192
 193 (defmethod tree-model-item ((model array-list-store) (path tree-path))
 194   (let ((n-row (first (tree-path-indices path))))
 195     (aref (store-items model) n-row)))
 196
 197 (export 'tree-model-item)
 198
 199 (defmethod tree-model-get-value-impl ((model array-list-store) iter n)
 200   (let ((n-row (tree-iter-user-data iter)))
 201     (values (funcall (aref (store-getters model) n)
 202                      (aref (store-items model) n-row))
 203             (aref (store-types model) n))))
 204
 205 (defcfun (tree-model-flags "gtk_tree_model_get_flags") tree-model-flags
 206   (tree-model g-object))
 207
 208 (export 'tree-model-flags)
 209
 210 (defcfun (tree-model-n-columns "gtk_tree_model_get_n_columns") :int
 211   (tree-model g-object))
 212
 213 (export 'tree-model-flags)
 214
 215 (defcfun (tree-model-column-type "gtk_tree_model_get_column_type") g-type-designator
 216   (tree-model g-object)
 217   (index :int))
 218
 219 (export 'tree-model-column-type)
 220
 221 (defcfun (tree-model-set-iter-to-path "gtk_tree_model_get_iter") :boolean
 222   (tree-model g-object)
 223   (iter (g-boxed-foreign tree-iter))
 224   (path (g-boxed-foreign tree-path)))
 225
 226 (defun tree-model-iter-by-path (tree-model tree-path)
 227   (let ((iter (make-tree-iter)))
 228     (if (tree-model-set-iter-to-path tree-model iter tree-path)
 229         iter
 230         nil)))
 231
 232 (export 'tree-model-iter-by-path)
 233
 234 (defcfun (tree-model-set-iter-from-string "gtk_tree_model_get_iter_from_string") :boolean
 235   (tree-model g-object)
 236   (iter (g-boxed-foreign tree-iter))
 237   (path-string :string))
 238
 239 (defun tree-model-iter-from-string (tree-model path-string)
 240   (let ((iter (make-tree-iter)))
 241     (if (tree-model-set-iter-from-string tree-model iter path-string)
 242         iter
 243         nil)))
 244
 245 (export 'tree-model-iter-from-string)
 246
 247 (defcfun (tree-model-set-iter-to-first "gtk_tree_model_get_iter_first") :boolean
 248   (model g-object)
 249   (iter (g-boxed-foreign tree-iter)))
 250
 251 (defun tree-model-iter-first (tree-model)
 252   (let ((iter (make-tree-iter)))
 253     (if (tree-model-set-iter-to-first tree-model iter)
 254         iter
 255         nil)))
 256
 257 (export 'tree-model-iter-first)
 258
 259 (defcfun (tree-model-path "gtk_tree_model_get_path") (g-boxed-foreign tree-path :return)
 260   (tree-model g-object)
 261   (iter (g-boxed-foreign tree-iter)))
 262
 263 (export 'tree-model-path)
 264
 265 (defcfun gtk-tree-model-get-value :void
 266   (model g-object)
 267   (iter (g-boxed-foreign tree-iter))
 268   (column :int)
 269   (value (:pointer g-value)))
 270
 271 (defun tree-model-value (tree-model iter column)
 272   (with-foreign-object (v 'g-value)
 273     (g-value-zero v)
 274     (gtk-tree-model-get-value tree-model iter column v)
 275     (prog1 (parse-g-value v)
 276       (g-value-unset v))))
 277
 278 (export 'tree-model-value)
 279
 280 (defcfun (tree-model-iter-next "gtk_tree_model_iter_next") :boolean
 281   (tree-model g-object)
 282   (iter (g-boxed-foreign tree-iter)))
 283
 284 (export 'tree-model-iter-next)
 285
 286 (defcfun gtk-tree-model-iter-children :boolean
 287   (tree-model g-object)
 288   (iter (g-boxed-foreign tree-iter))
 289   (parent (g-boxed-foreign tree-iter)))
 290
 291 (defun tree-model-iter-first-child (tree-model parent)
 292   (let ((iter (make-tree-iter)))
 293     (if (gtk-tree-model-iter-children tree-model iter parent)
 294         iter
 295         nil)))
 296
 297 (export 'tree-model-iter-first-child)
 298
 299 (defcfun (tree-model-iter-has-child "gtk_tree_model_iter_has_child") :boolean
 300   (tree-model g-object)
 301   (iter (g-boxed-foreign tree-iter)))
 302
 303 (export 'tree-model-iter-has-child)
 304
 305 (defcfun (tree-model-iter-n-children "gtk_tree_model_iter_n_children") :int
 306   (tree-model g-object)
 307   (iter (g-boxed-foreign tree-iter)))
 308
 309 (export 'tree-model-iter-n-children)
 310
 311 (defcfun gtk-tree-model-iter-nth-child :boolean
 312   (tree-model g-object)
 313   (iter (g-boxed-foreign tree-iter))
 314   (parent (g-boxed-foreign tree-iter))
 315   (n :int))
 316
 317 (defun tree-model-iter-nth-child (tree-model parent n)
 318   (let ((iter (make-tree-iter)))
 319     (if (gtk-tree-model-iter-nth-child tree-model iter parent n)
 320         iter
 321         n)))
 322
 323 (export 'tree-model-iter-nth-child)
 324
 325 (defcfun gtk-tree-model-iter-parent :boolean
 326   (tree-model g-object)
 327   (iter (g-boxed-foreign tree-iter))
 328   (parent (g-boxed-foreign tree-iter)))
 329
 330 (defun tree-model-iter-parent (tree-model iter)
 331   (let ((parent (make-tree-iter)))
 332     (if (gtk-tree-model-iter-parent tree-model iter parent)
 333         parent
 334         nil)))
 335
 336 (export 'tree-model-iter-parent)
 337
 338 (defcfun (tree-model-iter-to-string "gtk_tree_model_get_string_from_iter") (g-string :free-from-foreign t)
 339   (tree-model g-object)
 340   (iter (g-boxed-foreign tree-iter)))
 341
 342 (export 'tree-model-iter-to-string)
 343
 344 (defcfun (tree-model-ref-node "gtk_tree_model_ref_node") :void
 345   (tree-model g-object)
 346   (iter (g-boxed-foreign tree-iter)))
 347
 348 (export 'tree-model-ref-node)
 349
 350 (defcfun (tree-model-unref-node "gtk_tree_model_unref_node") :void
 351   (tree-model g-object)
 352   (iter (g-boxed-foreign tree-iter)))
 353
 354 (export 'tree-model-unref-node)
 355
 356 (defcallback gtk-tree-model-foreach-cb :boolean ((model g-object) (path (g-boxed-foreign tree-path)) (iter (g-boxed-foreign tree-iter)) (data :pointer))
 357   (let ((fn (get-stable-pointer-value data)))
 358     (restart-case
 359         (funcall fn model path iter)
 360       (stop-tree-model-iteration () t)
 361       (skip-tree-model-current () nil))))
 362
 363 (defcfun gtk-tree-model-foreach :void
 364   (model g-object)
 365   (func :pointer)
 366   (data :pointer))
 367
 368 (defun do-tree-model (model fn)
 369   (with-stable-pointer (ptr fn)
 370     (gtk-tree-model-foreach model (callback gtk-tree-model-foreach-cb) ptr)))
 371
 372 (export 'do-tree-model)
 373
 374 (defun array-insert-at (array element index)
 375   (assert (adjustable-array-p array))
 376   (adjust-array array (1+ (length array)) :fill-pointer t)
 377   (iter (for i from (1- (length array)) above index)
 378         (setf (aref array i)
 379               (aref array (1- i))))
 380   (setf (aref array index) element)
 381   array)
 382
 383 (defun array-remove-at (array index)
 384   (assert (adjustable-array-p array))
 385   (iter (for i from index below (1- (length array)))
 386         (setf (aref array i)
 387               (aref array (1+ i))))
 388   (adjust-array array (1- (length array)) :fill-pointer t)
 389   array)
 390
 391 (defstruct tree-node
 392   (tree nil)
 393   (parent nil)
 394   (id nil)
 395   (item nil)
 396   (children (make-array 0 :element-type 'tree-node :adjustable t :fill-pointer t)))
 397
 398 (defclass tree-lisp-store (tree-model)
 399   ((columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader tree-lisp-store-getters)
 400    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader tree-lisp-store-types)
 401    (root :initform (make-tree-node) :reader tree-lisp-store-root)
 402    (id-map :initform (make-hash-table) :reader tree-lisp-store-id-map)
 403    (next-id-value :initform 0 :accessor tree-lisp-store-next-id-value))
 404   (:metaclass gobject-class)
 405   (:g-type-name . "LispTreeStore"))
 406
 407 (defmethod initialize-instance :after ((object tree-lisp-store) &key &allow-other-keys)
 408   (setf (tree-node-tree (tree-lisp-store-root object)) object))
 409
 410 (register-object-type-implementation "LispTreeStore" tree-lisp-store "GObject" ("GtkTreeModel") nil)
 411
 412 (defun map-subtree (node fn)
 413   (funcall fn node)
 414   (iter (for child in-vector (tree-node-children node))
 415         (map-subtree child fn)))
 416
 417 (defun clear-id (node)
 418   (map-subtree node
 419                (lambda (n)
 420                  (when (and (tree-node-id n)
 421                             (tree-node-tree n))
 422                    (remhash (tree-node-id n)
 423                             (tree-lisp-store-id-map (tree-node-tree n))))
 424                  (setf (tree-node-id n) nil))))
 425
 426 (defun set-node-tree (node tree)
 427   (map-subtree node
 428                (lambda (n)
 429                  (setf (tree-node-tree n) tree))))
 430
 431 (defun tree-node-insert-at (node child index)
 432   (assert (null (tree-node-parent child)))
 433   (clear-id child)
 434   (setf (tree-node-parent child) node)
 435   (set-node-tree child (tree-node-tree node))
 436   (array-insert-at (tree-node-children node) child index)
 437   (notice-tree-node-insertion (tree-node-tree node) node child index)
 438   node)
 439
 440 (defun tree-node-child-at (node index)
 441   (aref (tree-node-children node) index))
 442
 443 (defun tree-node-remove-at (node index)
 444   (assert (<= 0 index (1- (length (tree-node-children node)))))
 445   (let ((child (tree-node-child-at node index)))
 446     (clear-id child)
 447     (setf (tree-node-parent child) nil)
 448     (set-node-tree child nil)
 449     (array-remove-at (tree-node-children node) index)
 450     (notice-tree-node-removal (tree-node-tree node) node child index)))
 451
 452 (defun tree-lisp-store-add-column (store column-type column-getter)
 453   (vector-push-extend column-getter (tree-lisp-store-getters store))
 454   (vector-push-extend column-type (tree-lisp-store-types store)))
 455
 456 (defmethod tree-model-get-flags-impl ((store tree-lisp-store))
 457   nil)
 458
 459 (defmethod tree-model-get-n-columns-impl ((store tree-lisp-store))
 460   (length (tree-lisp-store-getters store)))
 461
 462 (defmethod tree-model-get-column-type-impl ((store tree-lisp-store) index)
 463   (aref (tree-lisp-store-types store) index))
 464
 465 (defun get-node-by-indices (root indices)
 466   (if indices
 467       (get-node-by-indices (tree-node-child-at root (first indices)) (rest indices))
 468       root))
 469
 470 (defun get-node-by-path (tree path)
 471   (let ((indices (tree-path-indices path)))
 472     (get-node-by-indices (tree-lisp-store-root tree) indices)))
 473
 474 (defun get-node-path (node)
 475   (iter (with z = nil)
 476         (for parent = (tree-node-parent node))
 477         (while parent)
 478         (for index = (position node (tree-node-children parent)))
 479         (push index z)
 480         (setf node parent)
 481         (finally (return z))))
 482
 483 (defun tree-lisp-store-get-next-id (tree)
 484   (incf (tree-lisp-store-next-id-value tree)))
 485
 486 (defun tree-lisp-store-add-id-map (tree id node)
 487   (setf (gethash id (tree-lisp-store-id-map tree)) node))
 488
 489 (defun get-assigned-id (tree node)
 490   (or (tree-node-id node)
 491       (let ((id (tree-lisp-store-get-next-id tree)))
 492         (tree-lisp-store-add-id-map tree id node)
 493         (setf (tree-node-id node) id)
 494         id)))
 495
 496 (defun get-node-by-id (tree id)
 497   (gethash id (tree-lisp-store-id-map tree)))
 498
 499 (defmethod tree-model-get-iter-impl ((store tree-lisp-store) iter path)
 500   (let* ((node (get-node-by-path store path))
 501          (node-idx (get-assigned-id store node)))
 502     (setf (tree-iter-stamp iter) 0
 503           (tree-iter-user-data iter) node-idx)))
 504
 505 (defun get-node-by-iter (tree iter)
 506   (get-node-by-id tree (tree-iter-user-data iter)))
 507
 508 (defmethod tree-model-get-path-impl ((store tree-lisp-store) iter)
 509   (let* ((path (make-instance 'tree-path))
 510          (node (get-node-by-iter store iter))
 511          (indices (get-node-path node)))
 512     (setf (tree-path-indices path) indices)
 513     path))
 514
 515 (defmethod tree-model-get-value-impl ((store tree-lisp-store) iter n)
 516   (let* ((node (get-node-by-iter store iter))
 517          (getter (aref (tree-lisp-store-getters store) n))
 518          (type (aref (tree-lisp-store-types store) n)))
 519     (values (funcall getter (tree-node-item node))
 520             type)))
 521
 522 (defmethod tree-model-iter-next-impl ((store tree-lisp-store) iter)
 523   (let* ((node (get-node-by-iter store iter))
 524          (parent (tree-node-parent node))
 525          (index (position node (tree-node-children parent))))
 526     (when (< (1+ index) (length (tree-node-children parent)))
 527       (setf (tree-iter-stamp iter)
 528             0
 529             (tree-iter-user-data iter)
 530             (get-assigned-id store (tree-node-child-at parent (1+ index))))
 531       t)))
 532
 533 (defmethod tree-model-iter-children-impl ((store tree-lisp-store) iter parent)
 534   (let* ((node (if parent
 535                    (get-node-by-iter store parent)
 536                    (tree-lisp-store-root store))))
 537     (when (plusp (length (tree-node-children node)))
 538       (setf (tree-iter-stamp iter)
 539             0
 540             (tree-iter-user-data iter)
 541             (get-assigned-id store (tree-node-child-at node 0)))
 542       t)))
 543
 544 (defmethod tree-model-iter-has-child-impl ((store tree-lisp-store) iter)
 545   (let ((node (get-node-by-iter store iter)))
 546     (plusp (length (tree-node-children node)))))
 547
 548 (defmethod tree-model-iter-n-children-impl ((store tree-lisp-store) iter)
 549   (let* ((node (if iter
 550                    (get-node-by-iter store iter)
 551                    (tree-lisp-store-root store))))
 552     (length (tree-node-children node))))
 553
 554 (defmethod tree-model-iter-nth-child-impl ((store tree-lisp-store) iter parent n)
 555   (let* ((node (if parent
 556                    (get-node-by-iter store parent)
 557                    (tree-lisp-store-root store)))
 558          (requested-node (tree-node-child-at node n)))
 559     (setf (tree-iter-stamp iter) 0
 560           (tree-iter-user-data iter) (get-assigned-id store requested-node))
 561     t))
 562
 563 (defmethod tree-model-iter-parent-impl ((store tree-lisp-store) iter child)
 564   (let ((node (get-node-by-iter store child)))
 565     (when (tree-node-parent node)
 566       (setf (tree-iter-stamp iter) 0
 567             (tree-iter-user-data iter) (get-assigned-id store (tree-node-parent node))))))
 568
 569 (defmethod tree-model-ref-node-impl ((store tree-lisp-store) iter)
 570   (declare (ignorable iter)))
 571
 572 (defmethod tree-model-unref-node-impl ((store tree-lisp-store) iter)
 573   (declare (ignorable iter)))
 574
 575 (defun notice-tree-node-insertion (tree node child index)
 576   (declare (ignore node index))
 577   (when tree
 578     (let* ((path (make-instance 'tree-path))
 579            (iter (make-tree-iter)))
 580       (setf (tree-path-indices path) (get-node-path child)
 581             (tree-iter-stamp iter) 0
 582             (tree-iter-user-data iter) (get-assigned-id tree child))
 583       (emit-signal tree "row-inserted" path iter)
 584       (when (plusp (length (tree-node-children child)))
 585         (emit-signal tree "row-has-child-toggled" path iter)))))
 586
 587 (defun notice-tree-node-removal (tree node child index)
 588   (declare (ignore child))
 589   (when tree
 590     (let ((path (make-instance 'tree-path)))
 591       (setf (tree-path-indices path) (nconc (get-node-path node) (list index)))
 592       (emit-signal tree "row-deleted" path))
 593     (when (zerop (length (tree-node-children node)))
 594       (let* ((path (make-instance 'tree-path))
 595              (iter (make-tree-iter)))
 596         (setf (tree-path-indices path) (get-node-path node)
 597               (tree-iter-stamp iter) 0
 598               (tree-iter-user-data iter) (get-assigned-id tree node))
 599         (emit-signal tree "row-has-child-toggled" path iter)))))