src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data (array start end)
  50   (%with-array-data-macro array start end :fail-inline? t))
  51
  52 (defun %data-vector-and-index (array index)
  53   (if (array-header-p array)
  54       (multiple-value-bind (vector index)
  55           (%with-array-data array index nil)
  56         (values vector index))
  57       (values array index)))
  58
  59 ;;; It'd waste space to expand copies of error handling in every
  60 ;;; inline %WITH-ARRAY-DATA, so we have them call this function
  61 ;;; instead. This is just a wrapper which is known never to return.
  62 (defun failed-%with-array-data (array start end)
  63   (declare (notinline %with-array-data))
  64   (%with-array-data array start end)
  65   (bug "called FAILED-%WITH-ARRAY-DATA with valid array parameters?"))
  66 \f
  67 ;;;; MAKE-ARRAY
  68 (eval-when (:compile-toplevel :execute)
  69   (sb!xc:defmacro pick-vector-type (type &rest specs)
  70     `(cond ,@(mapcar (lambda (spec)
  71                        `(,(if (eq (car spec) t)
  72                               t
  73                               `(subtypep ,type ',(car spec)))
  74                          ,@(cdr spec)))
  75                      specs))))
  76
  77 ;;; These functions are used in the implementation of MAKE-ARRAY for
  78 ;;; complex arrays. There are lots of transforms to simplify
  79 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  80 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  81 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  82 ;;; making this somewhat efficient, at least not doing full calls to
  83 ;;; SUBTYPEP in the easy cases.
  84 (defun %vector-widetag-and-n-bits (type)
  85   (case type
  86     ;; Pick off some easy common cases.
  87     ;;
  88     ;; (Perhaps we should make a much more exhaustive table of easy
  89     ;; common cases here. Or perhaps the effort would be better spent
  90     ;; on smarter compiler transforms which do the calculation once
  91     ;; and for all in any reasonable user programs.)
  92     ((t)
  93      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
  94     ((base-char standard-char #!-sb-unicode character)
  95      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
  96     #!+sb-unicode
  97     ((character)
  98      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
  99     ((bit)
 100      (values #.sb!vm:simple-bit-vector-widetag 1))
 101     ;; OK, we have to wade into SUBTYPEPing after all.
 102     (t
 103      #.`(pick-vector-type type
 104          ,@(map 'list
 105                 (lambda (saetp)
 106                   `(,(sb!vm:saetp-specifier saetp)
 107                     (values ,(sb!vm:saetp-typecode saetp)
 108                             ,(sb!vm:saetp-n-bits saetp))))
 109                 sb!vm:*specialized-array-element-type-properties*)))))
 110
 111 (defun %complex-vector-widetag (type)
 112   (case type
 113     ;; Pick off some easy common cases.
 114     ((t)
 115      #.sb!vm:complex-vector-widetag)
 116     ((base-char #!-sb-unicode character)
 117      #.sb!vm:complex-base-string-widetag)
 118     #!+sb-unicode
 119     ((character)
 120      #.sb!vm:complex-character-string-widetag)
 121     ((nil)
 122      #.sb!vm:complex-vector-nil-widetag)
 123     ((bit)
 124      #.sb!vm:complex-bit-vector-widetag)
 125     ;; OK, we have to wade into SUBTYPEPing after all.
 126     (t
 127      (pick-vector-type type
 128        (nil #.sb!vm:complex-vector-nil-widetag)
 129        #!-sb-unicode
 130        (character #.sb!vm:complex-base-string-widetag)
 131        #!+sb-unicode
 132        (base-char #.sb!vm:complex-base-string-widetag)
 133        #!+sb-unicode
 134        (character #.sb!vm:complex-character-string-widetag)
 135        (bit #.sb!vm:complex-bit-vector-widetag)
 136        (t #.sb!vm:complex-vector-widetag)))))
 137
 138 (defun make-array (dimensions &key
 139                               (element-type t)
 140                               (initial-element nil initial-element-p)
 141                               (initial-contents nil initial-contents-p)
 142                               adjustable fill-pointer
 143                               displaced-to displaced-index-offset)
 144   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 145          (array-rank (length (the list dimensions)))
 146          (simple (and (null fill-pointer)
 147                       (not adjustable)
 148                       (null displaced-to))))
 149     (declare (fixnum array-rank))
 150     (when (and displaced-index-offset (null displaced-to))
 151       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 152     (when (and displaced-to
 153                (arrayp displaced-to)
 154                (not (equal (array-element-type displaced-to)
 155                            (upgraded-array-element-type element-type))))
 156       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 157     (if (and simple (= array-rank 1))
 158         ;; it's a (SIMPLE-ARRAY * (*))
 159         (multiple-value-bind (type n-bits)
 160             (%vector-widetag-and-n-bits element-type)
 161           (declare (type (unsigned-byte 8) type)
 162                    (type (integer 0 256) n-bits))
 163           (let* ((length (car dimensions))
 164                  (array (allocate-vector
 165                          type
 166                          length
 167                          (ceiling
 168                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 169                                      #!+sb-unicode
 170                                      (= type
 171                                         sb!vm:simple-character-string-widetag))
 172                                  (1+ length)
 173                                  length)
 174                              n-bits)
 175                           sb!vm:n-word-bits))))
 176             (declare (type index length))
 177             (when initial-element-p
 178               (fill array initial-element))
 179             (when initial-contents-p
 180               (when initial-element-p
 181                 (error "can't specify both :INITIAL-ELEMENT and ~
 182                        :INITIAL-CONTENTS"))
 183               (unless (= length (length initial-contents))
 184                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 185                        the vector length is ~W."
 186                        (length initial-contents)
 187                        length))
 188               (replace array initial-contents))
 189             array))
 190         ;; it's either a complex array or a multidimensional array.
 191         (let* ((total-size (reduce #'* dimensions))
 192                (data (or displaced-to
 193                          (data-vector-from-inits
 194                           dimensions total-size element-type
 195                           initial-contents initial-contents-p
 196                           initial-element initial-element-p)))
 197                (array (make-array-header
 198                        (cond ((= array-rank 1)
 199                               (%complex-vector-widetag element-type))
 200                              (simple sb!vm:simple-array-widetag)
 201                              (t sb!vm:complex-array-widetag))
 202                        array-rank)))
 203           (cond (fill-pointer
 204                  (unless (= array-rank 1)
 205                    (error "Only vectors can have fill pointers."))
 206                  (let ((length (car dimensions)))
 207                    (declare (fixnum length))
 208                    (setf (%array-fill-pointer array)
 209                      (cond ((eq fill-pointer t)
 210                             length)
 211                            (t
 212                             (unless (and (fixnump fill-pointer)
 213                                          (>= fill-pointer 0)
 214                                          (<= fill-pointer length))
 215                               ;; FIXME: should be TYPE-ERROR?
 216                               (error "invalid fill-pointer ~W"
 217                                      fill-pointer))
 218                             fill-pointer))))
 219                  (setf (%array-fill-pointer-p array) t))
 220                 (t
 221                  (setf (%array-fill-pointer array) total-size)
 222                  (setf (%array-fill-pointer-p array) nil)))
 223           (setf (%array-available-elements array) total-size)
 224           (setf (%array-data-vector array) data)
 225           (cond (displaced-to
 226                  (when (or initial-element-p initial-contents-p)
 227                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 228                    can be specified along with :DISPLACED-TO"))
 229                  (let ((offset (or displaced-index-offset 0)))
 230                    (when (> (+ offset total-size)
 231                             (array-total-size displaced-to))
 232                      (error "~S doesn't have enough elements." displaced-to))
 233                    (setf (%array-displacement array) offset)
 234                    (setf (%array-displaced-p array) t)))
 235                 (t
 236                  (setf (%array-displaced-p array) nil)))
 237           (let ((axis 0))
 238             (dolist (dim dimensions)
 239               (setf (%array-dimension array axis) dim)
 240               (incf axis)))
 241           array))))
 242
 243 (defun make-static-vector (length &key
 244                            (element-type '(unsigned-byte 8))
 245                            (initial-contents nil initial-contents-p)
 246                            (initial-element nil initial-element-p))
 247   "Allocate vector of LENGTH elements in static space. Only allocation
 248 of specialized arrays is supported."
 249   ;; STEP 1: check inputs fully
 250   ;;
 251   ;; This way of doing explicit checks before the vector is allocated
 252   ;; is expensive, but probably worth the trouble as once we've allocated
 253   ;; the vector we have no way to get rid of it anymore...
 254   (when (eq t (upgraded-array-element-type element-type))
 255     (error "Static arrays of type ~S not supported."
 256            element-type))
 257   (when initial-contents-p
 258     (when initial-element-p
 259       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 260     (unless (= length (length initial-contents))
 261       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 262               vector length is ~W."
 263              (length initial-contents)
 264              length))
 265     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 266       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 267              element-type)))
 268   (when initial-element-p
 269     (unless (typep initial-element element-type)
 270       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 271              initial-element element-type)))
 272   ;; STEP 2
 273   ;;
 274   ;; Allocate and possibly initialize the vector.
 275   (multiple-value-bind (type n-bits)
 276       (sb!impl::%vector-widetag-and-n-bits element-type)
 277     (let ((vector
 278            (allocate-static-vector type length
 279                                    (ceiling (* length n-bits)
 280                                             sb!vm:n-word-bits))))
 281       (cond (initial-element-p
 282              (fill vector initial-element))
 283             (initial-contents-p
 284              (replace vector initial-contents))
 285             (t
 286              vector)))))
 287
 288 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 289 ;;; specified array characteristics. Dimensions is only used to pass
 290 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 291 ;;; initial-contents.
 292 (defun data-vector-from-inits (dimensions total-size element-type
 293                                initial-contents initial-contents-p
 294                                initial-element initial-element-p)
 295   (when (and initial-contents-p initial-element-p)
 296     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 297             either MAKE-ARRAY or ADJUST-ARRAY."))
 298   (let ((data (if initial-element-p
 299                   (make-array total-size
 300                               :element-type element-type
 301                               :initial-element initial-element)
 302                   (make-array total-size
 303                               :element-type element-type))))
 304     (cond (initial-element-p
 305            (unless (simple-vector-p data)
 306              (unless (typep initial-element element-type)
 307                (error "~S cannot be used to initialize an array of type ~S."
 308                       initial-element element-type))
 309              (fill (the vector data) initial-element)))
 310           (initial-contents-p
 311            (fill-data-vector data dimensions initial-contents)))
 312     data))
 313
 314 (defun vector (&rest objects)
 315   #!+sb-doc
 316   "Construct a SIMPLE-VECTOR from the given objects."
 317   (coerce (the list objects) 'simple-vector))
 318 \f
 319
 320 ;;;; accessor/setter functions
 321
 322 ;;; Dispatch to an optimized routine the data vector accessors for
 323 ;;; each different specialized vector type. Do dispatching by looking
 324 ;;; up the widetag in the array rather than with the typecases, which
 325 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 326 ;;; provide separate versions where bounds checking has been moved
 327 ;;; from the callee to the caller, since it's much cheaper to do once
 328 ;;; the type information is available. Finally, for each of these
 329 ;;; routines also provide a slow path, taken for arrays that are not
 330 ;;; vectors or not simple.
 331 (macrolet ((define (accessor-name slow-accessor-name table-name extra-params
 332                                   check-bounds)
 333              `(progn
 334                 (defvar ,table-name)
 335                 (defun ,accessor-name (array index ,@extra-params)
 336                   (declare (optimize speed
 337                                      ;; (SAFETY 0) is ok. All calls to
 338                                      ;; these functions are generated by
 339                                      ;; the compiler, so argument count
 340                                      ;; checking isn't needed. Type checking
 341                                      ;; is done implicitly via the widetag
 342                                      ;; dispatch.
 343                                      (safety 0)))
 344                   #1=(funcall
 345                       (the function
 346                         (let ((tag 0)
 347                               (offset
 348                                #.(ecase sb!c:*backend-byte-order*
 349                                    (:little-endian
 350                                     (- sb!vm:other-pointer-lowtag))
 351                                    (:big-endian
 352                                     ;; I'm not completely sure of what this
 353                                     ;; 3 represents symbolically. It's
 354                                     ;; just what all the LOAD-TYPE vops
 355                                     ;; are doing.
 356                                     (- 3 sb!vm:other-pointer-lowtag)))))
 357                           ;; WIDETAG-OF needs extra code to handle
 358                           ;; LIST and FUNCTION lowtags. We're only
 359                           ;; dispatching on other pointers, so let's
 360                           ;; do the lowtag extraction manually.
 361                           (when (sb!vm::%other-pointer-p array)
 362                             (setf tag
 363                                   (sb!sys:sap-ref-8 (int-sap (get-lisp-obj-address array))
 364                                                     offset)))
 365                           ;; SYMBOL-GLOBAL-VALUE is a performance hack
 366                           ;; for threaded builds.
 367                           (svref (sb!vm::symbol-global-value ',table-name) tag)))
 368                       array index ,@extra-params))
 369                 (defun ,slow-accessor-name (array index ,@extra-params)
 370                   (declare (optimize speed (safety 0)))
 371                   (if (not (%array-displaced-p array))
 372                       ;; The reasonably quick path of non-displaced complex
 373                       ;; arrays.
 374                       (let ((array (%array-data-vector array)))
 375                         #1#)
 376                       ;; The real slow path.
 377                       (with-array-data
 378                           ((vector array)
 379                            (index (locally
 380                                       (declare (optimize (speed 1) (safety 1)))
 381                                     (,@check-bounds index)))
 382                            (end)
 383                            :force-inline t)
 384                         (declare (ignore end))
 385                         (,accessor-name vector index ,@extra-params)))))))
 386   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 387     *data-vector-reffers* nil (progn))
 388   (define hairy-data-vector-set slow-hairy-data-vector-set
 389     *data-vector-setters* (new-value) (progn))
 390   (define hairy-data-vector-ref/check-bounds
 391       slow-hairy-data-vector-ref/check-bounds
 392     *data-vector-reffers/check-bounds* nil
 393     (%check-bound array (array-dimension array 0)))
 394   (define hairy-data-vector-set/check-bounds
 395       slow-hairy-data-vector-set/check-bounds
 396     *data-vector-setters/check-bounds* (new-value)
 397     (%check-bound array (array-dimension array 0))))
 398
 399 (defun hairy-ref-error (array index &optional new-value)
 400   (declare (ignore index new-value))
 401   (error 'type-error
 402          :datum array
 403          :expected-type 'vector))
 404
 405 ;;; Populate the dispatch tables.
 406 (macrolet ((define-reffer (saetp check-form)
 407              (let* ((type (sb!vm:saetp-specifier saetp))
 408                     (atype `(simple-array ,type (*))))
 409                `(named-lambda optimized-data-vector-ref (vector index)
 410                   (declare (optimize speed (safety 0)))
 411                   (data-vector-ref (the ,atype vector)
 412                                    (locally
 413                                        (declare (optimize (safety 1)))
 414                                      (the index
 415                                        (,@check-form index)))))))
 416            (define-setter (saetp check-form)
 417              (let* ((type (sb!vm:saetp-specifier saetp))
 418                     (atype `(simple-array ,type (*))))
 419                `(named-lambda optimized-data-vector-set (vector index new-value)
 420                   (declare (optimize speed (safety 0)))
 421                   (data-vector-set (the ,atype vector)
 422                                    (locally
 423                                        (declare (optimize (safety 1)))
 424                                      (the index
 425                                        (,@check-form index)))
 426                                    (locally
 427                                        ;; SPEED 1 needed to avoid the compiler
 428                                        ;; from downgrading the type check to
 429                                        ;; a cheaper one.
 430                                        (declare (optimize (speed 1)
 431                                                           (safety 1)))
 432                                      (the ,type new-value)))
 433                   ;; For specialized arrays, the return from
 434                   ;; data-vector-set would have to be reboxed to be a
 435                   ;; (Lisp) return value; instead, we use the
 436                   ;; already-boxed value as the return.
 437                   new-value)))
 438            (define-reffers (symbol deffer check-form slow-path)
 439              `(progn
 440                 (setf ,symbol (make-array sb!vm::widetag-mask
 441                                           :initial-element #'hairy-ref-error))
 442                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 443                                          sb!vm:complex-vector-nil-widetag
 444                                          sb!vm:complex-bit-vector-widetag
 445                                          sb!vm:complex-character-string-widetag
 446                                          sb!vm:complex-base-string-widetag
 447                                          sb!vm:simple-array-widetag
 448                                          sb!vm:complex-array-widetag)
 449                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 450                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 451                         for widetag = (sb!vm:saetp-typecode saetp)
 452                         collect `(setf (svref ,symbol ,widetag)
 453                                        (,deffer ,saetp ,check-form))))))
 454   (defun !hairy-data-vector-reffer-init ()
 455     (define-reffers *data-vector-reffers* define-reffer
 456       (progn)
 457       #'slow-hairy-data-vector-ref)
 458     (define-reffers *data-vector-setters* define-setter
 459       (progn)
 460       #'slow-hairy-data-vector-set)
 461     (define-reffers *data-vector-reffers/check-bounds* define-reffer
 462       (%check-bound vector (length vector))
 463       #'slow-hairy-data-vector-ref/check-bounds)
 464     (define-reffers *data-vector-setters/check-bounds* define-setter
 465       (%check-bound vector (length vector))
 466       #'slow-hairy-data-vector-set/check-bounds)))
 467
 468 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 469 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 470 ;;; definition is needed for the compiler to use in constant folding.)
 471 (defun data-vector-ref (array index)
 472   (hairy-data-vector-ref array index))
 473
 474 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 475 (defun %array-row-major-index (array subscripts
 476                                      &optional (invalid-index-error-p t))
 477   (declare (array array)
 478            (list subscripts))
 479   (let ((rank (array-rank array)))
 480     (unless (= rank (length subscripts))
 481       (error "wrong number of subscripts, ~W, for array of rank ~W"
 482              (length subscripts) rank))
 483     (if (array-header-p array)
 484         (do ((subs (nreverse subscripts) (cdr subs))
 485              (axis (1- (array-rank array)) (1- axis))
 486              (chunk-size 1)
 487              (result 0))
 488             ((null subs) result)
 489           (declare (list subs) (fixnum axis chunk-size result))
 490           (let ((index (car subs))
 491                 (dim (%array-dimension array axis)))
 492             (declare (fixnum dim))
 493             (unless (and (fixnump index) (< -1 index dim))
 494               (if invalid-index-error-p
 495                   (error 'simple-type-error
 496                          :format-control "invalid index ~W~[~;~:; on axis ~:*~W~] in ~S"
 497                          :format-arguments (list index axis array)
 498                          :datum index
 499                          :expected-type `(integer 0 (,dim)))
 500                   (return-from %array-row-major-index nil)))
 501             (incf result (* chunk-size (the fixnum index)))
 502             (setf chunk-size (* chunk-size dim))))
 503         (let ((index (first subscripts))
 504               (length (length (the (simple-array * (*)) array))))
 505           (unless (and (fixnump index) (< -1 index length))
 506             (if invalid-index-error-p
 507                 ;; FIXME: perhaps this should share a format-string
 508                 ;; with INVALID-ARRAY-INDEX-ERROR or
 509                 ;; INDEX-TOO-LARGE-ERROR?
 510                 (error 'simple-type-error
 511                        :format-control "invalid index ~W in ~S"
 512                        :format-arguments (list index array)
 513                        :datum index
 514                        :expected-type `(integer 0 (,length)))
 515                 (return-from %array-row-major-index nil)))
 516           index))))
 517
 518 (defun array-in-bounds-p (array &rest subscripts)
 519   #!+sb-doc
 520   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 521   (if (%array-row-major-index array subscripts nil)
 522       t))
 523
 524 (defun array-row-major-index (array &rest subscripts)
 525   (declare (dynamic-extent subscripts))
 526   (%array-row-major-index array subscripts))
 527
 528 (defun aref (array &rest subscripts)
 529   #!+sb-doc
 530   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 531   (declare (dynamic-extent subscripts))
 532   (row-major-aref array (%array-row-major-index array subscripts)))
 533
 534 (defun %aset (array &rest stuff)
 535   (declare (dynamic-extent stuff))
 536   (let ((subscripts (butlast stuff))
 537         (new-value (car (last stuff))))
 538     (setf (row-major-aref array (%array-row-major-index array subscripts))
 539           new-value)))
 540
 541 ;;; FIXME: What's supposed to happen with functions
 542 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 543 ;;; DEFSETF FOO is also defined? It seems as though the logical
 544 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 545 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 546 ;;; just as for ordinary functions
 547 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 548 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 549 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 550 ;;;  ZOO
 551 ;;;  * (DEFUN ZOO (X) (* 3 X))
 552 ;;;  Warning: ZOO previously defined as a macro.
 553 ;;;  ZOO
 554 ;;; But that doesn't seem to be what happens in CMU CL.
 555 ;;;
 556 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 557 ;;; 5.1.2.5) requires implementations to support
 558 ;;;   (SETF (APPLY #'AREF ...) ...)
 559 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 560 ;;; also terrifying that this sequence of definitions causes it to
 561 ;;; work.
 562 ;;;
 563 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 564 ;;; has a setf expansion and/or a setf function defined.
 565
 566 #!-sb-fluid (declaim (inline (setf aref)))
 567 (defun (setf aref) (new-value array &rest subscripts)
 568   (declare (dynamic-extent subscripts))
 569   (declare (type array array))
 570   (setf (row-major-aref array (%array-row-major-index array subscripts))
 571         new-value))
 572
 573 (defun row-major-aref (array index)
 574   #!+sb-doc
 575   "Return the element of array corressponding to the row-major index. This is
 576    SETF'able."
 577   (declare (optimize (safety 1)))
 578   (row-major-aref array index))
 579
 580 (defun %set-row-major-aref (array index new-value)
 581   (declare (optimize (safety 1)))
 582   (setf (row-major-aref array index) new-value))
 583
 584 (defun svref (simple-vector index)
 585   #!+sb-doc
 586   "Return the INDEX'th element of the given Simple-Vector."
 587   (declare (optimize (safety 1)))
 588   (aref simple-vector index))
 589
 590 (defun %svset (simple-vector index new)
 591   (declare (optimize (safety 1)))
 592   (setf (aref simple-vector index) new))
 593
 594 (defun bit (bit-array &rest subscripts)
 595   #!+sb-doc
 596   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 597   (declare (type (array bit) bit-array) (optimize (safety 1)))
 598   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 599
 600 (defun %bitset (bit-array &rest stuff)
 601   (declare (type (array bit) bit-array) (optimize (safety 1)))
 602   (let ((subscripts (butlast stuff))
 603         (new-value (car (last stuff))))
 604     (setf (row-major-aref bit-array
 605                           (%array-row-major-index bit-array subscripts))
 606           new-value)))
 607
 608 #!-sb-fluid (declaim (inline (setf bit)))
 609 (defun (setf bit) (new-value bit-array &rest subscripts)
 610   (declare (type (array bit) bit-array) (optimize (safety 1)))
 611   (setf (row-major-aref bit-array
 612                         (%array-row-major-index bit-array subscripts))
 613         new-value))
 614
 615 (defun sbit (simple-bit-array &rest subscripts)
 616   #!+sb-doc
 617   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 618   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 619   (row-major-aref simple-bit-array
 620                   (%array-row-major-index simple-bit-array subscripts)))
 621
 622 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 623 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 624 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 625 ;;; -- WHN 19990911
 626 (defun %sbitset (simple-bit-array &rest stuff)
 627   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 628   (let ((subscripts (butlast stuff))
 629         (new-value (car (last stuff))))
 630     (setf (row-major-aref simple-bit-array
 631                           (%array-row-major-index simple-bit-array subscripts))
 632           new-value)))
 633
 634 #!-sb-fluid (declaim (inline (setf sbit)))
 635 (defun (setf sbit) (new-value bit-array &rest subscripts)
 636   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 637   (setf (row-major-aref bit-array
 638                         (%array-row-major-index bit-array subscripts))
 639         new-value))
 640 \f
 641 ;;;; miscellaneous array properties
 642
 643 (defun array-element-type (array)
 644   #!+sb-doc
 645   "Return the type of the elements of the array"
 646   (let ((widetag (widetag-of array)))
 647     (macrolet ((pick-element-type (&rest stuff)
 648                  `(cond ,@(mapcar (lambda (stuff)
 649                                     (cons
 650                                      (let ((item (car stuff)))
 651                                        (cond ((eq item t)
 652                                               t)
 653                                              ((listp item)
 654                                               (cons 'or
 655                                                     (mapcar (lambda (x)
 656                                                               `(= widetag ,x))
 657                                                             item)))
 658                                              (t
 659                                               `(= widetag ,item))))
 660                                      (cdr stuff)))
 661                                   stuff))))
 662       #.`(pick-element-type
 663           ,@(map 'list
 664                  (lambda (saetp)
 665                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 666                           (list (sb!vm:saetp-typecode saetp)
 667                                 (sb!vm:saetp-complex-typecode saetp))
 668                           (sb!vm:saetp-typecode saetp))
 669                      ',(sb!vm:saetp-specifier saetp)))
 670                  sb!vm:*specialized-array-element-type-properties*)
 671           ((sb!vm:simple-array-widetag
 672             sb!vm:complex-vector-widetag
 673             sb!vm:complex-array-widetag)
 674            (with-array-data ((array array) (start) (end))
 675              (declare (ignore start end))
 676              (array-element-type array)))
 677           (t
 678            (error 'type-error :datum array :expected-type 'array))))))
 679
 680 (defun array-rank (array)
 681   #!+sb-doc
 682   "Return the number of dimensions of ARRAY."
 683   (if (array-header-p array)
 684       (%array-rank array)
 685       1))
 686
 687 (defun array-dimension (array axis-number)
 688   #!+sb-doc
 689   "Return the length of dimension AXIS-NUMBER of ARRAY."
 690   (declare (array array) (type index axis-number))
 691   (cond ((not (array-header-p array))
 692          (unless (= axis-number 0)
 693            (error "Vector axis is not zero: ~S" axis-number))
 694          (length (the (simple-array * (*)) array)))
 695         ((>= axis-number (%array-rank array))
 696          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 697                 axis-number array (%array-rank array)))
 698         (t
 699          ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
 700          ;;
 701          ;;   "If A is displaced to B, the consequences are
 702          ;;   unspecified if B is adjusted in such a way that it no
 703          ;;   longer has enough elements to satisfy A.
 704          ;;
 705          ;; In situations where this matters we should be doing a
 706          ;; bounds-check, which in turn uses ARRAY-DIMENSION -- so
 707          ;; this seems like a good place to signal an error.
 708          (multiple-value-bind (target offset) (array-displacement array)
 709            (when (and target
 710                       (> (array-total-size array)
 711                          (- (array-total-size target) offset)))
 712                (error 'displaced-to-array-too-small-error
 713                       :format-control "~@<The displaced-to array is too small. ~S ~
 714                                       elements after offset required, ~S available.~:@>"
 715                       :format-arguments (list (array-total-size array)
 716                                               (- (array-total-size target) offset))))
 717            (%array-dimension array axis-number)))))
 718
 719 (defun array-dimensions (array)
 720   #!+sb-doc
 721   "Return a list whose elements are the dimensions of the array"
 722   (declare (array array))
 723   (if (array-header-p array)
 724       (do ((results nil (cons (array-dimension array index) results))
 725            (index (1- (array-rank array)) (1- index)))
 726           ((minusp index) results))
 727       (list (array-dimension array 0))))
 728
 729 (defun array-total-size (array)
 730   #!+sb-doc
 731   "Return the total number of elements in the Array."
 732   (declare (array array))
 733   (if (array-header-p array)
 734       (%array-available-elements array)
 735       (length (the vector array))))
 736
 737 (defun array-displacement (array)
 738   #!+sb-doc
 739   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 740    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 741   (declare (type array array))
 742   (if (and (array-header-p array) ; if unsimple and
 743            (%array-displaced-p array)) ; displaced
 744       (values (%array-data-vector array) (%array-displacement array))
 745       (values nil 0)))
 746
 747 (defun adjustable-array-p (array)
 748   #!+sb-doc
 749   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 750    to the argument, this happens for complex arrays."
 751   (declare (array array))
 752   ;; Note that this appears not to be a fundamental limitation.
 753   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 754   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 755   ;; -- CSR, 2004-03-01.
 756   (not (typep array 'simple-array)))
 757 \f
 758 ;;;; fill pointer frobbing stuff
 759
 760 (defun array-has-fill-pointer-p (array)
 761   #!+sb-doc
 762   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 763   (declare (array array))
 764   (and (array-header-p array) (%array-fill-pointer-p array)))
 765
 766 (defun fill-pointer (vector)
 767   #!+sb-doc
 768   "Return the FILL-POINTER of the given VECTOR."
 769   (declare (vector vector))
 770   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 771       (%array-fill-pointer vector)
 772       (error 'simple-type-error
 773              :datum vector
 774              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 775              :format-control "~S is not an array with a fill pointer."
 776              :format-arguments (list vector))))
 777
 778 (defun %set-fill-pointer (vector new)
 779   (declare (vector vector) (fixnum new))
 780   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 781       (if (> new (%array-available-elements vector))
 782         (error
 783          "The new fill pointer, ~S, is larger than the length of the vector."
 784          new)
 785         (setf (%array-fill-pointer vector) new))
 786       (error 'simple-type-error
 787              :datum vector
 788              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 789              :format-control "~S is not an array with a fill pointer."
 790              :format-arguments (list vector))))
 791
 792 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 793 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 794 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 795 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 796 ;;; back to CMU CL).
 797 (defun vector-push (new-el array)
 798   #!+sb-doc
 799   "Attempt to set the element of ARRAY designated by its fill pointer
 800    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 801    too large, NIL is returned, otherwise the index of the pushed element is
 802    returned."
 803   (declare (vector array))
 804   (let ((fill-pointer (fill-pointer array)))
 805     (declare (fixnum fill-pointer))
 806     (cond ((= fill-pointer (%array-available-elements array))
 807            nil)
 808           (t
 809            (setf (aref array fill-pointer) new-el)
 810            (setf (%array-fill-pointer array) (1+ fill-pointer))
 811            fill-pointer))))
 812
 813 (defun vector-push-extend (new-element
 814                            vector
 815                            &optional
 816                            (extension (1+ (length vector))))
 817   (declare (vector vector) (fixnum extension))
 818   (let ((fill-pointer (fill-pointer vector)))
 819     (declare (fixnum fill-pointer))
 820     (when (= fill-pointer (%array-available-elements vector))
 821       (adjust-array vector (+ fill-pointer extension)))
 822     ;; disable bounds checking
 823     (locally (declare (optimize (safety 0)))
 824       (setf (aref vector fill-pointer) new-element))
 825     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 826     fill-pointer))
 827
 828 (defun vector-pop (array)
 829   #!+sb-doc
 830   "Decrease the fill pointer by 1 and return the element pointed to by the
 831   new fill pointer."
 832   (declare (vector array))
 833   (let ((fill-pointer (fill-pointer array)))
 834     (declare (fixnum fill-pointer))
 835     (if (zerop fill-pointer)
 836         (error "There is nothing left to pop.")
 837         ;; disable bounds checking (and any fixnum test)
 838         (locally (declare (optimize (safety 0)))
 839           (aref array
 840                 (setf (%array-fill-pointer array)
 841                       (1- fill-pointer)))))))
 842
 843 \f
 844 ;;;; ADJUST-ARRAY
 845
 846 (defun adjust-array (array dimensions &key
 847                            (element-type (array-element-type array))
 848                            (initial-element nil initial-element-p)
 849                            (initial-contents nil initial-contents-p)
 850                            fill-pointer
 851                            displaced-to displaced-index-offset)
 852   #!+sb-doc
 853   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 854   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 855     (cond ((/= (the fixnum (length (the list dimensions)))
 856                (the fixnum (array-rank array)))
 857            (error "The number of dimensions not equal to rank of array."))
 858           ((not (subtypep element-type (array-element-type array)))
 859            (error "The new element type, ~S, is incompatible with old type."
 860                   element-type))
 861           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 862            (error 'type-error
 863                   :datum array
 864                   :expected-type '(satisfies array-has-fill-pointer-p))))
 865     (let ((array-rank (length (the list dimensions))))
 866       (declare (fixnum array-rank))
 867       (unless (= array-rank 1)
 868         (when fill-pointer
 869           (error "Only vectors can have fill pointers.")))
 870       (cond (initial-contents-p
 871              ;; array former contents replaced by INITIAL-CONTENTS
 872              (if (or initial-element-p displaced-to)
 873                  (error "INITIAL-CONTENTS may not be specified with ~
 874                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 875              (let* ((array-size (apply #'* dimensions))
 876                     (array-data (data-vector-from-inits
 877                                  dimensions array-size element-type
 878                                  initial-contents initial-contents-p
 879                                  initial-element initial-element-p)))
 880                (if (adjustable-array-p array)
 881                    (set-array-header array array-data array-size
 882                                  (get-new-fill-pointer array array-size
 883                                                        fill-pointer)
 884                                  0 dimensions nil)
 885                    (if (array-header-p array)
 886                        ;; simple multidimensional or single dimensional array
 887                        (make-array dimensions
 888                                    :element-type element-type
 889                                    :initial-contents initial-contents)
 890                        array-data))))
 891             (displaced-to
 892              ;; We already established that no INITIAL-CONTENTS was supplied.
 893              (when initial-element
 894                (error "The :INITIAL-ELEMENT option may not be specified ~
 895                        with :DISPLACED-TO."))
 896              (unless (subtypep element-type (array-element-type displaced-to))
 897                (error "can't displace an array of type ~S into another of ~
 898                        type ~S"
 899                       element-type (array-element-type displaced-to)))
 900              (let ((displacement (or displaced-index-offset 0))
 901                    (array-size (apply #'* dimensions)))
 902                (declare (fixnum displacement array-size))
 903                (if (< (the fixnum (array-total-size displaced-to))
 904                       (the fixnum (+ displacement array-size)))
 905                    (error "The :DISPLACED-TO array is too small."))
 906                (if (adjustable-array-p array)
 907                    ;; None of the original contents appear in adjusted array.
 908                    (set-array-header array displaced-to array-size
 909                                      (get-new-fill-pointer array array-size
 910                                                            fill-pointer)
 911                                      displacement dimensions t)
 912                    ;; simple multidimensional or single dimensional array
 913                    (make-array dimensions
 914                                :element-type element-type
 915                                :displaced-to displaced-to
 916                                :displaced-index-offset
 917                                displaced-index-offset))))
 918             ((= array-rank 1)
 919              (let ((old-length (array-total-size array))
 920                    (new-length (car dimensions))
 921                    new-data)
 922                (declare (fixnum old-length new-length))
 923                (with-array-data ((old-data array) (old-start)
 924                                  (old-end old-length))
 925                  (cond ((or (and (array-header-p array)
 926                                  (%array-displaced-p array))
 927                             (< old-length new-length))
 928                         (setf new-data
 929                               (data-vector-from-inits
 930                                dimensions new-length element-type
 931                                initial-contents initial-contents-p
 932                                initial-element initial-element-p))
 933                         (replace new-data old-data
 934                                  :start2 old-start :end2 old-end))
 935                        (t (setf new-data
 936                                 (shrink-vector old-data new-length))))
 937                  (if (adjustable-array-p array)
 938                      (set-array-header array new-data new-length
 939                                        (get-new-fill-pointer array new-length
 940                                                              fill-pointer)
 941                                        0 dimensions nil)
 942                      new-data))))
 943             (t
 944              (let ((old-length (%array-available-elements array))
 945                    (new-length (apply #'* dimensions)))
 946                (declare (fixnum old-length new-length))
 947                (with-array-data ((old-data array) (old-start)
 948                                  (old-end old-length))
 949                  (declare (ignore old-end))
 950                  (let ((new-data (if (or (and (array-header-p array)
 951                                               (%array-displaced-p array))
 952                                          (> new-length old-length))
 953                                      (data-vector-from-inits
 954                                       dimensions new-length
 955                                       element-type () nil
 956                                       initial-element initial-element-p)
 957                                      old-data)))
 958                    (if (or (zerop old-length) (zerop new-length))
 959                        (when initial-element-p (fill new-data initial-element))
 960                        (zap-array-data old-data (array-dimensions array)
 961                                        old-start
 962                                        new-data dimensions new-length
 963                                        element-type initial-element
 964                                        initial-element-p))
 965                    (if (adjustable-array-p array)
 966                        (set-array-header array new-data new-length
 967                                          new-length 0 dimensions nil)
 968                        (let ((new-array
 969                               (make-array-header
 970                                sb!vm:simple-array-widetag array-rank)))
 971                          (set-array-header new-array new-data new-length
 972                                            new-length 0 dimensions nil)))))))))))
 973
 974
 975 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 976   (cond ((not fill-pointer)
 977          (when (array-has-fill-pointer-p old-array)
 978            (when (> (%array-fill-pointer old-array) new-array-size)
 979              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 980                      smaller than its fill pointer (~S)"
 981                     old-array new-array-size (fill-pointer old-array)))
 982            (%array-fill-pointer old-array)))
 983         ((not (array-has-fill-pointer-p old-array))
 984          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 985                  in ADJUST-ARRAY unless the array (~S) was originally ~
 986                  created with a fill pointer"
 987                 fill-pointer
 988                 old-array))
 989         ((numberp fill-pointer)
 990          (when (> fill-pointer new-array-size)
 991            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 992                    than the new length of the vector (~S)"
 993                   fill-pointer new-array-size))
 994          fill-pointer)
 995         ((eq fill-pointer t)
 996          new-array-size)
 997         (t
 998          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
 999                 fill-pointer))))
1000
1001 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1002 ;;; which must be less than or equal to its current length. This can
1003 ;;; be called on vectors without a fill pointer but it is extremely
1004 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1005 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1006 ;;; or multi-threading. Call it only on provably local vectors.
1007 (defun %shrink-vector (vector new-length)
1008   (declare (vector vector))
1009   (unless (array-header-p vector)
1010     (macrolet ((frob (name &rest things)
1011                  `(etypecase ,name
1012                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1013                     ,@(mapcar (lambda (thing)
1014                                 (destructuring-bind (type-spec fill-value)
1015                                     thing
1016                                   `(,type-spec
1017                                     (fill (truly-the ,type-spec ,name)
1018                                           ,fill-value
1019                                           :start new-length))))
1020                               things))))
1021       ;; Set the 'tail' of the vector to the appropriate type of zero,
1022       ;; "because in some cases we'll scavenge larger areas in one go,
1023       ;; like groups of pages that had triggered the write barrier, or
1024       ;; the whole static space" according to jsnell.
1025       #.`(frob vector
1026           ,@(map 'list
1027                  (lambda (saetp)
1028                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1029                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1030                               #!+sb-unicode
1031                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1032                           *default-init-char-form*
1033                           (sb!vm:saetp-initial-element-default saetp))))
1034                  (remove-if-not
1035                   #'sb!vm:saetp-specifier
1036                   sb!vm:*specialized-array-element-type-properties*)))))
1037   ;; Only arrays have fill-pointers, but vectors have their length
1038   ;; parameter in the same place.
1039   (setf (%array-fill-pointer vector) new-length)
1040   vector)
1041
1042 (defun shrink-vector (vector new-length)
1043   (declare (vector vector))
1044   (cond
1045     ((eq (length vector) new-length)
1046      vector)
1047     ((array-has-fill-pointer-p vector)
1048      (setf (%array-fill-pointer vector) new-length)
1049      vector)
1050     (t (subseq vector 0 new-length))))
1051
1052 ;;; Fill in array header with the provided information, and return the array.
1053 (defun set-array-header (array data length fill-pointer displacement dimensions
1054                          &optional displacedp)
1055   (setf (%array-data-vector array) data)
1056   (setf (%array-available-elements array) length)
1057   (cond (fill-pointer
1058          (setf (%array-fill-pointer array) fill-pointer)
1059          (setf (%array-fill-pointer-p array) t))
1060         (t
1061          (setf (%array-fill-pointer array) length)
1062          (setf (%array-fill-pointer-p array) nil)))
1063   (setf (%array-displacement array) displacement)
1064   (if (listp dimensions)
1065       (dotimes (axis (array-rank array))
1066         (declare (type index axis))
1067         (setf (%array-dimension array axis) (pop dimensions)))
1068       (setf (%array-dimension array 0) dimensions))
1069   (setf (%array-displaced-p array) displacedp)
1070   array)
1071 \f
1072 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1073
1074 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1075 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1076 ;;; to length zero array in each new thread.
1077 ;;;
1078 ;;; DX is probably a bad idea, because a with a big array it would
1079 ;;; be fairly easy to blow the stack.
1080 (defvar *zap-array-data-temp* (vector))
1081 (declaim (simple-vector *zap-array-data-temp*))
1082
1083 (defun zap-array-data-temp (length initial-element initial-element-p)
1084   (declare (fixnum length))
1085   (let ((tmp *zap-array-data-temp*))
1086     (declare (simple-vector tmp))
1087     (cond ((> length (length tmp))
1088            (setf *zap-array-data-temp*
1089                  (if initial-element-p
1090                      (make-array length :initial-element initial-element)
1091                      (make-array length))))
1092           (initial-element-p
1093            (fill tmp initial-element :end length))
1094           (t
1095            tmp))))
1096
1097 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1098 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1099 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1100 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1101 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1102                        element-type initial-element initial-element-p)
1103   (declare (list old-dims new-dims))
1104   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1105   ;; at least in SBCL.
1106   ;; NEW-DIMS comes from the user.
1107   (setf old-dims (nreverse old-dims)
1108         new-dims (reverse new-dims))
1109   (cond ((eq old-data new-data)
1110          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1111          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1112          ;; EQ; in this case, a temporary must be used and filled
1113          ;; appropriately. specified initial-element.
1114          (when initial-element-p
1115            ;; FIXME: transforming this TYPEP to someting a bit faster
1116            ;; would be a win...
1117            (unless (typep initial-element element-type)
1118              (error "~S can't be used to initialize an array of type ~S."
1119                     initial-element element-type)))
1120          (without-interrupts
1121            ;; Need to disable interrupts while using the temp-vector.
1122            ;; An interrupt handler that also happened to call
1123            ;; ADJUST-ARRAY could otherwise stomp on our data here.
1124            (let ((temp (zap-array-data-temp new-length
1125                                             initial-element initial-element-p)))
1126              (declare (simple-vector temp))
1127              (zap-array-data-aux old-data old-dims offset temp new-dims)
1128              (dotimes (i new-length)
1129                (setf (aref new-data i) (aref temp i)
1130                      ;; zero out any garbage right away
1131                      (aref temp i) 0)))))
1132         (t
1133          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1134          ;; already been filled with any
1135          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1136
1137 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1138   (declare (fixnum offset))
1139   (let ((limits (mapcar (lambda (x y)
1140                           (declare (fixnum x y))
1141                           (1- (the fixnum (min x y))))
1142                         old-dims new-dims)))
1143     (macrolet ((bump-index-list (index limits)
1144                  `(do ((subscripts ,index (cdr subscripts))
1145                        (limits ,limits (cdr limits)))
1146                       ((null subscripts) :eof)
1147                     (cond ((< (the fixnum (car subscripts))
1148                               (the fixnum (car limits)))
1149                            (rplaca subscripts
1150                                    (1+ (the fixnum (car subscripts))))
1151                            (return ,index))
1152                           (t (rplaca subscripts 0))))))
1153       (do ((index (make-list (length old-dims) :initial-element 0)
1154                   (bump-index-list index limits)))
1155           ((eq index :eof))
1156         (setf (aref new-data (row-major-index-from-dims index new-dims))
1157               (aref old-data
1158                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1159                        offset)))))))
1160
1161 ;;; Figure out the row-major-order index of an array reference from a
1162 ;;; list of subscripts and a list of dimensions. This is for internal
1163 ;;; calls only, and the subscripts and dim-list variables are assumed
1164 ;;; to be reversed from what the user supplied.
1165 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1166   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1167        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1168        (chunk-size 1)
1169        (result 0))
1170       ((null rev-dim-list) result)
1171     (declare (fixnum chunk-size result))
1172     (setq result (+ result
1173                     (the fixnum (* (the fixnum (car rev-subscripts))
1174                                    chunk-size))))
1175     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1176 \f
1177 ;;;; some bit stuff
1178
1179 (defun bit-array-same-dimensions-p (array1 array2)
1180   (declare (type (array bit) array1 array2))
1181   (and (= (array-rank array1)
1182           (array-rank array2))
1183        (dotimes (index (array-rank array1) t)
1184          (when (/= (array-dimension array1 index)
1185                    (array-dimension array2 index))
1186            (return nil)))))
1187
1188 (defun pick-result-array (result-bit-array bit-array-1)
1189   (case result-bit-array
1190     ((t) bit-array-1)
1191     ((nil) (make-array (array-dimensions bit-array-1)
1192                        :element-type 'bit
1193                        :initial-element 0))
1194     (t
1195      (unless (bit-array-same-dimensions-p bit-array-1
1196                                           result-bit-array)
1197        (error "~S and ~S don't have the same dimensions."
1198               bit-array-1 result-bit-array))
1199      result-bit-array)))
1200
1201 (defmacro def-bit-array-op (name function)
1202   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1203      #!+sb-doc
1204      ,(format nil
1205               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1206                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1207                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1208                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1209                All the arrays must have the same rank and dimensions."
1210               (symbol-name function))
1211      (declare (type (array bit) bit-array-1 bit-array-2)
1212               (type (or (array bit) (member t nil)) result-bit-array))
1213      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1214        (error "~S and ~S don't have the same dimensions."
1215               bit-array-1 bit-array-2))
1216      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1217        (if (and (simple-bit-vector-p bit-array-1)
1218                 (simple-bit-vector-p bit-array-2)
1219                 (simple-bit-vector-p result-bit-array))
1220            (locally (declare (optimize (speed 3) (safety 0)))
1221              (,name bit-array-1 bit-array-2 result-bit-array))
1222            (with-array-data ((data1 bit-array-1) (start1) (end1))
1223              (declare (ignore end1))
1224              (with-array-data ((data2 bit-array-2) (start2) (end2))
1225                (declare (ignore end2))
1226                (with-array-data ((data3 result-bit-array) (start3) (end3))
1227                  (do ((index-1 start1 (1+ index-1))
1228                       (index-2 start2 (1+ index-2))
1229                       (index-3 start3 (1+ index-3)))
1230                      ((>= index-3 end3) result-bit-array)
1231                    (declare (type index index-1 index-2 index-3))
1232                    (setf (sbit data3 index-3)
1233                          (logand (,function (sbit data1 index-1)
1234                                             (sbit data2 index-2))
1235                                  1))))))))))
1236
1237 (def-bit-array-op bit-and logand)
1238 (def-bit-array-op bit-ior logior)
1239 (def-bit-array-op bit-xor logxor)
1240 (def-bit-array-op bit-eqv logeqv)
1241 (def-bit-array-op bit-nand lognand)
1242 (def-bit-array-op bit-nor lognor)
1243 (def-bit-array-op bit-andc1 logandc1)
1244 (def-bit-array-op bit-andc2 logandc2)
1245 (def-bit-array-op bit-orc1 logorc1)
1246 (def-bit-array-op bit-orc2 logorc2)
1247
1248 (defun bit-not (bit-array &optional result-bit-array)
1249   #!+sb-doc
1250   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1251   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1252   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1253   created. Both arrays must have the same rank and dimensions."
1254   (declare (type (array bit) bit-array)
1255            (type (or (array bit) (member t nil)) result-bit-array))
1256   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1257     (if (and (simple-bit-vector-p bit-array)
1258              (simple-bit-vector-p result-bit-array))
1259         (locally (declare (optimize (speed 3) (safety 0)))
1260           (bit-not bit-array result-bit-array))
1261         (with-array-data ((src bit-array) (src-start) (src-end))
1262           (declare (ignore src-end))
1263           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1264             (do ((src-index src-start (1+ src-index))
1265                  (dst-index dst-start (1+ dst-index)))
1266                 ((>= dst-index dst-end) result-bit-array)
1267               (declare (type index src-index dst-index))
1268               (setf (sbit dst dst-index)
1269                     (logxor (sbit src src-index) 1))))))))