src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p)
  34   (def %array-diplaced-from))
  35
  36 (defun %array-rank (array)
  37   (%array-rank array))
  38
  39 (defun %array-dimension (array axis)
  40   (%array-dimension array axis))
  41
  42 (defun %set-array-dimension (array axis value)
  43   (%set-array-dimension array axis value))
  44
  45 (defun %check-bound (array bound index)
  46   (declare (type index bound)
  47            (fixnum index))
  48   (%check-bound array bound index))
  49
  50 (defun %with-array-data/fp (array start end)
  51   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer t))
  52
  53 (defun %with-array-data (array start end)
  54   (%with-array-data-macro array start end :check-bounds t :check-fill-pointer nil))
  55
  56 (defun %data-vector-and-index (array index)
  57   (if (array-header-p array)
  58       (multiple-value-bind (vector index)
  59           (%with-array-data array index nil)
  60         (values vector index))
  61       (values array index)))
  62 \f
  63 ;;;; MAKE-ARRAY
  64 (eval-when (:compile-toplevel :execute)
  65   (sb!xc:defmacro pick-vector-type (type &rest specs)
  66     `(cond ,@(mapcar (lambda (spec)
  67                        `(,(if (eq (car spec) t)
  68                               t
  69                               `(subtypep ,type ',(car spec)))
  70                          ,@(cdr spec)))
  71                      specs))))
  72
  73 ;;; These functions are used in the implementation of MAKE-ARRAY for
  74 ;;; complex arrays. There are lots of transforms to simplify
  75 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  76 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  77 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  78 ;;; making this somewhat efficient, at least not doing full calls to
  79 ;;; SUBTYPEP in the easy cases.
  80 (defun %vector-widetag-and-n-bits (type)
  81   (case type
  82     ;; Pick off some easy common cases.
  83     ;;
  84     ;; (Perhaps we should make a much more exhaustive table of easy
  85     ;; common cases here. Or perhaps the effort would be better spent
  86     ;; on smarter compiler transforms which do the calculation once
  87     ;; and for all in any reasonable user programs.)
  88     ((t)
  89      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
  90     ((base-char standard-char #!-sb-unicode character)
  91      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
  92     #!+sb-unicode
  93     ((character)
  94      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
  95     ((bit)
  96      (values #.sb!vm:simple-bit-vector-widetag 1))
  97     ;; OK, we have to wade into SUBTYPEPing after all.
  98     (t
  99      #.`(pick-vector-type type
 100          ,@(map 'list
 101                 (lambda (saetp)
 102                   `(,(sb!vm:saetp-specifier saetp)
 103                     (values ,(sb!vm:saetp-typecode saetp)
 104                             ,(sb!vm:saetp-n-bits saetp))))
 105                 sb!vm:*specialized-array-element-type-properties*)))))
 106
 107 (defun %complex-vector-widetag (type)
 108   (case type
 109     ;; Pick off some easy common cases.
 110     ((t)
 111      #.sb!vm:complex-vector-widetag)
 112     ((base-char #!-sb-unicode character)
 113      #.sb!vm:complex-base-string-widetag)
 114     #!+sb-unicode
 115     ((character)
 116      #.sb!vm:complex-character-string-widetag)
 117     ((nil)
 118      #.sb!vm:complex-vector-nil-widetag)
 119     ((bit)
 120      #.sb!vm:complex-bit-vector-widetag)
 121     ;; OK, we have to wade into SUBTYPEPing after all.
 122     (t
 123      (pick-vector-type type
 124        (nil #.sb!vm:complex-vector-nil-widetag)
 125        #!-sb-unicode
 126        (character #.sb!vm:complex-base-string-widetag)
 127        #!+sb-unicode
 128        (base-char #.sb!vm:complex-base-string-widetag)
 129        #!+sb-unicode
 130        (character #.sb!vm:complex-character-string-widetag)
 131        (bit #.sb!vm:complex-bit-vector-widetag)
 132        (t #.sb!vm:complex-vector-widetag)))))
 133
 134 (defun make-array (dimensions &key
 135                               (element-type t)
 136                               (initial-element nil initial-element-p)
 137                               (initial-contents nil initial-contents-p)
 138                               adjustable fill-pointer
 139                               displaced-to displaced-index-offset)
 140   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 141          (array-rank (length (the list dimensions)))
 142          (simple (and (null fill-pointer)
 143                       (not adjustable)
 144                       (null displaced-to))))
 145     (declare (fixnum array-rank))
 146     (when (and displaced-index-offset (null displaced-to))
 147       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 148     (when (and displaced-to
 149                (arrayp displaced-to)
 150                (not (equal (array-element-type displaced-to)
 151                            (upgraded-array-element-type element-type))))
 152       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 153     (if (and simple (= array-rank 1))
 154         ;; it's a (SIMPLE-ARRAY * (*))
 155         (multiple-value-bind (type n-bits)
 156             (%vector-widetag-and-n-bits element-type)
 157           (declare (type (unsigned-byte 8) type)
 158                    (type (integer 0 256) n-bits))
 159           (let* ((length (car dimensions))
 160                  (array (allocate-vector
 161                          type
 162                          length
 163                          (ceiling
 164                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 165                                      #!+sb-unicode
 166                                      (= type
 167                                         sb!vm:simple-character-string-widetag))
 168                                  (1+ length)
 169                                  length)
 170                              n-bits)
 171                           sb!vm:n-word-bits))))
 172             (declare (type index length))
 173             (when initial-element-p
 174               (fill array initial-element))
 175             (when initial-contents-p
 176               (when initial-element-p
 177                 (error "can't specify both :INITIAL-ELEMENT and ~
 178                        :INITIAL-CONTENTS"))
 179               (unless (= length (length initial-contents))
 180                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 181                        the vector length is ~W."
 182                        (length initial-contents)
 183                        length))
 184               (replace array initial-contents))
 185             array))
 186         ;; it's either a complex array or a multidimensional array.
 187         (let* ((total-size (reduce #'* dimensions))
 188                (data (or displaced-to
 189                          (data-vector-from-inits
 190                           dimensions total-size element-type
 191                           initial-contents initial-contents-p
 192                           initial-element initial-element-p)))
 193                (array (make-array-header
 194                        (cond ((= array-rank 1)
 195                               (%complex-vector-widetag element-type))
 196                              (simple sb!vm:simple-array-widetag)
 197                              (t sb!vm:complex-array-widetag))
 198                        array-rank)))
 199           (cond (fill-pointer
 200                  (unless (= array-rank 1)
 201                    (error "Only vectors can have fill pointers."))
 202                  (let ((length (car dimensions)))
 203                    (declare (fixnum length))
 204                    (setf (%array-fill-pointer array)
 205                      (cond ((eq fill-pointer t)
 206                             length)
 207                            (t
 208                             (unless (and (fixnump fill-pointer)
 209                                          (>= fill-pointer 0)
 210                                          (<= fill-pointer length))
 211                               ;; FIXME: should be TYPE-ERROR?
 212                               (error "invalid fill-pointer ~W"
 213                                      fill-pointer))
 214                             fill-pointer))))
 215                  (setf (%array-fill-pointer-p array) t))
 216                 (t
 217                  (setf (%array-fill-pointer array) total-size)
 218                  (setf (%array-fill-pointer-p array) nil)))
 219           (setf (%array-available-elements array) total-size)
 220           (setf (%array-data-vector array) data)
 221           (setf (%array-displaced-from array) nil)
 222           (cond (displaced-to
 223                  (when (or initial-element-p initial-contents-p)
 224                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 225                    can be specified along with :DISPLACED-TO"))
 226                  (let ((offset (or displaced-index-offset 0)))
 227                    (when (> (+ offset total-size)
 228                             (array-total-size displaced-to))
 229                      (error "~S doesn't have enough elements." displaced-to))
 230                    (setf (%array-displacement array) offset)
 231                    (setf (%array-displaced-p array) t)
 232                    (%save-displaced-array-backpointer array data)))
 233                 (t
 234                  (setf (%array-displaced-p array) nil)))
 235           (let ((axis 0))
 236             (dolist (dim dimensions)
 237               (setf (%array-dimension array axis) dim)
 238               (incf axis)))
 239           array))))
 240
 241 (defun make-static-vector (length &key
 242                            (element-type '(unsigned-byte 8))
 243                            (initial-contents nil initial-contents-p)
 244                            (initial-element nil initial-element-p))
 245   "Allocate vector of LENGTH elements in static space. Only allocation
 246 of specialized arrays is supported."
 247   ;; STEP 1: check inputs fully
 248   ;;
 249   ;; This way of doing explicit checks before the vector is allocated
 250   ;; is expensive, but probably worth the trouble as once we've allocated
 251   ;; the vector we have no way to get rid of it anymore...
 252   (when (eq t (upgraded-array-element-type element-type))
 253     (error "Static arrays of type ~S not supported."
 254            element-type))
 255   (when initial-contents-p
 256     (when initial-element-p
 257       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 258     (unless (= length (length initial-contents))
 259       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 260               vector length is ~W."
 261              (length initial-contents)
 262              length))
 263     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 264       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 265              element-type)))
 266   (when initial-element-p
 267     (unless (typep initial-element element-type)
 268       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 269              initial-element element-type)))
 270   ;; STEP 2
 271   ;;
 272   ;; Allocate and possibly initialize the vector.
 273   (multiple-value-bind (type n-bits)
 274       (sb!impl::%vector-widetag-and-n-bits element-type)
 275     (let ((vector
 276            (allocate-static-vector type length
 277                                    (ceiling (* length n-bits)
 278                                             sb!vm:n-word-bits))))
 279       (cond (initial-element-p
 280              (fill vector initial-element))
 281             (initial-contents-p
 282              (replace vector initial-contents))
 283             (t
 284              vector)))))
 285
 286 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 287 ;;; specified array characteristics. Dimensions is only used to pass
 288 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 289 ;;; initial-contents.
 290 (defun data-vector-from-inits (dimensions total-size element-type
 291                                initial-contents initial-contents-p
 292                                initial-element initial-element-p)
 293   (when (and initial-contents-p initial-element-p)
 294     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 295             either MAKE-ARRAY or ADJUST-ARRAY."))
 296   (let ((data (if initial-element-p
 297                   (make-array total-size
 298                               :element-type element-type
 299                               :initial-element initial-element)
 300                   (make-array total-size
 301                               :element-type element-type))))
 302     (cond (initial-element-p
 303            (unless (simple-vector-p data)
 304              (unless (typep initial-element element-type)
 305                (error "~S cannot be used to initialize an array of type ~S."
 306                       initial-element element-type))
 307              (fill (the vector data) initial-element)))
 308           (initial-contents-p
 309            (fill-data-vector data dimensions initial-contents)))
 310     data))
 311
 312 (defun vector (&rest objects)
 313   #!+sb-doc
 314   "Construct a SIMPLE-VECTOR from the given objects."
 315   (coerce (the list objects) 'simple-vector))
 316 \f
 317
 318 ;;;; accessor/setter functions
 319
 320 ;;; Dispatch to an optimized routine the data vector accessors for
 321 ;;; each different specialized vector type. Do dispatching by looking
 322 ;;; up the widetag in the array rather than with the typecases, which
 323 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 324 ;;; provide separate versions where bounds checking has been moved
 325 ;;; from the callee to the caller, since it's much cheaper to do once
 326 ;;; the type information is available. Finally, for each of these
 327 ;;; routines also provide a slow path, taken for arrays that are not
 328 ;;; vectors or not simple.
 329 (macrolet ((def (name table-name)
 330              `(progn
 331                 (defvar ,table-name)
 332                 (defmacro ,name (array-var)
 333                  `(the function
 334                     (let ((tag 0))
 335                       (when (sb!vm::%other-pointer-p ,array-var)
 336                         (setf tag (%other-pointer-widetag ,array-var)))
 337                       ;; SYMBOL-GLOBAL-VALUE is a performance hack
 338                       ;; for threaded builds.
 339                       (svref (sb!vm::symbol-global-value ',',table-name) tag)))))))
 340   (def !find-data-vector-setter *data-vector-setters*)
 341   (def !find-data-vector-setter/check-bounds *data-vector-setters/check-bounds*)
 342   (def !find-data-vector-reffer *data-vector-reffers*)
 343   (def !find-data-vector-reffer/check-bounds *data-vector-reffers/check-bounds*))
 344
 345 (macrolet ((%ref (accessor-getter extra-params)
 346              `(funcall (,accessor-getter array) array index ,@extra-params))
 347            (define (accessor-name slow-accessor-name accessor-getter
 348                                   extra-params check-bounds)
 349              `(progn
 350                 (defun ,accessor-name (array index ,@extra-params)
 351                   (declare (optimize speed
 352                                      ;; (SAFETY 0) is ok. All calls to
 353                                      ;; these functions are generated by
 354                                      ;; the compiler, so argument count
 355                                      ;; checking isn't needed. Type checking
 356                                      ;; is done implicitly via the widetag
 357                                      ;; dispatch.
 358                                      (safety 0)))
 359                   (%ref ,accessor-getter ,extra-params))
 360                 (defun ,slow-accessor-name (array index ,@extra-params)
 361                   (declare (optimize speed (safety 0)))
 362                   (if (not (%array-displaced-p array))
 363                       ;; The reasonably quick path of non-displaced complex
 364                       ;; arrays.
 365                       (let ((array (%array-data-vector array)))
 366                         (%ref ,accessor-getter ,extra-params))
 367                       ;; The real slow path.
 368                       (with-array-data
 369                           ((vector array)
 370                            (index (locally
 371                                       (declare (optimize (speed 1) (safety 1)))
 372                                     (,@check-bounds index)))
 373                            (end)
 374                            :force-inline t)
 375                         (declare (ignore end))
 376                         (,accessor-name vector index ,@extra-params)))))))
 377   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 378     !find-data-vector-reffer
 379     nil (progn))
 380   (define hairy-data-vector-set slow-hairy-data-vector-set
 381     !find-data-vector-setter
 382     (new-value) (progn))
 383   (define hairy-data-vector-ref/check-bounds
 384       slow-hairy-data-vector-ref/check-bounds
 385     !find-data-vector-reffer/check-bounds
 386     nil (%check-bound array (array-dimension array 0)))
 387   (define hairy-data-vector-set/check-bounds
 388       slow-hairy-data-vector-set/check-bounds
 389     !find-data-vector-setter/check-bounds
 390     (new-value) (%check-bound array (array-dimension array 0))))
 391
 392 (defun hairy-ref-error (array index &optional new-value)
 393   (declare (ignore index new-value))
 394   (error 'type-error
 395          :datum array
 396          :expected-type 'vector))
 397
 398 ;;; Populate the dispatch tables.
 399 (macrolet ((define-reffer (saetp check-form)
 400              (let* ((type (sb!vm:saetp-specifier saetp))
 401                     (atype `(simple-array ,type (*))))
 402                `(named-lambda optimized-data-vector-ref (vector index)
 403                   (declare (optimize speed (safety 0)))
 404                   (data-vector-ref (the ,atype vector)
 405                                    (locally
 406                                        (declare (optimize (safety 1)))
 407                                      (the index
 408                                        (,@check-form index)))))))
 409            (define-setter (saetp check-form)
 410              (let* ((type (sb!vm:saetp-specifier saetp))
 411                     (atype `(simple-array ,type (*))))
 412                `(named-lambda optimized-data-vector-set (vector index new-value)
 413                   (declare (optimize speed (safety 0)))
 414                   (data-vector-set (the ,atype vector)
 415                                    (locally
 416                                        (declare (optimize (safety 1)))
 417                                      (the index
 418                                        (,@check-form index)))
 419                                    (locally
 420                                        ;; SPEED 1 needed to avoid the compiler
 421                                        ;; from downgrading the type check to
 422                                        ;; a cheaper one.
 423                                        (declare (optimize (speed 1)
 424                                                           (safety 1)))
 425                                      (the ,type new-value)))
 426                   ;; For specialized arrays, the return from
 427                   ;; data-vector-set would have to be reboxed to be a
 428                   ;; (Lisp) return value; instead, we use the
 429                   ;; already-boxed value as the return.
 430                   new-value)))
 431            (define-reffers (symbol deffer check-form slow-path)
 432              `(progn
 433                 (setf ,symbol (make-array sb!vm::widetag-mask
 434                                           :initial-element #'hairy-ref-error))
 435                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 436                                          sb!vm:complex-vector-nil-widetag
 437                                          sb!vm:complex-bit-vector-widetag
 438                                          #!+sb-unicode sb!vm:complex-character-string-widetag
 439                                          sb!vm:complex-base-string-widetag
 440                                          sb!vm:simple-array-widetag
 441                                          sb!vm:complex-array-widetag)
 442                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 443                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 444                         for widetag = (sb!vm:saetp-typecode saetp)
 445                         collect `(setf (svref ,symbol ,widetag)
 446                                        (,deffer ,saetp ,check-form))))))
 447   (defun !hairy-data-vector-reffer-init ()
 448     (define-reffers *data-vector-reffers* define-reffer
 449       (progn)
 450       #'slow-hairy-data-vector-ref)
 451     (define-reffers *data-vector-setters* define-setter
 452       (progn)
 453       #'slow-hairy-data-vector-set)
 454     (define-reffers *data-vector-reffers/check-bounds* define-reffer
 455       (%check-bound vector (length vector))
 456       #'slow-hairy-data-vector-ref/check-bounds)
 457     (define-reffers *data-vector-setters/check-bounds* define-setter
 458       (%check-bound vector (length vector))
 459       #'slow-hairy-data-vector-set/check-bounds)))
 460
 461 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 462 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 463 ;;; definition is needed for the compiler to use in constant folding.)
 464 (defun data-vector-ref (array index)
 465   (hairy-data-vector-ref array index))
 466
 467 (defun data-vector-ref-with-offset (array index offset)
 468   (hairy-data-vector-ref array (+ index offset)))
 469
 470 (defun invalid-array-p (array)
 471   (and (array-header-p array)
 472        (consp (%array-displaced-p array))))
 473
 474 (declaim (ftype (function (array) nil) invalid-array-error))
 475 (defun invalid-array-error (array)
 476   (aver (array-header-p array))
 477   ;; Array invalidation stashes the original dimensions here...
 478   (let ((dims (%array-displaced-p array))
 479         (et (array-element-type array)))
 480     (error 'invalid-array-error
 481            :datum array
 482            :expected-type
 483            (if (cdr dims)
 484                `(array ,et ,dims)
 485                `(vector ,et ,@dims)))))
 486
 487 (declaim (ftype (function (array integer integer &optional t) nil)
 488                 invalid-array-index-error))
 489 (defun invalid-array-index-error (array index bound &optional axis)
 490   (if (invalid-array-p array)
 491       (invalid-array-error array)
 492       (error 'invalid-array-index-error
 493              :array array
 494              :axis axis
 495              :datum index
 496              :expected-type `(integer 0 (,bound)))))
 497
 498 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 499 (defun %array-row-major-index (array subscripts
 500                                      &optional (invalid-index-error-p t))
 501   (declare (array array)
 502            (list subscripts))
 503   (let ((rank (array-rank array)))
 504     (unless (= rank (length subscripts))
 505       (error "wrong number of subscripts, ~W, for array of rank ~W"
 506              (length subscripts) rank))
 507     (if (array-header-p array)
 508         (do ((subs (nreverse subscripts) (cdr subs))
 509              (axis (1- (array-rank array)) (1- axis))
 510              (chunk-size 1)
 511              (result 0))
 512             ((null subs) result)
 513           (declare (list subs) (fixnum axis chunk-size result))
 514           (let ((index (car subs))
 515                 (dim (%array-dimension array axis)))
 516             (declare (fixnum dim))
 517             (unless (and (fixnump index) (< -1 index dim))
 518               (if invalid-index-error-p
 519                   (invalid-array-index-error array index dim axis)
 520                   (return-from %array-row-major-index nil)))
 521             (incf result (* chunk-size (the fixnum index)))
 522             (setf chunk-size (* chunk-size dim))))
 523         (let ((index (first subscripts))
 524               (length (length (the (simple-array * (*)) array))))
 525           (unless (and (fixnump index) (< -1 index length))
 526             (if invalid-index-error-p
 527                 (invalid-array-index-error array index length)
 528                 (return-from %array-row-major-index nil)))
 529           index))))
 530
 531 (defun array-in-bounds-p (array &rest subscripts)
 532   #!+sb-doc
 533   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 534   (if (%array-row-major-index array subscripts nil)
 535       t))
 536
 537 (defun array-row-major-index (array &rest subscripts)
 538   (declare (truly-dynamic-extent subscripts))
 539   (%array-row-major-index array subscripts))
 540
 541 (defun aref (array &rest subscripts)
 542   #!+sb-doc
 543   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 544   (declare (truly-dynamic-extent subscripts))
 545   (row-major-aref array (%array-row-major-index array subscripts)))
 546
 547 (defun %aset (array &rest stuff)
 548   (declare (truly-dynamic-extent stuff))
 549   (let ((subscripts (butlast stuff))
 550         (new-value (car (last stuff))))
 551     (setf (row-major-aref array (%array-row-major-index array subscripts))
 552           new-value)))
 553
 554 ;;; FIXME: What's supposed to happen with functions
 555 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 556 ;;; DEFSETF FOO is also defined? It seems as though the logical
 557 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 558 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 559 ;;; just as for ordinary functions
 560 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 561 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 562 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 563 ;;;  ZOO
 564 ;;;  * (DEFUN ZOO (X) (* 3 X))
 565 ;;;  Warning: ZOO previously defined as a macro.
 566 ;;;  ZOO
 567 ;;; But that doesn't seem to be what happens in CMU CL.
 568 ;;;
 569 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 570 ;;; 5.1.2.5) requires implementations to support
 571 ;;;   (SETF (APPLY #'AREF ...) ...)
 572 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 573 ;;; also terrifying that this sequence of definitions causes it to
 574 ;;; work.
 575 ;;;
 576 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 577 ;;; has a setf expansion and/or a setf function defined.
 578
 579 #!-sb-fluid (declaim (inline (setf aref)))
 580 (defun (setf aref) (new-value array &rest subscripts)
 581   (declare (truly-dynamic-extent subscripts))
 582   (declare (type array array))
 583   (setf (row-major-aref array (%array-row-major-index array subscripts))
 584         new-value))
 585
 586 (defun row-major-aref (array index)
 587   #!+sb-doc
 588   "Return the element of array corressponding to the row-major index. This is
 589    SETF'able."
 590   (declare (optimize (safety 1)))
 591   (row-major-aref array index))
 592
 593 (defun %set-row-major-aref (array index new-value)
 594   (declare (optimize (safety 1)))
 595   (setf (row-major-aref array index) new-value))
 596
 597 (defun svref (simple-vector index)
 598   #!+sb-doc
 599   "Return the INDEX'th element of the given Simple-Vector."
 600   (declare (optimize (safety 1)))
 601   (aref simple-vector index))
 602
 603 (defun %svset (simple-vector index new)
 604   (declare (optimize (safety 1)))
 605   (setf (aref simple-vector index) new))
 606
 607 (defun bit (bit-array &rest subscripts)
 608   #!+sb-doc
 609   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 610   (declare (type (array bit) bit-array) (optimize (safety 1)))
 611   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 612
 613 (defun %bitset (bit-array &rest stuff)
 614   (declare (type (array bit) bit-array) (optimize (safety 1)))
 615   (let ((subscripts (butlast stuff))
 616         (new-value (car (last stuff))))
 617     (setf (row-major-aref bit-array
 618                           (%array-row-major-index bit-array subscripts))
 619           new-value)))
 620
 621 #!-sb-fluid (declaim (inline (setf bit)))
 622 (defun (setf bit) (new-value bit-array &rest subscripts)
 623   (declare (type (array bit) bit-array) (optimize (safety 1)))
 624   (setf (row-major-aref bit-array
 625                         (%array-row-major-index bit-array subscripts))
 626         new-value))
 627
 628 (defun sbit (simple-bit-array &rest subscripts)
 629   #!+sb-doc
 630   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 631   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 632   (row-major-aref simple-bit-array
 633                   (%array-row-major-index simple-bit-array subscripts)))
 634
 635 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 636 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 637 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 638 ;;; -- WHN 19990911
 639 (defun %sbitset (simple-bit-array &rest stuff)
 640   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 641   (let ((subscripts (butlast stuff))
 642         (new-value (car (last stuff))))
 643     (setf (row-major-aref simple-bit-array
 644                           (%array-row-major-index simple-bit-array subscripts))
 645           new-value)))
 646
 647 #!-sb-fluid (declaim (inline (setf sbit)))
 648 (defun (setf sbit) (new-value bit-array &rest subscripts)
 649   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 650   (setf (row-major-aref bit-array
 651                         (%array-row-major-index bit-array subscripts))
 652         new-value))
 653 \f
 654 ;;;; miscellaneous array properties
 655
 656 (defun array-element-type (array)
 657   #!+sb-doc
 658   "Return the type of the elements of the array"
 659   (let ((widetag (widetag-of array)))
 660     (macrolet ((pick-element-type (&rest stuff)
 661                  `(cond ,@(mapcar (lambda (stuff)
 662                                     (cons
 663                                      (let ((item (car stuff)))
 664                                        (cond ((eq item t)
 665                                               t)
 666                                              ((listp item)
 667                                               (cons 'or
 668                                                     (mapcar (lambda (x)
 669                                                               `(= widetag ,x))
 670                                                             item)))
 671                                              (t
 672                                               `(= widetag ,item))))
 673                                      (cdr stuff)))
 674                                   stuff))))
 675       #.`(pick-element-type
 676           ,@(map 'list
 677                  (lambda (saetp)
 678                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 679                           (list (sb!vm:saetp-typecode saetp)
 680                                 (sb!vm:saetp-complex-typecode saetp))
 681                           (sb!vm:saetp-typecode saetp))
 682                      ',(sb!vm:saetp-specifier saetp)))
 683                  sb!vm:*specialized-array-element-type-properties*)
 684           ((sb!vm:simple-array-widetag
 685             sb!vm:complex-vector-widetag
 686             sb!vm:complex-array-widetag)
 687            (with-array-data ((array array) (start) (end))
 688              (declare (ignore start end))
 689              (array-element-type array)))
 690           (t
 691            (error 'type-error :datum array :expected-type 'array))))))
 692
 693 (defun array-rank (array)
 694   #!+sb-doc
 695   "Return the number of dimensions of ARRAY."
 696   (if (array-header-p array)
 697       (%array-rank array)
 698       1))
 699
 700 (defun array-dimension (array axis-number)
 701   #!+sb-doc
 702   "Return the length of dimension AXIS-NUMBER of ARRAY."
 703   (declare (array array) (type index axis-number))
 704   (cond ((not (array-header-p array))
 705          (unless (= axis-number 0)
 706            (error "Vector axis is not zero: ~S" axis-number))
 707          (length (the (simple-array * (*)) array)))
 708         ((>= axis-number (%array-rank array))
 709          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 710                 axis-number array (%array-rank array)))
 711         (t
 712          (%array-dimension array axis-number))))
 713
 714 (defun array-dimensions (array)
 715   #!+sb-doc
 716   "Return a list whose elements are the dimensions of the array"
 717   (declare (array array))
 718   (if (array-header-p array)
 719       (do ((results nil (cons (array-dimension array index) results))
 720            (index (1- (array-rank array)) (1- index)))
 721           ((minusp index) results))
 722       (list (array-dimension array 0))))
 723
 724 (defun array-total-size (array)
 725   #!+sb-doc
 726   "Return the total number of elements in the Array."
 727   (declare (array array))
 728   (if (array-header-p array)
 729       (%array-available-elements array)
 730       (length (the vector array))))
 731
 732 (defun array-displacement (array)
 733   #!+sb-doc
 734   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 735    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 736   (declare (type array array))
 737   (if (and (array-header-p array) ; if unsimple and
 738            (%array-displaced-p array)) ; displaced
 739       (values (%array-data-vector array) (%array-displacement array))
 740       (values nil 0)))
 741
 742 (defun adjustable-array-p (array)
 743   #!+sb-doc
 744   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 745    to the argument, this happens for complex arrays."
 746   (declare (array array))
 747   ;; Note that this appears not to be a fundamental limitation.
 748   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 749   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 750   ;; -- CSR, 2004-03-01.
 751   (not (typep array 'simple-array)))
 752 \f
 753 ;;;; fill pointer frobbing stuff
 754
 755 (defun array-has-fill-pointer-p (array)
 756   #!+sb-doc
 757   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 758   (declare (array array))
 759   (and (array-header-p array) (%array-fill-pointer-p array)))
 760
 761 (defun fill-pointer-error (vector arg)
 762   (cond (arg
 763          (aver (array-has-fill-pointer-p vector))
 764          (let ((max (%array-available-elements vector)))
 765            (error 'simple-type-error
 766                   :datum arg
 767                   :expected-type (list 'integer 0 max)
 768                   :format-control "The new fill pointer, ~S, is larger than the length of the vector (~S.)"
 769                   :format-arguments (list arg max))))
 770         (t
 771          (error 'simple-type-error
 772                 :datum vector
 773                 :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 774                 :format-control "~S is not an array with a fill pointer."
 775                 :format-arguments (list vector)))))
 776
 777 (defun fill-pointer (vector)
 778   #!+sb-doc
 779   "Return the FILL-POINTER of the given VECTOR."
 780   (if (array-has-fill-pointer-p vector)
 781       (%array-fill-pointer vector)
 782       (fill-pointer-error vector nil)))
 783
 784 (defun %set-fill-pointer (vector new)
 785   (flet ((oops (x)
 786            (fill-pointer-error vector x)))
 787     (if (array-has-fill-pointer-p vector)
 788         (if (> new (%array-available-elements vector))
 789             (oops new)
 790             (setf (%array-fill-pointer vector) new))
 791         (oops nil))))
 792
 793 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 794 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 795 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 796 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 797 ;;; back to CMU CL).
 798 (defun vector-push (new-el array)
 799   #!+sb-doc
 800   "Attempt to set the element of ARRAY designated by its fill pointer
 801    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 802    too large, NIL is returned, otherwise the index of the pushed element is
 803    returned."
 804   (declare (vector array))
 805   (let ((fill-pointer (fill-pointer array)))
 806     (declare (fixnum fill-pointer))
 807     (cond ((= fill-pointer (%array-available-elements array))
 808            nil)
 809           (t
 810            (locally (declare (optimize (safety 0)))
 811              (setf (aref array fill-pointer) new-el))
 812            (setf (%array-fill-pointer array) (1+ fill-pointer))
 813            fill-pointer))))
 814
 815 (defun vector-push-extend (new-element
 816                            vector
 817                            &optional
 818                            (min-extension
 819                             (let ((length (length vector)))
 820                               (min (1+ length)
 821                                    (- array-dimension-limit length)))))
 822   (declare (vector vector) (fixnum min-extension))
 823   (let ((fill-pointer (fill-pointer vector)))
 824     (declare (fixnum fill-pointer))
 825     (when (= fill-pointer (%array-available-elements vector))
 826       (adjust-array vector (+ fill-pointer (max 1 min-extension))))
 827     ;; disable bounds checking
 828     (locally (declare (optimize (safety 0)))
 829       (setf (aref vector fill-pointer) new-element))
 830     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 831     fill-pointer))
 832
 833 (defun vector-pop (array)
 834   #!+sb-doc
 835   "Decrease the fill pointer by 1 and return the element pointed to by the
 836   new fill pointer."
 837   (declare (vector array))
 838   (let ((fill-pointer (fill-pointer array)))
 839     (declare (fixnum fill-pointer))
 840     (if (zerop fill-pointer)
 841         (error "There is nothing left to pop.")
 842         ;; disable bounds checking (and any fixnum test)
 843         (locally (declare (optimize (safety 0)))
 844           (aref array
 845                 (setf (%array-fill-pointer array)
 846                       (1- fill-pointer)))))))
 847
 848 \f
 849 ;;;; ADJUST-ARRAY
 850
 851 (defun adjust-array (array dimensions &key
 852                            (element-type (array-element-type array))
 853                            (initial-element nil initial-element-p)
 854                            (initial-contents nil initial-contents-p)
 855                            fill-pointer
 856                            displaced-to displaced-index-offset)
 857   #!+sb-doc
 858   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 859   (when (invalid-array-p array)
 860     (invalid-array-error array))
 861   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 862     (cond ((/= (the fixnum (length (the list dimensions)))
 863                (the fixnum (array-rank array)))
 864            (error "The number of dimensions not equal to rank of array."))
 865           ((not (subtypep element-type (array-element-type array)))
 866            (error "The new element type, ~S, is incompatible with old type."
 867                   element-type))
 868           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 869            (error 'type-error
 870                   :datum array
 871                   :expected-type '(satisfies array-has-fill-pointer-p))))
 872     (let ((array-rank (length (the list dimensions))))
 873       (declare (fixnum array-rank))
 874       (unless (= array-rank 1)
 875         (when fill-pointer
 876           (error "Only vectors can have fill pointers.")))
 877       (cond (initial-contents-p
 878              ;; array former contents replaced by INITIAL-CONTENTS
 879              (if (or initial-element-p displaced-to)
 880                  (error "INITIAL-CONTENTS may not be specified with ~
 881                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 882              (let* ((array-size (apply #'* dimensions))
 883                     (array-data (data-vector-from-inits
 884                                  dimensions array-size element-type
 885                                  initial-contents initial-contents-p
 886                                  initial-element initial-element-p)))
 887                (if (adjustable-array-p array)
 888                    (set-array-header array array-data array-size
 889                                  (get-new-fill-pointer array array-size
 890                                                        fill-pointer)
 891                                  0 dimensions nil nil)
 892                    (if (array-header-p array)
 893                        ;; simple multidimensional or single dimensional array
 894                        (make-array dimensions
 895                                    :element-type element-type
 896                                    :initial-contents initial-contents)
 897                        array-data))))
 898             (displaced-to
 899              ;; We already established that no INITIAL-CONTENTS was supplied.
 900              (when initial-element
 901                (error "The :INITIAL-ELEMENT option may not be specified ~
 902                        with :DISPLACED-TO."))
 903              (unless (subtypep element-type (array-element-type displaced-to))
 904                (error "can't displace an array of type ~S into another of ~
 905                        type ~S"
 906                       element-type (array-element-type displaced-to)))
 907              (let ((displacement (or displaced-index-offset 0))
 908                    (array-size (apply #'* dimensions)))
 909                (declare (fixnum displacement array-size))
 910                (if (< (the fixnum (array-total-size displaced-to))
 911                       (the fixnum (+ displacement array-size)))
 912                    (error "The :DISPLACED-TO array is too small."))
 913                (if (adjustable-array-p array)
 914                    ;; None of the original contents appear in adjusted array.
 915                    (set-array-header array displaced-to array-size
 916                                      (get-new-fill-pointer array array-size
 917                                                            fill-pointer)
 918                                      displacement dimensions t nil)
 919                    ;; simple multidimensional or single dimensional array
 920                    (make-array dimensions
 921                                :element-type element-type
 922                                :displaced-to displaced-to
 923                                :displaced-index-offset
 924                                displaced-index-offset))))
 925             ((= array-rank 1)
 926              (let ((old-length (array-total-size array))
 927                    (new-length (car dimensions))
 928                    new-data)
 929                (declare (fixnum old-length new-length))
 930                (with-array-data ((old-data array) (old-start)
 931                                  (old-end old-length))
 932                  (cond ((or (and (array-header-p array)
 933                                  (%array-displaced-p array))
 934                             (< old-length new-length))
 935                         (setf new-data
 936                               (data-vector-from-inits
 937                                dimensions new-length element-type
 938                                initial-contents initial-contents-p
 939                                initial-element initial-element-p))
 940                         (replace new-data old-data
 941                                  :start2 old-start :end2 old-end))
 942                        (t (setf new-data
 943                                 (shrink-vector old-data new-length))))
 944                  (if (adjustable-array-p array)
 945                      (set-array-header array new-data new-length
 946                                        (get-new-fill-pointer array new-length
 947                                                              fill-pointer)
 948                                        0 dimensions nil nil)
 949                      new-data))))
 950             (t
 951              (let ((old-length (%array-available-elements array))
 952                    (new-length (apply #'* dimensions)))
 953                (declare (fixnum old-length new-length))
 954                (with-array-data ((old-data array) (old-start)
 955                                  (old-end old-length))
 956                  (declare (ignore old-end))
 957                  (let ((new-data (if (or (and (array-header-p array)
 958                                               (%array-displaced-p array))
 959                                          (> new-length old-length))
 960                                      (data-vector-from-inits
 961                                       dimensions new-length
 962                                       element-type () nil
 963                                       initial-element initial-element-p)
 964                                      old-data)))
 965                    (if (or (zerop old-length) (zerop new-length))
 966                        (when initial-element-p (fill new-data initial-element))
 967                        (zap-array-data old-data (array-dimensions array)
 968                                        old-start
 969                                        new-data dimensions new-length
 970                                        element-type initial-element
 971                                        initial-element-p))
 972                    (if (adjustable-array-p array)
 973                        (set-array-header array new-data new-length
 974                                          nil 0 dimensions nil nil)
 975                        (let ((new-array
 976                               (make-array-header
 977                                sb!vm:simple-array-widetag array-rank)))
 978                          (set-array-header new-array new-data new-length
 979                                            nil 0 dimensions nil t)))))))))))
 980
 981
 982 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 983   (cond ((not fill-pointer)
 984          (when (array-has-fill-pointer-p old-array)
 985            (when (> (%array-fill-pointer old-array) new-array-size)
 986              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 987                      smaller than its fill pointer (~S)"
 988                     old-array new-array-size (fill-pointer old-array)))
 989            (%array-fill-pointer old-array)))
 990         ((not (array-has-fill-pointer-p old-array))
 991          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 992                  in ADJUST-ARRAY unless the array (~S) was originally ~
 993                  created with a fill pointer"
 994                 fill-pointer
 995                 old-array))
 996         ((numberp fill-pointer)
 997          (when (> fill-pointer new-array-size)
 998            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 999                    than the new length of the vector (~S)"
1000                   fill-pointer new-array-size))
1001          fill-pointer)
1002         ((eq fill-pointer t)
1003          new-array-size)
1004         (t
1005          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
1006                 fill-pointer))))
1007
1008 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1009 ;;; which must be less than or equal to its current length. This can
1010 ;;; be called on vectors without a fill pointer but it is extremely
1011 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1012 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1013 ;;; or multi-threading. Call it only on provably local vectors.
1014 (defun %shrink-vector (vector new-length)
1015   (declare (vector vector))
1016   (unless (array-header-p vector)
1017     (macrolet ((frob (name &rest things)
1018                  `(etypecase ,name
1019                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1020                     ,@(mapcar (lambda (thing)
1021                                 (destructuring-bind (type-spec fill-value)
1022                                     thing
1023                                   `(,type-spec
1024                                     (fill (truly-the ,type-spec ,name)
1025                                           ,fill-value
1026                                           :start new-length))))
1027                               things))))
1028       ;; Set the 'tail' of the vector to the appropriate type of zero,
1029       ;; "because in some cases we'll scavenge larger areas in one go,
1030       ;; like groups of pages that had triggered the write barrier, or
1031       ;; the whole static space" according to jsnell.
1032       #.`(frob vector
1033           ,@(map 'list
1034                  (lambda (saetp)
1035                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1036                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1037                               #!+sb-unicode
1038                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1039                           *default-init-char-form*
1040                           (sb!vm:saetp-initial-element-default saetp))))
1041                  (remove-if-not
1042                   #'sb!vm:saetp-specifier
1043                   sb!vm:*specialized-array-element-type-properties*)))))
1044   ;; Only arrays have fill-pointers, but vectors have their length
1045   ;; parameter in the same place.
1046   (setf (%array-fill-pointer vector) new-length)
1047   vector)
1048
1049 (defun shrink-vector (vector new-length)
1050   (declare (vector vector))
1051   (cond
1052     ((eq (length vector) new-length)
1053      vector)
1054     ((array-has-fill-pointer-p vector)
1055      (setf (%array-fill-pointer vector) new-length)
1056      vector)
1057     (t (subseq vector 0 new-length))))
1058
1059 ;;; BIG THREAD SAFETY NOTE
1060 ;;;
1061 ;;; ADJUST-ARRAY/SET-ARRAY-HEADER, and its callees are very
1062 ;;; thread unsafe. They are nonatomic, and can mess with parallel
1063 ;;; code using the same arrays.
1064 ;;;
1065 ;;; A likely seeming fix is an additional level of indirection:
1066 ;;; ARRAY-HEADER -> ARRAY-INFO -> ... where ARRAY-HEADER would
1067 ;;; hold nothing but the pointer to ARRAY-INFO, and ARRAY-INFO
1068 ;;; would hold everything ARRAY-HEADER now holds. This allows
1069 ;;; consing up a new ARRAY-INFO and replacing it atomically in
1070 ;;; the ARRAY-HEADER.
1071 ;;;
1072 ;;; %WALK-DISPLACED-ARRAY-BACKPOINTERS is an especially nasty
1073 ;;; one: not only is it needed extremely rarely, which makes
1074 ;;; any thread safety bugs involving it look like rare random
1075 ;;; corruption, but because it walks the chain *upwards*, which
1076 ;;; may violate user expectations.
1077
1078 (defun %save-displaced-array-backpointer (array data)
1079   (flet ((purge (pointers)
1080            (remove-if (lambda (value)
1081                         (or (not value) (eq array value)))
1082                       pointers
1083                       :key #'weak-pointer-value)))
1084     ;; Add backpointer to the new data vector if it has a header.
1085     (when (array-header-p data)
1086       (setf (%array-displaced-from data)
1087             (cons (make-weak-pointer array)
1088                   (purge (%array-displaced-from data)))))
1089     ;; Remove old backpointer, if any.
1090     (let ((old-data (%array-data-vector array)))
1091       (when (and (neq data old-data) (array-header-p old-data))
1092         (setf (%array-displaced-from old-data)
1093               (purge (%array-displaced-from old-data)))))))
1094
1095 (defun %walk-displaced-array-backpointers (array new-length)
1096   (dolist (p (%array-displaced-from array))
1097     (let ((from (weak-pointer-value p)))
1098       (when (and from (eq array (%array-data-vector from)))
1099         (let ((requires (+ (%array-available-elements from)
1100                            (%array-displacement from))))
1101           (unless (>= new-length requires)
1102             ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
1103             ;;
1104             ;;   "If A is displaced to B, the consequences are unspecified if B is
1105             ;;   adjusted in such a way that it no longer has enough elements to
1106             ;;   satisfy A.
1107             ;;
1108             ;; since we're hanging on a weak pointer here, we can't signal an
1109             ;; error right now: the array that we're looking at might be
1110             ;; garbage. Instead, we set all dimensions to zero so that next
1111             ;; safe access to the displaced array will trap. Additionally, we
1112             ;; save the original dimensions, so we can signal a more
1113             ;; understandable error when the time comes.
1114             (%walk-displaced-array-backpointers from 0)
1115             (setf (%array-fill-pointer from) 0
1116                   (%array-available-elements from) 0
1117                   (%array-displaced-p from) (array-dimensions array))
1118             (dotimes (i (%array-rank from))
1119               (setf (%array-dimension from i) 0))))))))
1120
1121 ;;; Fill in array header with the provided information, and return the array.
1122 (defun set-array-header (array data length fill-pointer displacement dimensions
1123                          displacedp newp)
1124   (if newp
1125       (setf (%array-displaced-from array) nil)
1126       (%walk-displaced-array-backpointers array length))
1127   (when displacedp
1128     (%save-displaced-array-backpointer array data))
1129   (setf (%array-data-vector array) data)
1130   (setf (%array-available-elements array) length)
1131   (cond (fill-pointer
1132          (setf (%array-fill-pointer array) fill-pointer)
1133          (setf (%array-fill-pointer-p array) t))
1134         (t
1135          (setf (%array-fill-pointer array) length)
1136          (setf (%array-fill-pointer-p array) nil)))
1137   (setf (%array-displacement array) displacement)
1138   (if (listp dimensions)
1139       (dotimes (axis (array-rank array))
1140         (declare (type index axis))
1141         (setf (%array-dimension array axis) (pop dimensions)))
1142       (setf (%array-dimension array 0) dimensions))
1143   (setf (%array-displaced-p array) displacedp)
1144   array)
1145
1146 ;;; User visible extension
1147 (declaim (ftype (function (array) (values (simple-array * (*)) &optional))
1148                 array-storage-vector))
1149 (defun array-storage-vector (array)
1150   "Returns the underlying storage vector of ARRAY, which must be a non-displaced array.
1151
1152 In SBCL, if ARRAY is a of type \(SIMPLE-ARRAY * \(*)), it is its own storage
1153 vector. Multidimensional arrays, arrays with fill pointers, and adjustable
1154 arrays have an underlying storage vector with the same ARRAY-ELEMENT-TYPE as
1155 ARRAY, which this function returns.
1156
1157 Important note: the underlying vector is an implementation detail. Even though
1158 this function exposes it, changes in the implementation may cause this
1159 function to be removed without further warning."
1160   ;; KLUDGE: Without TRULY-THE the system is not smart enough to figure out that
1161   ;; the return value is always of the known type.
1162   (truly-the (simple-array * (*))
1163              (if (array-header-p array)
1164                  (if (%array-displaced-p array)
1165                      (error "~S cannot be used with displaced arrays. Use ~S instead."
1166                             'array-storage-vector 'array-displacement)
1167                      (%array-data-vector array))
1168                  array)))
1169 \f
1170 ;;;; used by SORT
1171
1172 ;;; temporary vector for stable sorting vectors, allocated for each new thread
1173 (defvar *merge-sort-temp-vector* (vector))
1174 (declaim (simple-vector *merge-sort-temp-vector*))
1175
1176 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1177
1178 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1179 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1180 ;;; to length zero array in each new thread.
1181 ;;;
1182 ;;; DX is probably a bad idea, because a with a big array it would
1183 ;;; be fairly easy to blow the stack.
1184 (defvar *zap-array-data-temp* (vector))
1185 (declaim (simple-vector *zap-array-data-temp*))
1186
1187 (defun zap-array-data-temp (length initial-element initial-element-p)
1188   (declare (fixnum length))
1189   (let ((tmp *zap-array-data-temp*))
1190     (declare (simple-vector tmp))
1191     (cond ((> length (length tmp))
1192            (setf *zap-array-data-temp*
1193                  (if initial-element-p
1194                      (make-array length :initial-element initial-element)
1195                      (make-array length))))
1196           (initial-element-p
1197            (fill tmp initial-element :end length))
1198           (t
1199            tmp))))
1200
1201 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1202 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1203 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1204 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1205 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1206                        element-type initial-element initial-element-p)
1207   (declare (list old-dims new-dims))
1208   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1209   ;; at least in SBCL.
1210   ;; NEW-DIMS comes from the user.
1211   (setf old-dims (nreverse old-dims)
1212         new-dims (reverse new-dims))
1213   (cond ((eq old-data new-data)
1214          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1215          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1216          ;; EQ; in this case, a temporary must be used and filled
1217          ;; appropriately. specified initial-element.
1218          (when initial-element-p
1219            ;; FIXME: transforming this TYPEP to someting a bit faster
1220            ;; would be a win...
1221            (unless (typep initial-element element-type)
1222              (error "~S can't be used to initialize an array of type ~S."
1223                     initial-element element-type)))
1224          (let ((temp (zap-array-data-temp new-length
1225                                           initial-element initial-element-p)))
1226            (declare (simple-vector temp))
1227            (zap-array-data-aux old-data old-dims offset temp new-dims)
1228            (dotimes (i new-length)
1229              (setf (aref new-data i) (aref temp i)
1230                    ;; zero out any garbage right away
1231                    (aref temp i) 0))))
1232         (t
1233          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1234          ;; already been filled with any
1235          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1236
1237 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1238   (declare (fixnum offset))
1239   (let ((limits (mapcar (lambda (x y)
1240                           (declare (fixnum x y))
1241                           (1- (the fixnum (min x y))))
1242                         old-dims new-dims)))
1243     (macrolet ((bump-index-list (index limits)
1244                  `(do ((subscripts ,index (cdr subscripts))
1245                        (limits ,limits (cdr limits)))
1246                       ((null subscripts) :eof)
1247                     (cond ((< (the fixnum (car subscripts))
1248                               (the fixnum (car limits)))
1249                            (rplaca subscripts
1250                                    (1+ (the fixnum (car subscripts))))
1251                            (return ,index))
1252                           (t (rplaca subscripts 0))))))
1253       (do ((index (make-list (length old-dims) :initial-element 0)
1254                   (bump-index-list index limits)))
1255           ((eq index :eof))
1256         (setf (aref new-data (row-major-index-from-dims index new-dims))
1257               (aref old-data
1258                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1259                        offset)))))))
1260
1261 ;;; Figure out the row-major-order index of an array reference from a
1262 ;;; list of subscripts and a list of dimensions. This is for internal
1263 ;;; calls only, and the subscripts and dim-list variables are assumed
1264 ;;; to be reversed from what the user supplied.
1265 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1266   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1267        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1268        (chunk-size 1)
1269        (result 0))
1270       ((null rev-dim-list) result)
1271     (declare (fixnum chunk-size result))
1272     (setq result (+ result
1273                     (the fixnum (* (the fixnum (car rev-subscripts))
1274                                    chunk-size))))
1275     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1276 \f
1277 ;;;; some bit stuff
1278
1279 (defun bit-array-same-dimensions-p (array1 array2)
1280   (declare (type (array bit) array1 array2))
1281   (and (= (array-rank array1)
1282           (array-rank array2))
1283        (dotimes (index (array-rank array1) t)
1284          (when (/= (array-dimension array1 index)
1285                    (array-dimension array2 index))
1286            (return nil)))))
1287
1288 (defun pick-result-array (result-bit-array bit-array-1)
1289   (case result-bit-array
1290     ((t) bit-array-1)
1291     ((nil) (make-array (array-dimensions bit-array-1)
1292                        :element-type 'bit
1293                        :initial-element 0))
1294     (t
1295      (unless (bit-array-same-dimensions-p bit-array-1
1296                                           result-bit-array)
1297        (error "~S and ~S don't have the same dimensions."
1298               bit-array-1 result-bit-array))
1299      result-bit-array)))
1300
1301 (defmacro def-bit-array-op (name function)
1302   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1303      #!+sb-doc
1304      ,(format nil
1305               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1306                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1307                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1308                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1309                All the arrays must have the same rank and dimensions."
1310               (symbol-name function))
1311      (declare (type (array bit) bit-array-1 bit-array-2)
1312               (type (or (array bit) (member t nil)) result-bit-array))
1313      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1314        (error "~S and ~S don't have the same dimensions."
1315               bit-array-1 bit-array-2))
1316      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1317        (if (and (simple-bit-vector-p bit-array-1)
1318                 (simple-bit-vector-p bit-array-2)
1319                 (simple-bit-vector-p result-bit-array))
1320            (locally (declare (optimize (speed 3) (safety 0)))
1321              (,name bit-array-1 bit-array-2 result-bit-array))
1322            (with-array-data ((data1 bit-array-1) (start1) (end1))
1323              (declare (ignore end1))
1324              (with-array-data ((data2 bit-array-2) (start2) (end2))
1325                (declare (ignore end2))
1326                (with-array-data ((data3 result-bit-array) (start3) (end3))
1327                  (do ((index-1 start1 (1+ index-1))
1328                       (index-2 start2 (1+ index-2))
1329                       (index-3 start3 (1+ index-3)))
1330                      ((>= index-3 end3) result-bit-array)
1331                    (declare (type index index-1 index-2 index-3))
1332                    (setf (sbit data3 index-3)
1333                          (logand (,function (sbit data1 index-1)
1334                                             (sbit data2 index-2))
1335                                  1))))))))))
1336
1337 (def-bit-array-op bit-and logand)
1338 (def-bit-array-op bit-ior logior)
1339 (def-bit-array-op bit-xor logxor)
1340 (def-bit-array-op bit-eqv logeqv)
1341 (def-bit-array-op bit-nand lognand)
1342 (def-bit-array-op bit-nor lognor)
1343 (def-bit-array-op bit-andc1 logandc1)
1344 (def-bit-array-op bit-andc2 logandc2)
1345 (def-bit-array-op bit-orc1 logorc1)
1346 (def-bit-array-op bit-orc2 logorc2)
1347
1348 (defun bit-not (bit-array &optional result-bit-array)
1349   #!+sb-doc
1350   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1351   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1352   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1353   created. Both arrays must have the same rank and dimensions."
1354   (declare (type (array bit) bit-array)
1355            (type (or (array bit) (member t nil)) result-bit-array))
1356   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1357     (if (and (simple-bit-vector-p bit-array)
1358              (simple-bit-vector-p result-bit-array))
1359         (locally (declare (optimize (speed 3) (safety 0)))
1360           (bit-not bit-array result-bit-array))
1361         (with-array-data ((src bit-array) (src-start) (src-end))
1362           (declare (ignore src-end))
1363           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1364             (do ((src-index src-start (1+ src-index))
1365                  (dst-index dst-start (1+ dst-index)))
1366                 ((>= dst-index dst-end) result-bit-array)
1367               (declare (type index src-index dst-index))
1368               (setf (sbit dst dst-index)
1369                     (logxor (sbit src src-index) 1))))))))