src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data (array start end)
  50   (%with-array-data-macro array start end :fail-inline? t))
  51
  52 (defun %data-vector-and-index (array index)
  53   (if (array-header-p array)
  54       (multiple-value-bind (vector index)
  55           (%with-array-data array index nil)
  56         (values vector index))
  57       (values array index)))
  58
  59 ;;; It'd waste space to expand copies of error handling in every
  60 ;;; inline %WITH-ARRAY-DATA, so we have them call this function
  61 ;;; instead. This is just a wrapper which is known never to return.
  62 (defun failed-%with-array-data (array start end)
  63   (declare (notinline %with-array-data))
  64   (%with-array-data array start end)
  65   (bug "called FAILED-%WITH-ARRAY-DATA with valid array parameters?"))
  66 \f
  67 ;;;; MAKE-ARRAY
  68 (defun upgraded-array-element-type (spec &optional environment)
  69   #!+sb-doc
  70   "Return the element type that will actually be used to implement an array
  71    with the specifier :ELEMENT-TYPE Spec."
  72   (declare (ignore environment))
  73   (if (unknown-type-p (specifier-type spec))
  74       (error "undefined type: ~S" spec)
  75       (type-specifier (array-type-specialized-element-type
  76                        (specifier-type `(array ,spec))))))
  77 (eval-when (:compile-toplevel :execute)
  78   (sb!xc:defmacro pick-vector-type (type &rest specs)
  79     `(cond ,@(mapcar (lambda (spec)
  80                        `(,(if (eq (car spec) t)
  81                               t
  82                               `(subtypep ,type ',(car spec)))
  83                          ,@(cdr spec)))
  84                      specs))))
  85
  86 ;;; These functions are used in the implementation of MAKE-ARRAY for
  87 ;;; complex arrays. There are lots of transforms to simplify
  88 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  89 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  90 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  91 ;;; making this somewhat efficient, at least not doing full calls to
  92 ;;; SUBTYPEP in the easy cases.
  93 (defun %vector-widetag-and-n-bits (type)
  94   (case type
  95     ;; Pick off some easy common cases.
  96     ;;
  97     ;; (Perhaps we should make a much more exhaustive table of easy
  98     ;; common cases here. Or perhaps the effort would be better spent
  99     ;; on smarter compiler transforms which do the calculation once
 100     ;; and for all in any reasonable user programs.)
 101     ((t)
 102      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
 103     ((base-char standard-char)
 104      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
 105     ((bit)
 106      (values #.sb!vm:simple-bit-vector-widetag 1))
 107     ;; OK, we have to wade into SUBTYPEPing after all.
 108     (t
 109      ;; FIXME: The data here are redundant with
 110      ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 111      (pick-vector-type type
 112        (nil (values #.sb!vm:simple-array-nil-widetag 0))
 113        (base-char (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
 114        (bit (values #.sb!vm:simple-bit-vector-widetag 1))
 115        ((unsigned-byte 2)
 116         (values #.sb!vm:simple-array-unsigned-byte-2-widetag 2))
 117        ((unsigned-byte 4)
 118         (values #.sb!vm:simple-array-unsigned-byte-4-widetag 4))
 119        ((unsigned-byte 8)
 120         (values #.sb!vm:simple-array-unsigned-byte-8-widetag 8))
 121        ((unsigned-byte 16)
 122         (values #.sb!vm:simple-array-unsigned-byte-16-widetag 16))
 123        ((unsigned-byte 32)
 124         (values #.sb!vm:simple-array-unsigned-byte-32-widetag 32))
 125        ((signed-byte 8)
 126         (values #.sb!vm:simple-array-signed-byte-8-widetag 8))
 127        ((signed-byte 16)
 128         (values #.sb!vm:simple-array-signed-byte-16-widetag 16))
 129        ((signed-byte 30)
 130         (values #.sb!vm:simple-array-signed-byte-30-widetag 32))
 131        ((signed-byte 32)
 132         (values #.sb!vm:simple-array-signed-byte-32-widetag 32))
 133        (single-float (values #.sb!vm:simple-array-single-float-widetag 32))
 134        (double-float (values #.sb!vm:simple-array-double-float-widetag 64))
 135        #!+long-float
 136        (long-float
 137         (values #.sb!vm:simple-array-long-float-widetag
 138                 #!+x86 96 #!+sparc 128))
 139        ((complex single-float)
 140         (values #.sb!vm:simple-array-complex-single-float-widetag 64))
 141        ((complex double-float)
 142         (values #.sb!vm:simple-array-complex-double-float-widetag 128))
 143        #!+long-float
 144        ((complex long-float)
 145         (values #.sb!vm:simple-array-complex-long-float-widetag
 146                 #!+x86 192
 147                 #!+sparc 256))
 148        (t (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))))))
 149 (defun %complex-vector-widetag (type)
 150   (case type
 151     ;; Pick off some easy common cases.
 152     ((t)
 153      #.sb!vm:complex-vector-widetag)
 154     ((base-char)
 155      #.sb!vm:complex-base-string-widetag)
 156     ((nil)
 157      #.sb!vm:complex-vector-nil-widetag)
 158     ((bit)
 159      #.sb!vm:complex-bit-vector-widetag)
 160     ;; OK, we have to wade into SUBTYPEPing after all.
 161     (t
 162      (pick-vector-type type
 163        (nil #.sb!vm:complex-vector-nil-widetag)
 164        (base-char #.sb!vm:complex-base-string-widetag)
 165        (bit #.sb!vm:complex-bit-vector-widetag)
 166        (t #.sb!vm:complex-vector-widetag)))))
 167
 168 (defun make-array (dimensions &key
 169                               (element-type t)
 170                               (initial-element nil initial-element-p)
 171                               initial-contents adjustable fill-pointer
 172                               displaced-to displaced-index-offset)
 173   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 174          (array-rank (length (the list dimensions)))
 175          (simple (and (null fill-pointer)
 176                       (not adjustable)
 177                       (null displaced-to))))
 178     (declare (fixnum array-rank))
 179     (when (and displaced-index-offset (null displaced-to))
 180       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 181     (if (and simple (= array-rank 1))
 182         ;; it's a (SIMPLE-ARRAY * (*))
 183         (multiple-value-bind (type n-bits)
 184             (%vector-widetag-and-n-bits element-type)
 185           (declare (type (unsigned-byte 8) type)
 186                    (type (integer 0 256) n-bits))
 187           (let* ((length (car dimensions))
 188                  (array (allocate-vector
 189                          type
 190                          length
 191                          (ceiling (* (if (= type sb!vm:simple-base-string-widetag)
 192                                          (1+ length)
 193                                          length)
 194                                      n-bits)
 195                                   sb!vm:n-word-bits))))
 196             (declare (type index length))
 197             (when initial-element-p
 198               (fill array initial-element))
 199             (when initial-contents
 200               (when initial-element
 201                 (error "can't specify both :INITIAL-ELEMENT and ~
 202                 :INITIAL-CONTENTS"))
 203               (unless (= length (length initial-contents))
 204                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 205                        the vector length is ~W."
 206                        (length initial-contents)
 207                        length))
 208               (replace array initial-contents))
 209             array))
 210         ;; it's either a complex array or a multidimensional array.
 211         (let* ((total-size (reduce #'* dimensions))
 212                (data (or displaced-to
 213                          (data-vector-from-inits
 214                           dimensions total-size element-type
 215                           initial-contents initial-element initial-element-p)))
 216                (array (make-array-header
 217                        (cond ((= array-rank 1)
 218                               (%complex-vector-widetag element-type))
 219                              (simple sb!vm:simple-array-widetag)
 220                              (t sb!vm:complex-array-widetag))
 221                        array-rank)))
 222           (cond (fill-pointer
 223                  (unless (= array-rank 1)
 224                    (error "Only vectors can have fill pointers."))
 225                  (let ((length (car dimensions)))
 226                    (declare (fixnum length))
 227                    (setf (%array-fill-pointer array)
 228                      (cond ((eq fill-pointer t)
 229                             length)
 230                            (t
 231                             (unless (and (fixnump fill-pointer)
 232                                          (>= fill-pointer 0)
 233                                          (<= fill-pointer length))
 234                               ;; FIXME: should be TYPE-ERROR?
 235                               (error "invalid fill-pointer ~W"
 236                                      fill-pointer))
 237                             fill-pointer))))
 238                  (setf (%array-fill-pointer-p array) t))
 239                 (t
 240                  (setf (%array-fill-pointer array) total-size)
 241                  (setf (%array-fill-pointer-p array) nil)))
 242           (setf (%array-available-elements array) total-size)
 243           (setf (%array-data-vector array) data)
 244           (cond (displaced-to
 245                  (when (or initial-element-p initial-contents)
 246                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 247                    can be specified along with :DISPLACED-TO"))
 248                  (let ((offset (or displaced-index-offset 0)))
 249                    (when (> (+ offset total-size)
 250                             (array-total-size displaced-to))
 251                      (error "~S doesn't have enough elements." displaced-to))
 252                    (setf (%array-displacement array) offset)
 253                    (setf (%array-displaced-p array) t)))
 254                 (t
 255                  (setf (%array-displaced-p array) nil)))
 256           (let ((axis 0))
 257             (dolist (dim dimensions)
 258               (setf (%array-dimension array axis) dim)
 259               (incf axis)))
 260           array))))
 261
 262 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 263 ;;; specified array characteristics. Dimensions is only used to pass
 264 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 265 ;;; initial-contents.
 266 (defun data-vector-from-inits (dimensions total-size element-type
 267                                initial-contents initial-element
 268                                initial-element-p)
 269   (when (and initial-contents initial-element-p)
 270     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 271             either MAKE-ARRAY or ADJUST-ARRAY."))
 272   (let ((data (if initial-element-p
 273                   (make-array total-size
 274                               :element-type element-type
 275                               :initial-element initial-element)
 276                   (make-array total-size
 277                               :element-type element-type))))
 278     (cond (initial-element-p
 279            (unless (simple-vector-p data)
 280              (unless (typep initial-element element-type)
 281                (error "~S cannot be used to initialize an array of type ~S."
 282                       initial-element element-type))
 283              (fill (the vector data) initial-element)))
 284           (initial-contents
 285            (fill-data-vector data dimensions initial-contents)))
 286     data))
 287
 288 (defun fill-data-vector (vector dimensions initial-contents)
 289   (let ((index 0))
 290     (labels ((frob (axis dims contents)
 291                (cond ((null dims)
 292                       (setf (aref vector index) contents)
 293                       (incf index))
 294                      (t
 295                       (unless (typep contents 'sequence)
 296                         (error "malformed :INITIAL-CONTENTS: ~S is not a ~
 297                                 sequence, but ~W more layer~:P needed."
 298                                contents
 299                                (- (length dimensions) axis)))
 300                       (unless (= (length contents) (car dims))
 301                         (error "malformed :INITIAL-CONTENTS: Dimension of ~
 302                                 axis ~W is ~W, but ~S is ~W long."
 303                                axis (car dims) contents (length contents)))
 304                       (if (listp contents)
 305                           (dolist (content contents)
 306                             (frob (1+ axis) (cdr dims) content))
 307                           (dotimes (i (length contents))
 308                             (frob (1+ axis) (cdr dims) (aref contents i))))))))
 309       (frob 0 dimensions initial-contents))))
 310
 311 (defun vector (&rest objects)
 312   #!+sb-doc
 313   "Construct a SIMPLE-VECTOR from the given objects."
 314   (coerce (the list objects) 'simple-vector))
 315 \f
 316 ;;;; accessor/setter functions
 317 (eval-when (:compile-toplevel :execute)
 318   (defparameter *specialized-array-element-types*
 319     '(t
 320       character
 321       bit
 322       (unsigned-byte 2)
 323       (unsigned-byte 4)
 324       (unsigned-byte 8)
 325       (unsigned-byte 16)
 326       (unsigned-byte 32)
 327       (signed-byte 8)
 328       (signed-byte 16)
 329       (signed-byte 30)
 330       (signed-byte 32)
 331       single-float
 332       double-float
 333       #!+long-float long-float
 334       (complex single-float)
 335       (complex double-float)
 336       #!+long-float (complex long-float)
 337       nil)))
 338
 339 (defun hairy-data-vector-ref (array index)
 340   (with-array-data ((vector array) (index index) (end))
 341     (declare (ignore end))
 342     (etypecase vector .
 343                #.(mapcar (lambda (type)
 344                            (let ((atype `(simple-array ,type (*))))
 345                              `(,atype
 346                                (data-vector-ref (the ,atype vector)
 347                                                 index))))
 348                          *specialized-array-element-types*))))
 349
 350 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 351 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 352 ;;; definition is needed for the compiler to use in constant folding.)
 353 (defun data-vector-ref (array index)
 354   (hairy-data-vector-ref array index))
 355
 356 (defun hairy-data-vector-set (array index new-value)
 357   (with-array-data ((vector array) (index index) (end))
 358     (declare (ignore end))
 359     (etypecase vector .
 360                #.(mapcar (lambda (type)
 361                            (let ((atype `(simple-array ,type (*))))
 362                              `(,atype
 363                                (data-vector-set (the ,atype vector)
 364                                                 index
 365                                                 (the ,type
 366                                                   new-value))
 367                                ;; For specialized arrays, the return
 368                                ;; from data-vector-set would have to
 369                                ;; be reboxed to be a (Lisp) return
 370                                ;; value; instead, we use the
 371                                ;; already-boxed value as the return.
 372                                new-value)))
 373                          *specialized-array-element-types*))))
 374
 375 (defun %array-row-major-index (array subscripts
 376                                      &optional (invalid-index-error-p t))
 377   (declare (array array)
 378            (list subscripts))
 379   (let ((rank (array-rank array)))
 380     (unless (= rank (length subscripts))
 381       (error "wrong number of subscripts, ~W, for array of rank ~W"
 382              (length subscripts) rank))
 383     (if (array-header-p array)
 384         (do ((subs (nreverse subscripts) (cdr subs))
 385              (axis (1- (array-rank array)) (1- axis))
 386              (chunk-size 1)
 387              (result 0))
 388             ((null subs) result)
 389           (declare (list subs) (fixnum axis chunk-size result))
 390           (let ((index (car subs))
 391                 (dim (%array-dimension array axis)))
 392             (declare (fixnum dim))
 393             (unless (< -1 index dim)
 394               (if invalid-index-error-p
 395                   (error 'simple-type-error
 396                          :format-control "invalid index ~W~[~;~:; on axis ~:*~W~] in ~S"
 397                          :format-arguments (list index axis array)
 398                          :datum index
 399                          :expected-type `(integer 0 (,dim)))
 400                   (return-from %array-row-major-index nil)))
 401             (incf result (* chunk-size (the fixnum index)))
 402             (setf chunk-size (* chunk-size dim))))
 403         (let ((index (first subscripts))
 404               (length (length (the (simple-array * (*)) array))))
 405           (unless (< -1 index length)
 406             (if invalid-index-error-p
 407                 ;; FIXME: perhaps this should share a format-string
 408                 ;; with INVALID-ARRAY-INDEX-ERROR or
 409                 ;; INDEX-TOO-LARGE-ERROR?
 410                 (error 'simple-type-error
 411                        :format-control "invalid index ~W in ~S"
 412                        :format-arguments (list index array)
 413                        :datum index
 414                        :expected-type `(integer 0 (,length)))
 415                 (return-from %array-row-major-index nil)))
 416           index))))
 417
 418 (defun array-in-bounds-p (array &rest subscripts)
 419   #!+sb-doc
 420   "Return T if the Subscipts are in bounds for the Array, Nil otherwise."
 421   (if (%array-row-major-index array subscripts nil)
 422       t))
 423
 424 (defun array-row-major-index (array &rest subscripts)
 425   (%array-row-major-index array subscripts))
 426
 427 (defun aref (array &rest subscripts)
 428   #!+sb-doc
 429   "Return the element of the Array specified by the Subscripts."
 430   (row-major-aref array (%array-row-major-index array subscripts)))
 431
 432 (defun %aset (array &rest stuff)
 433   (let ((subscripts (butlast stuff))
 434         (new-value (car (last stuff))))
 435     (setf (row-major-aref array (%array-row-major-index array subscripts))
 436           new-value)))
 437
 438 ;;; FIXME: What's supposed to happen with functions
 439 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 440 ;;; DEFSETF FOO is also defined? It seems as though the logical
 441 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 442 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 443 ;;; just as for ordinary functions
 444 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 445 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 446 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 447 ;;;  ZOO
 448 ;;;  * (DEFUN ZOO (X) (* 3 X))
 449 ;;;  Warning: ZOO previously defined as a macro.
 450 ;;;  ZOO
 451 ;;; But that doesn't seem to be what happens in CMU CL.
 452 ;;;
 453 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 454 ;;; 5.1.2.5) requires implementations to support
 455 ;;;   (SETF (APPLY #'AREF ...) ...)
 456 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 457 ;;; also terrifying that this sequence of definitions causes it to
 458 ;;; work.
 459 ;;;
 460 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 461 ;;; has a setf expansion and/or a setf function defined.
 462
 463 #!-sb-fluid (declaim (inline (setf aref)))
 464 (defun (setf aref) (new-value array &rest subscripts)
 465   (declare (type array array))
 466   (setf (row-major-aref array (%array-row-major-index array subscripts))
 467         new-value))
 468
 469 (defun row-major-aref (array index)
 470   #!+sb-doc
 471   "Return the element of array corressponding to the row-major index. This is
 472    SETF'able."
 473   (declare (optimize (safety 1)))
 474   (row-major-aref array index))
 475
 476 (defun %set-row-major-aref (array index new-value)
 477   (declare (optimize (safety 1)))
 478   (setf (row-major-aref array index) new-value))
 479
 480 (defun svref (simple-vector index)
 481   #!+sb-doc
 482   "Return the INDEX'th element of the given Simple-Vector."
 483   (declare (optimize (safety 1)))
 484   (aref simple-vector index))
 485
 486 (defun %svset (simple-vector index new)
 487   (declare (optimize (safety 1)))
 488   (setf (aref simple-vector index) new))
 489
 490 (defun bit (bit-array &rest subscripts)
 491   #!+sb-doc
 492   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 493   (declare (type (array bit) bit-array) (optimize (safety 1)))
 494   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 495
 496 (defun %bitset (bit-array &rest stuff)
 497   (declare (type (array bit) bit-array) (optimize (safety 1)))
 498   (let ((subscripts (butlast stuff))
 499         (new-value (car (last stuff))))
 500     (setf (row-major-aref bit-array
 501                           (%array-row-major-index bit-array subscripts))
 502           new-value)))
 503
 504 #!-sb-fluid (declaim (inline (setf bit)))
 505 (defun (setf bit) (new-value bit-array &rest subscripts)
 506   (declare (type (array bit) bit-array) (optimize (safety 1)))
 507   (setf (row-major-aref bit-array
 508                         (%array-row-major-index bit-array subscripts))
 509         new-value))
 510
 511 (defun sbit (simple-bit-array &rest subscripts)
 512   #!+sb-doc
 513   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 514   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 515   (row-major-aref simple-bit-array
 516                   (%array-row-major-index simple-bit-array subscripts)))
 517
 518 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 519 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 520 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 521 ;;; -- WHN 19990911
 522 (defun %sbitset (simple-bit-array &rest stuff)
 523   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 524   (let ((subscripts (butlast stuff))
 525         (new-value (car (last stuff))))
 526     (setf (row-major-aref simple-bit-array
 527                           (%array-row-major-index simple-bit-array subscripts))
 528           new-value)))
 529
 530 #!-sb-fluid (declaim (inline (setf sbit)))
 531 (defun (setf sbit) (new-value bit-array &rest subscripts)
 532   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 533   (setf (row-major-aref bit-array
 534                         (%array-row-major-index bit-array subscripts))
 535         new-value))
 536 \f
 537 ;;;; miscellaneous array properties
 538
 539 (defun array-element-type (array)
 540   #!+sb-doc
 541   "Return the type of the elements of the array"
 542   (let ((widetag (widetag-of array)))
 543     (macrolet ((pick-element-type (&rest stuff)
 544                  `(cond ,@(mapcar (lambda (stuff)
 545                                     (cons
 546                                      (let ((item (car stuff)))
 547                                        (cond ((eq item t)
 548                                               t)
 549                                              ((listp item)
 550                                               (cons 'or
 551                                                     (mapcar (lambda (x)
 552                                                               `(= widetag ,x))
 553                                                             item)))
 554                                              (t
 555                                               `(= widetag ,item))))
 556                                      (cdr stuff)))
 557                                   stuff))))
 558       ;; FIXME: The data here are redundant with
 559       ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 560       (pick-element-type
 561        ((sb!vm:simple-array-nil-widetag sb!vm:complex-vector-nil-widetag) nil)
 562        ((sb!vm:simple-base-string-widetag sb!vm:complex-base-string-widetag) 'base-char)
 563        ((sb!vm:simple-bit-vector-widetag
 564          sb!vm:complex-bit-vector-widetag) 'bit)
 565        (sb!vm:simple-vector-widetag t)
 566        (sb!vm:simple-array-unsigned-byte-2-widetag '(unsigned-byte 2))
 567        (sb!vm:simple-array-unsigned-byte-4-widetag '(unsigned-byte 4))
 568        (sb!vm:simple-array-unsigned-byte-8-widetag '(unsigned-byte 8))
 569        (sb!vm:simple-array-unsigned-byte-16-widetag '(unsigned-byte 16))
 570        (sb!vm:simple-array-unsigned-byte-32-widetag '(unsigned-byte 32))
 571        (sb!vm:simple-array-signed-byte-8-widetag '(signed-byte 8))
 572        (sb!vm:simple-array-signed-byte-16-widetag '(signed-byte 16))
 573        (sb!vm:simple-array-signed-byte-30-widetag '(signed-byte 30))
 574        (sb!vm:simple-array-signed-byte-32-widetag '(signed-byte 32))
 575        (sb!vm:simple-array-single-float-widetag 'single-float)
 576        (sb!vm:simple-array-double-float-widetag 'double-float)
 577        #!+long-float
 578        (sb!vm:simple-array-long-float-widetag 'long-float)
 579        (sb!vm:simple-array-complex-single-float-widetag
 580         '(complex single-float))
 581        (sb!vm:simple-array-complex-double-float-widetag
 582         '(complex double-float))
 583        #!+long-float
 584        (sb!vm:simple-array-complex-long-float-widetag '(complex long-float))
 585        ((sb!vm:simple-array-widetag
 586          sb!vm:complex-vector-widetag
 587          sb!vm:complex-array-widetag)
 588         (with-array-data ((array array) (start) (end))
 589           (declare (ignore start end))
 590           (array-element-type array)))
 591        (t
 592         (error 'type-error :datum array :expected-type 'array))))))
 593
 594 (defun array-rank (array)
 595   #!+sb-doc
 596   "Return the number of dimensions of ARRAY."
 597   (if (array-header-p array)
 598       (%array-rank array)
 599       1))
 600
 601 (defun array-dimension (array axis-number)
 602   #!+sb-doc
 603   "Return the length of dimension AXIS-NUMBER of ARRAY."
 604   (declare (array array) (type index axis-number))
 605   (cond ((not (array-header-p array))
 606          (unless (= axis-number 0)
 607            (error "Vector axis is not zero: ~S" axis-number))
 608          (length (the (simple-array * (*)) array)))
 609         ((>= axis-number (%array-rank array))
 610          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 611                 axis-number array (%array-rank array)))
 612         (t
 613          (%array-dimension array axis-number))))
 614
 615 (defun array-dimensions (array)
 616   #!+sb-doc
 617   "Return a list whose elements are the dimensions of the array"
 618   (declare (array array))
 619   (if (array-header-p array)
 620       (do ((results nil (cons (array-dimension array index) results))
 621            (index (1- (array-rank array)) (1- index)))
 622           ((minusp index) results))
 623       (list (array-dimension array 0))))
 624
 625 (defun array-total-size (array)
 626   #!+sb-doc
 627   "Return the total number of elements in the Array."
 628   (declare (array array))
 629   (if (array-header-p array)
 630       (%array-available-elements array)
 631       (length (the vector array))))
 632
 633 (defun array-displacement (array)
 634   #!+sb-doc
 635   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 636    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 637   (declare (type array array))
 638   (if (and (array-header-p array) ; if unsimple and
 639            (%array-displaced-p array)) ; displaced
 640       (values (%array-data-vector array) (%array-displacement array))
 641       (values nil 0)))
 642
 643 (defun adjustable-array-p (array)
 644   #!+sb-doc
 645   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 646    to the argument, this happens for complex arrays."
 647   (declare (array array))
 648   (not (typep array 'simple-array)))
 649 \f
 650 ;;;; fill pointer frobbing stuff
 651
 652 (defun array-has-fill-pointer-p (array)
 653   #!+sb-doc
 654   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 655   (declare (array array))
 656   (and (array-header-p array) (%array-fill-pointer-p array)))
 657
 658 (defun fill-pointer (vector)
 659   #!+sb-doc
 660   "Return the FILL-POINTER of the given VECTOR."
 661   (declare (vector vector))
 662   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 663       (%array-fill-pointer vector)
 664       (error 'simple-type-error
 665              :datum vector
 666              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 667              :format-control "~S is not an array with a fill pointer."
 668              :format-arguments (list vector))))
 669
 670 (defun %set-fill-pointer (vector new)
 671   (declare (vector vector) (fixnum new))
 672   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 673       (if (> new (%array-available-elements vector))
 674         (error
 675          "The new fill pointer, ~S, is larger than the length of the vector."
 676          new)
 677         (setf (%array-fill-pointer vector) new))
 678       (error 'simple-type-error
 679              :datum vector
 680              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 681              :format-control "~S is not an array with a fill pointer."
 682              :format-arguments (list vector))))
 683
 684 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 685 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 686 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 687 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 688 ;;; back to CMU CL).
 689 (defun vector-push (new-el array)
 690   #!+sb-doc
 691   "Attempt to set the element of ARRAY designated by its fill pointer
 692    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 693    too large, NIL is returned, otherwise the index of the pushed element is
 694    returned."
 695   (declare (vector array))
 696   (let ((fill-pointer (fill-pointer array)))
 697     (declare (fixnum fill-pointer))
 698     (cond ((= fill-pointer (%array-available-elements array))
 699            nil)
 700           (t
 701            (setf (aref array fill-pointer) new-el)
 702            (setf (%array-fill-pointer array) (1+ fill-pointer))
 703            fill-pointer))))
 704
 705 (defun vector-push-extend (new-element
 706                            vector
 707                            &optional
 708                            (extension (1+ (length vector))))
 709   (declare (vector vector) (fixnum extension))
 710   (let ((fill-pointer (fill-pointer vector)))
 711     (declare (fixnum fill-pointer))
 712     (when (= fill-pointer (%array-available-elements vector))
 713       (adjust-array vector (+ fill-pointer extension)))
 714     (setf (aref vector fill-pointer) new-element)
 715     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 716     fill-pointer))
 717
 718 (defun vector-pop (array)
 719   #!+sb-doc
 720   "Decrease the fill pointer by 1 and return the element pointed to by the
 721   new fill pointer."
 722   (declare (vector array))
 723   (let ((fill-pointer (fill-pointer array)))
 724     (declare (fixnum fill-pointer))
 725     (if (zerop fill-pointer)
 726         (error "There is nothing left to pop.")
 727         (aref array
 728               (setf (%array-fill-pointer array)
 729                     (1- fill-pointer))))))
 730 \f
 731 ;;;; ADJUST-ARRAY
 732
 733 (defun adjust-array (array dimensions &key
 734                            (element-type (array-element-type array))
 735                            (initial-element nil initial-element-p)
 736                            initial-contents fill-pointer
 737                            displaced-to displaced-index-offset)
 738   #!+sb-doc
 739   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 740   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 741     (cond ((/= (the fixnum (length (the list dimensions)))
 742                (the fixnum (array-rank array)))
 743            (error "The number of dimensions not equal to rank of array."))
 744           ((not (subtypep element-type (array-element-type array)))
 745            (error "The new element type, ~S, is incompatible with old type."
 746                   element-type)))
 747     (let ((array-rank (length (the list dimensions))))
 748       (declare (fixnum array-rank))
 749       (when (and fill-pointer (> array-rank 1))
 750         (error "Multidimensional arrays can't have fill pointers."))
 751       (cond (initial-contents
 752              ;; array former contents replaced by INITIAL-CONTENTS
 753              (if (or initial-element-p displaced-to)
 754                  (error "INITIAL-CONTENTS may not be specified with ~
 755                  the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 756              (let* ((array-size (apply #'* dimensions))
 757                     (array-data (data-vector-from-inits
 758                                  dimensions array-size element-type
 759                                  initial-contents initial-element
 760                                  initial-element-p)))
 761                (if (adjustable-array-p array)
 762                    (set-array-header array array-data array-size
 763                                  (get-new-fill-pointer array array-size
 764                                                        fill-pointer)
 765                                  0 dimensions nil)
 766                    (if (array-header-p array)
 767                        ;; simple multidimensional or single dimensional array
 768                        (make-array dimensions
 769                                    :element-type element-type
 770                                    :initial-contents initial-contents)
 771                        array-data))))
 772             (displaced-to
 773              ;; We already established that no INITIAL-CONTENTS was supplied.
 774              (when initial-element
 775                (error "The :INITIAL-ELEMENT option may not be specified ~
 776                       with :DISPLACED-TO."))
 777              (unless (subtypep element-type (array-element-type displaced-to))
 778                (error "can't displace an array of type ~S into another of ~
 779                        type ~S"
 780                       element-type (array-element-type displaced-to)))
 781              (let ((displacement (or displaced-index-offset 0))
 782                    (array-size (apply #'* dimensions)))
 783                (declare (fixnum displacement array-size))
 784                (if (< (the fixnum (array-total-size displaced-to))
 785                       (the fixnum (+ displacement array-size)))
 786                    (error "The :DISPLACED-TO array is too small."))
 787                (if (adjustable-array-p array)
 788                    ;; None of the original contents appear in adjusted array.
 789                    (set-array-header array displaced-to array-size
 790                                      (get-new-fill-pointer array array-size
 791                                                            fill-pointer)
 792                                      displacement dimensions t)
 793                    ;; simple multidimensional or single dimensional array
 794                    (make-array dimensions
 795                                :element-type element-type
 796                                :displaced-to displaced-to
 797                                :displaced-index-offset
 798                                displaced-index-offset))))
 799             ((= array-rank 1)
 800              (let ((old-length (array-total-size array))
 801                    (new-length (car dimensions))
 802                    new-data)
 803                (declare (fixnum old-length new-length))
 804                (with-array-data ((old-data array) (old-start)
 805                                  (old-end old-length))
 806                  (cond ((or (%array-displaced-p array)
 807                             (< old-length new-length))
 808                         (setf new-data
 809                               (data-vector-from-inits
 810                                dimensions new-length element-type
 811                                initial-contents initial-element
 812                                initial-element-p))
 813                         (replace new-data old-data
 814                                  :start2 old-start :end2 old-end))
 815                        (t (setf new-data
 816                                 (shrink-vector old-data new-length))))
 817                  (if (adjustable-array-p array)
 818                      (set-array-header array new-data new-length
 819                                        (get-new-fill-pointer array new-length
 820                                                              fill-pointer)
 821                                        0 dimensions nil)
 822                      new-data))))
 823             (t
 824              (let ((old-length (%array-available-elements array))
 825                    (new-length (apply #'* dimensions)))
 826                (declare (fixnum old-length new-length))
 827                (with-array-data ((old-data array) (old-start)
 828                                  (old-end old-length))
 829                  (declare (ignore old-end))
 830                  (let ((new-data (if (or (%array-displaced-p array)
 831                                          (> new-length old-length))
 832                                      (data-vector-from-inits
 833                                       dimensions new-length
 834                                       element-type () initial-element
 835                                       initial-element-p)
 836                                      old-data)))
 837                    (if (or (zerop old-length) (zerop new-length))
 838                        (when initial-element-p (fill new-data initial-element))
 839                        (zap-array-data old-data (array-dimensions array)
 840                                        old-start
 841                                        new-data dimensions new-length
 842                                        element-type initial-element
 843                                        initial-element-p))
 844                    (set-array-header array new-data new-length
 845                                      new-length 0 dimensions nil)))))))))
 846
 847 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 848   (cond ((not fill-pointer)
 849          (when (array-has-fill-pointer-p old-array)
 850            (when (> (%array-fill-pointer old-array) new-array-size)
 851              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 852                     smaller than its fill pointer (~S)"
 853                     old-array new-array-size (fill-pointer old-array)))
 854            (%array-fill-pointer old-array)))
 855         ((not (array-has-fill-pointer-p old-array))
 856          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 857                 in ADJUST-ARRAY unless the array (~S) was originally ~
 858                 created with a fill pointer"
 859                 fill-pointer
 860                 old-array))
 861         ((numberp fill-pointer)
 862          (when (> fill-pointer new-array-size)
 863            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 864                   than the new length of the vector (~S)"
 865                   fill-pointer new-array-size))
 866          fill-pointer)
 867         ((eq fill-pointer t)
 868          new-array-size)
 869         (t
 870          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
 871                 fill-pointer))))
 872
 873 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
 874 ;;; which must be less than or equal to its current length.
 875 (defun shrink-vector (vector new-length)
 876   (declare (vector vector))
 877   (unless (array-header-p vector)
 878     (macrolet ((frob (name &rest things)
 879                  `(etypecase ,name
 880                     ((simple-array nil (*)) (error 'cell-error
 881                                              :name 'nil-array-element))
 882                     ,@(mapcar (lambda (thing)
 883                                 (destructuring-bind (type-spec fill-value)
 884                                     thing
 885                                   `(,type-spec
 886                                     (fill (truly-the ,type-spec ,name)
 887                                           ,fill-value
 888                                           :start new-length))))
 889                               things))))
 890       ;; FIXME: The associations between vector types and initial
 891       ;; values here are redundant with
 892       ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 893       (frob vector
 894         (simple-vector 0)
 895         (simple-base-string #.*default-init-char-form*)
 896         (simple-bit-vector 0)
 897         ((simple-array (unsigned-byte 2) (*)) 0)
 898         ((simple-array (unsigned-byte 4) (*)) 0)
 899         ((simple-array (unsigned-byte 8) (*)) 0)
 900         ((simple-array (unsigned-byte 16) (*)) 0)
 901         ((simple-array (unsigned-byte 32) (*)) 0)
 902         ((simple-array (signed-byte 8) (*)) 0)
 903         ((simple-array (signed-byte 16) (*)) 0)
 904         ((simple-array (signed-byte 30) (*)) 0)
 905         ((simple-array (signed-byte 32) (*)) 0)
 906         ((simple-array single-float (*)) (coerce 0 'single-float))
 907         ((simple-array double-float (*)) (coerce 0 'double-float))
 908         #!+long-float
 909         ((simple-array long-float (*)) (coerce 0 'long-float))
 910         ((simple-array (complex single-float) (*))
 911          (coerce 0 '(complex single-float)))
 912         ((simple-array (complex double-float) (*))
 913          (coerce 0 '(complex double-float)))
 914         #!+long-float
 915         ((simple-array (complex long-float) (*))
 916          (coerce 0 '(complex long-float))))))
 917   ;; Only arrays have fill-pointers, but vectors have their length
 918   ;; parameter in the same place.
 919   (setf (%array-fill-pointer vector) new-length)
 920   vector)
 921
 922 ;;; Fill in array header with the provided information, and return the array.
 923 (defun set-array-header (array data length fill-pointer displacement dimensions
 924                          &optional displacedp)
 925   (setf (%array-data-vector array) data)
 926   (setf (%array-available-elements array) length)
 927   (cond (fill-pointer
 928          (setf (%array-fill-pointer array) fill-pointer)
 929          (setf (%array-fill-pointer-p array) t))
 930         (t
 931          (setf (%array-fill-pointer array) length)
 932          (setf (%array-fill-pointer-p array) nil)))
 933   (setf (%array-displacement array) displacement)
 934   (if (listp dimensions)
 935       (dotimes (axis (array-rank array))
 936         (declare (type index axis))
 937         (setf (%array-dimension array axis) (pop dimensions)))
 938       (setf (%array-dimension array 0) dimensions))
 939   (setf (%array-displaced-p array) displacedp)
 940   array)
 941 \f
 942 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
 943
 944 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
 945 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice.
 946 (defvar *zap-array-data-temp* (make-array 1000 :initial-element t))
 947
 948 (defun zap-array-data-temp (length element-type initial-element
 949                             initial-element-p)
 950   (declare (fixnum length))
 951   (when (> length (the fixnum (length *zap-array-data-temp*)))
 952     (setf *zap-array-data-temp*
 953           (make-array length :initial-element t)))
 954   (when initial-element-p
 955     (unless (typep initial-element element-type)
 956       (error "~S can't be used to initialize an array of type ~S."
 957              initial-element element-type))
 958     (fill (the simple-vector *zap-array-data-temp*) initial-element
 959           :end length))
 960   *zap-array-data-temp*)
 961
 962 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
 963 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
 964 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
 965 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
 966 ;;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and INITIAL-ELEMENT-P
 967 ;;; are used when OLD-DATA and NEW-DATA are EQ; in this case, a
 968 ;;; temporary must be used and filled appropriately. When OLD-DATA and
 969 ;;; NEW-DATA are not EQ, NEW-DATA has already been filled with any
 970 ;;; specified initial-element.
 971 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
 972                        element-type initial-element initial-element-p)
 973   (declare (list old-dims new-dims))
 974   (setq old-dims (nreverse old-dims))
 975   (setq new-dims (reverse new-dims))
 976   (if (eq old-data new-data)
 977       (let ((temp (zap-array-data-temp new-length element-type
 978                                        initial-element initial-element-p)))
 979         (zap-array-data-aux old-data old-dims offset temp new-dims)
 980         (dotimes (i new-length) (setf (aref new-data i) (aref temp i))))
 981       (zap-array-data-aux old-data old-dims offset new-data new-dims)))
 982
 983 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
 984   (declare (fixnum offset))
 985   (let ((limits (mapcar (lambda (x y)
 986                           (declare (fixnum x y))
 987                           (1- (the fixnum (min x y))))
 988                         old-dims new-dims)))
 989     (macrolet ((bump-index-list (index limits)
 990                  `(do ((subscripts ,index (cdr subscripts))
 991                        (limits ,limits (cdr limits)))
 992                       ((null subscripts) nil)
 993                     (cond ((< (the fixnum (car subscripts))
 994                               (the fixnum (car limits)))
 995                            (rplaca subscripts
 996                                    (1+ (the fixnum (car subscripts))))
 997                            (return ,index))
 998                           (t (rplaca subscripts 0))))))
 999       (do ((index (make-list (length old-dims) :initial-element 0)
1000                   (bump-index-list index limits)))
1001           ((null index))
1002         (setf (aref new-data (row-major-index-from-dims index new-dims))
1003               (aref old-data
1004                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1005                        offset)))))))
1006
1007 ;;; Figure out the row-major-order index of an array reference from a
1008 ;;; list of subscripts and a list of dimensions. This is for internal
1009 ;;; calls only, and the subscripts and dim-list variables are assumed
1010 ;;; to be reversed from what the user supplied.
1011 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1012   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1013        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1014        (chunk-size 1)
1015        (result 0))
1016       ((null rev-dim-list) result)
1017     (declare (fixnum chunk-size result))
1018     (setq result (+ result
1019                     (the fixnum (* (the fixnum (car rev-subscripts))
1020                                    chunk-size))))
1021     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1022 \f
1023 ;;;; some bit stuff
1024
1025 (defun bit-array-same-dimensions-p (array1 array2)
1026   (declare (type (array bit) array1 array2))
1027   (and (= (array-rank array1)
1028           (array-rank array2))
1029        (dotimes (index (array-rank array1) t)
1030          (when (/= (array-dimension array1 index)
1031                    (array-dimension array2 index))
1032            (return nil)))))
1033
1034 (defun pick-result-array (result-bit-array bit-array-1)
1035   (case result-bit-array
1036     ((t) bit-array-1)
1037     ((nil) (make-array (array-dimensions bit-array-1)
1038                        :element-type 'bit
1039                        :initial-element 0))
1040     (t
1041      (unless (bit-array-same-dimensions-p bit-array-1
1042                                           result-bit-array)
1043        (error "~S and ~S don't have the same dimensions."
1044               bit-array-1 result-bit-array))
1045      result-bit-array)))
1046
1047 (defmacro def-bit-array-op (name function)
1048   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1049      ,(format nil
1050               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1051               BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1052               If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1053               RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1054               All the arrays must have the same rank and dimensions."
1055               (symbol-name function))
1056      (declare (type (array bit) bit-array-1 bit-array-2)
1057               (type (or (array bit) (member t nil)) result-bit-array))
1058      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1059        (error "~S and ~S don't have the same dimensions."
1060               bit-array-1 bit-array-2))
1061      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1062        (if (and (simple-bit-vector-p bit-array-1)
1063                 (simple-bit-vector-p bit-array-2)
1064                 (simple-bit-vector-p result-bit-array))
1065            (locally (declare (optimize (speed 3) (safety 0)))
1066              (,name bit-array-1 bit-array-2 result-bit-array))
1067            (with-array-data ((data1 bit-array-1) (start1) (end1))
1068              (declare (ignore end1))
1069              (with-array-data ((data2 bit-array-2) (start2) (end2))
1070                (declare (ignore end2))
1071                (with-array-data ((data3 result-bit-array) (start3) (end3))
1072                  (do ((index-1 start1 (1+ index-1))
1073                       (index-2 start2 (1+ index-2))
1074                       (index-3 start3 (1+ index-3)))
1075                      ((>= index-3 end3) result-bit-array)
1076                    (declare (type index index-1 index-2 index-3))
1077                    (setf (sbit data3 index-3)
1078                          (logand (,function (sbit data1 index-1)
1079                                             (sbit data2 index-2))
1080                                  1))))))))))
1081
1082 (def-bit-array-op bit-and logand)
1083 (def-bit-array-op bit-ior logior)
1084 (def-bit-array-op bit-xor logxor)
1085 (def-bit-array-op bit-eqv logeqv)
1086 (def-bit-array-op bit-nand lognand)
1087 (def-bit-array-op bit-nor lognor)
1088 (def-bit-array-op bit-andc1 logandc1)
1089 (def-bit-array-op bit-andc2 logandc2)
1090 (def-bit-array-op bit-orc1 logorc1)
1091 (def-bit-array-op bit-orc2 logorc2)
1092
1093 (defun bit-not (bit-array &optional result-bit-array)
1094   #!+sb-doc
1095   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1096   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1097   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1098   created. Both arrays must have the same rank and dimensions."
1099   (declare (type (array bit) bit-array)
1100            (type (or (array bit) (member t nil)) result-bit-array))
1101   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1102     (if (and (simple-bit-vector-p bit-array)
1103              (simple-bit-vector-p result-bit-array))
1104         (locally (declare (optimize (speed 3) (safety 0)))
1105           (bit-not bit-array result-bit-array))
1106         (with-array-data ((src bit-array) (src-start) (src-end))
1107           (declare (ignore src-end))
1108           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1109             (do ((src-index src-start (1+ src-index))
1110                  (dst-index dst-start (1+ dst-index)))
1111                 ((>= dst-index dst-end) result-bit-array)
1112               (declare (type index src-index dst-index))
1113               (setf (sbit dst dst-index)
1114                     (logxor (sbit src src-index) 1))))))))