src/assembly/x86/alloc.lisp

   1 ;;;; allocating simple objects
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!VM")
  13 \f
  14 ;;;; Signed and unsigned bignums from word-sized integers. Argument
  15 ;;;; and return in the same register. No VOPs, as these are only used
  16 ;;;; as out-of-line versions: MOVE-FROM-[UN]SIGNED VOPs handle the
  17 ;;;; fixnum cases inline.
  18
  19 ;;; #+SB-ASSEMBLING as we don't need VOPS, just the asm routines:
  20 ;;; these are out-of-line versions called by VOPs.
  21
  22 #+sb-assembling
  23 (macrolet ((def (reg)
  24              (let ((tn (symbolicate reg "-TN")))
  25                `(define-assembly-routine (,(symbolicate "ALLOC-SIGNED-BIGNUM-IN-" reg)) ()
  26                   (inst push ,tn)
  27                   (with-fixed-allocation (,tn bignum-widetag (+ bignum-digits-offset 1))
  28                     (popw ,tn bignum-digits-offset other-pointer-lowtag))
  29                   (inst ret)))))
  30   (def eax)
  31   (def ebx)
  32   (def ecx)
  33   (def edx)
  34   (def edi)
  35   (def esi))
  36
  37 #+sb-assembling
  38 (macrolet ((def (reg)
  39              (let ((tn (symbolicate reg "-TN")))
  40                `(define-assembly-routine (,(symbolicate "ALLOC-UNSIGNED-BIGNUM-IN-" reg)) ()
  41                   (inst push ,tn)
  42                   ;; Sign flag is set by the caller! Note: The inline
  43                   ;; version always allocates space for two words, but
  44                   ;; here we minimize garbage.
  45                   (inst jmp :ns one-word-bignum)
  46                   ;; Two word bignum
  47                   (with-fixed-allocation (,tn bignum-widetag (+ bignum-digits-offset 2))
  48                     (popw ,tn bignum-digits-offset other-pointer-lowtag))
  49                   (inst ret)
  50                   ONE-WORD-BIGNUM
  51                   (with-fixed-allocation (,tn bignum-widetag (+ bignum-digits-offset 1))
  52                     (popw ,tn bignum-digits-offset other-pointer-lowtag))
  53                   (inst ret)))))
  54   (def eax)
  55   (def ebx)
  56   (def ecx)
  57   (def edx)
  58   (def edi)
  59   (def esi))
  60
  61 ;;; FIXME: This is dead, right? Can it go?
  62 #+sb-assembling
  63 (defun frob-allocation-assembly-routine (obj lowtag arg-tn)
  64   `(define-assembly-routine (,(intern (format nil "ALLOCATE-~A-TO-~A" obj arg-tn)))
  65      ((:temp ,arg-tn descriptor-reg ,(intern (format nil "~A-OFFSET" arg-tn))))
  66      (pseudo-atomic
  67       (allocation ,arg-tn (pad-data-block ,(intern (format nil "~A-SIZE" obj))))
  68       (inst lea ,arg-tn (make-ea :byte :base ,arg-tn :disp ,lowtag)))
  69      (inst ret)))
  70
  71 #+sb-assembling
  72 (macrolet ((frob-cons-routines ()
  73              (let ((routines nil))
  74                (dolist (tn-offset *dword-regs*
  75                         `(progn ,@routines))
  76                  (push (frob-allocation-assembly-routine 'cons
  77                                                          list-pointer-lowtag
  78                                                          (intern (aref *dword-register-names* tn-offset)))
  79                        routines)))))
  80   (frob-cons-routines))
  81
  82 #+sb-assembling
  83 (macrolet ((def (reg)
  84              (let* ((name (intern (format nil "ALLOCATE-TLS-INDEX-IN-~A" reg)))
  85                     (target-offset (intern (format nil "~A-OFFSET" reg)))
  86                     (other-offset (if (eql 'eax reg)
  87                                       'ecx-offset
  88                                       'eax-offset)))
  89                ;; Symbol starts in TARGET, where the TLS-INDEX ends up in.
  90                `(define-assembly-routine ,name
  91                     ((:temp other descriptor-reg ,other-offset)
  92                      (:temp target descriptor-reg ,target-offset))
  93                   (let ((get-tls-index-lock (gen-label))
  94                         (release-tls-index-lock (gen-label)))
  95                     (pseudo-atomic
  96                      ;; Save OTHER & push the symbol. EAX is either one of the two.
  97                      (inst push other)
  98                      (inst push target)
  99                      (emit-label get-tls-index-lock)
 100                      (inst mov target 1)
 101                      (inst xor eax-tn eax-tn)
 102                      (inst lock)
 103                      (inst cmpxchg (make-ea-for-symbol-value *tls-index-lock*) target)
 104                      (inst jmp :ne get-tls-index-lock)
 105                      ;; The symbol is now in OTHER.
 106                      (inst pop other)
 107                      ;; Now with the lock held, see if the symbol's tls index has been
 108                      ;; set in the meantime.
 109                      (loadw target other symbol-tls-index-slot other-pointer-lowtag)
 110                      (inst or target target)
 111                      (inst jmp :ne release-tls-index-lock)
 112                      ;; Allocate a new tls-index.
 113                      (load-symbol-value target *free-tls-index*)
 114                      (inst add (make-ea-for-symbol-value *free-tls-index*) 4) ; fixnum + 1
 115                      (storew target other symbol-tls-index-slot other-pointer-lowtag)
 116                      (emit-label release-tls-index-lock)
 117                      (store-symbol-value 0 *tls-index-lock*)
 118                      ;; Restore OTHER.
 119                      (inst pop other))
 120                     (inst ret))))))
 121   (def eax)
 122   (def ebx)
 123   (def ecx)
 124   (def edx)
 125   (def edi)
 126   (def esi))
 127