src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data (array start end)
  50   (%with-array-data-macro array start end :fail-inline? t))
  51
  52 (defun %data-vector-and-index (array index)
  53   (if (array-header-p array)
  54       (multiple-value-bind (vector index)
  55           (%with-array-data array index nil)
  56         (values vector index))
  57       (values array index)))
  58
  59 (declaim (inline simple-vector-compare-and-swap))
  60 (defun simple-vector-compare-and-swap (vector index old new)
  61   #!+(or x86 x86-64)
  62   (%simple-vector-compare-and-swap vector
  63                                    (%check-bound vector (length vector) index)
  64                                    old
  65                                    new)
  66   #!-(or x86 x86-64)
  67   (let ((n-old (svref vector index)))
  68     (when (eq old n-old)
  69       (setf (svref vector index) new))
  70     n-old))
  71
  72 ;;; It'd waste space to expand copies of error handling in every
  73 ;;; inline %WITH-ARRAY-DATA, so we have them call this function
  74 ;;; instead. This is just a wrapper which is known never to return.
  75 (defun failed-%with-array-data (array start end)
  76   (declare (notinline %with-array-data))
  77   (%with-array-data array start end)
  78   (bug "called FAILED-%WITH-ARRAY-DATA with valid array parameters?"))
  79 \f
  80 ;;;; MAKE-ARRAY
  81 (eval-when (:compile-toplevel :execute)
  82   (sb!xc:defmacro pick-vector-type (type &rest specs)
  83     `(cond ,@(mapcar (lambda (spec)
  84                        `(,(if (eq (car spec) t)
  85                               t
  86                               `(subtypep ,type ',(car spec)))
  87                          ,@(cdr spec)))
  88                      specs))))
  89
  90 ;;; These functions are used in the implementation of MAKE-ARRAY for
  91 ;;; complex arrays. There are lots of transforms to simplify
  92 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  93 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  94 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  95 ;;; making this somewhat efficient, at least not doing full calls to
  96 ;;; SUBTYPEP in the easy cases.
  97 (defun %vector-widetag-and-n-bits (type)
  98   (case type
  99     ;; Pick off some easy common cases.
 100     ;;
 101     ;; (Perhaps we should make a much more exhaustive table of easy
 102     ;; common cases here. Or perhaps the effort would be better spent
 103     ;; on smarter compiler transforms which do the calculation once
 104     ;; and for all in any reasonable user programs.)
 105     ((t)
 106      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
 107     ((base-char standard-char #!-sb-unicode character)
 108      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
 109     #!+sb-unicode
 110     ((character)
 111      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
 112     ((bit)
 113      (values #.sb!vm:simple-bit-vector-widetag 1))
 114     ;; OK, we have to wade into SUBTYPEPing after all.
 115     (t
 116      #.`(pick-vector-type type
 117          ,@(map 'list
 118                 (lambda (saetp)
 119                   `(,(sb!vm:saetp-specifier saetp)
 120                     (values ,(sb!vm:saetp-typecode saetp)
 121                             ,(sb!vm:saetp-n-bits saetp))))
 122                 sb!vm:*specialized-array-element-type-properties*)))))
 123
 124 (defun %complex-vector-widetag (type)
 125   (case type
 126     ;; Pick off some easy common cases.
 127     ((t)
 128      #.sb!vm:complex-vector-widetag)
 129     ((base-char #!-sb-unicode character)
 130      #.sb!vm:complex-base-string-widetag)
 131     #!+sb-unicode
 132     ((character)
 133      #.sb!vm:complex-character-string-widetag)
 134     ((nil)
 135      #.sb!vm:complex-vector-nil-widetag)
 136     ((bit)
 137      #.sb!vm:complex-bit-vector-widetag)
 138     ;; OK, we have to wade into SUBTYPEPing after all.
 139     (t
 140      (pick-vector-type type
 141        (nil #.sb!vm:complex-vector-nil-widetag)
 142        #!-sb-unicode
 143        (character #.sb!vm:complex-base-string-widetag)
 144        #!+sb-unicode
 145        (base-char #.sb!vm:complex-base-string-widetag)
 146        #!+sb-unicode
 147        (character #.sb!vm:complex-character-string-widetag)
 148        (bit #.sb!vm:complex-bit-vector-widetag)
 149        (t #.sb!vm:complex-vector-widetag)))))
 150
 151 (defun make-array (dimensions &key
 152                               (element-type t)
 153                               (initial-element nil initial-element-p)
 154                               (initial-contents nil initial-contents-p)
 155                               adjustable fill-pointer
 156                               displaced-to displaced-index-offset)
 157   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 158          (array-rank (length (the list dimensions)))
 159          (simple (and (null fill-pointer)
 160                       (not adjustable)
 161                       (null displaced-to))))
 162     (declare (fixnum array-rank))
 163     (when (and displaced-index-offset (null displaced-to))
 164       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 165     (when (and displaced-to
 166                (arrayp displaced-to)
 167                (not (equal (array-element-type displaced-to)
 168                            (upgraded-array-element-type element-type))))
 169       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 170     (if (and simple (= array-rank 1))
 171         ;; it's a (SIMPLE-ARRAY * (*))
 172         (multiple-value-bind (type n-bits)
 173             (%vector-widetag-and-n-bits element-type)
 174           (declare (type (unsigned-byte 8) type)
 175                    (type (integer 0 256) n-bits))
 176           (let* ((length (car dimensions))
 177                  (array (allocate-vector
 178                          type
 179                          length
 180                          (ceiling
 181                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 182                                      #!+sb-unicode
 183                                      (= type
 184                                         sb!vm:simple-character-string-widetag))
 185                                  (1+ length)
 186                                  length)
 187                              n-bits)
 188                           sb!vm:n-word-bits))))
 189             (declare (type index length))
 190             (when initial-element-p
 191               (fill array initial-element))
 192             (when initial-contents-p
 193               (when initial-element-p
 194                 (error "can't specify both :INITIAL-ELEMENT and ~
 195                        :INITIAL-CONTENTS"))
 196               (unless (= length (length initial-contents))
 197                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 198                        the vector length is ~W."
 199                        (length initial-contents)
 200                        length))
 201               (replace array initial-contents))
 202             array))
 203         ;; it's either a complex array or a multidimensional array.
 204         (let* ((total-size (reduce #'* dimensions))
 205                (data (or displaced-to
 206                          (data-vector-from-inits
 207                           dimensions total-size element-type
 208                           initial-contents initial-contents-p
 209                           initial-element initial-element-p)))
 210                (array (make-array-header
 211                        (cond ((= array-rank 1)
 212                               (%complex-vector-widetag element-type))
 213                              (simple sb!vm:simple-array-widetag)
 214                              (t sb!vm:complex-array-widetag))
 215                        array-rank)))
 216           (cond (fill-pointer
 217                  (unless (= array-rank 1)
 218                    (error "Only vectors can have fill pointers."))
 219                  (let ((length (car dimensions)))
 220                    (declare (fixnum length))
 221                    (setf (%array-fill-pointer array)
 222                      (cond ((eq fill-pointer t)
 223                             length)
 224                            (t
 225                             (unless (and (fixnump fill-pointer)
 226                                          (>= fill-pointer 0)
 227                                          (<= fill-pointer length))
 228                               ;; FIXME: should be TYPE-ERROR?
 229                               (error "invalid fill-pointer ~W"
 230                                      fill-pointer))
 231                             fill-pointer))))
 232                  (setf (%array-fill-pointer-p array) t))
 233                 (t
 234                  (setf (%array-fill-pointer array) total-size)
 235                  (setf (%array-fill-pointer-p array) nil)))
 236           (setf (%array-available-elements array) total-size)
 237           (setf (%array-data-vector array) data)
 238           (cond (displaced-to
 239                  (when (or initial-element-p initial-contents-p)
 240                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 241                    can be specified along with :DISPLACED-TO"))
 242                  (let ((offset (or displaced-index-offset 0)))
 243                    (when (> (+ offset total-size)
 244                             (array-total-size displaced-to))
 245                      (error "~S doesn't have enough elements." displaced-to))
 246                    (setf (%array-displacement array) offset)
 247                    (setf (%array-displaced-p array) t)))
 248                 (t
 249                  (setf (%array-displaced-p array) nil)))
 250           (let ((axis 0))
 251             (dolist (dim dimensions)
 252               (setf (%array-dimension array axis) dim)
 253               (incf axis)))
 254           array))))
 255
 256 (defun make-static-vector (length &key
 257                            (element-type '(unsigned-byte 8))
 258                            (initial-contents nil initial-contents-p)
 259                            (initial-element nil initial-element-p))
 260   "Allocate vector of LENGTH elements in static space. Only allocation
 261 of specialized arrays is supported."
 262   ;; STEP 1: check inputs fully
 263   ;;
 264   ;; This way of doing explicit checks before the vector is allocated
 265   ;; is expensive, but probably worth the trouble as once we've allocated
 266   ;; the vector we have no way to get rid of it anymore...
 267   (when (eq t (upgraded-array-element-type element-type))
 268     (error "Static arrays of type ~S not supported."
 269            element-type))
 270   (when initial-contents-p
 271     (when initial-element-p
 272       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 273     (unless (= length (length initial-contents))
 274       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 275               vector length is ~W."
 276              (length initial-contents)
 277              length))
 278     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 279       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 280              element-type)))
 281   (when initial-element-p
 282     (unless (typep initial-element element-type)
 283       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 284              initial-element element-type)))
 285   ;; STEP 2
 286   ;;
 287   ;; Allocate and possibly initialize the vector.
 288   (multiple-value-bind (type n-bits)
 289       (sb!impl::%vector-widetag-and-n-bits element-type)
 290     (let ((vector
 291            (allocate-static-vector type length
 292                                    (ceiling (* length n-bits)
 293                                             sb!vm:n-word-bits))))
 294       (cond (initial-element-p
 295              (fill vector initial-element))
 296             (initial-contents-p
 297              (replace vector initial-contents))
 298             (t
 299              vector)))))
 300
 301 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 302 ;;; specified array characteristics. Dimensions is only used to pass
 303 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 304 ;;; initial-contents.
 305 (defun data-vector-from-inits (dimensions total-size element-type
 306                                initial-contents initial-contents-p
 307                                initial-element initial-element-p)
 308   (when (and initial-contents-p initial-element-p)
 309     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 310             either MAKE-ARRAY or ADJUST-ARRAY."))
 311   (let ((data (if initial-element-p
 312                   (make-array total-size
 313                               :element-type element-type
 314                               :initial-element initial-element)
 315                   (make-array total-size
 316                               :element-type element-type))))
 317     (cond (initial-element-p
 318            (unless (simple-vector-p data)
 319              (unless (typep initial-element element-type)
 320                (error "~S cannot be used to initialize an array of type ~S."
 321                       initial-element element-type))
 322              (fill (the vector data) initial-element)))
 323           (initial-contents-p
 324            (fill-data-vector data dimensions initial-contents)))
 325     data))
 326
 327 (defun vector (&rest objects)
 328   #!+sb-doc
 329   "Construct a SIMPLE-VECTOR from the given objects."
 330   (coerce (the list objects) 'simple-vector))
 331 \f
 332
 333 ;;;; accessor/setter functions
 334
 335 ;;; Dispatch to an optimized routine the data vector accessors for
 336 ;;; each different specialized vector type. Do dispatching by looking
 337 ;;; up the widetag in the array rather than with the typecases, which
 338 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 339 ;;; provide separate versions where bounds checking has been moved
 340 ;;; from the callee to the caller, since it's much cheaper to do once
 341 ;;; the type information is available. Finally, for each of these
 342 ;;; routines also provide a slow path, taken for arrays that are not
 343 ;;; vectors or not simple.
 344 (macrolet ((%define (table-name extra-params)
 345              `(funcall
 346                (the function
 347                  (let ((tag 0)
 348                        (offset
 349                         #.(ecase sb!c:*backend-byte-order*
 350                             (:little-endian
 351                              (- sb!vm:other-pointer-lowtag))
 352                             (:big-endian
 353                              (- (1- sb!vm:n-word-bytes) sb!vm:other-pointer-lowtag)))))
 354                    ;; WIDETAG-OF needs extra code to handle
 355                    ;; LIST and FUNCTION lowtags. We're only
 356                    ;; dispatching on other pointers, so let's
 357                    ;; do the lowtag extraction manually.
 358                    (when (sb!vm::%other-pointer-p array)
 359                      (setf tag
 360                            (sb!sys:sap-ref-8 (int-sap (get-lisp-obj-address array))
 361                                              offset)))
 362                    ;; SYMBOL-GLOBAL-VALUE is a performance hack
 363                    ;; for threaded builds.
 364                    (svref (sb!vm::symbol-global-value ',table-name) tag)))
 365                array index ,@extra-params))
 366            (define (accessor-name slow-accessor-name table-name extra-params
 367                                   check-bounds)
 368                `(progn
 369                  (defvar ,table-name)
 370                  (defun ,accessor-name (array index ,@extra-params)
 371                    (declare (optimize speed
 372                                       ;; (SAFETY 0) is ok. All calls to
 373                                       ;; these functions are generated by
 374                                       ;; the compiler, so argument count
 375                                       ;; checking isn't needed. Type checking
 376                                       ;; is done implicitly via the widetag
 377                                       ;; dispatch.
 378                                       (safety 0)))
 379                    (%define ,table-name ,extra-params))
 380                  (defun ,slow-accessor-name (array index ,@extra-params)
 381                    (declare (optimize speed (safety 0)))
 382                    (if (not (%array-displaced-p array))
 383                        ;; The reasonably quick path of non-displaced complex
 384                        ;; arrays.
 385                        (let ((array (%array-data-vector array)))
 386                          (%define ,table-name ,extra-params))
 387                        ;; The real slow path.
 388                        (with-array-data
 389                            ((vector array)
 390                             (index (locally
 391                                        (declare (optimize (speed 1) (safety 1)))
 392                                      (,@check-bounds index)))
 393                             (end)
 394                             :force-inline t)
 395                          (declare (ignore end))
 396                          (,accessor-name vector index ,@extra-params)))))))
 397   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 398     *data-vector-reffers* nil (progn))
 399   (define hairy-data-vector-set slow-hairy-data-vector-set
 400     *data-vector-setters* (new-value) (progn))
 401   (define hairy-data-vector-ref/check-bounds
 402       slow-hairy-data-vector-ref/check-bounds
 403     *data-vector-reffers/check-bounds* nil
 404     (%check-bound array (array-dimension array 0)))
 405   (define hairy-data-vector-set/check-bounds
 406       slow-hairy-data-vector-set/check-bounds
 407     *data-vector-setters/check-bounds* (new-value)
 408     (%check-bound array (array-dimension array 0))))
 409
 410 (defun hairy-ref-error (array index &optional new-value)
 411   (declare (ignore index new-value))
 412   (error 'type-error
 413          :datum array
 414          :expected-type 'vector))
 415
 416 ;;; Populate the dispatch tables.
 417 (macrolet ((define-reffer (saetp check-form)
 418              (let* ((type (sb!vm:saetp-specifier saetp))
 419                     (atype `(simple-array ,type (*))))
 420                `(named-lambda optimized-data-vector-ref (vector index)
 421                   (declare (optimize speed (safety 0)))
 422                   (data-vector-ref (the ,atype vector)
 423                                    (locally
 424                                        (declare (optimize (safety 1)))
 425                                      (the index
 426                                        (,@check-form index)))))))
 427            (define-setter (saetp check-form)
 428              (let* ((type (sb!vm:saetp-specifier saetp))
 429                     (atype `(simple-array ,type (*))))
 430                `(named-lambda optimized-data-vector-set (vector index new-value)
 431                   (declare (optimize speed (safety 0)))
 432                   (data-vector-set (the ,atype vector)
 433                                    (locally
 434                                        (declare (optimize (safety 1)))
 435                                      (the index
 436                                        (,@check-form index)))
 437                                    (locally
 438                                        ;; SPEED 1 needed to avoid the compiler
 439                                        ;; from downgrading the type check to
 440                                        ;; a cheaper one.
 441                                        (declare (optimize (speed 1)
 442                                                           (safety 1)))
 443                                      (the ,type new-value)))
 444                   ;; For specialized arrays, the return from
 445                   ;; data-vector-set would have to be reboxed to be a
 446                   ;; (Lisp) return value; instead, we use the
 447                   ;; already-boxed value as the return.
 448                   new-value)))
 449            (define-reffers (symbol deffer check-form slow-path)
 450              `(progn
 451                 (setf ,symbol (make-array sb!vm::widetag-mask
 452                                           :initial-element #'hairy-ref-error))
 453                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 454                                          sb!vm:complex-vector-nil-widetag
 455                                          sb!vm:complex-bit-vector-widetag
 456                                          #!+sb-unicode sb!vm:complex-character-string-widetag
 457                                          sb!vm:complex-base-string-widetag
 458                                          sb!vm:simple-array-widetag
 459                                          sb!vm:complex-array-widetag)
 460                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 461                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 462                         for widetag = (sb!vm:saetp-typecode saetp)
 463                         collect `(setf (svref ,symbol ,widetag)
 464                                        (,deffer ,saetp ,check-form))))))
 465   (defun !hairy-data-vector-reffer-init ()
 466     (define-reffers *data-vector-reffers* define-reffer
 467       (progn)
 468       #'slow-hairy-data-vector-ref)
 469     (define-reffers *data-vector-setters* define-setter
 470       (progn)
 471       #'slow-hairy-data-vector-set)
 472     (define-reffers *data-vector-reffers/check-bounds* define-reffer
 473       (%check-bound vector (length vector))
 474       #'slow-hairy-data-vector-ref/check-bounds)
 475     (define-reffers *data-vector-setters/check-bounds* define-setter
 476       (%check-bound vector (length vector))
 477       #'slow-hairy-data-vector-set/check-bounds)))
 478
 479 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 480 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 481 ;;; definition is needed for the compiler to use in constant folding.)
 482 (defun data-vector-ref (array index)
 483   (hairy-data-vector-ref array index))
 484
 485 (defun data-vector-ref-with-offset (array index offset)
 486   (hairy-data-vector-ref array (+ index offset)))
 487
 488 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 489 (defun %array-row-major-index (array subscripts
 490                                      &optional (invalid-index-error-p t))
 491   (declare (array array)
 492            (list subscripts))
 493   (let ((rank (array-rank array)))
 494     (unless (= rank (length subscripts))
 495       (error "wrong number of subscripts, ~W, for array of rank ~W"
 496              (length subscripts) rank))
 497     (if (array-header-p array)
 498         (do ((subs (nreverse subscripts) (cdr subs))
 499              (axis (1- (array-rank array)) (1- axis))
 500              (chunk-size 1)
 501              (result 0))
 502             ((null subs) result)
 503           (declare (list subs) (fixnum axis chunk-size result))
 504           (let ((index (car subs))
 505                 (dim (%array-dimension array axis)))
 506             (declare (fixnum dim))
 507             (unless (and (fixnump index) (< -1 index dim))
 508               (if invalid-index-error-p
 509                   (error 'simple-type-error
 510                          :format-control "invalid index ~W~[~;~:; on axis ~:*~W~] in ~S"
 511                          :format-arguments (list index axis array)
 512                          :datum index
 513                          :expected-type `(integer 0 (,dim)))
 514                   (return-from %array-row-major-index nil)))
 515             (incf result (* chunk-size (the fixnum index)))
 516             (setf chunk-size (* chunk-size dim))))
 517         (let ((index (first subscripts))
 518               (length (length (the (simple-array * (*)) array))))
 519           (unless (and (fixnump index) (< -1 index length))
 520             (if invalid-index-error-p
 521                 ;; FIXME: perhaps this should share a format-string
 522                 ;; with INVALID-ARRAY-INDEX-ERROR or
 523                 ;; INDEX-TOO-LARGE-ERROR?
 524                 (error 'simple-type-error
 525                        :format-control "invalid index ~W in ~S"
 526                        :format-arguments (list index array)
 527                        :datum index
 528                        :expected-type `(integer 0 (,length)))
 529                 (return-from %array-row-major-index nil)))
 530           index))))
 531
 532 (defun array-in-bounds-p (array &rest subscripts)
 533   #!+sb-doc
 534   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 535   (if (%array-row-major-index array subscripts nil)
 536       t))
 537
 538 (defun array-row-major-index (array &rest subscripts)
 539   (declare (dynamic-extent subscripts))
 540   (%array-row-major-index array subscripts))
 541
 542 (defun aref (array &rest subscripts)
 543   #!+sb-doc
 544   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 545   (declare (dynamic-extent subscripts))
 546   (row-major-aref array (%array-row-major-index array subscripts)))
 547
 548 (defun %aset (array &rest stuff)
 549   (declare (dynamic-extent stuff))
 550   (let ((subscripts (butlast stuff))
 551         (new-value (car (last stuff))))
 552     (setf (row-major-aref array (%array-row-major-index array subscripts))
 553           new-value)))
 554
 555 ;;; FIXME: What's supposed to happen with functions
 556 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 557 ;;; DEFSETF FOO is also defined? It seems as though the logical
 558 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 559 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 560 ;;; just as for ordinary functions
 561 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 562 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 563 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 564 ;;;  ZOO
 565 ;;;  * (DEFUN ZOO (X) (* 3 X))
 566 ;;;  Warning: ZOO previously defined as a macro.
 567 ;;;  ZOO
 568 ;;; But that doesn't seem to be what happens in CMU CL.
 569 ;;;
 570 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 571 ;;; 5.1.2.5) requires implementations to support
 572 ;;;   (SETF (APPLY #'AREF ...) ...)
 573 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 574 ;;; also terrifying that this sequence of definitions causes it to
 575 ;;; work.
 576 ;;;
 577 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 578 ;;; has a setf expansion and/or a setf function defined.
 579
 580 #!-sb-fluid (declaim (inline (setf aref)))
 581 (defun (setf aref) (new-value array &rest subscripts)
 582   (declare (dynamic-extent subscripts))
 583   (declare (type array array))
 584   (setf (row-major-aref array (%array-row-major-index array subscripts))
 585         new-value))
 586
 587 (defun row-major-aref (array index)
 588   #!+sb-doc
 589   "Return the element of array corressponding to the row-major index. This is
 590    SETF'able."
 591   (declare (optimize (safety 1)))
 592   (row-major-aref array index))
 593
 594 (defun %set-row-major-aref (array index new-value)
 595   (declare (optimize (safety 1)))
 596   (setf (row-major-aref array index) new-value))
 597
 598 (defun svref (simple-vector index)
 599   #!+sb-doc
 600   "Return the INDEX'th element of the given Simple-Vector."
 601   (declare (optimize (safety 1)))
 602   (aref simple-vector index))
 603
 604 (defun %svset (simple-vector index new)
 605   (declare (optimize (safety 1)))
 606   (setf (aref simple-vector index) new))
 607
 608 (defun bit (bit-array &rest subscripts)
 609   #!+sb-doc
 610   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 611   (declare (type (array bit) bit-array) (optimize (safety 1)))
 612   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 613
 614 (defun %bitset (bit-array &rest stuff)
 615   (declare (type (array bit) bit-array) (optimize (safety 1)))
 616   (let ((subscripts (butlast stuff))
 617         (new-value (car (last stuff))))
 618     (setf (row-major-aref bit-array
 619                           (%array-row-major-index bit-array subscripts))
 620           new-value)))
 621
 622 #!-sb-fluid (declaim (inline (setf bit)))
 623 (defun (setf bit) (new-value bit-array &rest subscripts)
 624   (declare (type (array bit) bit-array) (optimize (safety 1)))
 625   (setf (row-major-aref bit-array
 626                         (%array-row-major-index bit-array subscripts))
 627         new-value))
 628
 629 (defun sbit (simple-bit-array &rest subscripts)
 630   #!+sb-doc
 631   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 632   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 633   (row-major-aref simple-bit-array
 634                   (%array-row-major-index simple-bit-array subscripts)))
 635
 636 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 637 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 638 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 639 ;;; -- WHN 19990911
 640 (defun %sbitset (simple-bit-array &rest stuff)
 641   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 642   (let ((subscripts (butlast stuff))
 643         (new-value (car (last stuff))))
 644     (setf (row-major-aref simple-bit-array
 645                           (%array-row-major-index simple-bit-array subscripts))
 646           new-value)))
 647
 648 #!-sb-fluid (declaim (inline (setf sbit)))
 649 (defun (setf sbit) (new-value bit-array &rest subscripts)
 650   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 651   (setf (row-major-aref bit-array
 652                         (%array-row-major-index bit-array subscripts))
 653         new-value))
 654 \f
 655 ;;;; miscellaneous array properties
 656
 657 (defun array-element-type (array)
 658   #!+sb-doc
 659   "Return the type of the elements of the array"
 660   (let ((widetag (widetag-of array)))
 661     (macrolet ((pick-element-type (&rest stuff)
 662                  `(cond ,@(mapcar (lambda (stuff)
 663                                     (cons
 664                                      (let ((item (car stuff)))
 665                                        (cond ((eq item t)
 666                                               t)
 667                                              ((listp item)
 668                                               (cons 'or
 669                                                     (mapcar (lambda (x)
 670                                                               `(= widetag ,x))
 671                                                             item)))
 672                                              (t
 673                                               `(= widetag ,item))))
 674                                      (cdr stuff)))
 675                                   stuff))))
 676       #.`(pick-element-type
 677           ,@(map 'list
 678                  (lambda (saetp)
 679                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 680                           (list (sb!vm:saetp-typecode saetp)
 681                                 (sb!vm:saetp-complex-typecode saetp))
 682                           (sb!vm:saetp-typecode saetp))
 683                      ',(sb!vm:saetp-specifier saetp)))
 684                  sb!vm:*specialized-array-element-type-properties*)
 685           ((sb!vm:simple-array-widetag
 686             sb!vm:complex-vector-widetag
 687             sb!vm:complex-array-widetag)
 688            (with-array-data ((array array) (start) (end))
 689              (declare (ignore start end))
 690              (array-element-type array)))
 691           (t
 692            (error 'type-error :datum array :expected-type 'array))))))
 693
 694 (defun array-rank (array)
 695   #!+sb-doc
 696   "Return the number of dimensions of ARRAY."
 697   (if (array-header-p array)
 698       (%array-rank array)
 699       1))
 700
 701 (defun array-dimension (array axis-number)
 702   #!+sb-doc
 703   "Return the length of dimension AXIS-NUMBER of ARRAY."
 704   (declare (array array) (type index axis-number))
 705   (cond ((not (array-header-p array))
 706          (unless (= axis-number 0)
 707            (error "Vector axis is not zero: ~S" axis-number))
 708          (length (the (simple-array * (*)) array)))
 709         ((>= axis-number (%array-rank array))
 710          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 711                 axis-number array (%array-rank array)))
 712         (t
 713          ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
 714          ;;
 715          ;;   "If A is displaced to B, the consequences are
 716          ;;   unspecified if B is adjusted in such a way that it no
 717          ;;   longer has enough elements to satisfy A.
 718          ;;
 719          ;; In situations where this matters we should be doing a
 720          ;; bounds-check, which in turn uses ARRAY-DIMENSION -- so
 721          ;; this seems like a good place to signal an error.
 722          (multiple-value-bind (target offset) (array-displacement array)
 723            (when (and target
 724                       (> (array-total-size array)
 725                          (- (array-total-size target) offset)))
 726                (error 'displaced-to-array-too-small-error
 727                       :format-control "~@<The displaced-to array is too small. ~S ~
 728                                       elements after offset required, ~S available.~:@>"
 729                       :format-arguments (list (array-total-size array)
 730                                               (- (array-total-size target) offset))))
 731            (%array-dimension array axis-number)))))
 732
 733 (defun array-dimensions (array)
 734   #!+sb-doc
 735   "Return a list whose elements are the dimensions of the array"
 736   (declare (array array))
 737   (if (array-header-p array)
 738       (do ((results nil (cons (array-dimension array index) results))
 739            (index (1- (array-rank array)) (1- index)))
 740           ((minusp index) results))
 741       (list (array-dimension array 0))))
 742
 743 (defun array-total-size (array)
 744   #!+sb-doc
 745   "Return the total number of elements in the Array."
 746   (declare (array array))
 747   (if (array-header-p array)
 748       (%array-available-elements array)
 749       (length (the vector array))))
 750
 751 (defun array-displacement (array)
 752   #!+sb-doc
 753   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 754    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 755   (declare (type array array))
 756   (if (and (array-header-p array) ; if unsimple and
 757            (%array-displaced-p array)) ; displaced
 758       (values (%array-data-vector array) (%array-displacement array))
 759       (values nil 0)))
 760
 761 (defun adjustable-array-p (array)
 762   #!+sb-doc
 763   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 764    to the argument, this happens for complex arrays."
 765   (declare (array array))
 766   ;; Note that this appears not to be a fundamental limitation.
 767   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 768   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 769   ;; -- CSR, 2004-03-01.
 770   (not (typep array 'simple-array)))
 771 \f
 772 ;;;; fill pointer frobbing stuff
 773
 774 (defun array-has-fill-pointer-p (array)
 775   #!+sb-doc
 776   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 777   (declare (array array))
 778   (and (array-header-p array) (%array-fill-pointer-p array)))
 779
 780 (defun fill-pointer (vector)
 781   #!+sb-doc
 782   "Return the FILL-POINTER of the given VECTOR."
 783   (declare (vector vector))
 784   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 785       (%array-fill-pointer vector)
 786       (error 'simple-type-error
 787              :datum vector
 788              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 789              :format-control "~S is not an array with a fill pointer."
 790              :format-arguments (list vector))))
 791
 792 (defun %set-fill-pointer (vector new)
 793   (declare (vector vector) (fixnum new))
 794   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 795       (if (> new (%array-available-elements vector))
 796         (error
 797          "The new fill pointer, ~S, is larger than the length of the vector."
 798          new)
 799         (setf (%array-fill-pointer vector) new))
 800       (error 'simple-type-error
 801              :datum vector
 802              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 803              :format-control "~S is not an array with a fill pointer."
 804              :format-arguments (list vector))))
 805
 806 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 807 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 808 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 809 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 810 ;;; back to CMU CL).
 811 (defun vector-push (new-el array)
 812   #!+sb-doc
 813   "Attempt to set the element of ARRAY designated by its fill pointer
 814    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 815    too large, NIL is returned, otherwise the index of the pushed element is
 816    returned."
 817   (declare (vector array))
 818   (let ((fill-pointer (fill-pointer array)))
 819     (declare (fixnum fill-pointer))
 820     (cond ((= fill-pointer (%array-available-elements array))
 821            nil)
 822           (t
 823            (setf (aref array fill-pointer) new-el)
 824            (setf (%array-fill-pointer array) (1+ fill-pointer))
 825            fill-pointer))))
 826
 827 (defun vector-push-extend (new-element
 828                            vector
 829                            &optional
 830                            (extension (1+ (length vector))))
 831   (declare (vector vector) (fixnum extension))
 832   (let ((fill-pointer (fill-pointer vector)))
 833     (declare (fixnum fill-pointer))
 834     (when (= fill-pointer (%array-available-elements vector))
 835       (adjust-array vector (+ fill-pointer extension)))
 836     ;; disable bounds checking
 837     (locally (declare (optimize (safety 0)))
 838       (setf (aref vector fill-pointer) new-element))
 839     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 840     fill-pointer))
 841
 842 (defun vector-pop (array)
 843   #!+sb-doc
 844   "Decrease the fill pointer by 1 and return the element pointed to by the
 845   new fill pointer."
 846   (declare (vector array))
 847   (let ((fill-pointer (fill-pointer array)))
 848     (declare (fixnum fill-pointer))
 849     (if (zerop fill-pointer)
 850         (error "There is nothing left to pop.")
 851         ;; disable bounds checking (and any fixnum test)
 852         (locally (declare (optimize (safety 0)))
 853           (aref array
 854                 (setf (%array-fill-pointer array)
 855                       (1- fill-pointer)))))))
 856
 857 \f
 858 ;;;; ADJUST-ARRAY
 859
 860 (defun adjust-array (array dimensions &key
 861                            (element-type (array-element-type array))
 862                            (initial-element nil initial-element-p)
 863                            (initial-contents nil initial-contents-p)
 864                            fill-pointer
 865                            displaced-to displaced-index-offset)
 866   #!+sb-doc
 867   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 868   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 869     (cond ((/= (the fixnum (length (the list dimensions)))
 870                (the fixnum (array-rank array)))
 871            (error "The number of dimensions not equal to rank of array."))
 872           ((not (subtypep element-type (array-element-type array)))
 873            (error "The new element type, ~S, is incompatible with old type."
 874                   element-type))
 875           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 876            (error 'type-error
 877                   :datum array
 878                   :expected-type '(satisfies array-has-fill-pointer-p))))
 879     (let ((array-rank (length (the list dimensions))))
 880       (declare (fixnum array-rank))
 881       (unless (= array-rank 1)
 882         (when fill-pointer
 883           (error "Only vectors can have fill pointers.")))
 884       (cond (initial-contents-p
 885              ;; array former contents replaced by INITIAL-CONTENTS
 886              (if (or initial-element-p displaced-to)
 887                  (error "INITIAL-CONTENTS may not be specified with ~
 888                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 889              (let* ((array-size (apply #'* dimensions))
 890                     (array-data (data-vector-from-inits
 891                                  dimensions array-size element-type
 892                                  initial-contents initial-contents-p
 893                                  initial-element initial-element-p)))
 894                (if (adjustable-array-p array)
 895                    (set-array-header array array-data array-size
 896                                  (get-new-fill-pointer array array-size
 897                                                        fill-pointer)
 898                                  0 dimensions nil)
 899                    (if (array-header-p array)
 900                        ;; simple multidimensional or single dimensional array
 901                        (make-array dimensions
 902                                    :element-type element-type
 903                                    :initial-contents initial-contents)
 904                        array-data))))
 905             (displaced-to
 906              ;; We already established that no INITIAL-CONTENTS was supplied.
 907              (when initial-element
 908                (error "The :INITIAL-ELEMENT option may not be specified ~
 909                        with :DISPLACED-TO."))
 910              (unless (subtypep element-type (array-element-type displaced-to))
 911                (error "can't displace an array of type ~S into another of ~
 912                        type ~S"
 913                       element-type (array-element-type displaced-to)))
 914              (let ((displacement (or displaced-index-offset 0))
 915                    (array-size (apply #'* dimensions)))
 916                (declare (fixnum displacement array-size))
 917                (if (< (the fixnum (array-total-size displaced-to))
 918                       (the fixnum (+ displacement array-size)))
 919                    (error "The :DISPLACED-TO array is too small."))
 920                (if (adjustable-array-p array)
 921                    ;; None of the original contents appear in adjusted array.
 922                    (set-array-header array displaced-to array-size
 923                                      (get-new-fill-pointer array array-size
 924                                                            fill-pointer)
 925                                      displacement dimensions t)
 926                    ;; simple multidimensional or single dimensional array
 927                    (make-array dimensions
 928                                :element-type element-type
 929                                :displaced-to displaced-to
 930                                :displaced-index-offset
 931                                displaced-index-offset))))
 932             ((= array-rank 1)
 933              (let ((old-length (array-total-size array))
 934                    (new-length (car dimensions))
 935                    new-data)
 936                (declare (fixnum old-length new-length))
 937                (with-array-data ((old-data array) (old-start)
 938                                  (old-end old-length))
 939                  (cond ((or (and (array-header-p array)
 940                                  (%array-displaced-p array))
 941                             (< old-length new-length))
 942                         (setf new-data
 943                               (data-vector-from-inits
 944                                dimensions new-length element-type
 945                                initial-contents initial-contents-p
 946                                initial-element initial-element-p))
 947                         (replace new-data old-data
 948                                  :start2 old-start :end2 old-end))
 949                        (t (setf new-data
 950                                 (shrink-vector old-data new-length))))
 951                  (if (adjustable-array-p array)
 952                      (set-array-header array new-data new-length
 953                                        (get-new-fill-pointer array new-length
 954                                                              fill-pointer)
 955                                        0 dimensions nil)
 956                      new-data))))
 957             (t
 958              (let ((old-length (%array-available-elements array))
 959                    (new-length (apply #'* dimensions)))
 960                (declare (fixnum old-length new-length))
 961                (with-array-data ((old-data array) (old-start)
 962                                  (old-end old-length))
 963                  (declare (ignore old-end))
 964                  (let ((new-data (if (or (and (array-header-p array)
 965                                               (%array-displaced-p array))
 966                                          (> new-length old-length))
 967                                      (data-vector-from-inits
 968                                       dimensions new-length
 969                                       element-type () nil
 970                                       initial-element initial-element-p)
 971                                      old-data)))
 972                    (if (or (zerop old-length) (zerop new-length))
 973                        (when initial-element-p (fill new-data initial-element))
 974                        (zap-array-data old-data (array-dimensions array)
 975                                        old-start
 976                                        new-data dimensions new-length
 977                                        element-type initial-element
 978                                        initial-element-p))
 979                    (if (adjustable-array-p array)
 980                        (set-array-header array new-data new-length
 981                                          new-length 0 dimensions nil)
 982                        (let ((new-array
 983                               (make-array-header
 984                                sb!vm:simple-array-widetag array-rank)))
 985                          (set-array-header new-array new-data new-length
 986                                            new-length 0 dimensions nil)))))))))))
 987
 988
 989 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 990   (cond ((not fill-pointer)
 991          (when (array-has-fill-pointer-p old-array)
 992            (when (> (%array-fill-pointer old-array) new-array-size)
 993              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 994                      smaller than its fill pointer (~S)"
 995                     old-array new-array-size (fill-pointer old-array)))
 996            (%array-fill-pointer old-array)))
 997         ((not (array-has-fill-pointer-p old-array))
 998          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 999                  in ADJUST-ARRAY unless the array (~S) was originally ~
1000                  created with a fill pointer"
1001                 fill-pointer
1002                 old-array))
1003         ((numberp fill-pointer)
1004          (when (> fill-pointer new-array-size)
1005            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
1006                    than the new length of the vector (~S)"
1007                   fill-pointer new-array-size))
1008          fill-pointer)
1009         ((eq fill-pointer t)
1010          new-array-size)
1011         (t
1012          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
1013                 fill-pointer))))
1014
1015 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1016 ;;; which must be less than or equal to its current length. This can
1017 ;;; be called on vectors without a fill pointer but it is extremely
1018 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1019 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1020 ;;; or multi-threading. Call it only on provably local vectors.
1021 (defun %shrink-vector (vector new-length)
1022   (declare (vector vector))
1023   (unless (array-header-p vector)
1024     (macrolet ((frob (name &rest things)
1025                  `(etypecase ,name
1026                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1027                     ,@(mapcar (lambda (thing)
1028                                 (destructuring-bind (type-spec fill-value)
1029                                     thing
1030                                   `(,type-spec
1031                                     (fill (truly-the ,type-spec ,name)
1032                                           ,fill-value
1033                                           :start new-length))))
1034                               things))))
1035       ;; Set the 'tail' of the vector to the appropriate type of zero,
1036       ;; "because in some cases we'll scavenge larger areas in one go,
1037       ;; like groups of pages that had triggered the write barrier, or
1038       ;; the whole static space" according to jsnell.
1039       #.`(frob vector
1040           ,@(map 'list
1041                  (lambda (saetp)
1042                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1043                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1044                               #!+sb-unicode
1045                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1046                           *default-init-char-form*
1047                           (sb!vm:saetp-initial-element-default saetp))))
1048                  (remove-if-not
1049                   #'sb!vm:saetp-specifier
1050                   sb!vm:*specialized-array-element-type-properties*)))))
1051   ;; Only arrays have fill-pointers, but vectors have their length
1052   ;; parameter in the same place.
1053   (setf (%array-fill-pointer vector) new-length)
1054   vector)
1055
1056 (defun shrink-vector (vector new-length)
1057   (declare (vector vector))
1058   (cond
1059     ((eq (length vector) new-length)
1060      vector)
1061     ((array-has-fill-pointer-p vector)
1062      (setf (%array-fill-pointer vector) new-length)
1063      vector)
1064     (t (subseq vector 0 new-length))))
1065
1066 ;;; Fill in array header with the provided information, and return the array.
1067 (defun set-array-header (array data length fill-pointer displacement dimensions
1068                          &optional displacedp)
1069   (setf (%array-data-vector array) data)
1070   (setf (%array-available-elements array) length)
1071   (cond (fill-pointer
1072          (setf (%array-fill-pointer array) fill-pointer)
1073          (setf (%array-fill-pointer-p array) t))
1074         (t
1075          (setf (%array-fill-pointer array) length)
1076          (setf (%array-fill-pointer-p array) nil)))
1077   (setf (%array-displacement array) displacement)
1078   (if (listp dimensions)
1079       (dotimes (axis (array-rank array))
1080         (declare (type index axis))
1081         (setf (%array-dimension array axis) (pop dimensions)))
1082       (setf (%array-dimension array 0) dimensions))
1083   (setf (%array-displaced-p array) displacedp)
1084   array)
1085 \f
1086 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1087
1088 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1089 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1090 ;;; to length zero array in each new thread.
1091 ;;;
1092 ;;; DX is probably a bad idea, because a with a big array it would
1093 ;;; be fairly easy to blow the stack.
1094 (defvar *zap-array-data-temp* (vector))
1095 (declaim (simple-vector *zap-array-data-temp*))
1096
1097 (defun zap-array-data-temp (length initial-element initial-element-p)
1098   (declare (fixnum length))
1099   (let ((tmp *zap-array-data-temp*))
1100     (declare (simple-vector tmp))
1101     (cond ((> length (length tmp))
1102            (setf *zap-array-data-temp*
1103                  (if initial-element-p
1104                      (make-array length :initial-element initial-element)
1105                      (make-array length))))
1106           (initial-element-p
1107            (fill tmp initial-element :end length))
1108           (t
1109            tmp))))
1110
1111 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1112 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1113 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1114 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1115 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1116                        element-type initial-element initial-element-p)
1117   (declare (list old-dims new-dims))
1118   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1119   ;; at least in SBCL.
1120   ;; NEW-DIMS comes from the user.
1121   (setf old-dims (nreverse old-dims)
1122         new-dims (reverse new-dims))
1123   (cond ((eq old-data new-data)
1124          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1125          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1126          ;; EQ; in this case, a temporary must be used and filled
1127          ;; appropriately. specified initial-element.
1128          (when initial-element-p
1129            ;; FIXME: transforming this TYPEP to someting a bit faster
1130            ;; would be a win...
1131            (unless (typep initial-element element-type)
1132              (error "~S can't be used to initialize an array of type ~S."
1133                     initial-element element-type)))
1134          (without-interrupts
1135            ;; Need to disable interrupts while using the temp-vector.
1136            ;; An interrupt handler that also happened to call
1137            ;; ADJUST-ARRAY could otherwise stomp on our data here.
1138            (let ((temp (zap-array-data-temp new-length
1139                                             initial-element initial-element-p)))
1140              (declare (simple-vector temp))
1141              (zap-array-data-aux old-data old-dims offset temp new-dims)
1142              (dotimes (i new-length)
1143                (setf (aref new-data i) (aref temp i)
1144                      ;; zero out any garbage right away
1145                      (aref temp i) 0)))))
1146         (t
1147          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1148          ;; already been filled with any
1149          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1150
1151 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1152   (declare (fixnum offset))
1153   (let ((limits (mapcar (lambda (x y)
1154                           (declare (fixnum x y))
1155                           (1- (the fixnum (min x y))))
1156                         old-dims new-dims)))
1157     (macrolet ((bump-index-list (index limits)
1158                  `(do ((subscripts ,index (cdr subscripts))
1159                        (limits ,limits (cdr limits)))
1160                       ((null subscripts) :eof)
1161                     (cond ((< (the fixnum (car subscripts))
1162                               (the fixnum (car limits)))
1163                            (rplaca subscripts
1164                                    (1+ (the fixnum (car subscripts))))
1165                            (return ,index))
1166                           (t (rplaca subscripts 0))))))
1167       (do ((index (make-list (length old-dims) :initial-element 0)
1168                   (bump-index-list index limits)))
1169           ((eq index :eof))
1170         (setf (aref new-data (row-major-index-from-dims index new-dims))
1171               (aref old-data
1172                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1173                        offset)))))))
1174
1175 ;;; Figure out the row-major-order index of an array reference from a
1176 ;;; list of subscripts and a list of dimensions. This is for internal
1177 ;;; calls only, and the subscripts and dim-list variables are assumed
1178 ;;; to be reversed from what the user supplied.
1179 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1180   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1181        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1182        (chunk-size 1)
1183        (result 0))
1184       ((null rev-dim-list) result)
1185     (declare (fixnum chunk-size result))
1186     (setq result (+ result
1187                     (the fixnum (* (the fixnum (car rev-subscripts))
1188                                    chunk-size))))
1189     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1190 \f
1191 ;;;; some bit stuff
1192
1193 (defun bit-array-same-dimensions-p (array1 array2)
1194   (declare (type (array bit) array1 array2))
1195   (and (= (array-rank array1)
1196           (array-rank array2))
1197        (dotimes (index (array-rank array1) t)
1198          (when (/= (array-dimension array1 index)
1199                    (array-dimension array2 index))
1200            (return nil)))))
1201
1202 (defun pick-result-array (result-bit-array bit-array-1)
1203   (case result-bit-array
1204     ((t) bit-array-1)
1205     ((nil) (make-array (array-dimensions bit-array-1)
1206                        :element-type 'bit
1207                        :initial-element 0))
1208     (t
1209      (unless (bit-array-same-dimensions-p bit-array-1
1210                                           result-bit-array)
1211        (error "~S and ~S don't have the same dimensions."
1212               bit-array-1 result-bit-array))
1213      result-bit-array)))
1214
1215 (defmacro def-bit-array-op (name function)
1216   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1217      #!+sb-doc
1218      ,(format nil
1219               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1220                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1221                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1222                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1223                All the arrays must have the same rank and dimensions."
1224               (symbol-name function))
1225      (declare (type (array bit) bit-array-1 bit-array-2)
1226               (type (or (array bit) (member t nil)) result-bit-array))
1227      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1228        (error "~S and ~S don't have the same dimensions."
1229               bit-array-1 bit-array-2))
1230      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1231        (if (and (simple-bit-vector-p bit-array-1)
1232                 (simple-bit-vector-p bit-array-2)
1233                 (simple-bit-vector-p result-bit-array))
1234            (locally (declare (optimize (speed 3) (safety 0)))
1235              (,name bit-array-1 bit-array-2 result-bit-array))
1236            (with-array-data ((data1 bit-array-1) (start1) (end1))
1237              (declare (ignore end1))
1238              (with-array-data ((data2 bit-array-2) (start2) (end2))
1239                (declare (ignore end2))
1240                (with-array-data ((data3 result-bit-array) (start3) (end3))
1241                  (do ((index-1 start1 (1+ index-1))
1242                       (index-2 start2 (1+ index-2))
1243                       (index-3 start3 (1+ index-3)))
1244                      ((>= index-3 end3) result-bit-array)
1245                    (declare (type index index-1 index-2 index-3))
1246                    (setf (sbit data3 index-3)
1247                          (logand (,function (sbit data1 index-1)
1248                                             (sbit data2 index-2))
1249                                  1))))))))))
1250
1251 (def-bit-array-op bit-and logand)
1252 (def-bit-array-op bit-ior logior)
1253 (def-bit-array-op bit-xor logxor)
1254 (def-bit-array-op bit-eqv logeqv)
1255 (def-bit-array-op bit-nand lognand)
1256 (def-bit-array-op bit-nor lognor)
1257 (def-bit-array-op bit-andc1 logandc1)
1258 (def-bit-array-op bit-andc2 logandc2)
1259 (def-bit-array-op bit-orc1 logorc1)
1260 (def-bit-array-op bit-orc2 logorc2)
1261
1262 (defun bit-not (bit-array &optional result-bit-array)
1263   #!+sb-doc
1264   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1265   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1266   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1267   created. Both arrays must have the same rank and dimensions."
1268   (declare (type (array bit) bit-array)
1269            (type (or (array bit) (member t nil)) result-bit-array))
1270   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1271     (if (and (simple-bit-vector-p bit-array)
1272              (simple-bit-vector-p result-bit-array))
1273         (locally (declare (optimize (speed 3) (safety 0)))
1274           (bit-not bit-array result-bit-array))
1275         (with-array-data ((src bit-array) (src-start) (src-end))
1276           (declare (ignore src-end))
1277           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1278             (do ((src-index src-start (1+ src-index))
1279                  (dst-index dst-start (1+ dst-index)))
1280                 ((>= dst-index dst-end) result-bit-array)
1281               (declare (type index src-index dst-index))
1282               (setf (sbit dst dst-index)
1283                     (logxor (sbit src src-index) 1))))))))