gtk/gtk.tree-model.lisp

   1 (in-package :gtk)
   2
   3 (define-vtable ("GtkTreeModel" c-gtk-tree-model)
   4   (:skip parent-instance g-type-interface)
   5   ;;some signals
   6   (:skip tree-model-row-changed :pointer)
   7   (:skip tree-model-row-inserted :pointer)
   8   (:skip tree-model-row-has-child-toggled :pointer)
   9   (:skip tree-model-row-deleted :pointer)
  10   (:skip tree-model-rows-reordered :pointer)
  11   ;;methods
  12   (tree-model-get-flags-impl tree-model-get-flags-cb tree-model-flags (tree-model g-object))
  13   (tree-model-get-n-columns-impl tree-model-get-n-columns-cb :int (tree-model g-object))
  14   (tree-model-get-column-type-impl tree-model-get-column-type-cb g-type (tree-model g-object) (index :int))
  15   (tree-model-get-iter-impl tree-model-get-iter-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (path (g-boxed-ref tree-path)))
  16   (tree-model-get-path-impl tree-model-get-path-cb (g-boxed-ref tree-path) (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  17   (tree-model-get-value-impl tree-model-get-value-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)) (n :int) (value (:pointer g-value)))
  18   (tree-model-iter-next-impl tree-model-iter-next-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  19   (tree-model-iter-children-impl tree-model-iter-children-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)))
  20   (tree-model-iter-has-child-impl tree-model-iter-has-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  21   (tree-model-iter-n-children-impl tree-model-iter-n-children-cb :int (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  22   (tree-model-iter-nth-child-impl tree-model-iter-nth-child-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (parent (g-boxed-ref tree-iter)) (n :int))
  23   (tree-model-iter-parent-impl tree-model-iter-parent-cb :boolean (tree-model g-object) (iter (g-boxed-ref tree-iter)) (child (g-boxed-ref tree-iter)))
  24   (tree-model-ref-node-impl tree-model-ref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter)))
  25   (tree-model-unref-node-impl tree-model-unref-node-cb :void (tree-model g-object) (iter (g-boxed-ref tree-iter))))
  26
  27 ; TODO: GtkTreeSortable
  28
  29 ; TODO: GtkTreeModelSort
  30
  31 ; TODO: GtkTreeModelFilter
  32
  33
  34 (defclass array-list-store (g-object tree-model)
  35   ((items :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-items)
  36    (columns-getters :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-getters)
  37    (columns-types :initform (make-array 0 :adjustable t :fill-pointer t) :reader store-types)))
  38
  39 (export 'array-list-store)
  40
  41 (register-object-type-implementation "LispArrayListStore" array-list-store "GObject" ("GtkTreeModel") nil)
  42
  43 (defun store-add-item (store item)
  44   (vector-push-extend item (store-items store))
  45   (using* ((path (make-instance 'tree-path))
  46                    (iter (make-instance 'tree-iter)))
  47     (setf (tree-path-indices path) (list (1- (length (store-items store)))))
  48     (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (1- (length (store-items store))))
  49     (emit-signal store "row-inserted" path iter)))
  50
  51 (export 'store-add-item)
  52
  53 (defun store-add-column (store type getter)
  54   (vector-push-extend (ensure-g-type type) (store-types store))
  55   (vector-push-extend getter (store-getters store))
  56   (1- (length (store-types store))))
  57
  58 (export 'store-add-column)
  59
  60 (defmethod tree-model-get-flags-impl ((model array-list-store))
  61   '(:list-only))
  62
  63 (defmethod tree-model-get-n-columns-impl ((model array-list-store))
  64   (length (store-types model)))
  65
  66 (defmethod tree-model-get-column-type-impl ((tree-model array-list-store) index)
  67   (aref (store-types tree-model) index))
  68
  69 (defmethod tree-model-get-iter-impl ((model array-list-store) iter path)
  70   (using* (iter path)
  71     (let ((indices (tree-path-indices path)))
  72       (when (and (= 1 (length indices))
  73                  (< (first indices) (length (store-items model))))
  74         (setf (tree-iter-stamp iter) 0 (tree-iter-user-data iter) (first indices))
  75         t))))
  76
  77 (defmethod tree-model-ref-node-impl ((model array-list-store) iter) (release iter))
  78 (defmethod tree-model-unref-node-impl ((model array-list-store) iter) (release iter))
  79
  80 (defmethod tree-model-iter-next-impl ((model array-list-store) iter)
  81   (using* (iter)
  82     (let ((n (tree-iter-user-data iter)))
  83       (when (< n (1- (length (store-items model))))
  84         (setf (tree-iter-user-data iter) (1+ n))
  85         t))))
  86
  87 (defmethod tree-model-iter-nth-child-impl ((model array-list-store) iter parent n)
  88   (using* (iter parent)
  89     (setf (tree-iter-stamp iter) 0
  90           (tree-iter-user-data iter) n)
  91     t))
  92
  93 (defmethod tree-model-iter-n-children-impl ((model array-list-store) iter)
  94   (if (null iter)
  95       (length (store-items model))
  96       0))
  97
  98 (defmethod tree-model-get-path-impl ((model array-list-store) iter)
  99   (using* (iter)
 100     (anaphora:aprog1 (make-instance 'tree-path)
 101       (setf (tree-path-indices anaphora:it) (list (tree-iter-user-data iter)))
 102       (disown-boxed-ref anaphora:it))))
 103
 104 (defmethod tree-model-iter-has-child-impl ((model array-list-store) iter)
 105   (release iter)
 106   nil)
 107
 108 (defgeneric tree-model-item (model iter-or-path))
 109
 110 (defmethod tree-model-item ((model array-list-store) (iter tree-iter))
 111   (let ((n-row (tree-iter-user-data iter)))
 112     (aref (store-items model) n-row)))
 113
 114 (defmethod tree-model-item ((model array-list-store) (path tree-path))
 115   (let ((n-row (first (tree-path-indices path))))
 116     (aref (store-items model) n-row)))
 117
 118 (export 'tree-model-item)
 119
 120 (defmethod tree-model-get-value-impl ((model array-list-store) iter n value)
 121   (using (iter)
 122     (let ((n-row (tree-iter-user-data iter)))
 123       (set-g-value value
 124                    (funcall (aref (store-getters model) n)
 125                             (aref (store-items model) n-row))
 126                    (aref (store-types model) n)))))
 127
 128 (defcfun (tree-model-flags "gtk_tree_model_get_flags") tree-model-flags
 129   (tree-model g-object))
 130
 131 (export 'tree-modelg-flags)
 132
 133 (defcfun (tree-model-n-columns "gtk_tree_model_get_n_columns") :int
 134   (tree-model g-object))
 135
 136 (export 'tree-model-flags)
 137
 138 (defcfun (tree-model-column-type "gtk_tree_model_get_column_type") g-type
 139   (tree-model g-object)
 140   (index :int))
 141
 142 (export 'tree-model-column-type)
 143
 144 (defcfun (tree-model-set-iter-to-path "gtk_tree_model_get_iter") :boolean
 145   (tree-model g-object)
 146   (iter (g-boxed-ref tree-iter))
 147   (path (g-boxed-ref tree-path)))
 148
 149 (defun tree-model-iter-by-path (tree-model tree-path)
 150   (let ((iter (make-instance 'tree-iter)))
 151     (if (tree-model-set-iter-to-path tree-model iter tree-path)
 152         iter
 153         (progn (release iter) nil))))
 154
 155 (export 'tree-model-iter-by-path)
 156
 157 (defcfun (tree-model-set-iter-from-string "gtk_tree_model_get_iter_from_string") :boolean
 158   (tree-model g-object)
 159   (iter (g-boxed-ref tree-iter))
 160   (path-string :string))
 161
 162 (defun tree-model-iter-from-string (tree-model path-string)
 163   (let ((iter (make-instance 'tree-iter)))
 164     (if (tree-model-set-iter-from-string tree-model iter path-string)
 165         iter
 166         (progn (release iter) nil))))
 167
 168 (export 'tree-model-iter-from-string)
 169
 170 (defcfun (tree-model-set-iter-to-first "gtk_tree_model_get_iter_first") :boolean
 171   (model g-object)
 172   (iter (g-boxed-ref tree-iter)))
 173
 174 (defun tree-model-iter-first (tree-model)
 175   (let ((iter (make-instance 'tree-iter)))
 176     (if (tree-model-set-iter-to-first tree-model iter)
 177         iter
 178         (progn (release iter) nil))))
 179
 180 (export 'tree-model-iter-first)
 181
 182 (defcfun (tree-model-path "gtk_tree_model_get_path") (g-boxed-ref tree-path :owner :lisp)
 183   (tree-model g-object)
 184   (iter (g-boxed-ref tree-iter)))
 185
 186 (export 'tree-model-path)
 187
 188 (defcfun gtk-tree-model-get-value :void
 189   (model g-object)
 190   (iter (g-boxed-ref tree-iter))
 191   (column :int)
 192   (value (:pointer g-value)))
 193
 194 (defun tree-model-value (tree-model iter column)
 195   (with-foreign-object (v 'g-value)
 196     (g-value-zero v)
 197     (gtk-tree-model-get-value tree-model iter column v)
 198     (prog1 (parse-gvalue v)
 199       (g-value-unset v))))
 200
 201 (export 'tree-model-value)
 202
 203 (defcfun (tree-model-iter-next "gtk_tree_model_iter_next") :boolean
 204   (tree-model g-object)
 205   (iter (g-boxed-ref tree-iter)))
 206
 207 (export 'tree-model-iter-next)
 208
 209 (defcfun gtk-tree-model-iter-children :boolean
 210   (tree-model g-object)
 211   (iter (g-boxed-ref tree-iter))
 212   (parent (g-boxed-ref tree-iter)))
 213
 214 (defun tree-model-iter-first-child (tree-model parent)
 215   (let ((iter (make-instance 'tree-iter)))
 216     (if (gtk-tree-model-iter-children tree-model iter parent)
 217         iter
 218         (progn (release iter) nil))))
 219
 220 (export 'tree-model-iter-first-child)
 221
 222 (defcfun (tree-model-iter-has-child "gtk_tree_model_iter_has_child") :boolean
 223   (tree-model g-object)
 224   (iter (g-boxed-ref tree-iter)))
 225
 226 (export 'tree-model-iter-has-child)
 227
 228 (defcfun (tree-model-iter-n-children "gtk_tree_model_iter_n_children") :int
 229   (tree-model g-object)
 230   (iter (g-boxed-ref tree-iter)))
 231
 232 (export 'tree-model-iter-n-children)
 233
 234 (defcfun gtk-tree-model-iter-nth-child :boolean
 235   (tree-model g-object)
 236   (iter (g-boxed-ref tree-iter))
 237   (parent (g-boxed-ref tree-iter))
 238   (n :int))
 239
 240 (defun tree-model-iter-nth-child (tree-model parent n)
 241   (let ((iter (make-instance 'tree-iter)))
 242     (if (gtk-tree-model-iter-nth-child tree-model iter parent n)
 243         iter
 244         (progn (release iter) n))))
 245
 246 (export 'tree-model-iter-nth-child)
 247
 248 (defcfun gtk-tree-model-iter-parent :boolean
 249   (tree-model g-object)
 250   (iter (g-boxed-ref tree-iter))
 251   (parent (g-boxed-ref tree-iter)))
 252
 253 (defun tree-model-iter-parent (tree-model iter)
 254   (let ((parent (make-instance 'tree-iter)))
 255     (if (gtk-tree-model-iter-parent tree-model iter parent)
 256         parent
 257         (progn (release parent) nil))))
 258
 259 (export 'tree-model-iter-parent)
 260
 261 (defcfun (tree-model-iter-to-string "gtk_tree_model_get_string_from_iter") (g-string :free-from-foreign t)
 262   (tree-model g-object)
 263   (iter (g-boxed-ref tree-iter)))
 264
 265 (export 'tree-model-iter-to-string)
 266
 267 (defcfun (tree-model-ref-node "gtk_tree_model_ref_node") :void
 268   (tree-model g-object)
 269   (iter (g-boxed-ref tree-iter)))
 270
 271 (export 'tree-model-ref-node)
 272
 273 (defcfun (tree-model-unref-node "gtk_tree_model_unref_node") :void
 274   (tree-model g-object)
 275   (iter (g-boxed-ref tree-iter)))
 276
 277 (export 'tree-model-unref-node)
 278
 279 (defcallback gtk-tree-model-foreach-cb :boolean ((model g-object) (path (g-boxed-ref tree-path)) (iter (g-boxed-ref tree-iter)) (data :pointer))
 280   (let ((fn (get-stable-pointer-value data)))
 281     (restart-case
 282         (funcall fn model path iter)
 283       (stop-tree-model-iteration () t)
 284       (skip-tree-model-current () nil))))
 285
 286 (defcfun gtk-tree-model-foreach :void
 287   (model g-object)
 288   (func :pointer)
 289   (data :pointer))
 290
 291 (defun do-tree-model (model fn)
 292   (with-stable-pointer (ptr fn)
 293     (gtk-tree-model-foreach model (callback gtk-tree-model-foreach-cb) ptr)))
 294
 295 (export 'do-tree-model)
 296