src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p)
  34   (def %array-diplaced-from))
  35
  36 (defun %array-rank (array)
  37   (%array-rank array))
  38
  39 (defun %array-dimension (array axis)
  40   (%array-dimension array axis))
  41
  42 (defun %set-array-dimension (array axis value)
  43   (%set-array-dimension array axis value))
  44
  45 (defun %check-bound (array bound index)
  46   (declare (type index bound)
  47            (fixnum index))
  48   (%check-bound array bound index))
  49
  50 (defun %with-array-data/fp (array start end)
  51   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer t))
  52
  53 (defun %with-array-data (array start end)
  54   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer nil))
  55
  56 (defun %data-vector-and-index (array index)
  57   (if (array-header-p array)
  58       (multiple-value-bind (vector index)
  59           (%with-array-data array index nil)
  60         (values vector index))
  61       (values array index)))
  62 \f
  63 ;;;; MAKE-ARRAY
  64 (eval-when (:compile-toplevel :execute)
  65   (sb!xc:defmacro pick-vector-type (type &rest specs)
  66     `(cond ,@(mapcar (lambda (spec)
  67                        `(,(if (eq (car spec) t)
  68                               t
  69                               `(subtypep ,type ',(car spec)))
  70                          ,@(cdr spec)))
  71                      specs))))
  72
  73 ;;; These functions are used in the implementation of MAKE-ARRAY for
  74 ;;; complex arrays. There are lots of transforms to simplify
  75 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  76 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  77 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  78 ;;; making this somewhat efficient, at least not doing full calls to
  79 ;;; SUBTYPEP in the easy cases.
  80 (defun %vector-widetag-and-n-bits (type)
  81   (case type
  82     ;; Pick off some easy common cases.
  83     ;;
  84     ;; (Perhaps we should make a much more exhaustive table of easy
  85     ;; common cases here. Or perhaps the effort would be better spent
  86     ;; on smarter compiler transforms which do the calculation once
  87     ;; and for all in any reasonable user programs.)
  88     ((t)
  89      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
  90     ((base-char standard-char #!-sb-unicode character)
  91      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
  92     #!+sb-unicode
  93     ((character)
  94      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
  95     ((bit)
  96      (values #.sb!vm:simple-bit-vector-widetag 1))
  97     ;; OK, we have to wade into SUBTYPEPing after all.
  98     (t
  99      #.`(pick-vector-type type
 100          ,@(map 'list
 101                 (lambda (saetp)
 102                   `(,(sb!vm:saetp-specifier saetp)
 103                     (values ,(sb!vm:saetp-typecode saetp)
 104                             ,(sb!vm:saetp-n-bits saetp))))
 105                 sb!vm:*specialized-array-element-type-properties*)))))
 106
 107 (defun %complex-vector-widetag (type)
 108   (case type
 109     ;; Pick off some easy common cases.
 110     ((t)
 111      #.sb!vm:complex-vector-widetag)
 112     ((base-char #!-sb-unicode character)
 113      #.sb!vm:complex-base-string-widetag)
 114     #!+sb-unicode
 115     ((character)
 116      #.sb!vm:complex-character-string-widetag)
 117     ((nil)
 118      #.sb!vm:complex-vector-nil-widetag)
 119     ((bit)
 120      #.sb!vm:complex-bit-vector-widetag)
 121     ;; OK, we have to wade into SUBTYPEPing after all.
 122     (t
 123      (pick-vector-type type
 124        (nil #.sb!vm:complex-vector-nil-widetag)
 125        #!-sb-unicode
 126        (character #.sb!vm:complex-base-string-widetag)
 127        #!+sb-unicode
 128        (base-char #.sb!vm:complex-base-string-widetag)
 129        #!+sb-unicode
 130        (character #.sb!vm:complex-character-string-widetag)
 131        (bit #.sb!vm:complex-bit-vector-widetag)
 132        (t #.sb!vm:complex-vector-widetag)))))
 133
 134 (defun make-array (dimensions &key
 135                               (element-type t)
 136                               (initial-element nil initial-element-p)
 137                               (initial-contents nil initial-contents-p)
 138                               adjustable fill-pointer
 139                               displaced-to displaced-index-offset)
 140   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 141          (array-rank (length (the list dimensions)))
 142          (simple (and (null fill-pointer)
 143                       (not adjustable)
 144                       (null displaced-to))))
 145     (declare (fixnum array-rank))
 146     (when (and displaced-index-offset (null displaced-to))
 147       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 148     (when (and displaced-to
 149                (arrayp displaced-to)
 150                (not (equal (array-element-type displaced-to)
 151                            (upgraded-array-element-type element-type))))
 152       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 153     (if (and simple (= array-rank 1))
 154         ;; it's a (SIMPLE-ARRAY * (*))
 155         (multiple-value-bind (type n-bits)
 156             (%vector-widetag-and-n-bits element-type)
 157           (declare (type (unsigned-byte 8) type)
 158                    (type (integer 0 256) n-bits))
 159           (let* ((length (car dimensions))
 160                  (array (allocate-vector
 161                          type
 162                          length
 163                          (ceiling
 164                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 165                                      #!+sb-unicode
 166                                      (= type
 167                                         sb!vm:simple-character-string-widetag))
 168                                  (1+ length)
 169                                  length)
 170                              n-bits)
 171                           sb!vm:n-word-bits))))
 172             (declare (type index length))
 173             (when initial-element-p
 174               (fill array initial-element))
 175             (when initial-contents-p
 176               (when initial-element-p
 177                 (error "can't specify both :INITIAL-ELEMENT and ~
 178                        :INITIAL-CONTENTS"))
 179               (unless (= length (length initial-contents))
 180                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 181                        the vector length is ~W."
 182                        (length initial-contents)
 183                        length))
 184               (replace array initial-contents))
 185             array))
 186         ;; it's either a complex array or a multidimensional array.
 187         (let* ((total-size (reduce #'* dimensions))
 188                (data (or displaced-to
 189                          (data-vector-from-inits
 190                           dimensions total-size element-type
 191                           initial-contents initial-contents-p
 192                           initial-element initial-element-p)))
 193                (array (make-array-header
 194                        (cond ((= array-rank 1)
 195                               (%complex-vector-widetag element-type))
 196                              (simple sb!vm:simple-array-widetag)
 197                              (t sb!vm:complex-array-widetag))
 198                        array-rank)))
 199           (cond (fill-pointer
 200                  (unless (= array-rank 1)
 201                    (error "Only vectors can have fill pointers."))
 202                  (let ((length (car dimensions)))
 203                    (declare (fixnum length))
 204                    (setf (%array-fill-pointer array)
 205                      (cond ((eq fill-pointer t)
 206                             length)
 207                            (t
 208                             (unless (and (fixnump fill-pointer)
 209                                          (>= fill-pointer 0)
 210                                          (<= fill-pointer length))
 211                               ;; FIXME: should be TYPE-ERROR?
 212                               (error "invalid fill-pointer ~W"
 213                                      fill-pointer))
 214                             fill-pointer))))
 215                  (setf (%array-fill-pointer-p array) t))
 216                 (t
 217                  (setf (%array-fill-pointer array) total-size)
 218                  (setf (%array-fill-pointer-p array) nil)))
 219           (setf (%array-available-elements array) total-size)
 220           (setf (%array-data-vector array) data)
 221           (setf (%array-displaced-from array) nil)
 222           (cond (displaced-to
 223                  (when (or initial-element-p initial-contents-p)
 224                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 225                    can be specified along with :DISPLACED-TO"))
 226                  (let ((offset (or displaced-index-offset 0)))
 227                    (when (> (+ offset total-size)
 228                             (array-total-size displaced-to))
 229                      (error "~S doesn't have enough elements." displaced-to))
 230                    (setf (%array-displacement array) offset)
 231                    (setf (%array-displaced-p array) t)
 232                    (%save-displaced-array-backpointer array data)))
 233                 (t
 234                  (setf (%array-displaced-p array) nil)))
 235           (let ((axis 0))
 236             (dolist (dim dimensions)
 237               (setf (%array-dimension array axis) dim)
 238               (incf axis)))
 239           array))))
 240
 241 (defun make-static-vector (length &key
 242                            (element-type '(unsigned-byte 8))
 243                            (initial-contents nil initial-contents-p)
 244                            (initial-element nil initial-element-p))
 245   "Allocate vector of LENGTH elements in static space. Only allocation
 246 of specialized arrays is supported."
 247   ;; STEP 1: check inputs fully
 248   ;;
 249   ;; This way of doing explicit checks before the vector is allocated
 250   ;; is expensive, but probably worth the trouble as once we've allocated
 251   ;; the vector we have no way to get rid of it anymore...
 252   (when (eq t (upgraded-array-element-type element-type))
 253     (error "Static arrays of type ~S not supported."
 254            element-type))
 255   (when initial-contents-p
 256     (when initial-element-p
 257       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 258     (unless (= length (length initial-contents))
 259       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 260               vector length is ~W."
 261              (length initial-contents)
 262              length))
 263     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 264       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 265              element-type)))
 266   (when initial-element-p
 267     (unless (typep initial-element element-type)
 268       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 269              initial-element element-type)))
 270   ;; STEP 2
 271   ;;
 272   ;; Allocate and possibly initialize the vector.
 273   (multiple-value-bind (type n-bits)
 274       (sb!impl::%vector-widetag-and-n-bits element-type)
 275     (let ((vector
 276            (allocate-static-vector type length
 277                                    (ceiling (* length n-bits)
 278                                             sb!vm:n-word-bits))))
 279       (cond (initial-element-p
 280              (fill vector initial-element))
 281             (initial-contents-p
 282              (replace vector initial-contents))
 283             (t
 284              vector)))))
 285
 286 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 287 ;;; specified array characteristics. Dimensions is only used to pass
 288 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 289 ;;; initial-contents.
 290 (defun data-vector-from-inits (dimensions total-size element-type
 291                                initial-contents initial-contents-p
 292                                initial-element initial-element-p)
 293   (when (and initial-contents-p initial-element-p)
 294     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 295             either MAKE-ARRAY or ADJUST-ARRAY."))
 296   (let ((data (if initial-element-p
 297                   (make-array total-size
 298                               :element-type element-type
 299                               :initial-element initial-element)
 300                   (make-array total-size
 301                               :element-type element-type))))
 302     (cond (initial-element-p
 303            (unless (simple-vector-p data)
 304              (unless (typep initial-element element-type)
 305                (error "~S cannot be used to initialize an array of type ~S."
 306                       initial-element element-type))
 307              (fill (the vector data) initial-element)))
 308           (initial-contents-p
 309            (fill-data-vector data dimensions initial-contents)))
 310     data))
 311
 312 (defun vector (&rest objects)
 313   #!+sb-doc
 314   "Construct a SIMPLE-VECTOR from the given objects."
 315   (coerce (the list objects) 'simple-vector))
 316 \f
 317
 318 ;;;; accessor/setter functions
 319
 320 ;;; Dispatch to an optimized routine the data vector accessors for
 321 ;;; each different specialized vector type. Do dispatching by looking
 322 ;;; up the widetag in the array rather than with the typecases, which
 323 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 324 ;;; provide separate versions where bounds checking has been moved
 325 ;;; from the callee to the caller, since it's much cheaper to do once
 326 ;;; the type information is available. Finally, for each of these
 327 ;;; routines also provide a slow path, taken for arrays that are not
 328 ;;; vectors or not simple.
 329 (macrolet ((def (name table-name)
 330              `(progn
 331                 (defglobal ,table-name (make-array ,sb!vm:widetag-mask))
 332                 (defmacro ,name (array-var)
 333                   `(the function
 334                      (let ((tag 0))
 335                        (when (sb!vm::%other-pointer-p ,array-var)
 336                          (setf tag (%other-pointer-widetag ,array-var)))
 337                        (svref ,',table-name tag)))))))
 338   (def !find-data-vector-setter **data-vector-setters**)
 339   (def !find-data-vector-setter/check-bounds **data-vector-setters/check-bounds**)
 340   (def !find-data-vector-reffer **data-vector-reffers**)
 341   (def !find-data-vector-reffer/check-bounds **data-vector-reffers/check-bounds**))
 342
 343 (macrolet ((%ref (accessor-getter extra-params)
 344              `(funcall (,accessor-getter array) array index ,@extra-params))
 345            (define (accessor-name slow-accessor-name accessor-getter
 346                                   extra-params check-bounds)
 347              `(progn
 348                 (defun ,accessor-name (array index ,@extra-params)
 349                   (declare (optimize speed
 350                                      ;; (SAFETY 0) is ok. All calls to
 351                                      ;; these functions are generated by
 352                                      ;; the compiler, so argument count
 353                                      ;; checking isn't needed. Type checking
 354                                      ;; is done implicitly via the widetag
 355                                      ;; dispatch.
 356                                      (safety 0)))
 357                   (%ref ,accessor-getter ,extra-params))
 358                 (defun ,slow-accessor-name (array index ,@extra-params)
 359                   (declare (optimize speed (safety 0)))
 360                   (if (not (%array-displaced-p array))
 361                       ;; The reasonably quick path of non-displaced complex
 362                       ;; arrays.
 363                       (let ((array (%array-data-vector array)))
 364                         (%ref ,accessor-getter ,extra-params))
 365                       ;; The real slow path.
 366                       (with-array-data
 367                           ((vector array)
 368                            (index (locally
 369                                       (declare (optimize (speed 1) (safety 1)))
 370                                     (,@check-bounds index)))
 371                            (end)
 372                            :force-inline t)
 373                         (declare (ignore end))
 374                         (,accessor-name vector index ,@extra-params)))))))
 375   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 376     !find-data-vector-reffer
 377     nil (progn))
 378   (define hairy-data-vector-set slow-hairy-data-vector-set
 379     !find-data-vector-setter
 380     (new-value) (progn))
 381   (define hairy-data-vector-ref/check-bounds
 382       slow-hairy-data-vector-ref/check-bounds
 383     !find-data-vector-reffer/check-bounds
 384     nil (%check-bound array (array-dimension array 0)))
 385   (define hairy-data-vector-set/check-bounds
 386       slow-hairy-data-vector-set/check-bounds
 387     !find-data-vector-setter/check-bounds
 388     (new-value) (%check-bound array (array-dimension array 0))))
 389
 390 (defun hairy-ref-error (array index &optional new-value)
 391   (declare (ignore index new-value))
 392   (error 'type-error
 393          :datum array
 394          :expected-type 'vector))
 395
 396 ;;; Populate the dispatch tables.
 397 (macrolet ((define-reffer (saetp check-form)
 398              (let* ((type (sb!vm:saetp-specifier saetp))
 399                     (atype `(simple-array ,type (*))))
 400                `(named-lambda optimized-data-vector-ref (vector index)
 401                   (declare (optimize speed (safety 0)))
 402                   (data-vector-ref (the ,atype vector)
 403                                    (locally
 404                                        (declare (optimize (safety 1)))
 405                                      (the index
 406                                        (,@check-form index)))))))
 407            (define-setter (saetp check-form)
 408              (let* ((type (sb!vm:saetp-specifier saetp))
 409                     (atype `(simple-array ,type (*))))
 410                `(named-lambda optimized-data-vector-set (vector index new-value)
 411                   (declare (optimize speed (safety 0)))
 412                   (data-vector-set (the ,atype vector)
 413                                    (locally
 414                                        (declare (optimize (safety 1)))
 415                                      (the index
 416                                        (,@check-form index)))
 417                                    (locally
 418                                        ;; SPEED 1 needed to avoid the compiler
 419                                        ;; from downgrading the type check to
 420                                        ;; a cheaper one.
 421                                        (declare (optimize (speed 1)
 422                                                           (safety 1)))
 423                                      (the ,type new-value)))
 424                   ;; For specialized arrays, the return from
 425                   ;; data-vector-set would have to be reboxed to be a
 426                   ;; (Lisp) return value; instead, we use the
 427                   ;; already-boxed value as the return.
 428                   new-value)))
 429            (define-reffers (symbol deffer check-form slow-path)
 430              `(progn
 431                 (setf ,symbol (make-array sb!vm::widetag-mask
 432                                           :initial-element #'hairy-ref-error))
 433                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 434                                          sb!vm:complex-vector-nil-widetag
 435                                          sb!vm:complex-bit-vector-widetag
 436                                          #!+sb-unicode sb!vm:complex-character-string-widetag
 437                                          sb!vm:complex-base-string-widetag
 438                                          sb!vm:simple-array-widetag
 439                                          sb!vm:complex-array-widetag)
 440                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 441                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 442                         for widetag = (sb!vm:saetp-typecode saetp)
 443                         collect `(setf (svref ,symbol ,widetag)
 444                                        (,deffer ,saetp ,check-form))))))
 445   (defun !hairy-data-vector-reffer-init ()
 446     (define-reffers **data-vector-reffers** define-reffer
 447       (progn)
 448       #'slow-hairy-data-vector-ref)
 449     (define-reffers **data-vector-setters** define-setter
 450       (progn)
 451       #'slow-hairy-data-vector-set)
 452     (define-reffers **data-vector-reffers/check-bounds** define-reffer
 453       (%check-bound vector (length vector))
 454       #'slow-hairy-data-vector-ref/check-bounds)
 455     (define-reffers **data-vector-setters/check-bounds** define-setter
 456       (%check-bound vector (length vector))
 457       #'slow-hairy-data-vector-set/check-bounds)))
 458
 459 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 460 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 461 ;;; definition is needed for the compiler to use in constant folding.)
 462 (defun data-vector-ref (array index)
 463   (hairy-data-vector-ref array index))
 464
 465 (defun data-vector-ref-with-offset (array index offset)
 466   (hairy-data-vector-ref array (+ index offset)))
 467
 468 (defun invalid-array-p (array)
 469   (and (array-header-p array)
 470        (consp (%array-displaced-p array))))
 471
 472 (declaim (ftype (function (array) nil) invalid-array-error))
 473 (defun invalid-array-error (array)
 474   (aver (array-header-p array))
 475   ;; Array invalidation stashes the original dimensions here...
 476   (let ((dims (%array-displaced-p array))
 477         (et (array-element-type array)))
 478     (error 'invalid-array-error
 479            :datum array
 480            :expected-type
 481            (if (cdr dims)
 482                `(array ,et ,dims)
 483                `(vector ,et ,@dims)))))
 484
 485 (declaim (ftype (function (array integer integer &optional t) nil)
 486                 invalid-array-index-error))
 487 (defun invalid-array-index-error (array index bound &optional axis)
 488   (if (invalid-array-p array)
 489       (invalid-array-error array)
 490       (error 'invalid-array-index-error
 491              :array array
 492              :axis axis
 493              :datum index
 494              :expected-type `(integer 0 (,bound)))))
 495
 496 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 497 (defun %array-row-major-index (array subscripts
 498                                      &optional (invalid-index-error-p t))
 499   (declare (array array)
 500            (list subscripts))
 501   (let ((rank (array-rank array)))
 502     (unless (= rank (length subscripts))
 503       (error "wrong number of subscripts, ~W, for array of rank ~W"
 504              (length subscripts) rank))
 505     (if (array-header-p array)
 506         (do ((subs (nreverse subscripts) (cdr subs))
 507              (axis (1- (array-rank array)) (1- axis))
 508              (chunk-size 1)
 509              (result 0))
 510             ((null subs) result)
 511           (declare (list subs) (fixnum axis chunk-size result))
 512           (let ((index (car subs))
 513                 (dim (%array-dimension array axis)))
 514             (declare (fixnum dim))
 515             (unless (and (fixnump index) (< -1 index dim))
 516               (if invalid-index-error-p
 517                   (invalid-array-index-error array index dim axis)
 518                   (return-from %array-row-major-index nil)))
 519             (incf result (* chunk-size (the fixnum index)))
 520             (setf chunk-size (* chunk-size dim))))
 521         (let ((index (first subscripts))
 522               (length (length (the (simple-array * (*)) array))))
 523           (unless (and (fixnump index) (< -1 index length))
 524             (if invalid-index-error-p
 525                 (invalid-array-index-error array index length)
 526                 (return-from %array-row-major-index nil)))
 527           index))))
 528
 529 (defun array-in-bounds-p (array &rest subscripts)
 530   #!+sb-doc
 531   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 532   (if (%array-row-major-index array subscripts nil)
 533       t))
 534
 535 (defun array-row-major-index (array &rest subscripts)
 536   (declare (truly-dynamic-extent subscripts))
 537   (%array-row-major-index array subscripts))
 538
 539 (defun aref (array &rest subscripts)
 540   #!+sb-doc
 541   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 542   (declare (truly-dynamic-extent subscripts))
 543   (row-major-aref array (%array-row-major-index array subscripts)))
 544
 545 (defun %aset (array &rest stuff)
 546   (declare (truly-dynamic-extent stuff))
 547   (let ((subscripts (butlast stuff))
 548         (new-value (car (last stuff))))
 549     (setf (row-major-aref array (%array-row-major-index array subscripts))
 550           new-value)))
 551
 552 ;;; FIXME: What's supposed to happen with functions
 553 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 554 ;;; DEFSETF FOO is also defined? It seems as though the logical
 555 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 556 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 557 ;;; just as for ordinary functions
 558 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 559 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 560 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 561 ;;;  ZOO
 562 ;;;  * (DEFUN ZOO (X) (* 3 X))
 563 ;;;  Warning: ZOO previously defined as a macro.
 564 ;;;  ZOO
 565 ;;; But that doesn't seem to be what happens in CMU CL.
 566 ;;;
 567 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 568 ;;; 5.1.2.5) requires implementations to support
 569 ;;;   (SETF (APPLY #'AREF ...) ...)
 570 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 571 ;;; also terrifying that this sequence of definitions causes it to
 572 ;;; work.
 573 ;;;
 574 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 575 ;;; has a setf expansion and/or a setf function defined.
 576
 577 #!-sb-fluid (declaim (inline (setf aref)))
 578 (defun (setf aref) (new-value array &rest subscripts)
 579   (declare (truly-dynamic-extent subscripts))
 580   (declare (type array array))
 581   (setf (row-major-aref array (%array-row-major-index array subscripts))
 582         new-value))
 583
 584 (defun row-major-aref (array index)
 585   #!+sb-doc
 586   "Return the element of array corressponding to the row-major index. This is
 587    SETF'able."
 588   (declare (optimize (safety 1)))
 589   (row-major-aref array index))
 590
 591 (defun %set-row-major-aref (array index new-value)
 592   (declare (optimize (safety 1)))
 593   (setf (row-major-aref array index) new-value))
 594
 595 (defun svref (simple-vector index)
 596   #!+sb-doc
 597   "Return the INDEX'th element of the given Simple-Vector."
 598   (declare (optimize (safety 1)))
 599   (aref simple-vector index))
 600
 601 (defun %svset (simple-vector index new)
 602   (declare (optimize (safety 1)))
 603   (setf (aref simple-vector index) new))
 604
 605 (defun bit (bit-array &rest subscripts)
 606   #!+sb-doc
 607   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 608   (declare (type (array bit) bit-array) (optimize (safety 1)))
 609   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 610
 611 (defun %bitset (bit-array &rest stuff)
 612   (declare (type (array bit) bit-array) (optimize (safety 1)))
 613   (let ((subscripts (butlast stuff))
 614         (new-value (car (last stuff))))
 615     (setf (row-major-aref bit-array
 616                           (%array-row-major-index bit-array subscripts))
 617           new-value)))
 618
 619 #!-sb-fluid (declaim (inline (setf bit)))
 620 (defun (setf bit) (new-value bit-array &rest subscripts)
 621   (declare (type (array bit) bit-array) (optimize (safety 1)))
 622   (setf (row-major-aref bit-array
 623                         (%array-row-major-index bit-array subscripts))
 624         new-value))
 625
 626 (defun sbit (simple-bit-array &rest subscripts)
 627   #!+sb-doc
 628   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 629   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 630   (row-major-aref simple-bit-array
 631                   (%array-row-major-index simple-bit-array subscripts)))
 632
 633 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 634 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 635 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 636 ;;; -- WHN 19990911
 637 (defun %sbitset (simple-bit-array &rest stuff)
 638   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 639   (let ((subscripts (butlast stuff))
 640         (new-value (car (last stuff))))
 641     (setf (row-major-aref simple-bit-array
 642                           (%array-row-major-index simple-bit-array subscripts))
 643           new-value)))
 644
 645 #!-sb-fluid (declaim (inline (setf sbit)))
 646 (defun (setf sbit) (new-value bit-array &rest subscripts)
 647   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 648   (setf (row-major-aref bit-array
 649                         (%array-row-major-index bit-array subscripts))
 650         new-value))
 651 \f
 652 ;;;; miscellaneous array properties
 653
 654 (defun array-element-type (array)
 655   #!+sb-doc
 656   "Return the type of the elements of the array"
 657   (let ((widetag (widetag-of array)))
 658     (macrolet ((pick-element-type (&rest stuff)
 659                  `(cond ,@(mapcar (lambda (stuff)
 660                                     (cons
 661                                      (let ((item (car stuff)))
 662                                        (cond ((eq item t)
 663                                               t)
 664                                              ((listp item)
 665                                               (cons 'or
 666                                                     (mapcar (lambda (x)
 667                                                               `(= widetag ,x))
 668                                                             item)))
 669                                              (t
 670                                               `(= widetag ,item))))
 671                                      (cdr stuff)))
 672                                   stuff))))
 673       #.`(pick-element-type
 674           ,@(map 'list
 675                  (lambda (saetp)
 676                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 677                           (list (sb!vm:saetp-typecode saetp)
 678                                 (sb!vm:saetp-complex-typecode saetp))
 679                           (sb!vm:saetp-typecode saetp))
 680                      ',(sb!vm:saetp-specifier saetp)))
 681                  sb!vm:*specialized-array-element-type-properties*)
 682           ((sb!vm:simple-array-widetag
 683             sb!vm:complex-vector-widetag
 684             sb!vm:complex-array-widetag)
 685            (with-array-data ((array array) (start) (end))
 686              (declare (ignore start end))
 687              (array-element-type array)))
 688           (t
 689            (error 'type-error :datum array :expected-type 'array))))))
 690
 691 (defun array-rank (array)
 692   #!+sb-doc
 693   "Return the number of dimensions of ARRAY."
 694   (if (array-header-p array)
 695       (%array-rank array)
 696       1))
 697
 698 (defun array-dimension (array axis-number)
 699   #!+sb-doc
 700   "Return the length of dimension AXIS-NUMBER of ARRAY."
 701   (declare (array array) (type index axis-number))
 702   (cond ((not (array-header-p array))
 703          (unless (= axis-number 0)
 704            (error "Vector axis is not zero: ~S" axis-number))
 705          (length (the (simple-array * (*)) array)))
 706         ((>= axis-number (%array-rank array))
 707          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 708                 axis-number array (%array-rank array)))
 709         (t
 710          (%array-dimension array axis-number))))
 711
 712 (defun array-dimensions (array)
 713   #!+sb-doc
 714   "Return a list whose elements are the dimensions of the array"
 715   (declare (array array))
 716   (if (array-header-p array)
 717       (do ((results nil (cons (array-dimension array index) results))
 718            (index (1- (array-rank array)) (1- index)))
 719           ((minusp index) results))
 720       (list (array-dimension array 0))))
 721
 722 (defun array-total-size (array)
 723   #!+sb-doc
 724   "Return the total number of elements in the Array."
 725   (declare (array array))
 726   (if (array-header-p array)
 727       (%array-available-elements array)
 728       (length (the vector array))))
 729
 730 (defun array-displacement (array)
 731   #!+sb-doc
 732   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 733    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 734   (declare (type array array))
 735   (if (and (array-header-p array) ; if unsimple and
 736            (%array-displaced-p array)) ; displaced
 737       (values (%array-data-vector array) (%array-displacement array))
 738       (values nil 0)))
 739
 740 (defun adjustable-array-p (array)
 741   #!+sb-doc
 742   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 743    to the argument, this happens for complex arrays."
 744   (declare (array array))
 745   ;; Note that this appears not to be a fundamental limitation.
 746   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 747   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 748   ;; -- CSR, 2004-03-01.
 749   (not (typep array 'simple-array)))
 750 \f
 751 ;;;; fill pointer frobbing stuff
 752
 753 (defun array-has-fill-pointer-p (array)
 754   #!+sb-doc
 755   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 756   (declare (array array))
 757   (and (array-header-p array) (%array-fill-pointer-p array)))
 758
 759 (defun fill-pointer-error (vector arg)
 760   (cond (arg
 761          (aver (array-has-fill-pointer-p vector))
 762          (let ((max (%array-available-elements vector)))
 763            (error 'simple-type-error
 764                   :datum arg
 765                   :expected-type (list 'integer 0 max)
 766                   :format-control "The new fill pointer, ~S, is larger than the length of the vector (~S.)"
 767                   :format-arguments (list arg max))))
 768         (t
 769          (error 'simple-type-error
 770                 :datum vector
 771                 :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 772                 :format-control "~S is not an array with a fill pointer."
 773                 :format-arguments (list vector)))))
 774
 775 (defun fill-pointer (vector)
 776   #!+sb-doc
 777   "Return the FILL-POINTER of the given VECTOR."
 778   (if (array-has-fill-pointer-p vector)
 779       (%array-fill-pointer vector)
 780       (fill-pointer-error vector nil)))
 781
 782 (defun %set-fill-pointer (vector new)
 783   (flet ((oops (x)
 784            (fill-pointer-error vector x)))
 785     (if (array-has-fill-pointer-p vector)
 786         (if (> new (%array-available-elements vector))
 787             (oops new)
 788             (setf (%array-fill-pointer vector) new))
 789         (oops nil))))
 790
 791 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 792 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 793 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 794 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 795 ;;; back to CMU CL).
 796 (defun vector-push (new-el array)
 797   #!+sb-doc
 798   "Attempt to set the element of ARRAY designated by its fill pointer
 799    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 800    too large, NIL is returned, otherwise the index of the pushed element is
 801    returned."
 802   (declare (vector array))
 803   (let ((fill-pointer (fill-pointer array)))
 804     (declare (fixnum fill-pointer))
 805     (cond ((= fill-pointer (%array-available-elements array))
 806            nil)
 807           (t
 808            (locally (declare (optimize (safety 0)))
 809              (setf (aref array fill-pointer) new-el))
 810            (setf (%array-fill-pointer array) (1+ fill-pointer))
 811            fill-pointer))))
 812
 813 (defun vector-push-extend (new-element
 814                            vector
 815                            &optional
 816                            (min-extension
 817                             (let ((length (length vector)))
 818                               (min (1+ length)
 819                                    (- array-dimension-limit length)))))
 820   (declare (vector vector) (fixnum min-extension))
 821   (let ((fill-pointer (fill-pointer vector)))
 822     (declare (fixnum fill-pointer))
 823     (when (= fill-pointer (%array-available-elements vector))
 824       (adjust-array vector (+ fill-pointer (max 1 min-extension))))
 825     ;; disable bounds checking
 826     (locally (declare (optimize (safety 0)))
 827       (setf (aref vector fill-pointer) new-element))
 828     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 829     fill-pointer))
 830
 831 (defun vector-pop (array)
 832   #!+sb-doc
 833   "Decrease the fill pointer by 1 and return the element pointed to by the
 834   new fill pointer."
 835   (declare (vector array))
 836   (let ((fill-pointer (fill-pointer array)))
 837     (declare (fixnum fill-pointer))
 838     (if (zerop fill-pointer)
 839         (error "There is nothing left to pop.")
 840         ;; disable bounds checking (and any fixnum test)
 841         (locally (declare (optimize (safety 0)))
 842           (aref array
 843                 (setf (%array-fill-pointer array)
 844                       (1- fill-pointer)))))))
 845
 846 \f
 847 ;;;; ADJUST-ARRAY
 848
 849 (defun adjust-array (array dimensions &key
 850                            (element-type (array-element-type array))
 851                            (initial-element nil initial-element-p)
 852                            (initial-contents nil initial-contents-p)
 853                            fill-pointer
 854                            displaced-to displaced-index-offset)
 855   #!+sb-doc
 856   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 857   (when (invalid-array-p array)
 858     (invalid-array-error array))
 859   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 860     (cond ((/= (the fixnum (length (the list dimensions)))
 861                (the fixnum (array-rank array)))
 862            (error "The number of dimensions not equal to rank of array."))
 863           ((not (subtypep element-type (array-element-type array)))
 864            (error "The new element type, ~S, is incompatible with old type."
 865                   element-type))
 866           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 867            (error 'type-error
 868                   :datum array
 869                   :expected-type '(satisfies array-has-fill-pointer-p))))
 870     (let ((array-rank (length (the list dimensions))))
 871       (declare (fixnum array-rank))
 872       (unless (= array-rank 1)
 873         (when fill-pointer
 874           (error "Only vectors can have fill pointers.")))
 875       (cond (initial-contents-p
 876              ;; array former contents replaced by INITIAL-CONTENTS
 877              (if (or initial-element-p displaced-to)
 878                  (error "INITIAL-CONTENTS may not be specified with ~
 879                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 880              (let* ((array-size (apply #'* dimensions))
 881                     (array-data (data-vector-from-inits
 882                                  dimensions array-size element-type
 883                                  initial-contents initial-contents-p
 884                                  initial-element initial-element-p)))
 885                (if (adjustable-array-p array)
 886                    (set-array-header array array-data array-size
 887                                  (get-new-fill-pointer array array-size
 888                                                        fill-pointer)
 889                                  0 dimensions nil nil)
 890                    (if (array-header-p array)
 891                        ;; simple multidimensional or single dimensional array
 892                        (make-array dimensions
 893                                    :element-type element-type
 894                                    :initial-contents initial-contents)
 895                        array-data))))
 896             (displaced-to
 897              ;; We already established that no INITIAL-CONTENTS was supplied.
 898              (when initial-element
 899                (error "The :INITIAL-ELEMENT option may not be specified ~
 900                        with :DISPLACED-TO."))
 901              (unless (subtypep element-type (array-element-type displaced-to))
 902                (error "can't displace an array of type ~S into another of ~
 903                        type ~S"
 904                       element-type (array-element-type displaced-to)))
 905              (let ((displacement (or displaced-index-offset 0))
 906                    (array-size (apply #'* dimensions)))
 907                (declare (fixnum displacement array-size))
 908                (if (< (the fixnum (array-total-size displaced-to))
 909                       (the fixnum (+ displacement array-size)))
 910                    (error "The :DISPLACED-TO array is too small."))
 911                (if (adjustable-array-p array)
 912                    ;; None of the original contents appear in adjusted array.
 913                    (set-array-header array displaced-to array-size
 914                                      (get-new-fill-pointer array array-size
 915                                                            fill-pointer)
 916                                      displacement dimensions t nil)
 917                    ;; simple multidimensional or single dimensional array
 918                    (make-array dimensions
 919                                :element-type element-type
 920                                :displaced-to displaced-to
 921                                :displaced-index-offset
 922                                displaced-index-offset))))
 923             ((= array-rank 1)
 924              (let ((old-length (array-total-size array))
 925                    (new-length (car dimensions))
 926                    new-data)
 927                (declare (fixnum old-length new-length))
 928                (with-array-data ((old-data array) (old-start)
 929                                  (old-end old-length))
 930                  (cond ((or (and (array-header-p array)
 931                                  (%array-displaced-p array))
 932                             (< old-length new-length))
 933                         (setf new-data
 934                               (data-vector-from-inits
 935                                dimensions new-length element-type
 936                                initial-contents initial-contents-p
 937                                initial-element initial-element-p))
 938                         (replace new-data old-data
 939                                  :start2 old-start :end2 old-end))
 940                        (t (setf new-data
 941                                 (shrink-vector old-data new-length))))
 942                  (if (adjustable-array-p array)
 943                      (set-array-header array new-data new-length
 944                                        (get-new-fill-pointer array new-length
 945                                                              fill-pointer)
 946                                        0 dimensions nil nil)
 947                      new-data))))
 948             (t
 949              (let ((old-length (%array-available-elements array))
 950                    (new-length (apply #'* dimensions)))
 951                (declare (fixnum old-length new-length))
 952                (with-array-data ((old-data array) (old-start)
 953                                  (old-end old-length))
 954                  (declare (ignore old-end))
 955                  (let ((new-data (if (or (and (array-header-p array)
 956                                               (%array-displaced-p array))
 957                                          (> new-length old-length))
 958                                      (data-vector-from-inits
 959                                       dimensions new-length
 960                                       element-type () nil
 961                                       initial-element initial-element-p)
 962                                      old-data)))
 963                    (if (or (zerop old-length) (zerop new-length))
 964                        (when initial-element-p (fill new-data initial-element))
 965                        (zap-array-data old-data (array-dimensions array)
 966                                        old-start
 967                                        new-data dimensions new-length
 968                                        element-type initial-element
 969                                        initial-element-p))
 970                    (if (adjustable-array-p array)
 971                        (set-array-header array new-data new-length
 972                                          nil 0 dimensions nil nil)
 973                        (let ((new-array
 974                               (make-array-header
 975                                sb!vm:simple-array-widetag array-rank)))
 976                          (set-array-header new-array new-data new-length
 977                                            nil 0 dimensions nil t)))))))))))
 978
 979
 980 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 981   (cond ((not fill-pointer)
 982          (when (array-has-fill-pointer-p old-array)
 983            (when (> (%array-fill-pointer old-array) new-array-size)
 984              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 985                      smaller than its fill pointer (~S)"
 986                     old-array new-array-size (fill-pointer old-array)))
 987            (%array-fill-pointer old-array)))
 988         ((not (array-has-fill-pointer-p old-array))
 989          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 990                  in ADJUST-ARRAY unless the array (~S) was originally ~
 991                  created with a fill pointer"
 992                 fill-pointer
 993                 old-array))
 994         ((numberp fill-pointer)
 995          (when (> fill-pointer new-array-size)
 996            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 997                    than the new length of the vector (~S)"
 998                   fill-pointer new-array-size))
 999          fill-pointer)
1000         ((eq fill-pointer t)
1001          new-array-size)
1002         (t
1003          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
1004                 fill-pointer))))
1005
1006 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1007 ;;; which must be less than or equal to its current length. This can
1008 ;;; be called on vectors without a fill pointer but it is extremely
1009 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1010 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1011 ;;; or multi-threading. Call it only on provably local vectors.
1012 (defun %shrink-vector (vector new-length)
1013   (declare (vector vector))
1014   (unless (array-header-p vector)
1015     (macrolet ((frob (name &rest things)
1016                  `(etypecase ,name
1017                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1018                     ,@(mapcar (lambda (thing)
1019                                 (destructuring-bind (type-spec fill-value)
1020                                     thing
1021                                   `(,type-spec
1022                                     (fill (truly-the ,type-spec ,name)
1023                                           ,fill-value
1024                                           :start new-length))))
1025                               things))))
1026       ;; Set the 'tail' of the vector to the appropriate type of zero,
1027       ;; "because in some cases we'll scavenge larger areas in one go,
1028       ;; like groups of pages that had triggered the write barrier, or
1029       ;; the whole static space" according to jsnell.
1030       #.`(frob vector
1031           ,@(map 'list
1032                  (lambda (saetp)
1033                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1034                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1035                               #!+sb-unicode
1036                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1037                           *default-init-char-form*
1038                           (sb!vm:saetp-initial-element-default saetp))))
1039                  (remove-if-not
1040                   #'sb!vm:saetp-specifier
1041                   sb!vm:*specialized-array-element-type-properties*)))))
1042   ;; Only arrays have fill-pointers, but vectors have their length
1043   ;; parameter in the same place.
1044   (setf (%array-fill-pointer vector) new-length)
1045   vector)
1046
1047 (defun shrink-vector (vector new-length)
1048   (declare (vector vector))
1049   (cond
1050     ((eq (length vector) new-length)
1051      vector)
1052     ((array-has-fill-pointer-p vector)
1053      (setf (%array-fill-pointer vector) new-length)
1054      vector)
1055     (t (subseq vector 0 new-length))))
1056
1057 ;;; BIG THREAD SAFETY NOTE
1058 ;;;
1059 ;;; ADJUST-ARRAY/SET-ARRAY-HEADER, and its callees are very
1060 ;;; thread unsafe. They are nonatomic, and can mess with parallel
1061 ;;; code using the same arrays.
1062 ;;;
1063 ;;; A likely seeming fix is an additional level of indirection:
1064 ;;; ARRAY-HEADER -> ARRAY-INFO -> ... where ARRAY-HEADER would
1065 ;;; hold nothing but the pointer to ARRAY-INFO, and ARRAY-INFO
1066 ;;; would hold everything ARRAY-HEADER now holds. This allows
1067 ;;; consing up a new ARRAY-INFO and replacing it atomically in
1068 ;;; the ARRAY-HEADER.
1069 ;;;
1070 ;;; %WALK-DISPLACED-ARRAY-BACKPOINTERS is an especially nasty
1071 ;;; one: not only is it needed extremely rarely, which makes
1072 ;;; any thread safety bugs involving it look like rare random
1073 ;;; corruption, but because it walks the chain *upwards*, which
1074 ;;; may violate user expectations.
1075
1076 (defun %save-displaced-array-backpointer (array data)
1077   (flet ((purge (pointers)
1078            (remove-if (lambda (value)
1079                         (or (not value) (eq array value)))
1080                       pointers
1081                       :key #'weak-pointer-value)))
1082     ;; Add backpointer to the new data vector if it has a header.
1083     (when (array-header-p data)
1084       (setf (%array-displaced-from data)
1085             (cons (make-weak-pointer array)
1086                   (purge (%array-displaced-from data)))))
1087     ;; Remove old backpointer, if any.
1088     (let ((old-data (%array-data-vector array)))
1089       (when (and (neq data old-data) (array-header-p old-data))
1090         (setf (%array-displaced-from old-data)
1091               (purge (%array-displaced-from old-data)))))))
1092
1093 (defun %walk-displaced-array-backpointers (array new-length)
1094   (dolist (p (%array-displaced-from array))
1095     (let ((from (weak-pointer-value p)))
1096       (when (and from (eq array (%array-data-vector from)))
1097         (let ((requires (+ (%array-available-elements from)
1098                            (%array-displacement from))))
1099           (unless (>= new-length requires)
1100             ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
1101             ;;
1102             ;;   "If A is displaced to B, the consequences are unspecified if B is
1103             ;;   adjusted in such a way that it no longer has enough elements to
1104             ;;   satisfy A.
1105             ;;
1106             ;; since we're hanging on a weak pointer here, we can't signal an
1107             ;; error right now: the array that we're looking at might be
1108             ;; garbage. Instead, we set all dimensions to zero so that next
1109             ;; safe access to the displaced array will trap. Additionally, we
1110             ;; save the original dimensions, so we can signal a more
1111             ;; understandable error when the time comes.
1112             (%walk-displaced-array-backpointers from 0)
1113             (setf (%array-fill-pointer from) 0
1114                   (%array-available-elements from) 0
1115                   (%array-displaced-p from) (array-dimensions array))
1116             (dotimes (i (%array-rank from))
1117               (setf (%array-dimension from i) 0))))))))
1118
1119 ;;; Fill in array header with the provided information, and return the array.
1120 (defun set-array-header (array data length fill-pointer displacement dimensions
1121                          displacedp newp)
1122   (if newp
1123       (setf (%array-displaced-from array) nil)
1124       (%walk-displaced-array-backpointers array length))
1125   (when displacedp
1126     (%save-displaced-array-backpointer array data))
1127   (setf (%array-data-vector array) data)
1128   (setf (%array-available-elements array) length)
1129   (cond (fill-pointer
1130          (setf (%array-fill-pointer array) fill-pointer)
1131          (setf (%array-fill-pointer-p array) t))
1132         (t
1133          (setf (%array-fill-pointer array) length)
1134          (setf (%array-fill-pointer-p array) nil)))
1135   (setf (%array-displacement array) displacement)
1136   (if (listp dimensions)
1137       (dotimes (axis (array-rank array))
1138         (declare (type index axis))
1139         (setf (%array-dimension array axis) (pop dimensions)))
1140       (setf (%array-dimension array 0) dimensions))
1141   (setf (%array-displaced-p array) displacedp)
1142   array)
1143
1144 ;;; User visible extension
1145 (declaim (ftype (function (array) (values (simple-array * (*)) &optional))
1146                 array-storage-vector))
1147 (defun array-storage-vector (array)
1148   "Returns the underlying storage vector of ARRAY, which must be a non-displaced array.
1149
1150 In SBCL, if ARRAY is a of type \(SIMPLE-ARRAY * \(*)), it is its own storage
1151 vector. Multidimensional arrays, arrays with fill pointers, and adjustable
1152 arrays have an underlying storage vector with the same ARRAY-ELEMENT-TYPE as
1153 ARRAY, which this function returns.
1154
1155 Important note: the underlying vector is an implementation detail. Even though
1156 this function exposes it, changes in the implementation may cause this
1157 function to be removed without further warning."
1158   ;; KLUDGE: Without TRULY-THE the system is not smart enough to figure out that
1159   ;; the return value is always of the known type.
1160   (truly-the (simple-array * (*))
1161              (if (array-header-p array)
1162                  (if (%array-displaced-p array)
1163                      (error "~S cannot be used with displaced arrays. Use ~S instead."
1164                             'array-storage-vector 'array-displacement)
1165                      (%array-data-vector array))
1166                  array)))
1167 \f
1168 ;;;; used by SORT
1169
1170 ;;; temporary vector for stable sorting vectors, allocated for each new thread
1171 (defvar *merge-sort-temp-vector* (vector))
1172 (declaim (simple-vector *merge-sort-temp-vector*))
1173
1174 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1175
1176 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1177 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1178 ;;; to length zero array in each new thread.
1179 ;;;
1180 ;;; DX is probably a bad idea, because a with a big array it would
1181 ;;; be fairly easy to blow the stack.
1182 (defvar *zap-array-data-temp* (vector))
1183 (declaim (simple-vector *zap-array-data-temp*))
1184
1185 (defun zap-array-data-temp (length initial-element initial-element-p)
1186   (declare (fixnum length))
1187   (let ((tmp *zap-array-data-temp*))
1188     (declare (simple-vector tmp))
1189     (cond ((> length (length tmp))
1190            (setf *zap-array-data-temp*
1191                  (if initial-element-p
1192                      (make-array length :initial-element initial-element)
1193                      (make-array length))))
1194           (initial-element-p
1195            (fill tmp initial-element :end length))
1196           (t
1197            tmp))))
1198
1199 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1200 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1201 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1202 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1203 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1204                        element-type initial-element initial-element-p)
1205   (declare (list old-dims new-dims))
1206   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1207   ;; at least in SBCL.
1208   ;; NEW-DIMS comes from the user.
1209   (setf old-dims (nreverse old-dims)
1210         new-dims (reverse new-dims))
1211   (cond ((eq old-data new-data)
1212          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1213          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1214          ;; EQ; in this case, a temporary must be used and filled
1215          ;; appropriately. specified initial-element.
1216          (when initial-element-p
1217            ;; FIXME: transforming this TYPEP to someting a bit faster
1218            ;; would be a win...
1219            (unless (typep initial-element element-type)
1220              (error "~S can't be used to initialize an array of type ~S."
1221                     initial-element element-type)))
1222          (let ((temp (zap-array-data-temp new-length
1223                                           initial-element initial-element-p)))
1224            (declare (simple-vector temp))
1225            (zap-array-data-aux old-data old-dims offset temp new-dims)
1226            (dotimes (i new-length)
1227              (setf (aref new-data i) (aref temp i)
1228                    ;; zero out any garbage right away
1229                    (aref temp i) 0))))
1230         (t
1231          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1232          ;; already been filled with any
1233          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1234
1235 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1236   (declare (fixnum offset))
1237   (let ((limits (mapcar (lambda (x y)
1238                           (declare (fixnum x y))
1239                           (1- (the fixnum (min x y))))
1240                         old-dims new-dims)))
1241     (macrolet ((bump-index-list (index limits)
1242                  `(do ((subscripts ,index (cdr subscripts))
1243                        (limits ,limits (cdr limits)))
1244                       ((null subscripts) :eof)
1245                     (cond ((< (the fixnum (car subscripts))
1246                               (the fixnum (car limits)))
1247                            (rplaca subscripts
1248                                    (1+ (the fixnum (car subscripts))))
1249                            (return ,index))
1250                           (t (rplaca subscripts 0))))))
1251       (do ((index (make-list (length old-dims) :initial-element 0)
1252                   (bump-index-list index limits)))
1253           ((eq index :eof))
1254         (setf (aref new-data (row-major-index-from-dims index new-dims))
1255               (aref old-data
1256                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1257                        offset)))))))
1258
1259 ;;; Figure out the row-major-order index of an array reference from a
1260 ;;; list of subscripts and a list of dimensions. This is for internal
1261 ;;; calls only, and the subscripts and dim-list variables are assumed
1262 ;;; to be reversed from what the user supplied.
1263 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1264   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1265        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1266        (chunk-size 1)
1267        (result 0))
1268       ((null rev-dim-list) result)
1269     (declare (fixnum chunk-size result))
1270     (setq result (+ result
1271                     (the fixnum (* (the fixnum (car rev-subscripts))
1272                                    chunk-size))))
1273     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1274 \f
1275 ;;;; some bit stuff
1276
1277 (defun bit-array-same-dimensions-p (array1 array2)
1278   (declare (type (array bit) array1 array2))
1279   (and (= (array-rank array1)
1280           (array-rank array2))
1281        (dotimes (index (array-rank array1) t)
1282          (when (/= (array-dimension array1 index)
1283                    (array-dimension array2 index))
1284            (return nil)))))
1285
1286 (defun pick-result-array (result-bit-array bit-array-1)
1287   (case result-bit-array
1288     ((t) bit-array-1)
1289     ((nil) (make-array (array-dimensions bit-array-1)
1290                        :element-type 'bit
1291                        :initial-element 0))
1292     (t
1293      (unless (bit-array-same-dimensions-p bit-array-1
1294                                           result-bit-array)
1295        (error "~S and ~S don't have the same dimensions."
1296               bit-array-1 result-bit-array))
1297      result-bit-array)))
1298
1299 (defmacro def-bit-array-op (name function)
1300   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1301      #!+sb-doc
1302      ,(format nil
1303               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1304                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1305                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1306                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1307                All the arrays must have the same rank and dimensions."
1308               (symbol-name function))
1309      (declare (type (array bit) bit-array-1 bit-array-2)
1310               (type (or (array bit) (member t nil)) result-bit-array))
1311      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1312        (error "~S and ~S don't have the same dimensions."
1313               bit-array-1 bit-array-2))
1314      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1315        (if (and (simple-bit-vector-p bit-array-1)
1316                 (simple-bit-vector-p bit-array-2)
1317                 (simple-bit-vector-p result-bit-array))
1318            (locally (declare (optimize (speed 3) (safety 0)))
1319              (,name bit-array-1 bit-array-2 result-bit-array))
1320            (with-array-data ((data1 bit-array-1) (start1) (end1))
1321              (declare (ignore end1))
1322              (with-array-data ((data2 bit-array-2) (start2) (end2))
1323                (declare (ignore end2))
1324                (with-array-data ((data3 result-bit-array) (start3) (end3))
1325                  (do ((index-1 start1 (1+ index-1))
1326                       (index-2 start2 (1+ index-2))
1327                       (index-3 start3 (1+ index-3)))
1328                      ((>= index-3 end3) result-bit-array)
1329                    (declare (type index index-1 index-2 index-3))
1330                    (setf (sbit data3 index-3)
1331                          (logand (,function (sbit data1 index-1)
1332                                             (sbit data2 index-2))
1333                                  1))))))))))
1334
1335 (def-bit-array-op bit-and logand)
1336 (def-bit-array-op bit-ior logior)
1337 (def-bit-array-op bit-xor logxor)
1338 (def-bit-array-op bit-eqv logeqv)
1339 (def-bit-array-op bit-nand lognand)
1340 (def-bit-array-op bit-nor lognor)
1341 (def-bit-array-op bit-andc1 logandc1)
1342 (def-bit-array-op bit-andc2 logandc2)
1343 (def-bit-array-op bit-orc1 logorc1)
1344 (def-bit-array-op bit-orc2 logorc2)
1345
1346 (defun bit-not (bit-array &optional result-bit-array)
1347   #!+sb-doc
1348   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1349   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1350   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1351   created. Both arrays must have the same rank and dimensions."
1352   (declare (type (array bit) bit-array)
1353            (type (or (array bit) (member t nil)) result-bit-array))
1354   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1355     (if (and (simple-bit-vector-p bit-array)
1356              (simple-bit-vector-p result-bit-array))
1357         (locally (declare (optimize (speed 3) (safety 0)))
1358           (bit-not bit-array result-bit-array))
1359         (with-array-data ((src bit-array) (src-start) (src-end))
1360           (declare (ignore src-end))
1361           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1362             (do ((src-index src-start (1+ src-index))
1363                  (dst-index dst-start (1+ dst-index)))
1364                 ((>= dst-index dst-end) result-bit-array)
1365               (declare (type index src-index dst-index))
1366               (setf (sbit dst dst-index)
1367                     (logxor (sbit src src-index) 1))))))))