src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data/fp (array start end)
  50   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer t))
  51
  52 (defun %with-array-data (array start end)
  53   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer nil))
  54
  55 (defun %data-vector-and-index (array index)
  56   (if (array-header-p array)
  57       (multiple-value-bind (vector index)
  58           (%with-array-data array index nil)
  59         (values vector index))
  60       (values array index)))
  61 \f
  62 ;;;; MAKE-ARRAY
  63 (eval-when (:compile-toplevel :execute)
  64   (sb!xc:defmacro pick-vector-type (type &rest specs)
  65     `(cond ,@(mapcar (lambda (spec)
  66                        `(,(if (eq (car spec) t)
  67                               t
  68                               `(subtypep ,type ',(car spec)))
  69                          ,@(cdr spec)))
  70                      specs))))
  71
  72 ;;; These functions are used in the implementation of MAKE-ARRAY for
  73 ;;; complex arrays. There are lots of transforms to simplify
  74 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  75 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  76 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  77 ;;; making this somewhat efficient, at least not doing full calls to
  78 ;;; SUBTYPEP in the easy cases.
  79 (defun %vector-widetag-and-n-bits (type)
  80   (case type
  81     ;; Pick off some easy common cases.
  82     ;;
  83     ;; (Perhaps we should make a much more exhaustive table of easy
  84     ;; common cases here. Or perhaps the effort would be better spent
  85     ;; on smarter compiler transforms which do the calculation once
  86     ;; and for all in any reasonable user programs.)
  87     ((t)
  88      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
  89     ((base-char standard-char #!-sb-unicode character)
  90      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
  91     #!+sb-unicode
  92     ((character)
  93      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
  94     ((bit)
  95      (values #.sb!vm:simple-bit-vector-widetag 1))
  96     ;; OK, we have to wade into SUBTYPEPing after all.
  97     (t
  98      #.`(pick-vector-type type
  99          ,@(map 'list
 100                 (lambda (saetp)
 101                   `(,(sb!vm:saetp-specifier saetp)
 102                     (values ,(sb!vm:saetp-typecode saetp)
 103                             ,(sb!vm:saetp-n-bits saetp))))
 104                 sb!vm:*specialized-array-element-type-properties*)))))
 105
 106 (defun %complex-vector-widetag (type)
 107   (case type
 108     ;; Pick off some easy common cases.
 109     ((t)
 110      #.sb!vm:complex-vector-widetag)
 111     ((base-char #!-sb-unicode character)
 112      #.sb!vm:complex-base-string-widetag)
 113     #!+sb-unicode
 114     ((character)
 115      #.sb!vm:complex-character-string-widetag)
 116     ((nil)
 117      #.sb!vm:complex-vector-nil-widetag)
 118     ((bit)
 119      #.sb!vm:complex-bit-vector-widetag)
 120     ;; OK, we have to wade into SUBTYPEPing after all.
 121     (t
 122      (pick-vector-type type
 123        (nil #.sb!vm:complex-vector-nil-widetag)
 124        #!-sb-unicode
 125        (character #.sb!vm:complex-base-string-widetag)
 126        #!+sb-unicode
 127        (base-char #.sb!vm:complex-base-string-widetag)
 128        #!+sb-unicode
 129        (character #.sb!vm:complex-character-string-widetag)
 130        (bit #.sb!vm:complex-bit-vector-widetag)
 131        (t #.sb!vm:complex-vector-widetag)))))
 132
 133 (defun make-array (dimensions &key
 134                               (element-type t)
 135                               (initial-element nil initial-element-p)
 136                               (initial-contents nil initial-contents-p)
 137                               adjustable fill-pointer
 138                               displaced-to displaced-index-offset)
 139   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 140          (array-rank (length (the list dimensions)))
 141          (simple (and (null fill-pointer)
 142                       (not adjustable)
 143                       (null displaced-to))))
 144     (declare (fixnum array-rank))
 145     (when (and displaced-index-offset (null displaced-to))
 146       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 147     (when (and displaced-to
 148                (arrayp displaced-to)
 149                (not (equal (array-element-type displaced-to)
 150                            (upgraded-array-element-type element-type))))
 151       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 152     (if (and simple (= array-rank 1))
 153         ;; it's a (SIMPLE-ARRAY * (*))
 154         (multiple-value-bind (type n-bits)
 155             (%vector-widetag-and-n-bits element-type)
 156           (declare (type (unsigned-byte 8) type)
 157                    (type (integer 0 256) n-bits))
 158           (let* ((length (car dimensions))
 159                  (array (allocate-vector
 160                          type
 161                          length
 162                          (ceiling
 163                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 164                                      #!+sb-unicode
 165                                      (= type
 166                                         sb!vm:simple-character-string-widetag))
 167                                  (1+ length)
 168                                  length)
 169                              n-bits)
 170                           sb!vm:n-word-bits))))
 171             (declare (type index length))
 172             (when initial-element-p
 173               (fill array initial-element))
 174             (when initial-contents-p
 175               (when initial-element-p
 176                 (error "can't specify both :INITIAL-ELEMENT and ~
 177                        :INITIAL-CONTENTS"))
 178               (unless (= length (length initial-contents))
 179                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 180                        the vector length is ~W."
 181                        (length initial-contents)
 182                        length))
 183               (replace array initial-contents))
 184             array))
 185         ;; it's either a complex array or a multidimensional array.
 186         (let* ((total-size (reduce #'* dimensions))
 187                (data (or displaced-to
 188                          (data-vector-from-inits
 189                           dimensions total-size element-type
 190                           initial-contents initial-contents-p
 191                           initial-element initial-element-p)))
 192                (array (make-array-header
 193                        (cond ((= array-rank 1)
 194                               (%complex-vector-widetag element-type))
 195                              (simple sb!vm:simple-array-widetag)
 196                              (t sb!vm:complex-array-widetag))
 197                        array-rank)))
 198           (cond (fill-pointer
 199                  (unless (= array-rank 1)
 200                    (error "Only vectors can have fill pointers."))
 201                  (let ((length (car dimensions)))
 202                    (declare (fixnum length))
 203                    (setf (%array-fill-pointer array)
 204                      (cond ((eq fill-pointer t)
 205                             length)
 206                            (t
 207                             (unless (and (fixnump fill-pointer)
 208                                          (>= fill-pointer 0)
 209                                          (<= fill-pointer length))
 210                               ;; FIXME: should be TYPE-ERROR?
 211                               (error "invalid fill-pointer ~W"
 212                                      fill-pointer))
 213                             fill-pointer))))
 214                  (setf (%array-fill-pointer-p array) t))
 215                 (t
 216                  (setf (%array-fill-pointer array) total-size)
 217                  (setf (%array-fill-pointer-p array) nil)))
 218           (setf (%array-available-elements array) total-size)
 219           (setf (%array-data-vector array) data)
 220           (cond (displaced-to
 221                  (when (or initial-element-p initial-contents-p)
 222                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 223                    can be specified along with :DISPLACED-TO"))
 224                  (let ((offset (or displaced-index-offset 0)))
 225                    (when (> (+ offset total-size)
 226                             (array-total-size displaced-to))
 227                      (error "~S doesn't have enough elements." displaced-to))
 228                    (setf (%array-displacement array) offset)
 229                    (setf (%array-displaced-p array) t)))
 230                 (t
 231                  (setf (%array-displaced-p array) nil)))
 232           (let ((axis 0))
 233             (dolist (dim dimensions)
 234               (setf (%array-dimension array axis) dim)
 235               (incf axis)))
 236           array))))
 237
 238 (defun make-static-vector (length &key
 239                            (element-type '(unsigned-byte 8))
 240                            (initial-contents nil initial-contents-p)
 241                            (initial-element nil initial-element-p))
 242   "Allocate vector of LENGTH elements in static space. Only allocation
 243 of specialized arrays is supported."
 244   ;; STEP 1: check inputs fully
 245   ;;
 246   ;; This way of doing explicit checks before the vector is allocated
 247   ;; is expensive, but probably worth the trouble as once we've allocated
 248   ;; the vector we have no way to get rid of it anymore...
 249   (when (eq t (upgraded-array-element-type element-type))
 250     (error "Static arrays of type ~S not supported."
 251            element-type))
 252   (when initial-contents-p
 253     (when initial-element-p
 254       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 255     (unless (= length (length initial-contents))
 256       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 257               vector length is ~W."
 258              (length initial-contents)
 259              length))
 260     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 261       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 262              element-type)))
 263   (when initial-element-p
 264     (unless (typep initial-element element-type)
 265       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 266              initial-element element-type)))
 267   ;; STEP 2
 268   ;;
 269   ;; Allocate and possibly initialize the vector.
 270   (multiple-value-bind (type n-bits)
 271       (sb!impl::%vector-widetag-and-n-bits element-type)
 272     (let ((vector
 273            (allocate-static-vector type length
 274                                    (ceiling (* length n-bits)
 275                                             sb!vm:n-word-bits))))
 276       (cond (initial-element-p
 277              (fill vector initial-element))
 278             (initial-contents-p
 279              (replace vector initial-contents))
 280             (t
 281              vector)))))
 282
 283 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 284 ;;; specified array characteristics. Dimensions is only used to pass
 285 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 286 ;;; initial-contents.
 287 (defun data-vector-from-inits (dimensions total-size element-type
 288                                initial-contents initial-contents-p
 289                                initial-element initial-element-p)
 290   (when (and initial-contents-p initial-element-p)
 291     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 292             either MAKE-ARRAY or ADJUST-ARRAY."))
 293   (let ((data (if initial-element-p
 294                   (make-array total-size
 295                               :element-type element-type
 296                               :initial-element initial-element)
 297                   (make-array total-size
 298                               :element-type element-type))))
 299     (cond (initial-element-p
 300            (unless (simple-vector-p data)
 301              (unless (typep initial-element element-type)
 302                (error "~S cannot be used to initialize an array of type ~S."
 303                       initial-element element-type))
 304              (fill (the vector data) initial-element)))
 305           (initial-contents-p
 306            (fill-data-vector data dimensions initial-contents)))
 307     data))
 308
 309 (defun vector (&rest objects)
 310   #!+sb-doc
 311   "Construct a SIMPLE-VECTOR from the given objects."
 312   (coerce (the list objects) 'simple-vector))
 313 \f
 314
 315 ;;;; accessor/setter functions
 316
 317 ;;; Dispatch to an optimized routine the data vector accessors for
 318 ;;; each different specialized vector type. Do dispatching by looking
 319 ;;; up the widetag in the array rather than with the typecases, which
 320 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 321 ;;; provide separate versions where bounds checking has been moved
 322 ;;; from the callee to the caller, since it's much cheaper to do once
 323 ;;; the type information is available. Finally, for each of these
 324 ;;; routines also provide a slow path, taken for arrays that are not
 325 ;;; vectors or not simple.
 326 (macrolet ((def (name table-name)
 327              `(progn
 328                 (defvar ,table-name)
 329                 (defmacro ,name (array-var)
 330                  `(the function
 331                     (let ((tag 0)
 332                           (offset
 333                            #.(ecase sb!c:*backend-byte-order*
 334                                (:little-endian
 335                                 (- sb!vm:other-pointer-lowtag))
 336                                (:big-endian
 337                                 (- (1- sb!vm:n-word-bytes) sb!vm:other-pointer-lowtag)))))
 338                       ;; WIDETAG-OF needs extra code to handle LIST and
 339                       ;; FUNCTION lowtags. We're only dispatching on
 340                       ;; other pointers, so let's do the lowtag
 341                       ;; extraction manually.
 342                       (when (sb!vm::%other-pointer-p ,array-var)
 343                         (setf tag
 344                               (sb!sys:sap-ref-8 (int-sap (get-lisp-obj-address ,array-var))
 345                                                 offset)))
 346                       ;; SYMBOL-GLOBAL-VALUE is a performance hack
 347                       ;; for threaded builds.
 348                       (svref (sb!vm::symbol-global-value ',',table-name) tag)))))))
 349   (def !find-data-vector-setter *data-vector-setters*)
 350   (def !find-data-vector-setter/check-bounds *data-vector-setters/check-bounds*)
 351   (def !find-data-vector-reffer *data-vector-reffers*)
 352   (def !find-data-vector-reffer/check-bounds *data-vector-reffers/check-bounds*))
 353
 354 (macrolet ((%ref (accessor-getter extra-params)
 355              `(funcall (,accessor-getter array) array index ,@extra-params))
 356            (define (accessor-name slow-accessor-name accessor-getter
 357                                   extra-params check-bounds)
 358              `(progn
 359                 (defun ,accessor-name (array index ,@extra-params)
 360                   (declare (optimize speed
 361                                      ;; (SAFETY 0) is ok. All calls to
 362                                      ;; these functions are generated by
 363                                      ;; the compiler, so argument count
 364                                      ;; checking isn't needed. Type checking
 365                                      ;; is done implicitly via the widetag
 366                                      ;; dispatch.
 367                                      (safety 0)))
 368                   (%ref ,accessor-getter ,extra-params))
 369                 (defun ,slow-accessor-name (array index ,@extra-params)
 370                   (declare (optimize speed (safety 0)))
 371                   (if (not (%array-displaced-p array))
 372                       ;; The reasonably quick path of non-displaced complex
 373                       ;; arrays.
 374                       (let ((array (%array-data-vector array)))
 375                         (%ref ,accessor-getter ,extra-params))
 376                       ;; The real slow path.
 377                       (with-array-data
 378                           ((vector array)
 379                            (index (locally
 380                                       (declare (optimize (speed 1) (safety 1)))
 381                                     (,@check-bounds index)))
 382                            (end)
 383                            :force-inline t)
 384                         (declare (ignore end))
 385                         (,accessor-name vector index ,@extra-params)))))))
 386   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 387     !find-data-vector-reffer
 388     nil (progn))
 389   (define hairy-data-vector-set slow-hairy-data-vector-set
 390     !find-data-vector-setter
 391     (new-value) (progn))
 392   (define hairy-data-vector-ref/check-bounds
 393       slow-hairy-data-vector-ref/check-bounds
 394     !find-data-vector-reffer/check-bounds
 395     nil (%check-bound array (array-dimension array 0)))
 396   (define hairy-data-vector-set/check-bounds
 397       slow-hairy-data-vector-set/check-bounds
 398     !find-data-vector-setter/check-bounds
 399     (new-value) (%check-bound array (array-dimension array 0))))
 400
 401 (defun hairy-ref-error (array index &optional new-value)
 402   (declare (ignore index new-value))
 403   (error 'type-error
 404          :datum array
 405          :expected-type 'vector))
 406
 407 ;;; Populate the dispatch tables.
 408 (macrolet ((define-reffer (saetp check-form)
 409              (let* ((type (sb!vm:saetp-specifier saetp))
 410                     (atype `(simple-array ,type (*))))
 411                `(named-lambda optimized-data-vector-ref (vector index)
 412                   (declare (optimize speed (safety 0)))
 413                   (data-vector-ref (the ,atype vector)
 414                                    (locally
 415                                        (declare (optimize (safety 1)))
 416                                      (the index
 417                                        (,@check-form index)))))))
 418            (define-setter (saetp check-form)
 419              (let* ((type (sb!vm:saetp-specifier saetp))
 420                     (atype `(simple-array ,type (*))))
 421                `(named-lambda optimized-data-vector-set (vector index new-value)
 422                   (declare (optimize speed (safety 0)))
 423                   (data-vector-set (the ,atype vector)
 424                                    (locally
 425                                        (declare (optimize (safety 1)))
 426                                      (the index
 427                                        (,@check-form index)))
 428                                    (locally
 429                                        ;; SPEED 1 needed to avoid the compiler
 430                                        ;; from downgrading the type check to
 431                                        ;; a cheaper one.
 432                                        (declare (optimize (speed 1)
 433                                                           (safety 1)))
 434                                      (the ,type new-value)))
 435                   ;; For specialized arrays, the return from
 436                   ;; data-vector-set would have to be reboxed to be a
 437                   ;; (Lisp) return value; instead, we use the
 438                   ;; already-boxed value as the return.
 439                   new-value)))
 440            (define-reffers (symbol deffer check-form slow-path)
 441              `(progn
 442                 (setf ,symbol (make-array sb!vm::widetag-mask
 443                                           :initial-element #'hairy-ref-error))
 444                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 445                                          sb!vm:complex-vector-nil-widetag
 446                                          sb!vm:complex-bit-vector-widetag
 447                                          #!+sb-unicode sb!vm:complex-character-string-widetag
 448                                          sb!vm:complex-base-string-widetag
 449                                          sb!vm:simple-array-widetag
 450                                          sb!vm:complex-array-widetag)
 451                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 452                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 453                         for widetag = (sb!vm:saetp-typecode saetp)
 454                         collect `(setf (svref ,symbol ,widetag)
 455                                        (,deffer ,saetp ,check-form))))))
 456   (defun !hairy-data-vector-reffer-init ()
 457     (define-reffers *data-vector-reffers* define-reffer
 458       (progn)
 459       #'slow-hairy-data-vector-ref)
 460     (define-reffers *data-vector-setters* define-setter
 461       (progn)
 462       #'slow-hairy-data-vector-set)
 463     (define-reffers *data-vector-reffers/check-bounds* define-reffer
 464       (%check-bound vector (length vector))
 465       #'slow-hairy-data-vector-ref/check-bounds)
 466     (define-reffers *data-vector-setters/check-bounds* define-setter
 467       (%check-bound vector (length vector))
 468       #'slow-hairy-data-vector-set/check-bounds)))
 469
 470 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 471 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 472 ;;; definition is needed for the compiler to use in constant folding.)
 473 (defun data-vector-ref (array index)
 474   (hairy-data-vector-ref array index))
 475
 476 (defun data-vector-ref-with-offset (array index offset)
 477   (hairy-data-vector-ref array (+ index offset)))
 478
 479 (declaim (ftype (function (array integer integer &optional t) nil)
 480                 invalid-array-index-error))
 481 (defun invalid-array-index-error (array index bound &optional axis)
 482   (error 'invalid-array-index-error
 483          :array array
 484          :axis axis
 485          :datum index
 486          :expected-type `(integer 0 (,bound))))
 487
 488 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 489 (defun %array-row-major-index (array subscripts
 490                                      &optional (invalid-index-error-p t))
 491   (declare (array array)
 492            (list subscripts))
 493   (let ((rank (array-rank array)))
 494     (unless (= rank (length subscripts))
 495       (error "wrong number of subscripts, ~W, for array of rank ~W"
 496              (length subscripts) rank))
 497     (if (array-header-p array)
 498         (do ((subs (nreverse subscripts) (cdr subs))
 499              (axis (1- (array-rank array)) (1- axis))
 500              (chunk-size 1)
 501              (result 0))
 502             ((null subs) result)
 503           (declare (list subs) (fixnum axis chunk-size result))
 504           (let ((index (car subs))
 505                 (dim (%array-dimension array axis)))
 506             (declare (fixnum dim))
 507             (unless (and (fixnump index) (< -1 index dim))
 508               (if invalid-index-error-p
 509                   (invalid-array-index-error array index dim axis)
 510                   (return-from %array-row-major-index nil)))
 511             (incf result (* chunk-size (the fixnum index)))
 512             (setf chunk-size (* chunk-size dim))))
 513         (let ((index (first subscripts))
 514               (length (length (the (simple-array * (*)) array))))
 515           (unless (and (fixnump index) (< -1 index length))
 516             (if invalid-index-error-p
 517                 (invalid-array-index-error array index length)
 518                 (return-from %array-row-major-index nil)))
 519           index))))
 520
 521 (defun array-in-bounds-p (array &rest subscripts)
 522   #!+sb-doc
 523   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 524   (if (%array-row-major-index array subscripts nil)
 525       t))
 526
 527 (defun array-row-major-index (array &rest subscripts)
 528   (declare (truly-dynamic-extent subscripts))
 529   (%array-row-major-index array subscripts))
 530
 531 (defun aref (array &rest subscripts)
 532   #!+sb-doc
 533   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 534   (declare (truly-dynamic-extent subscripts))
 535   (row-major-aref array (%array-row-major-index array subscripts)))
 536
 537 (defun %aset (array &rest stuff)
 538   (declare (truly-dynamic-extent stuff))
 539   (let ((subscripts (butlast stuff))
 540         (new-value (car (last stuff))))
 541     (setf (row-major-aref array (%array-row-major-index array subscripts))
 542           new-value)))
 543
 544 ;;; FIXME: What's supposed to happen with functions
 545 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 546 ;;; DEFSETF FOO is also defined? It seems as though the logical
 547 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 548 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 549 ;;; just as for ordinary functions
 550 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 551 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 552 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 553 ;;;  ZOO
 554 ;;;  * (DEFUN ZOO (X) (* 3 X))
 555 ;;;  Warning: ZOO previously defined as a macro.
 556 ;;;  ZOO
 557 ;;; But that doesn't seem to be what happens in CMU CL.
 558 ;;;
 559 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 560 ;;; 5.1.2.5) requires implementations to support
 561 ;;;   (SETF (APPLY #'AREF ...) ...)
 562 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 563 ;;; also terrifying that this sequence of definitions causes it to
 564 ;;; work.
 565 ;;;
 566 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 567 ;;; has a setf expansion and/or a setf function defined.
 568
 569 #!-sb-fluid (declaim (inline (setf aref)))
 570 (defun (setf aref) (new-value array &rest subscripts)
 571   (declare (truly-dynamic-extent subscripts))
 572   (declare (type array array))
 573   (setf (row-major-aref array (%array-row-major-index array subscripts))
 574         new-value))
 575
 576 (defun row-major-aref (array index)
 577   #!+sb-doc
 578   "Return the element of array corressponding to the row-major index. This is
 579    SETF'able."
 580   (declare (optimize (safety 1)))
 581   (row-major-aref array index))
 582
 583 (defun %set-row-major-aref (array index new-value)
 584   (declare (optimize (safety 1)))
 585   (setf (row-major-aref array index) new-value))
 586
 587 (defun svref (simple-vector index)
 588   #!+sb-doc
 589   "Return the INDEX'th element of the given Simple-Vector."
 590   (declare (optimize (safety 1)))
 591   (aref simple-vector index))
 592
 593 (defun %svset (simple-vector index new)
 594   (declare (optimize (safety 1)))
 595   (setf (aref simple-vector index) new))
 596
 597 (defun bit (bit-array &rest subscripts)
 598   #!+sb-doc
 599   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 600   (declare (type (array bit) bit-array) (optimize (safety 1)))
 601   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 602
 603 (defun %bitset (bit-array &rest stuff)
 604   (declare (type (array bit) bit-array) (optimize (safety 1)))
 605   (let ((subscripts (butlast stuff))
 606         (new-value (car (last stuff))))
 607     (setf (row-major-aref bit-array
 608                           (%array-row-major-index bit-array subscripts))
 609           new-value)))
 610
 611 #!-sb-fluid (declaim (inline (setf bit)))
 612 (defun (setf bit) (new-value bit-array &rest subscripts)
 613   (declare (type (array bit) bit-array) (optimize (safety 1)))
 614   (setf (row-major-aref bit-array
 615                         (%array-row-major-index bit-array subscripts))
 616         new-value))
 617
 618 (defun sbit (simple-bit-array &rest subscripts)
 619   #!+sb-doc
 620   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 621   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 622   (row-major-aref simple-bit-array
 623                   (%array-row-major-index simple-bit-array subscripts)))
 624
 625 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 626 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 627 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 628 ;;; -- WHN 19990911
 629 (defun %sbitset (simple-bit-array &rest stuff)
 630   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 631   (let ((subscripts (butlast stuff))
 632         (new-value (car (last stuff))))
 633     (setf (row-major-aref simple-bit-array
 634                           (%array-row-major-index simple-bit-array subscripts))
 635           new-value)))
 636
 637 #!-sb-fluid (declaim (inline (setf sbit)))
 638 (defun (setf sbit) (new-value bit-array &rest subscripts)
 639   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 640   (setf (row-major-aref bit-array
 641                         (%array-row-major-index bit-array subscripts))
 642         new-value))
 643 \f
 644 ;;;; miscellaneous array properties
 645
 646 (defun array-element-type (array)
 647   #!+sb-doc
 648   "Return the type of the elements of the array"
 649   (let ((widetag (widetag-of array)))
 650     (macrolet ((pick-element-type (&rest stuff)
 651                  `(cond ,@(mapcar (lambda (stuff)
 652                                     (cons
 653                                      (let ((item (car stuff)))
 654                                        (cond ((eq item t)
 655                                               t)
 656                                              ((listp item)
 657                                               (cons 'or
 658                                                     (mapcar (lambda (x)
 659                                                               `(= widetag ,x))
 660                                                             item)))
 661                                              (t
 662                                               `(= widetag ,item))))
 663                                      (cdr stuff)))
 664                                   stuff))))
 665       #.`(pick-element-type
 666           ,@(map 'list
 667                  (lambda (saetp)
 668                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 669                           (list (sb!vm:saetp-typecode saetp)
 670                                 (sb!vm:saetp-complex-typecode saetp))
 671                           (sb!vm:saetp-typecode saetp))
 672                      ',(sb!vm:saetp-specifier saetp)))
 673                  sb!vm:*specialized-array-element-type-properties*)
 674           ((sb!vm:simple-array-widetag
 675             sb!vm:complex-vector-widetag
 676             sb!vm:complex-array-widetag)
 677            (with-array-data ((array array) (start) (end))
 678              (declare (ignore start end))
 679              (array-element-type array)))
 680           (t
 681            (error 'type-error :datum array :expected-type 'array))))))
 682
 683 (defun array-rank (array)
 684   #!+sb-doc
 685   "Return the number of dimensions of ARRAY."
 686   (if (array-header-p array)
 687       (%array-rank array)
 688       1))
 689
 690 (defun array-dimension (array axis-number)
 691   #!+sb-doc
 692   "Return the length of dimension AXIS-NUMBER of ARRAY."
 693   (declare (array array) (type index axis-number))
 694   (cond ((not (array-header-p array))
 695          (unless (= axis-number 0)
 696            (error "Vector axis is not zero: ~S" axis-number))
 697          (length (the (simple-array * (*)) array)))
 698         ((>= axis-number (%array-rank array))
 699          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 700                 axis-number array (%array-rank array)))
 701         (t
 702          ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
 703          ;;
 704          ;;   "If A is displaced to B, the consequences are
 705          ;;   unspecified if B is adjusted in such a way that it no
 706          ;;   longer has enough elements to satisfy A.
 707          ;;
 708          ;; In situations where this matters we should be doing a
 709          ;; bounds-check, which in turn uses ARRAY-DIMENSION -- so
 710          ;; this seems like a good place to signal an error.
 711          (multiple-value-bind (target offset) (array-displacement array)
 712            (when (and target
 713                       (> (array-total-size array)
 714                          (- (array-total-size target) offset)))
 715                (error 'displaced-to-array-too-small-error
 716                       :format-control "~@<The displaced-to array is too small. ~S ~
 717                                       elements after offset required, ~S available.~:@>"
 718                       :format-arguments (list (array-total-size array)
 719                                               (- (array-total-size target) offset))))
 720            (%array-dimension array axis-number)))))
 721
 722 (defun array-dimensions (array)
 723   #!+sb-doc
 724   "Return a list whose elements are the dimensions of the array"
 725   (declare (array array))
 726   (if (array-header-p array)
 727       (do ((results nil (cons (array-dimension array index) results))
 728            (index (1- (array-rank array)) (1- index)))
 729           ((minusp index) results))
 730       (list (array-dimension array 0))))
 731
 732 (defun array-total-size (array)
 733   #!+sb-doc
 734   "Return the total number of elements in the Array."
 735   (declare (array array))
 736   (if (array-header-p array)
 737       (%array-available-elements array)
 738       (length (the vector array))))
 739
 740 (defun array-displacement (array)
 741   #!+sb-doc
 742   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 743    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 744   (declare (type array array))
 745   (if (and (array-header-p array) ; if unsimple and
 746            (%array-displaced-p array)) ; displaced
 747       (values (%array-data-vector array) (%array-displacement array))
 748       (values nil 0)))
 749
 750 (defun adjustable-array-p (array)
 751   #!+sb-doc
 752   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 753    to the argument, this happens for complex arrays."
 754   (declare (array array))
 755   ;; Note that this appears not to be a fundamental limitation.
 756   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 757   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 758   ;; -- CSR, 2004-03-01.
 759   (not (typep array 'simple-array)))
 760 \f
 761 ;;;; fill pointer frobbing stuff
 762
 763 (defun array-has-fill-pointer-p (array)
 764   #!+sb-doc
 765   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 766   (declare (array array))
 767   (and (array-header-p array) (%array-fill-pointer-p array)))
 768
 769 (defun fill-pointer-error (vector arg)
 770   (cond (arg
 771          (aver (array-has-fill-pointer-p vector))
 772          (let ((max (%array-available-elements vector)))
 773            (error 'simple-type-error
 774                   :datum arg
 775                   :expected-type (list 'integer 0 max)
 776                   :format-control "The new fill pointer, ~S, is larger than the length of the vector (~S.)"
 777                   :format-arguments (list arg max))))
 778         (t
 779          (error 'simple-type-error
 780                 :datum vector
 781                 :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 782                 :format-control "~S is not an array with a fill pointer."
 783                 :format-arguments (list vector)))))
 784
 785 (defun fill-pointer (vector)
 786   #!+sb-doc
 787   "Return the FILL-POINTER of the given VECTOR."
 788   (if (array-has-fill-pointer-p vector)
 789       (%array-fill-pointer vector)
 790       (fill-pointer-error vector nil)))
 791
 792 (defun %set-fill-pointer (vector new)
 793   (flet ((oops (x)
 794            (fill-pointer-error vector x)))
 795     (if (array-has-fill-pointer-p vector)
 796         (if (> new (%array-available-elements vector))
 797             (oops new)
 798             (setf (%array-fill-pointer vector) new))
 799         (oops nil))))
 800
 801 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 802 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 803 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 804 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 805 ;;; back to CMU CL).
 806 (defun vector-push (new-el array)
 807   #!+sb-doc
 808   "Attempt to set the element of ARRAY designated by its fill pointer
 809    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 810    too large, NIL is returned, otherwise the index of the pushed element is
 811    returned."
 812   (declare (vector array))
 813   (let ((fill-pointer (fill-pointer array)))
 814     (declare (fixnum fill-pointer))
 815     (cond ((= fill-pointer (%array-available-elements array))
 816            nil)
 817           (t
 818            (locally (declare (optimize (safety 0)))
 819              (setf (aref array fill-pointer) new-el))
 820            (setf (%array-fill-pointer array) (1+ fill-pointer))
 821            fill-pointer))))
 822
 823 (defun vector-push-extend (new-element
 824                            vector
 825                            &optional
 826                            (min-extension
 827                             (let ((length (length vector)))
 828                               (min (1+ length)
 829                                    (- array-dimension-limit length)))))
 830   (declare (vector vector) (fixnum min-extension))
 831   (let ((fill-pointer (fill-pointer vector)))
 832     (declare (fixnum fill-pointer))
 833     (when (= fill-pointer (%array-available-elements vector))
 834       (adjust-array vector (+ fill-pointer (max 1 min-extension))))
 835     ;; disable bounds checking
 836     (locally (declare (optimize (safety 0)))
 837       (setf (aref vector fill-pointer) new-element))
 838     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 839     fill-pointer))
 840
 841 (defun vector-pop (array)
 842   #!+sb-doc
 843   "Decrease the fill pointer by 1 and return the element pointed to by the
 844   new fill pointer."
 845   (declare (vector array))
 846   (let ((fill-pointer (fill-pointer array)))
 847     (declare (fixnum fill-pointer))
 848     (if (zerop fill-pointer)
 849         (error "There is nothing left to pop.")
 850         ;; disable bounds checking (and any fixnum test)
 851         (locally (declare (optimize (safety 0)))
 852           (aref array
 853                 (setf (%array-fill-pointer array)
 854                       (1- fill-pointer)))))))
 855
 856 \f
 857 ;;;; ADJUST-ARRAY
 858
 859 (defun adjust-array (array dimensions &key
 860                            (element-type (array-element-type array))
 861                            (initial-element nil initial-element-p)
 862                            (initial-contents nil initial-contents-p)
 863                            fill-pointer
 864                            displaced-to displaced-index-offset)
 865   #!+sb-doc
 866   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 867   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 868     (cond ((/= (the fixnum (length (the list dimensions)))
 869                (the fixnum (array-rank array)))
 870            (error "The number of dimensions not equal to rank of array."))
 871           ((not (subtypep element-type (array-element-type array)))
 872            (error "The new element type, ~S, is incompatible with old type."
 873                   element-type))
 874           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 875            (error 'type-error
 876                   :datum array
 877                   :expected-type '(satisfies array-has-fill-pointer-p))))
 878     (let ((array-rank (length (the list dimensions))))
 879       (declare (fixnum array-rank))
 880       (unless (= array-rank 1)
 881         (when fill-pointer
 882           (error "Only vectors can have fill pointers.")))
 883       (cond (initial-contents-p
 884              ;; array former contents replaced by INITIAL-CONTENTS
 885              (if (or initial-element-p displaced-to)
 886                  (error "INITIAL-CONTENTS may not be specified with ~
 887                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 888              (let* ((array-size (apply #'* dimensions))
 889                     (array-data (data-vector-from-inits
 890                                  dimensions array-size element-type
 891                                  initial-contents initial-contents-p
 892                                  initial-element initial-element-p)))
 893                (if (adjustable-array-p array)
 894                    (set-array-header array array-data array-size
 895                                  (get-new-fill-pointer array array-size
 896                                                        fill-pointer)
 897                                  0 dimensions nil)
 898                    (if (array-header-p array)
 899                        ;; simple multidimensional or single dimensional array
 900                        (make-array dimensions
 901                                    :element-type element-type
 902                                    :initial-contents initial-contents)
 903                        array-data))))
 904             (displaced-to
 905              ;; We already established that no INITIAL-CONTENTS was supplied.
 906              (when initial-element
 907                (error "The :INITIAL-ELEMENT option may not be specified ~
 908                        with :DISPLACED-TO."))
 909              (unless (subtypep element-type (array-element-type displaced-to))
 910                (error "can't displace an array of type ~S into another of ~
 911                        type ~S"
 912                       element-type (array-element-type displaced-to)))
 913              (let ((displacement (or displaced-index-offset 0))
 914                    (array-size (apply #'* dimensions)))
 915                (declare (fixnum displacement array-size))
 916                (if (< (the fixnum (array-total-size displaced-to))
 917                       (the fixnum (+ displacement array-size)))
 918                    (error "The :DISPLACED-TO array is too small."))
 919                (if (adjustable-array-p array)
 920                    ;; None of the original contents appear in adjusted array.
 921                    (set-array-header array displaced-to array-size
 922                                      (get-new-fill-pointer array array-size
 923                                                            fill-pointer)
 924                                      displacement dimensions t)
 925                    ;; simple multidimensional or single dimensional array
 926                    (make-array dimensions
 927                                :element-type element-type
 928                                :displaced-to displaced-to
 929                                :displaced-index-offset
 930                                displaced-index-offset))))
 931             ((= array-rank 1)
 932              (let ((old-length (array-total-size array))
 933                    (new-length (car dimensions))
 934                    new-data)
 935                (declare (fixnum old-length new-length))
 936                (with-array-data ((old-data array) (old-start)
 937                                  (old-end old-length))
 938                  (cond ((or (and (array-header-p array)
 939                                  (%array-displaced-p array))
 940                             (< old-length new-length))
 941                         (setf new-data
 942                               (data-vector-from-inits
 943                                dimensions new-length element-type
 944                                initial-contents initial-contents-p
 945                                initial-element initial-element-p))
 946                         (replace new-data old-data
 947                                  :start2 old-start :end2 old-end))
 948                        (t (setf new-data
 949                                 (shrink-vector old-data new-length))))
 950                  (if (adjustable-array-p array)
 951                      (set-array-header array new-data new-length
 952                                        (get-new-fill-pointer array new-length
 953                                                              fill-pointer)
 954                                        0 dimensions nil)
 955                      new-data))))
 956             (t
 957              (let ((old-length (%array-available-elements array))
 958                    (new-length (apply #'* dimensions)))
 959                (declare (fixnum old-length new-length))
 960                (with-array-data ((old-data array) (old-start)
 961                                  (old-end old-length))
 962                  (declare (ignore old-end))
 963                  (let ((new-data (if (or (and (array-header-p array)
 964                                               (%array-displaced-p array))
 965                                          (> new-length old-length))
 966                                      (data-vector-from-inits
 967                                       dimensions new-length
 968                                       element-type () nil
 969                                       initial-element initial-element-p)
 970                                      old-data)))
 971                    (if (or (zerop old-length) (zerop new-length))
 972                        (when initial-element-p (fill new-data initial-element))
 973                        (zap-array-data old-data (array-dimensions array)
 974                                        old-start
 975                                        new-data dimensions new-length
 976                                        element-type initial-element
 977                                        initial-element-p))
 978                    (if (adjustable-array-p array)
 979                        (set-array-header array new-data new-length
 980                                          nil 0 dimensions nil)
 981                        (let ((new-array
 982                               (make-array-header
 983                                sb!vm:simple-array-widetag array-rank)))
 984                          (set-array-header new-array new-data new-length
 985                                            nil 0 dimensions nil)))))))))))
 986
 987
 988 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 989   (cond ((not fill-pointer)
 990          (when (array-has-fill-pointer-p old-array)
 991            (when (> (%array-fill-pointer old-array) new-array-size)
 992              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 993                      smaller than its fill pointer (~S)"
 994                     old-array new-array-size (fill-pointer old-array)))
 995            (%array-fill-pointer old-array)))
 996         ((not (array-has-fill-pointer-p old-array))
 997          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 998                  in ADJUST-ARRAY unless the array (~S) was originally ~
 999                  created with a fill pointer"
1000                 fill-pointer
1001                 old-array))
1002         ((numberp fill-pointer)
1003          (when (> fill-pointer new-array-size)
1004            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
1005                    than the new length of the vector (~S)"
1006                   fill-pointer new-array-size))
1007          fill-pointer)
1008         ((eq fill-pointer t)
1009          new-array-size)
1010         (t
1011          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
1012                 fill-pointer))))
1013
1014 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1015 ;;; which must be less than or equal to its current length. This can
1016 ;;; be called on vectors without a fill pointer but it is extremely
1017 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1018 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1019 ;;; or multi-threading. Call it only on provably local vectors.
1020 (defun %shrink-vector (vector new-length)
1021   (declare (vector vector))
1022   (unless (array-header-p vector)
1023     (macrolet ((frob (name &rest things)
1024                  `(etypecase ,name
1025                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1026                     ,@(mapcar (lambda (thing)
1027                                 (destructuring-bind (type-spec fill-value)
1028                                     thing
1029                                   `(,type-spec
1030                                     (fill (truly-the ,type-spec ,name)
1031                                           ,fill-value
1032                                           :start new-length))))
1033                               things))))
1034       ;; Set the 'tail' of the vector to the appropriate type of zero,
1035       ;; "because in some cases we'll scavenge larger areas in one go,
1036       ;; like groups of pages that had triggered the write barrier, or
1037       ;; the whole static space" according to jsnell.
1038       #.`(frob vector
1039           ,@(map 'list
1040                  (lambda (saetp)
1041                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1042                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1043                               #!+sb-unicode
1044                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1045                           *default-init-char-form*
1046                           (sb!vm:saetp-initial-element-default saetp))))
1047                  (remove-if-not
1048                   #'sb!vm:saetp-specifier
1049                   sb!vm:*specialized-array-element-type-properties*)))))
1050   ;; Only arrays have fill-pointers, but vectors have their length
1051   ;; parameter in the same place.
1052   (setf (%array-fill-pointer vector) new-length)
1053   vector)
1054
1055 (defun shrink-vector (vector new-length)
1056   (declare (vector vector))
1057   (cond
1058     ((eq (length vector) new-length)
1059      vector)
1060     ((array-has-fill-pointer-p vector)
1061      (setf (%array-fill-pointer vector) new-length)
1062      vector)
1063     (t (subseq vector 0 new-length))))
1064
1065 ;;; Fill in array header with the provided information, and return the array.
1066 (defun set-array-header (array data length fill-pointer displacement dimensions
1067                          &optional displacedp)
1068   (setf (%array-data-vector array) data)
1069   (setf (%array-available-elements array) length)
1070   (cond (fill-pointer
1071          (setf (%array-fill-pointer array) fill-pointer)
1072          (setf (%array-fill-pointer-p array) t))
1073         (t
1074          (setf (%array-fill-pointer array) length)
1075          (setf (%array-fill-pointer-p array) nil)))
1076   (setf (%array-displacement array) displacement)
1077   (if (listp dimensions)
1078       (dotimes (axis (array-rank array))
1079         (declare (type index axis))
1080         (setf (%array-dimension array axis) (pop dimensions)))
1081       (setf (%array-dimension array 0) dimensions))
1082   (setf (%array-displaced-p array) displacedp)
1083   array)
1084
1085 ;;; User visible extension
1086 (declaim (ftype (function (array) (values (simple-array * (*)) &optional))
1087                 array-storage-vector))
1088 (defun array-storage-vector (array)
1089   "Returns the underlying storage vector of ARRAY, which must be a non-displaced array.
1090
1091 In SBCL, if ARRAY is a of type \(SIMPLE-ARRAY * \(*)), it is its own storage
1092 vector. Multidimensional arrays, arrays with fill pointers, and adjustable
1093 arrays have an underlying storage vector with the same ARRAY-ELEMENT-TYPE as
1094 ARRAY, which this function returns.
1095
1096 Important note: the underlying vector is an implementation detail. Even though
1097 this function exposes it, changes in the implementation may cause this
1098 function to be removed without further warning."
1099   ;; KLUDGE: Without TRULY-THE the system is not smart enough to figure out that
1100   ;; the return value is always of the known type.
1101   (truly-the (simple-array * (*))
1102              (if (array-header-p array)
1103                  (if (%array-displaced-p array)
1104                      (error "~S cannot be used with displaced arrays. Use ~S instead."
1105                             'array-storage-vector 'array-displacement)
1106                      (%array-data-vector array))
1107                  array)))
1108 \f
1109 ;;;; used by SORT
1110
1111 ;;; temporary vector for stable sorting vectors, allocated for each new thread
1112 (defvar *merge-sort-temp-vector* (vector))
1113 (declaim (simple-vector *merge-sort-temp-vector*))
1114
1115 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1116
1117 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1118 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1119 ;;; to length zero array in each new thread.
1120 ;;;
1121 ;;; DX is probably a bad idea, because a with a big array it would
1122 ;;; be fairly easy to blow the stack.
1123 (defvar *zap-array-data-temp* (vector))
1124 (declaim (simple-vector *zap-array-data-temp*))
1125
1126 (defun zap-array-data-temp (length initial-element initial-element-p)
1127   (declare (fixnum length))
1128   (let ((tmp *zap-array-data-temp*))
1129     (declare (simple-vector tmp))
1130     (cond ((> length (length tmp))
1131            (setf *zap-array-data-temp*
1132                  (if initial-element-p
1133                      (make-array length :initial-element initial-element)
1134                      (make-array length))))
1135           (initial-element-p
1136            (fill tmp initial-element :end length))
1137           (t
1138            tmp))))
1139
1140 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1141 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1142 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1143 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1144 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1145                        element-type initial-element initial-element-p)
1146   (declare (list old-dims new-dims))
1147   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1148   ;; at least in SBCL.
1149   ;; NEW-DIMS comes from the user.
1150   (setf old-dims (nreverse old-dims)
1151         new-dims (reverse new-dims))
1152   (cond ((eq old-data new-data)
1153          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1154          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1155          ;; EQ; in this case, a temporary must be used and filled
1156          ;; appropriately. specified initial-element.
1157          (when initial-element-p
1158            ;; FIXME: transforming this TYPEP to someting a bit faster
1159            ;; would be a win...
1160            (unless (typep initial-element element-type)
1161              (error "~S can't be used to initialize an array of type ~S."
1162                     initial-element element-type)))
1163          (let ((temp (zap-array-data-temp new-length
1164                                           initial-element initial-element-p)))
1165            (declare (simple-vector temp))
1166            (zap-array-data-aux old-data old-dims offset temp new-dims)
1167            (dotimes (i new-length)
1168              (setf (aref new-data i) (aref temp i)
1169                    ;; zero out any garbage right away
1170                    (aref temp i) 0))))
1171         (t
1172          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1173          ;; already been filled with any
1174          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1175
1176 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1177   (declare (fixnum offset))
1178   (let ((limits (mapcar (lambda (x y)
1179                           (declare (fixnum x y))
1180                           (1- (the fixnum (min x y))))
1181                         old-dims new-dims)))
1182     (macrolet ((bump-index-list (index limits)
1183                  `(do ((subscripts ,index (cdr subscripts))
1184                        (limits ,limits (cdr limits)))
1185                       ((null subscripts) :eof)
1186                     (cond ((< (the fixnum (car subscripts))
1187                               (the fixnum (car limits)))
1188                            (rplaca subscripts
1189                                    (1+ (the fixnum (car subscripts))))
1190                            (return ,index))
1191                           (t (rplaca subscripts 0))))))
1192       (do ((index (make-list (length old-dims) :initial-element 0)
1193                   (bump-index-list index limits)))
1194           ((eq index :eof))
1195         (setf (aref new-data (row-major-index-from-dims index new-dims))
1196               (aref old-data
1197                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1198                        offset)))))))
1199
1200 ;;; Figure out the row-major-order index of an array reference from a
1201 ;;; list of subscripts and a list of dimensions. This is for internal
1202 ;;; calls only, and the subscripts and dim-list variables are assumed
1203 ;;; to be reversed from what the user supplied.
1204 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1205   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1206        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1207        (chunk-size 1)
1208        (result 0))
1209       ((null rev-dim-list) result)
1210     (declare (fixnum chunk-size result))
1211     (setq result (+ result
1212                     (the fixnum (* (the fixnum (car rev-subscripts))
1213                                    chunk-size))))
1214     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1215 \f
1216 ;;;; some bit stuff
1217
1218 (defun bit-array-same-dimensions-p (array1 array2)
1219   (declare (type (array bit) array1 array2))
1220   (and (= (array-rank array1)
1221           (array-rank array2))
1222        (dotimes (index (array-rank array1) t)
1223          (when (/= (array-dimension array1 index)
1224                    (array-dimension array2 index))
1225            (return nil)))))
1226
1227 (defun pick-result-array (result-bit-array bit-array-1)
1228   (case result-bit-array
1229     ((t) bit-array-1)
1230     ((nil) (make-array (array-dimensions bit-array-1)
1231                        :element-type 'bit
1232                        :initial-element 0))
1233     (t
1234      (unless (bit-array-same-dimensions-p bit-array-1
1235                                           result-bit-array)
1236        (error "~S and ~S don't have the same dimensions."
1237               bit-array-1 result-bit-array))
1238      result-bit-array)))
1239
1240 (defmacro def-bit-array-op (name function)
1241   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1242      #!+sb-doc
1243      ,(format nil
1244               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1245                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1246                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1247                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1248                All the arrays must have the same rank and dimensions."
1249               (symbol-name function))
1250      (declare (type (array bit) bit-array-1 bit-array-2)
1251               (type (or (array bit) (member t nil)) result-bit-array))
1252      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1253        (error "~S and ~S don't have the same dimensions."
1254               bit-array-1 bit-array-2))
1255      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1256        (if (and (simple-bit-vector-p bit-array-1)
1257                 (simple-bit-vector-p bit-array-2)
1258                 (simple-bit-vector-p result-bit-array))
1259            (locally (declare (optimize (speed 3) (safety 0)))
1260              (,name bit-array-1 bit-array-2 result-bit-array))
1261            (with-array-data ((data1 bit-array-1) (start1) (end1))
1262              (declare (ignore end1))
1263              (with-array-data ((data2 bit-array-2) (start2) (end2))
1264                (declare (ignore end2))
1265                (with-array-data ((data3 result-bit-array) (start3) (end3))
1266                  (do ((index-1 start1 (1+ index-1))
1267                       (index-2 start2 (1+ index-2))
1268                       (index-3 start3 (1+ index-3)))
1269                      ((>= index-3 end3) result-bit-array)
1270                    (declare (type index index-1 index-2 index-3))
1271                    (setf (sbit data3 index-3)
1272                          (logand (,function (sbit data1 index-1)
1273                                             (sbit data2 index-2))
1274                                  1))))))))))
1275
1276 (def-bit-array-op bit-and logand)
1277 (def-bit-array-op bit-ior logior)
1278 (def-bit-array-op bit-xor logxor)
1279 (def-bit-array-op bit-eqv logeqv)
1280 (def-bit-array-op bit-nand lognand)
1281 (def-bit-array-op bit-nor lognor)
1282 (def-bit-array-op bit-andc1 logandc1)
1283 (def-bit-array-op bit-andc2 logandc2)
1284 (def-bit-array-op bit-orc1 logorc1)
1285 (def-bit-array-op bit-orc2 logorc2)
1286
1287 (defun bit-not (bit-array &optional result-bit-array)
1288   #!+sb-doc
1289   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1290   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1291   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1292   created. Both arrays must have the same rank and dimensions."
1293   (declare (type (array bit) bit-array)
1294            (type (or (array bit) (member t nil)) result-bit-array))
1295   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1296     (if (and (simple-bit-vector-p bit-array)
1297              (simple-bit-vector-p result-bit-array))
1298         (locally (declare (optimize (speed 3) (safety 0)))
1299           (bit-not bit-array result-bit-array))
1300         (with-array-data ((src bit-array) (src-start) (src-end))
1301           (declare (ignore src-end))
1302           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1303             (do ((src-index src-start (1+ src-index))
1304                  (dst-index dst-start (1+ dst-index)))
1305                 ((>= dst-index dst-end) result-bit-array)
1306               (declare (type index src-index dst-index))
1307               (setf (sbit dst dst-index)
1308                     (logxor (sbit src src-index) 1))))))))