src/check.lisp

   1 ;; -*- lisp -*-
   2
   3 (in-package :it.bese.FiveAM)
   4
   5 ;;;; * Checks
   6
   7 ;;;; At the lowest level testing the system requires that certain
   8 ;;;; forms be evaluated and that certain post conditions are met: the
   9 ;;;; value returned must satisfy a certain predicate, the form must
  10 ;;;; (or must not) signal a certain condition, etc. In FiveAM these
  11 ;;;; low level operations are called 'checks' and are defined using
  12 ;;;; the various checking macros.
  13
  14 ;;;; Checks are the basic operators for collecting results. Tests and
  15 ;;;; test suites on the other hand allow grouping multiple checks into
  16 ;;;; logic collections.
  17
  18 (defvar *test-dribble* t)
  19
  20 (defmacro with-*test-dribble* (stream &body body)
  21   `(let ((*test-dribble* ,stream))
  22      (declare (special *test-dribble*))
  23      ,@body))
  24
  25 (eval-when (:compile-toplevel :load-toplevel :execute)
  26   (def-special-environment run-state ()
  27     result-list
  28     current-test))
  29
  30 ;;;; ** Types of test results
  31
  32 ;;;; Every check produces a result object.
  33
  34 (defclass test-result ()
  35   ((reason :accessor reason :initarg :reason :initform "no reason given")
  36    (test-case :accessor test-case :initarg :test-case)
  37    (test-expr :accessor test-expr :initarg :test-expr))
  38   (:documentation "All checking macros will generate an object of
  39  type TEST-RESULT."))
  40
  41 (defclass test-passed (test-result)
  42   ()
  43   (:documentation "Class for successful checks."))
  44
  45 (defgeneric test-passed-p (object)
  46   (:method ((o t)) nil)
  47   (:method ((o test-passed)) t))
  48
  49 (defclass test-failure (test-result)
  50   ()
  51   (:documentation "Class for unsuccessful checks."))
  52
  53 (defgeneric test-failure-p (object)
  54   (:method ((o t)) nil)
  55   (:method ((o test-failure)) t))
  56
  57 (defclass unexpected-test-failure (test-failure)
  58   ((actual-condition :accessor actual-condition :initarg :condition))
  59   (:documentation "Represents the result of a test which neither
  60 passed nor failed, but signaled an error we couldn't deal
  61 with.
  62
  63 Note: This is very different than a SIGNALS check which instead
  64 creates a TEST-PASSED or TEST-FAILURE object."))
  65
  66 (defclass test-skipped (test-result)
  67   ()
  68   (:documentation "A test which was not run. Usually this is due
  69 to unsatisfied dependencies, but users can decide to skip test
  70 when appropiate."))
  71
  72 (defgeneric test-skipped-p (object)
  73   (:method ((o t)) nil)
  74   (:method ((o test-skipped)) t))
  75
  76 (defun add-result (result-type &rest make-instance-args)
  77   "Create a TEST-RESULT object of type RESULT-TYPE passing it the
  78   initialize args MAKE-INSTANCE-ARGS and adds the resulting
  79   object to the list of test results."
  80   (with-run-state (result-list current-test)
  81     (let ((result (apply #'make-instance result-type
  82                          (append make-instance-args (list :test-case current-test)))))
  83       (etypecase result
  84         (test-passed  (format *test-dribble* "."))
  85         (unexpected-test-failure (format *test-dribble* "X"))
  86         (test-failure (format *test-dribble* "f"))
  87         (test-skipped (format *test-dribble* "s")))
  88       (push result result-list))))
  89
  90 ;;;; ** The check operators
  91
  92 ;;;; *** The IS check
  93
  94 (defmacro is (test &rest reason-args)
  95   "The DWIM checking operator.
  96
  97 If TEST returns a true value a test-passed result is generated,
  98 otherwise a test-failure result is generated and the reason,
  99 unless REASON-ARGS is provided, is generated based on the form of
 100 TEST:
 101
 102  (predicate expected actual) - Means that we want to check
 103  whether, according to PREDICATE, the ACTUAL value is
 104  in fact what we EXPECTED.
 105
 106  (predicate value) - Means that we want to ensure that VALUE
 107  satisfies PREDICATE.
 108
 109 Wrapping the TEST form in a NOT simply preducse a negated reason string."
 110   (assert (listp test)
 111           (test)
 112           "Argument to IS must be a list, not ~S" test)
 113   (let (bindings effective-test default-reason-args)
 114     (with-unique-names (e a v)
 115       (list-match-case test
 116         ((not (?predicate ?expected ?actual))
 117          (setf bindings (list (list e ?expected)
 118                               (list a ?actual))
 119                effective-test `(not (,?predicate ,e ,a))
 120                default-reason-args (list "~S was ~S to ~S" a `',?predicate e)))
 121         ((not (?satisfies ?value))
 122          (setf bindings (list (list v ?value))
 123                effective-test `(not (,?satisfies ,v))
 124                default-reason-args (list  "~S satisfied ~S" v `',?satisfies)))
 125         ((?predicate ?expected ?actual)
 126          (setf bindings (list (list e ?expected)
 127                               (list a ?actual))
 128                effective-test `(,?predicate ,e ,a)
 129                default-reason-args (list "~S was not ~S to ~S" a `',?predicate e)))
 130         ((?satisfies ?value)
 131          (setf bindings (list (list v ?value))
 132                effective-test `(,?satisfies ,v)
 133                default-reason-args (list "~S did not satisfy ~S" v `',?satisfies)))
 134         (t
 135          (setf bindings '()
 136                effective-test test
 137                default-reason-args "No reason supplied.")))
 138       `(let ,bindings
 139          (if ,effective-test
 140              (add-result 'test-passed :test-expr ',test)
 141              (add-result 'test-failure
 142                          :reason ,(if (null reason-args)
 143                                       `(format nil ,@default-reason-args)
 144                                       `(format nil ,@reason-args))
 145                          :test-expr ',test))))))
 146
 147 ;;;; *** Other checks
 148
 149 (defmacro skip (&rest reason)
 150   "Generates a TEST-SKIPPED result."
 151   `(progn
 152      (format *test-dribble* "s")
 153      (add-result 'test-skipped :reason (format nil ,@reason))))
 154
 155 (defmacro is-true (condition &rest reason-args)
 156   "Like IS this check generates a pass if CONDITION returns true
 157   and a failure if CONDITION returns false. Unlike IS this check
 158   does not inspect CONDITION to determine how to report the
 159   failure."
 160   `(if ,condition
 161        (add-result 'test-passed :test-expr ',condition)
 162        (add-result 'test-failure :reason ,(if reason-args
 163                                               `(format nil ,@reason-args)
 164                                               `(format nil "~S did not return a true value" ',condition))
 165                    :test-expr ',condition)))
 166
 167 (defmacro is-false (condition &rest reason-args)
 168   "Generates a pass if CONDITION returns false, generates a
 169   failure otherwise. Like IS-TRUE, and unlike IS, IS-FALSE does
 170   not inspect CONDITION to determine what reason to give it case
 171   of test failure"
 172   `(if ,condition
 173        (add-result 'test-failure :reason ,(if reason-args
 174                                               `(format nil ,@reason-args)
 175                                               `(format nil "~S returned a true value" ',condition))
 176                    :test-expr ',condition)
 177        (add-result 'test-passed :test-expr ',condition)))
 178
 179 (defmacro signals (condition &body body)
 180   "Generates a pass if BODY signals a condition of type
 181 CONDITION. BODY is evaluated in a block named NIL, CONDITION is
 182 not evaluated."
 183   (let ((block-name (gensym)))
 184     `(block ,block-name
 185        (handler-bind ((,condition (lambda (c)
 186                                     (declare (ignore c))
 187                                     ;; ok, body threw condition
 188                                     (add-result 'test-passed
 189                                                 :test-expr ',condition)
 190                                     (return-from ,block-name t))))
 191          (block nil
 192            ,@body
 193            (add-result 'test-failure
 194                        :reason (format nil "Failed to signal a ~S" ',condition)
 195                        :test-expr ',condition)
 196            (return-from ,block-name nil))))))
 197
 198 (defmacro finishes (&body body)
 199   "Generates a pass if BODY executes to normal completion. In
 200 other words if body does signal, return-from or throw this test
 201 fails."
 202   `(let ((ok nil))
 203      (unwind-protect
 204          (progn
 205            ,@body
 206            (setf ok t))
 207        (if ok
 208            (add-result 'test-passed :test-expr ',body)
 209            (add-result 'test-failure
 210                        :reason (format nil "Test didn't finish")
 211                        :test-expr ',body)))))
 212
 213 (defmacro pass (&rest message-args)
 214   "Simply generate a PASS."
 215   `(add-result 'test-passed
 216                :test-expr ',message-args
 217                ,@(when message-args
 218                        `(:reason (format nil ,@message-args)))))
 219
 220 (defmacro fail (&rest message-args)
 221   "Simply generate a FAIL."
 222   `(add-result 'test-failure
 223                :test-expr ',message-args
 224                ,@(when message-args
 225                        `(:reason (format nil ,@message-args)))))
 226
 227 ;; Copyright (c) 2002-2003, Edward Marco Baringer
 228 ;; All rights reserved.
 229 ;;
 230 ;; Redistribution and use in source and binary forms, with or without
 231 ;; modification, are permitted provided that the following conditions are
 232 ;; met:
 233 ;;
 234 ;;  - Redistributions of source code must retain the above copyright
 235 ;;    notice, this list of conditions and the following disclaimer.
 236 ;;
 237 ;;  - Redistributions in binary form must reproduce the above copyright
 238 ;;    notice, this list of conditions and the following disclaimer in the
 239 ;;    documentation and/or other materials provided with the distribution.
 240 ;;
 241 ;;  - Neither the name of Edward Marco Baringer, nor BESE, nor the names
 242 ;;    of its contributors may be used to endorse or promote products
 243 ;;    derived from this software without specific prior written permission.
 244 ;;
 245 ;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 246 ;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 247 ;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 248 ;; A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE COPYRIGHT
 249 ;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 250 ;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 251 ;; LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 252 ;; DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 253 ;; THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 254 ;; (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 255 ;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE