gtk/gtk.tree-model.lisp

   1 (in-package :gtk)
   2
   3 (define-vtable ("GtkTreeModel" c-gtk-tree-model)
   4   (:skip parent-instance g-type-interface)
   5   ;;some signals
   6   (:skip tree-model-row-changed :pointer)
   7   (:skip tree-model-row-inserted :pointer)
   8   (:skip tree-model-row-has-child-toggled :pointer)
   9   (:skip tree-model-row-deleted :pointer)
  10   (:skip tree-model-rows-reordered :pointer)
  11   ;;methods
  12   (tree-model-get-flags-impl tree-model-get-flags-cb tree-model-flags (tree-model g-object))
  13   (tree-model-get-n-columns-impl tree-model-get-n-columns-cb :int (tree-model g-object))
  14   (tree-model-get-column-type-impl tree-model-get-column-type-cb g-type-designator (tree-model g-object) (index :int))
  15   (tree-model-get-iter-impl tree-model-get-iter-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (path (g-boxed-ref tree-path)))
  16   (tree-model-get-path-impl tree-model-get-path-cb (g-boxed-ref tree-path) (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  17   (tree-model-get-value-impl tree-model-get-value-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)) (n :int) (value (:pointer g-value)))
  18   (tree-model-iter-next-impl tree-model-iter-next-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  19   (tree-model-iter-children-impl tree-model-iter-children-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)))
  20   (tree-model-iter-has-child-impl tree-model-iter-has-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  21   (tree-model-iter-n-children-impl tree-model-iter-n-children-cb :int (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  22   (tree-model-iter-nth-child-impl tree-model-iter-nth-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)) (n :int))
  23   (tree-model-iter-parent-impl tree-model-iter-parent-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (child (g-boxed-ref tree-iter)))
  24   (tree-model-ref-node-impl tree-model-ref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  25   (tree-model-unref-node-impl tree-model-unref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter))))
  26
  27 ; TODO: GtkTreeSortable
  28
  29 ; TODO: GtkTreeModelSort
  30
  31 ; TODO: GtkTreeModelFilter
  32
  33
  34 (defclass array-list-store (g-object tree-model)
  35   ((items :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-items)
  36    (columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-getters)
  37    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-types)))
  38
  39 (export 'array-list-store)
  40
  41 (register-object-type-implementation "LispArrayListStore" array-list-store "GObject" ("GtkTreeModel") nil)
  42
  43 (defun store-items-count (store)
  44   (length (store-items store)))
  45
  46 (export 'store-items-count)
  47
  48 (defun store-item (store index)
  49   (aref (store-items store) index))
  50
  51 (export 'store-item)
  52
  53 (defun store-add-item (store item)
  54   (vector-push-extend item (store-items store))
  55   (using* ((path (make-instance 'tree-path))
  56            (iter (make-instance 'tree-iter)))
  57     (setf (tree-path-indices path) (list (1- (length (store-items store)))))
  58     (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (1- (length (store-items store))))
  59     (emit-signal store "row-inserted" path iter)))
  60
  61 (export 'store-add-item)
  62
  63 (defun store-remove-item (store item &key (test 'eq))
  64   (with-slots (items) store
  65     (let ((index (position item items :test test)))
  66       (unless index (error "No such item~%~A~%in list-store~%~A" item store))
  67       (setf items (delete item items :test test))
  68       (using (path (make-instance 'tree-path))
  69              (setf (tree-path-indices path) (list index))
  70              (emit-signal store "row-deleted" path)))))
  71
  72 (export 'store-remove-item)
  73
  74 (defun store-add-column (store type getter)
  75   (vector-push-extend type (store-types store))
  76   (vector-push-extend getter (store-getters store))
  77   (1- (length (store-types store))))
  78
  79 (export 'store-add-column)
  80
  81 (defmethod tree-model-get-flags-impl ((model array-list-store))
  82   '(:list-only))
  83
  84 (defmethod tree-model-get-n-columns-impl ((model array-list-store))
  85   (length (store-types model)))
  86
  87 (defmethod tree-model-get-column-type-impl ((tree-model array-list-store) index)
  88   (aref (store-types tree-model) index))
  89
  90 (defmethod tree-model-get-iter-impl ((model array-list-store) iter path)
  91   (using* (iter path)
  92     (let ((indices (tree-path-indices path)))
  93       (when (and (= 1 (length indices))
  94                  (< (first indices) (length (store-items model))))
  95         (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (first indices))
  96         t))))
  97
  98 (defmethod tree-model-ref-node-impl ((model array-list-store) iter) (release iter))
  99 (defmethod tree-model-unref-node-impl ((model array-list-store) iter) (release iter))
 100
 101 (defmethod tree-model-iter-next-impl ((model array-list-store) iter)
 102   (using* (iter)
 103     (let ((n (tree-iter-user-data iter)))
 104       (when (< n (1- (length (store-items model))))
 105         (setf (tree-iter-user-data iter) (1+ n))
 106         t))))
 107
 108 (defmethod tree-model-iter-nth-child-impl ((model array-list-store) iter parent n)
 109   (using* (iter parent)
 110     (setf (tree-iter-stamp iter) 0
 111           (tree-iter-user-data iter) n)
 112     t))
 113
 114 (defmethod tree-model-iter-n-children-impl ((model array-list-store) iter)
 115   (if (null iter)
 116       (length (store-items model))
 117       0))
 118
 119 (defmethod tree-model-get-path-impl ((model array-list-store) iter)
 120   (using* (iter)
 121     (let ((path (make-instance 'tree-path)))
 122       (setf (tree-path-indices path) (list (tree-iter-user-data iter)))
 123       (disown-boxed-ref path)
 124       path)))
 125
 126 (defmethod tree-model-iter-has-child-impl ((model array-list-store) iter)
 127   (release iter)
 128   nil)
 129
 130 (defgeneric tree-model-item (model iter-or-path))
 131
 132 (defmethod tree-model-item ((model array-list-store) (iter tree-iter))
 133   (let ((n-row (tree-iter-user-data iter)))
 134     (aref (store-items model) n-row)))
 135
 136 (defmethod tree-model-item ((model array-list-store) (path tree-path))
 137   (let ((n-row (first (tree-path-indices path))))
 138     (aref (store-items model) n-row)))
 139
 140 (export 'tree-model-item)
 141
 142 (defmethod tree-model-get-value-impl ((model array-list-store) iter n value)
 143   (using (iter)
 144     (let ((n-row (tree-iter-user-data iter)))
 145       (set-g-value value
 146                    (funcall (aref (store-getters model) n)
 147                             (aref (store-items model) n-row))
 148                    (aref (store-types model) n)))))
 149
 150 (defcfun (tree-model-flags "gtk_tree_model_get_flags") tree-model-flags
 151   (tree-model g-object))
 152
 153 (export 'tree-modelg-flags)
 154
 155 (defcfun (tree-model-n-columns "gtk_tree_model_get_n_columns") :int
 156   (tree-model g-object))
 157
 158 (export 'tree-model-flags)
 159
 160 (defcfun (tree-model-column-type "gtk_tree_model_get_column_type") g-type-designator
 161   (tree-model g-object)
 162   (index :int))
 163
 164 (export 'tree-model-column-type)
 165
 166 (defcfun (tree-model-set-iter-to-path "gtk_tree_model_get_iter") :boolean
 167   (tree-model g-object)
 168   (iter (g-boxed-ref tree-iter))
 169   (path (g-boxed-ref tree-path)))
 170
 171 (defun tree-model-iter-by-path (tree-model tree-path)
 172   (let ((iter (make-instance 'tree-iter)))
 173     (if (tree-model-set-iter-to-path tree-model iter tree-path)
 174         iter
 175         (progn (release iter) nil))))
 176
 177 (export 'tree-model-iter-by-path)
 178
 179 (defcfun (tree-model-set-iter-from-string "gtk_tree_model_get_iter_from_string") :boolean
 180   (tree-model g-object)
 181   (iter (g-boxed-ref tree-iter))
 182   (path-string :string))
 183
 184 (defun tree-model-iter-from-string (tree-model path-string)
 185   (let ((iter (make-instance 'tree-iter)))
 186     (if (tree-model-set-iter-from-string tree-model iter path-string)
 187         iter
 188         (progn (release iter) nil))))
 189
 190 (export 'tree-model-iter-from-string)
 191
 192 (defcfun (tree-model-set-iter-to-first "gtk_tree_model_get_iter_first") :boolean
 193   (model g-object)
 194   (iter (g-boxed-ref tree-iter)))
 195
 196 (defun tree-model-iter-first (tree-model)
 197   (let ((iter (make-instance 'tree-iter)))
 198     (if (tree-model-set-iter-to-first tree-model iter)
 199         iter
 200         (progn (release iter) nil))))
 201
 202 (export 'tree-model-iter-first)
 203
 204 (defcfun (tree-model-path "gtk_tree_model_get_path") (g-boxed-ref tree-path :owner :lisp)
 205   (tree-model g-object)
 206   (iter (g-boxed-ref tree-iter)))
 207
 208 (export 'tree-model-path)
 209
 210 (defcfun gtk-tree-model-get-value :void
 211   (model g-object)
 212   (iter (g-boxed-ref tree-iter))
 213   (column :int)
 214   (value (:pointer g-value)))
 215
 216 (defun tree-model-value (tree-model iter column)
 217   (with-foreign-object (v 'g-value)
 218     (g-value-zero v)
 219     (gtk-tree-model-get-value tree-model iter column v)
 220     (prog1 (parse-g-value v)
 221       (g-value-unset v))))
 222
 223 (export 'tree-model-value)
 224
 225 (defcfun (tree-model-iter-next "gtk_tree_model_iter_next") :boolean
 226   (tree-model g-object)
 227   (iter (g-boxed-ref tree-iter)))
 228
 229 (export 'tree-model-iter-next)
 230
 231 (defcfun gtk-tree-model-iter-children :boolean
 232   (tree-model g-object)
 233   (iter (g-boxed-ref tree-iter))
 234   (parent (g-boxed-ref tree-iter)))
 235
 236 (defun tree-model-iter-first-child (tree-model parent)
 237   (let ((iter (make-instance 'tree-iter)))
 238     (if (gtk-tree-model-iter-children tree-model iter parent)
 239         iter
 240         (progn (release iter) nil))))
 241
 242 (export 'tree-model-iter-first-child)
 243
 244 (defcfun (tree-model-iter-has-child "gtk_tree_model_iter_has_child") :boolean
 245   (tree-model g-object)
 246   (iter (g-boxed-ref tree-iter)))
 247
 248 (export 'tree-model-iter-has-child)
 249
 250 (defcfun (tree-model-iter-n-children "gtk_tree_model_iter_n_children") :int
 251   (tree-model g-object)
 252   (iter (g-boxed-ref tree-iter)))
 253
 254 (export 'tree-model-iter-n-children)
 255
 256 (defcfun gtk-tree-model-iter-nth-child :boolean
 257   (tree-model g-object)
 258   (iter (g-boxed-ref tree-iter))
 259   (parent (g-boxed-ref tree-iter))
 260   (n :int))
 261
 262 (defun tree-model-iter-nth-child (tree-model parent n)
 263   (let ((iter (make-instance 'tree-iter)))
 264     (if (gtk-tree-model-iter-nth-child tree-model iter parent n)
 265         iter
 266         (progn (release iter) n))))
 267
 268 (export 'tree-model-iter-nth-child)
 269
 270 (defcfun gtk-tree-model-iter-parent :boolean
 271   (tree-model g-object)
 272   (iter (g-boxed-ref tree-iter))
 273   (parent (g-boxed-ref tree-iter)))
 274
 275 (defun tree-model-iter-parent (tree-model iter)
 276   (let ((parent (make-instance 'tree-iter)))
 277     (if (gtk-tree-model-iter-parent tree-model iter parent)
 278         parent
 279         (progn (release parent) nil))))
 280
 281 (export 'tree-model-iter-parent)
 282
 283 (defcfun (tree-model-iter-to-string "gtk_tree_model_get_string_from_iter") (g-string :free-from-foreign t)
 284   (tree-model g-object)
 285   (iter (g-boxed-ref tree-iter)))
 286
 287 (export 'tree-model-iter-to-string)
 288
 289 (defcfun (tree-model-ref-node "gtk_tree_model_ref_node") :void
 290   (tree-model g-object)
 291   (iter (g-boxed-ref tree-iter)))
 292
 293 (export 'tree-model-ref-node)
 294
 295 (defcfun (tree-model-unref-node "gtk_tree_model_unref_node") :void
 296   (tree-model g-object)
 297   (iter (g-boxed-ref tree-iter)))
 298
 299 (export 'tree-model-unref-node)
 300
 301 (defcallback gtk-tree-model-foreach-cb :boolean ((model g-object) (path (g-boxed-ref tree-path)) (iter (g-boxed-ref tree-iter)) (data :pointer))
 302   (let ((fn (get-stable-pointer-value data)))
 303     (restart-case
 304         (funcall fn model path iter)
 305       (stop-tree-model-iteration () t)
 306       (skip-tree-model-current () nil))))
 307
 308 (defcfun gtk-tree-model-foreach :void
 309   (model g-object)
 310   (func :pointer)
 311   (data :pointer))
 312
 313 (defun do-tree-model (model fn)
 314   (with-stable-pointer (ptr fn)
 315     (gtk-tree-model-foreach model (callback gtk-tree-model-foreach-cb) ptr)))
 316
 317 (export 'do-tree-model)
 318