gtk/gtk.tree-model.lisp

   1 (in-package :gtk)
   2
   3 (define-vtable ("GtkTreeModel" c-gtk-tree-model)
   4   (:skip parent-instance g-type-interface)
   5   ;;some signals
   6   (:skip tree-model-row-changed :pointer)
   7   (:skip tree-model-row-inserted :pointer)
   8   (:skip tree-model-row-has-child-toggled :pointer)
   9   (:skip tree-model-row-deleted :pointer)
  10   (:skip tree-model-rows-reordered :pointer)
  11   ;;methods
  12   (tree-model-get-flags-impl tree-model-get-flags-cb tree-model-flags (tree-model g-object))
  13   (tree-model-get-n-columns-impl tree-model-get-n-columns-cb :int (tree-model g-object))
  14   (tree-model-get-column-type-impl tree-model-get-column-type-cb g-type (tree-model g-object) (index :int))
  15   (tree-model-get-iter-impl tree-model-get-iter-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (path (g-boxed-ref tree-path)))
  16   (tree-model-get-path-impl tree-model-get-path-cb (g-boxed-ref tree-path) (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  17   (tree-model-get-value-impl tree-model-get-value-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)) (n :int) (value (:pointer g-value)))
  18   (tree-model-iter-next-impl tree-model-iter-next-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  19   (tree-model-iter-children-impl tree-model-iter-children-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)))
  20   (tree-model-iter-has-child-impl tree-model-iter-has-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  21   (tree-model-iter-n-children-impl tree-model-iter-n-children-cb :int (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  22   (tree-model-iter-nth-child-impl tree-model-iter-nth-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)) (n :int))
  23   (tree-model-iter-parent-impl tree-model-iter-parent-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (child (g-boxed-ref tree-iter)))
  24   (tree-model-ref-node-impl tree-model-ref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  25   (tree-model-unref-node-impl tree-model-unref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter))))
  26
  27 ; TODO: GtkTreeSortable
  28
  29 ; TODO: GtkTreeModelSort
  30
  31 ; TODO: GtkTreeModelFilter
  32
  33 (defclass array-list-store (g-object tree-model)
  34   ((items :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-items)
  35    (columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-getters)
  36    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-types)))
  37
  38 (export 'array-list-store)
  39
  40 (register-object-type-implementation "LispArrayListStore" array-list-store "GObject" ("GtkTreeModel") nil)
  41
  42 (defun store-add-item (store item)
  43   (vector-push-extend item (store-items store))
  44   (using* ((path (make-instance 'tree-path))
  45                    (iter (make-instance 'tree-iter)))
  46     (setf (tree-path-indices path) (list (1- (length (store-items store)))))
  47     (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (1- (length (store-items store))))
  48     (emit-signal store "row-inserted" path iter)))
  49
  50 (export 'store-add-item)
  51
  52 (defun store-add-column (store type getter)
  53   (vector-push-extend (ensure-g-type type) (store-types store))
  54   (vector-push-extend getter (store-getters store))
  55   (1- (length (store-types store))))
  56
  57 (export 'store-add-column)
  58
  59 (defmethod tree-model-get-flags-impl ((model array-list-store))
  60   '(:list-only))
  61
  62 (defmethod tree-model-get-n-columns-impl ((model array-list-store))
  63   (length (store-types model)))
  64
  65 (defmethod tree-model-get-column-type-impl ((tree-model array-list-store) index)
  66   (aref (store-types tree-model) index))
  67
  68 (defmethod tree-model-get-iter-impl ((model array-list-store) iter path)
  69   (using* (iter path)
  70     (let ((indices (tree-path-indices path)))
  71       (when (and (= 1 (length indices))
  72                  (< (first indices) (length (store-items model))))
  73         (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (first indices))
  74         t))))
  75
  76 (defmethod tree-model-ref-node-impl ((model array-list-store) iter) (release iter))
  77 (defmethod tree-model-unref-node-impl ((model array-list-store) iter) (release iter))
  78
  79 (defmethod tree-model-iter-next-impl ((model array-list-store) iter)
  80   (using* (iter)
  81     (let ((n (tree-iter-user-data iter)))
  82       (when (< n (1- (length (store-items model))))
  83         (setf (tree-iter-user-data iter) (1+ n))
  84         t))))
  85
  86 (defmethod tree-model-iter-nth-child-impl ((model array-list-store) iter parent n)
  87   (using* (iter parent)
  88     (setf (tree-iter-stamp iter) 0
  89           (tree-iter-user-data iter) n)
  90     t))
  91
  92 (defmethod tree-model-iter-n-children-impl ((model array-list-store) iter)
  93   (if (null iter)
  94       (length (store-items model))
  95       0))
  96
  97 (defmethod tree-model-get-path-impl ((model array-list-store) iter)
  98   (using* (iter)
  99     (anaphora:aprog1 (make-instance 'tree-path)
 100       (setf (tree-path-indices anaphora:it) (list (tree-iter-user-data iter)))
 101       (disown-boxed-ref anaphora:it))))
 102
 103 (defmethod tree-model-iter-has-child-impl ((model array-list-store) iter)
 104   (release iter)
 105   nil)
 106
 107 (defgeneric tree-model-item (model iter-or-path))
 108
 109 (defmethod tree-model-item ((model array-list-store) (iter tree-iter))
 110   (let ((n-row (tree-iter-user-data iter)))
 111     (aref (store-items model) n-row)))
 112
 113 (defmethod tree-model-item ((model array-list-store) (path tree-path))
 114   (let ((n-row (first (tree-path-indices path))))
 115     (aref (store-items model) n-row)))
 116
 117 (export 'tree-model-item)
 118
 119 (defmethod tree-model-get-value-impl ((model array-list-store) iter n value)
 120   (using (iter)
 121     (let ((n-row (tree-iter-user-data iter)))
 122       (set-g-value value
 123                    (funcall (aref (store-getters model) n)
 124                             (aref (store-items model) n-row))
 125                    (aref (store-types model) n)))))
 126
 127 (defstruct tree-node
 128   store
 129   (columns-values (make-array 0 :adjustable t :fill-pointer t) :type vector)
 130   (children (make-array 0 :adjustable t :fill-pointer t) :type (vector tree-node)))
 131
 132 (export 'tree-node)
 133
 134 (defclass tree-store (g-object tree-model)
 135   ((root :reader tree-store-root)
 136    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader tree-store-types)
 137    (columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader tree-store-getters)))
 138
 139 (export 'tree-store)
 140
 141 (register-object-type-implementation "LispTreeStore" tree-store "GObject" ("GtkTreeModel") nil)
 142
 143 (defcfun (tree-model-flags "gtk_tree_model_get_flags") tree-model-flags
 144   (tree-model g-object))
 145
 146 (export 'tree-modelg-flags)
 147
 148 (defcfun (tree-model-n-columns "gtk_tree_model_get_n_columns") :int
 149   (tree-model g-object))
 150
 151 (export 'tree-model-flags)
 152
 153 (defcfun (tree-model-column-type "gtk_tree_model_get_column_type") g-type
 154   (tree-model g-object)
 155   (index :int))
 156
 157 (export 'tree-model-column-type)
 158
 159 (defcfun (tree-model-set-iter-to-path "gtk_tree_model_get_iter") :boolean
 160   (tree-model g-object)
 161   (iter (g-boxed-ref tree-iter))
 162   (path (g-boxed-ref tree-path)))
 163
 164 (defun tree-model-iter-by-path (tree-model tree-path)
 165   (let ((iter (make-instance 'tree-iter)))
 166     (if (tree-model-set-iter-to-path tree-model iter tree-path)
 167         iter
 168         (progn (release iter) nil))))
 169
 170 (export 'tree-model-iter-by-path)
 171
 172 (defcfun (tree-model-set-iter-from-string "gtk_tree_model_get_iter_from_string") :boolean
 173   (tree-model g-object)
 174   (iter (g-boxed-ref tree-iter))
 175   (path-string :string))
 176
 177 (defun tree-model-iter-from-string (tree-model path-string)
 178   (let ((iter (make-instance 'tree-iter)))
 179     (if (tree-model-set-iter-from-string tree-model iter path-string)
 180         iter
 181         (progn (release iter) nil))))
 182
 183 (export 'tree-model-iter-from-string)
 184
 185 (defcfun (tree-model-set-iter-to-first "gtk_tree_model_get_iter_first") :boolean
 186   (model g-object)
 187   (iter (g-boxed-ref tree-iter)))
 188
 189 (defun tree-model-iter-first (tree-model)
 190   (let ((iter (make-instance 'tree-iter)))
 191     (if (tree-model-set-iter-to-first tree-model iter)
 192         iter
 193         (progn (release iter) nil))))
 194
 195 (export 'tree-model-iter-first)
 196
 197 (defcfun (tree-model-path "gtk_tree_model_get_path") (g-boxed-ref tree-path :owner :lisp)
 198   (tree-model g-object)
 199   (iter (g-boxed-ref tree-iter)))
 200
 201 (export 'tree-model-path)
 202
 203 (defcfun gtk-tree-model-get-value :void
 204   (model g-object)
 205   (iter (g-boxed-ref tree-iter))
 206   (column :int)
 207   (value (:pointer g-value)))
 208
 209 (defun tree-model-value (tree-model iter column)
 210   (with-foreign-object (v 'g-value)
 211     (g-value-zero v)
 212     (gtk-tree-model-get-value tree-model iter column v)
 213     (prog1 (parse-gvalue v)
 214       (g-value-unset v))))
 215
 216 (export 'tree-model-value)
 217
 218 (defcfun (tree-model-iter-next "gtk_tree_model_iter_next") :boolean
 219   (tree-model g-object)
 220   (iter (g-boxed-ref tree-iter)))
 221
 222 (export 'tree-model-iter-next)
 223
 224 (defcfun gtk-tree-model-iter-children :boolean
 225   (tree-model g-object)
 226   (iter (g-boxed-ref tree-iter))
 227   (parent (g-boxed-ref tree-iter)))
 228
 229 (defun tree-model-iter-first-child (tree-model parent)
 230   (let ((iter (make-instance 'tree-iter)))
 231     (if (gtk-tree-model-iter-children tree-model iter parent)
 232         iter
 233         (progn (release iter) nil))))
 234
 235 (export 'tree-model-iter-first-child)
 236
 237 (defcfun (tree-model-iter-has-child "gtk_tree_model_iter_has_child") :boolean
 238   (tree-model g-object)
 239   (iter (g-boxed-ref tree-iter)))
 240
 241 (export 'tree-model-iter-has-child)
 242
 243 (defcfun (tree-model-iter-n-children "gtk_tree_model_iter_n_children") :int
 244   (tree-model g-object)
 245   (iter (g-boxed-ref tree-iter)))
 246
 247 (export 'tree-model-iter-n-children)
 248
 249 (defcfun gtk-tree-model-iter-nth-child :boolean
 250   (tree-model g-object)
 251   (iter (g-boxed-ref tree-iter))
 252   (parent (g-boxed-ref tree-iter))
 253   (n :int))
 254
 255 (defun tree-model-iter-nth-child (tree-model parent n)
 256   (let ((iter (make-instance 'tree-iter)))
 257     (if (gtk-tree-model-iter-nth-child tree-model iter parent n)
 258         iter
 259         (progn (release iter) n))))
 260
 261 (export 'tree-model-iter-nth-child)
 262
 263 (defcfun gtk-tree-model-iter-parent :boolean
 264   (tree-model g-object)
 265   (iter (g-boxed-ref tree-iter))
 266   (parent (g-boxed-ref tree-iter)))
 267
 268 (defun tree-model-iter-parent (tree-model iter)
 269   (let ((parent (make-instance 'tree-iter)))
 270     (if (gtk-tree-model-iter-parent tree-model iter parent)
 271         parent
 272         (progn (release parent) nil))))
 273
 274 (export 'tree-model-iter-parent)
 275
 276 (defcfun (tree-model-iter-to-string "gtk_tree_model_get_string_from_iter") (g-string :free-from-foreign t)
 277   (tree-model g-object)
 278   (iter (g-boxed-ref tree-iter)))
 279
 280 (export 'tree-model-iter-to-string)
 281
 282 (defcfun (tree-model-ref-node "gtk_tree_model_ref_node") :void
 283   (tree-model g-object)
 284   (iter (g-boxed-ref tree-iter)))
 285
 286 (export 'tree-model-ref-node)
 287
 288 (defcfun (tree-model-unref-node "gtk_tree_model_unref_node") :void
 289   (tree-model g-object)
 290   (iter (g-boxed-ref tree-iter)))
 291
 292 (export 'tree-model-unref-node)
 293
 294 (defcallback gtk-tree-model-foreach-cb :boolean ((model g-object) (path (g-boxed-ref tree-path)) (iter (g-boxed-ref tree-iter)) (data :pointer))
 295   (let ((fn (get-stable-pointer-value data)))
 296     (restart-case
 297         (funcall fn model path iter)
 298       (stop-tree-model-iteration () t)
 299       (skip-tree-model-current () nil))))
 300
 301 (defcfun gtk-tree-model-foreach :void
 302   (model g-object)
 303   (func :pointer)
 304   (data :pointer))
 305
 306 (defun do-tree-model (model fn)
 307   (with-stable-pointer (ptr fn)
 308     (gtk-tree-model-foreach model (callback gtk-tree-model-foreach-cb) ptr)))
 309
 310 (export 'do-tree-model)
 311