src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data (array start end)
  50   (%with-array-data-macro array start end :fail-inline? t))
  51
  52 (defun %data-vector-and-index (array index)
  53   (if (array-header-p array)
  54       (%with-array-data array index nil)
  55       (values array index)))
  56
  57 ;;; It'd waste space to expand copies of error handling in every
  58 ;;; inline %WITH-ARRAY-DATA, so we have them call this function
  59 ;;; instead. This is just a wrapper which is known never to return.
  60 (defun failed-%with-array-data (array start end)
  61   (declare (notinline %with-array-data))
  62   (%with-array-data array start end)
  63   (bug "called FAILED-%WITH-ARRAY-DATA with valid array parameters?"))
  64 \f
  65 ;;;; MAKE-ARRAY
  66 (defun upgraded-array-element-type (spec &optional environment)
  67   #!+sb-doc
  68   "Return the element type that will actually be used to implement an array
  69    with the specifier :ELEMENT-TYPE Spec."
  70   (declare (ignore environment))
  71   (if (unknown-type-p (specifier-type spec))
  72       (error "undefined type: ~S" spec)
  73       (type-specifier (array-type-specialized-element-type
  74                        (specifier-type `(array ,spec))))))
  75 (eval-when (:compile-toplevel :execute)
  76   (sb!xc:defmacro pick-vector-type (type &rest specs)
  77     `(cond ,@(mapcar (lambda (spec)
  78                        `(,(if (eq (car spec) t)
  79                               t
  80                               `(subtypep ,type ',(car spec)))
  81                          ,@(cdr spec)))
  82                      specs))))
  83
  84 ;;; These functions are used in the implementation of MAKE-ARRAY for
  85 ;;; complex arrays. There are lots of transforms to simplify
  86 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  87 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  88 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  89 ;;; making this somewhat efficient, at least not doing full calls to
  90 ;;; SUBTYPEP in the easy cases.
  91 (defun %vector-widetag-and-n-bits (type)
  92   (case type
  93     ;; Pick off some easy common cases.
  94     ;;
  95     ;; (Perhaps we should make a much more exhaustive table of easy
  96     ;; common cases here. Or perhaps the effort would be better spent
  97     ;; on smarter compiler transforms which do the calculation once
  98     ;; and for all in any reasonable user programs.)
  99     ((t)
 100      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
 101     ((character base-char standard-char)
 102      (values #.sb!vm:simple-string-widetag #.sb!vm:n-byte-bits))
 103     ((bit)
 104      (values #.sb!vm:simple-bit-vector-widetag 1))
 105     ;; OK, we have to wade into SUBTYPEPing after all.
 106     (t
 107      ;; FIXME: The data here are redundant with
 108      ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 109      (pick-vector-type type
 110        (base-char (values #.sb!vm:simple-string-widetag #.sb!vm:n-byte-bits))
 111        (bit (values #.sb!vm:simple-bit-vector-widetag 1))
 112        ((unsigned-byte 2)
 113         (values #.sb!vm:simple-array-unsigned-byte-2-widetag 2))
 114        ((unsigned-byte 4)
 115         (values #.sb!vm:simple-array-unsigned-byte-4-widetag 4))
 116        ((unsigned-byte 8)
 117         (values #.sb!vm:simple-array-unsigned-byte-8-widetag 8))
 118        ((unsigned-byte 16)
 119         (values #.sb!vm:simple-array-unsigned-byte-16-widetag 16))
 120        ((unsigned-byte 32)
 121         (values #.sb!vm:simple-array-unsigned-byte-32-widetag 32))
 122        ((signed-byte 8)
 123         (values #.sb!vm:simple-array-signed-byte-8-widetag 8))
 124        ((signed-byte 16)
 125         (values #.sb!vm:simple-array-signed-byte-16-widetag 16))
 126        ((signed-byte 30)
 127         (values #.sb!vm:simple-array-signed-byte-30-widetag 32))
 128        ((signed-byte 32)
 129         (values #.sb!vm:simple-array-signed-byte-32-widetag 32))
 130        (single-float (values #.sb!vm:simple-array-single-float-widetag 32))
 131        (double-float (values #.sb!vm:simple-array-double-float-widetag 64))
 132        #!+long-float
 133        (long-float
 134         (values #.sb!vm:simple-array-long-float-widetag
 135                 #!+x86 96 #!+sparc 128))
 136        ((complex single-float)
 137         (values #.sb!vm:simple-array-complex-single-float-widetag 64))
 138        ((complex double-float)
 139         (values #.sb!vm:simple-array-complex-double-float-widetag 128))
 140        #!+long-float
 141        ((complex long-float)
 142         (values #.sb!vm:simple-array-complex-long-float-widetag
 143                 #!+x86 192
 144                 #!+sparc 256))
 145        (t (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))))))
 146 (defun %complex-vector-widetag (type)
 147   (case type
 148     ;; Pick off some easy common cases.
 149     ((t)
 150      #.sb!vm:complex-vector-widetag)
 151     ((character base-char)
 152      #.sb!vm:complex-string-widetag)
 153     ((bit)
 154      #.sb!vm:complex-bit-vector-widetag)
 155     ;; OK, we have to wade into SUBTYPEPing after all.
 156     (t
 157      (pick-vector-type type
 158        (base-char #.sb!vm:complex-string-widetag)
 159        (bit #.sb!vm:complex-bit-vector-widetag)
 160        (t #.sb!vm:complex-vector-widetag)))))
 161
 162 (defun make-array (dimensions &key
 163                               (element-type t)
 164                               (initial-element nil initial-element-p)
 165                               initial-contents adjustable fill-pointer
 166                               displaced-to displaced-index-offset)
 167   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 168          (array-rank (length (the list dimensions)))
 169          (simple (and (null fill-pointer)
 170                       (not adjustable)
 171                       (null displaced-to))))
 172     (declare (fixnum array-rank))
 173     (when (and displaced-index-offset (null displaced-to))
 174       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 175     (if (and simple (= array-rank 1))
 176         ;; Its a (simple-array * (*))
 177         (multiple-value-bind (type n-bits)
 178             (%vector-widetag-and-n-bits element-type)
 179           (declare (type (unsigned-byte 8) type)
 180                    (type (integer 1 256) n-bits))
 181           (let* ((length (car dimensions))
 182                  (array (allocate-vector
 183                          type
 184                          length
 185                          (ceiling (* (if (= type sb!vm:simple-string-widetag)
 186                                          (1+ length)
 187                                          length)
 188                                      n-bits)
 189                                   sb!vm:n-word-bits))))
 190             (declare (type index length))
 191             (when initial-element-p
 192               (fill array initial-element))
 193             (when initial-contents
 194               (when initial-element
 195                 (error "can't specify both :INITIAL-ELEMENT and ~
 196                 :INITIAL-CONTENTS"))
 197               (unless (= length (length initial-contents))
 198                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 199                        the vector length is ~W."
 200                        (length initial-contents)
 201                        length))
 202               (replace array initial-contents))
 203             array))
 204         ;; It's either a complex array or a multidimensional array.
 205         (let* ((total-size (reduce #'* dimensions))
 206                (data (or displaced-to
 207                          (data-vector-from-inits
 208                           dimensions total-size element-type
 209                           initial-contents initial-element initial-element-p)))
 210                (array (make-array-header
 211                        (cond ((= array-rank 1)
 212                               (%complex-vector-widetag element-type))
 213                              (simple sb!vm:simple-array-widetag)
 214                              (t sb!vm:complex-array-widetag))
 215                        array-rank)))
 216           (cond (fill-pointer
 217                  (unless (= array-rank 1)
 218                    (error "Only vectors can have fill pointers."))
 219                  (let ((length (car dimensions)))
 220                    (declare (fixnum length))
 221                    (setf (%array-fill-pointer array)
 222                      (cond ((eq fill-pointer t)
 223                             length)
 224                            (t
 225                             (unless (and (fixnump fill-pointer)
 226                                          (>= fill-pointer 0)
 227                                          (<= fill-pointer length))
 228                               ;; FIXME: should be TYPE-ERROR?
 229                               (error "invalid fill-pointer ~W"
 230                                      fill-pointer))
 231                             fill-pointer))))
 232                  (setf (%array-fill-pointer-p array) t))
 233                 (t
 234                  (setf (%array-fill-pointer array) total-size)
 235                  (setf (%array-fill-pointer-p array) nil)))
 236           (setf (%array-available-elements array) total-size)
 237           (setf (%array-data-vector array) data)
 238           (cond (displaced-to
 239                  (when (or initial-element-p initial-contents)
 240                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 241                    can be specified along with :DISPLACED-TO"))
 242                  (let ((offset (or displaced-index-offset 0)))
 243                    (when (> (+ offset total-size)
 244                             (array-total-size displaced-to))
 245                      (error "~S doesn't have enough elements." displaced-to))
 246                    (setf (%array-displacement array) offset)
 247                    (setf (%array-displaced-p array) t)))
 248                 (t
 249                  (setf (%array-displaced-p array) nil)))
 250           (let ((axis 0))
 251             (dolist (dim dimensions)
 252               (setf (%array-dimension array axis) dim)
 253               (incf axis)))
 254           array))))
 255
 256 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 257 ;;; specified array characteristics. Dimensions is only used to pass
 258 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 259 ;;; initial-contents.
 260 (defun data-vector-from-inits (dimensions total-size element-type
 261                                initial-contents initial-element
 262                                initial-element-p)
 263   (when (and initial-contents initial-element-p)
 264     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 265             either MAKE-ARRAY or ADJUST-ARRAY."))
 266   (let ((data (if initial-element-p
 267                   (make-array total-size
 268                               :element-type element-type
 269                               :initial-element initial-element)
 270                   (make-array total-size
 271                               :element-type element-type))))
 272     (cond (initial-element-p
 273            (unless (simple-vector-p data)
 274              (unless (typep initial-element element-type)
 275                (error "~S cannot be used to initialize an array of type ~S."
 276                       initial-element element-type))
 277              (fill (the vector data) initial-element)))
 278           (initial-contents
 279            (fill-data-vector data dimensions initial-contents)))
 280     data))
 281
 282 (defun fill-data-vector (vector dimensions initial-contents)
 283   (let ((index 0))
 284     (labels ((frob (axis dims contents)
 285                (cond ((null dims)
 286                       (setf (aref vector index) contents)
 287                       (incf index))
 288                      (t
 289                       (unless (typep contents 'sequence)
 290                         (error "malformed :INITIAL-CONTENTS: ~S is not a ~
 291                                 sequence, but ~W more layer~:P needed."
 292                                contents
 293                                (- (length dimensions) axis)))
 294                       (unless (= (length contents) (car dims))
 295                         (error "malformed :INITIAL-CONTENTS: Dimension of ~
 296                                 axis ~W is ~W, but ~S is ~W long."
 297                                axis (car dims) contents (length contents)))
 298                       (if (listp contents)
 299                           (dolist (content contents)
 300                             (frob (1+ axis) (cdr dims) content))
 301                           (dotimes (i (length contents))
 302                             (frob (1+ axis) (cdr dims) (aref contents i))))))))
 303       (frob 0 dimensions initial-contents))))
 304
 305 (defun vector (&rest objects)
 306   #!+sb-doc
 307   "Construct a SIMPLE-VECTOR from the given objects."
 308   (coerce (the list objects) 'simple-vector))
 309 \f
 310 ;;;; accessor/setter functions
 311
 312 (eval-when (:compile-toplevel :execute)
 313   (defparameter *specialized-array-element-types*
 314     '(t
 315       character
 316       bit
 317       (unsigned-byte 2)
 318       (unsigned-byte 4)
 319       (unsigned-byte 8)
 320       (unsigned-byte 16)
 321       (unsigned-byte 32)
 322       (signed-byte 8)
 323       (signed-byte 16)
 324       (signed-byte 30)
 325       (signed-byte 32)
 326       single-float
 327       double-float
 328       #!+long-float long-float
 329       (complex single-float)
 330       (complex double-float)
 331       #!+long-float (complex long-float))))
 332
 333 (defun hairy-data-vector-ref (array index)
 334   (with-array-data ((vector array) (index index) (end))
 335     (declare (ignore end))
 336     (etypecase vector .
 337                #.(mapcar (lambda (type)
 338                            (let ((atype `(simple-array ,type (*))))
 339                              `(,atype
 340                                (data-vector-ref (the ,atype vector)
 341                                                 index))))
 342                          *specialized-array-element-types*))))
 343
 344 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 345 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 346 ;;; definition is needed for the compiler to use in constant folding.)
 347 (defun data-vector-ref (array index)
 348   (hairy-data-vector-ref array index))
 349
 350 (defun hairy-data-vector-set (array index new-value)
 351   (with-array-data ((vector array) (index index) (end))
 352     (declare (ignore end))
 353     (etypecase vector .
 354                #.(mapcar (lambda (type)
 355                            (let ((atype `(simple-array ,type (*))))
 356                              `(,atype
 357                                (data-vector-set (the ,atype vector)
 358                                                 index
 359                                                 (the ,type
 360                                                   new-value))
 361                                ;; For specialized arrays, the return
 362                                ;; from data-vector-set would have to
 363                                ;; be reboxed to be a (Lisp) return
 364                                ;; value; instead, we use the
 365                                ;; already-boxed value as the return.
 366                                new-value)))
 367                          *specialized-array-element-types*))))
 368
 369 (defun %array-row-major-index (array subscripts
 370                                      &optional (invalid-index-error-p t))
 371   (declare (array array)
 372            (list subscripts))
 373   (let ((rank (array-rank array)))
 374     (unless (= rank (length subscripts))
 375       (error "wrong number of subscripts, ~W, for array of rank ~W"
 376              (length subscripts) rank))
 377     (if (array-header-p array)
 378         (do ((subs (nreverse subscripts) (cdr subs))
 379              (axis (1- (array-rank array)) (1- axis))
 380              (chunk-size 1)
 381              (result 0))
 382             ((null subs) result)
 383           (declare (list subs) (fixnum axis chunk-size result))
 384           (let ((index (car subs))
 385                 (dim (%array-dimension array axis)))
 386             (declare (fixnum dim))
 387             (unless (< -1 index dim)
 388               (if invalid-index-error-p
 389                   (error 'simple-type-error
 390                          :format-control "invalid index ~W~[~;~:; on axis ~:*~W~] in ~S"
 391                          :format-arguments (list index axis array)
 392                          :datum index
 393                          :expected-type `(integer 0 (,dim)))
 394                   (return-from %array-row-major-index nil)))
 395             (incf result (* chunk-size (the fixnum index)))
 396             (setf chunk-size (* chunk-size dim))))
 397         (let ((index (first subscripts))
 398               (length (length (the (simple-array * (*)) array))))
 399           (unless (< -1 index length)
 400             (if invalid-index-error-p
 401                 ;; FIXME: perhaps this should share a format-string
 402                 ;; with INVALID-ARRAY-INDEX-ERROR or
 403                 ;; INDEX-TOO-LARGE-ERROR?
 404                 (error 'simple-type-error
 405                        :format-control "invalid index ~W in ~S"
 406                        :format-arguments (list index array)
 407                        :datum index
 408                        :expected-type `(integer 0 (,length)))
 409                 (return-from %array-row-major-index nil)))
 410           index))))
 411
 412 (defun array-in-bounds-p (array &rest subscripts)
 413   #!+sb-doc
 414   "Return T if the Subscipts are in bounds for the Array, Nil otherwise."
 415   (if (%array-row-major-index array subscripts nil)
 416       t))
 417
 418 (defun array-row-major-index (array &rest subscripts)
 419   (%array-row-major-index array subscripts))
 420
 421 (defun aref (array &rest subscripts)
 422   #!+sb-doc
 423   "Return the element of the Array specified by the Subscripts."
 424   (row-major-aref array (%array-row-major-index array subscripts)))
 425
 426 (defun %aset (array &rest stuff)
 427   (let ((subscripts (butlast stuff))
 428         (new-value (car (last stuff))))
 429     (setf (row-major-aref array (%array-row-major-index array subscripts))
 430           new-value)))
 431
 432 ;;; FIXME: What's supposed to happen with functions
 433 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 434 ;;; DEFSETF FOO is also defined? It seems as though the logical
 435 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 436 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 437 ;;; just as for ordinary functions
 438 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 439 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 440 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 441 ;;;  ZOO
 442 ;;;  * (DEFUN ZOO (X) (* 3 X))
 443 ;;;  Warning: ZOO previously defined as a macro.
 444 ;;;  ZOO
 445 ;;; But that doesn't seem to be what happens in CMU CL.
 446 ;;;
 447 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 448 ;;; has a setf expansion and/or a setf function defined.
 449
 450 #!-sb-fluid (declaim (inline (setf aref)))
 451 (defun (setf aref) (new-value array &rest subscripts)
 452   (declare (type array array))
 453   (setf (row-major-aref array (%array-row-major-index array subscripts))
 454         new-value))
 455
 456 (defun row-major-aref (array index)
 457   #!+sb-doc
 458   "Return the element of array corressponding to the row-major index. This is
 459    SETF'able."
 460   (declare (optimize (safety 1)))
 461   (row-major-aref array index))
 462
 463 (defun %set-row-major-aref (array index new-value)
 464   (declare (optimize (safety 1)))
 465   (setf (row-major-aref array index) new-value))
 466
 467 (defun svref (simple-vector index)
 468   #!+sb-doc
 469   "Return the INDEX'th element of the given Simple-Vector."
 470   (declare (optimize (safety 1)))
 471   (aref simple-vector index))
 472
 473 (defun %svset (simple-vector index new)
 474   (declare (optimize (safety 1)))
 475   (setf (aref simple-vector index) new))
 476
 477 (defun bit (bit-array &rest subscripts)
 478   #!+sb-doc
 479   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 480   (declare (type (array bit) bit-array) (optimize (safety 1)))
 481   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 482
 483 (defun %bitset (bit-array &rest stuff)
 484   (declare (type (array bit) bit-array) (optimize (safety 1)))
 485   (let ((subscripts (butlast stuff))
 486         (new-value (car (last stuff))))
 487     (setf (row-major-aref bit-array
 488                           (%array-row-major-index bit-array subscripts))
 489           new-value)))
 490
 491 #!-sb-fluid (declaim (inline (setf bit)))
 492 (defun (setf bit) (new-value bit-array &rest subscripts)
 493   (declare (type (array bit) bit-array) (optimize (safety 1)))
 494   (setf (row-major-aref bit-array
 495                         (%array-row-major-index bit-array subscripts))
 496         new-value))
 497
 498 (defun sbit (simple-bit-array &rest subscripts)
 499   #!+sb-doc
 500   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 501   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 502   (row-major-aref simple-bit-array
 503                   (%array-row-major-index simple-bit-array subscripts)))
 504
 505 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 506 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 507 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 508 ;;; -- WHN 19990911
 509 (defun %sbitset (simple-bit-array &rest stuff)
 510   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 511   (let ((subscripts (butlast stuff))
 512         (new-value (car (last stuff))))
 513     (setf (row-major-aref simple-bit-array
 514                           (%array-row-major-index simple-bit-array subscripts))
 515           new-value)))
 516
 517 #!-sb-fluid (declaim (inline (setf sbit)))
 518 (defun (setf sbit) (new-value bit-array &rest subscripts)
 519   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 520   (setf (row-major-aref bit-array
 521                         (%array-row-major-index bit-array subscripts))
 522         new-value))
 523 \f
 524 ;;;; miscellaneous array properties
 525
 526 (defun array-element-type (array)
 527   #!+sb-doc
 528   "Return the type of the elements of the array"
 529   (let ((widetag (widetag-of array)))
 530     (macrolet ((pick-element-type (&rest stuff)
 531                  `(cond ,@(mapcar (lambda (stuff)
 532                                     (cons
 533                                      (let ((item (car stuff)))
 534                                        (cond ((eq item t)
 535                                               t)
 536                                              ((listp item)
 537                                               (cons 'or
 538                                                     (mapcar (lambda (x)
 539                                                               `(= widetag ,x))
 540                                                             item)))
 541                                              (t
 542                                               `(= widetag ,item))))
 543                                      (cdr stuff)))
 544                                   stuff))))
 545       ;; FIXME: The data here are redundant with
 546       ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 547       (pick-element-type
 548        ((sb!vm:simple-string-widetag sb!vm:complex-string-widetag) 'base-char)
 549        ((sb!vm:simple-bit-vector-widetag
 550          sb!vm:complex-bit-vector-widetag) 'bit)
 551        (sb!vm:simple-vector-widetag t)
 552        (sb!vm:simple-array-unsigned-byte-2-widetag '(unsigned-byte 2))
 553        (sb!vm:simple-array-unsigned-byte-4-widetag '(unsigned-byte 4))
 554        (sb!vm:simple-array-unsigned-byte-8-widetag '(unsigned-byte 8))
 555        (sb!vm:simple-array-unsigned-byte-16-widetag '(unsigned-byte 16))
 556        (sb!vm:simple-array-unsigned-byte-32-widetag '(unsigned-byte 32))
 557        (sb!vm:simple-array-signed-byte-8-widetag '(signed-byte 8))
 558        (sb!vm:simple-array-signed-byte-16-widetag '(signed-byte 16))
 559        (sb!vm:simple-array-signed-byte-30-widetag '(signed-byte 30))
 560        (sb!vm:simple-array-signed-byte-32-widetag '(signed-byte 32))
 561        (sb!vm:simple-array-single-float-widetag 'single-float)
 562        (sb!vm:simple-array-double-float-widetag 'double-float)
 563        #!+long-float
 564        (sb!vm:simple-array-long-float-widetag 'long-float)
 565        (sb!vm:simple-array-complex-single-float-widetag
 566         '(complex single-float))
 567        (sb!vm:simple-array-complex-double-float-widetag
 568         '(complex double-float))
 569        #!+long-float
 570        (sb!vm:simple-array-complex-long-float-widetag '(complex long-float))
 571        ((sb!vm:simple-array-widetag
 572          sb!vm:complex-vector-widetag
 573          sb!vm:complex-array-widetag)
 574         (with-array-data ((array array) (start) (end))
 575           (declare (ignore start end))
 576           (array-element-type array)))
 577        (t
 578         (error 'type-error :datum array :expected-type 'array))))))
 579
 580 (defun array-rank (array)
 581   #!+sb-doc
 582   "Return the number of dimensions of ARRAY."
 583   (if (array-header-p array)
 584       (%array-rank array)
 585       1))
 586
 587 (defun array-dimension (array axis-number)
 588   #!+sb-doc
 589   "Return the length of dimension AXIS-NUMBER of ARRAY."
 590   (declare (array array) (type index axis-number))
 591   (cond ((not (array-header-p array))
 592          (unless (= axis-number 0)
 593            (error "Vector axis is not zero: ~S" axis-number))
 594          (length (the (simple-array * (*)) array)))
 595         ((>= axis-number (%array-rank array))
 596          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 597                 axis-number array (%array-rank array)))
 598         (t
 599          (%array-dimension array axis-number))))
 600
 601 (defun array-dimensions (array)
 602   #!+sb-doc
 603   "Return a list whose elements are the dimensions of the array"
 604   (declare (array array))
 605   (if (array-header-p array)
 606       (do ((results nil (cons (array-dimension array index) results))
 607            (index (1- (array-rank array)) (1- index)))
 608           ((minusp index) results))
 609       (list (array-dimension array 0))))
 610
 611 (defun array-total-size (array)
 612   #!+sb-doc
 613   "Return the total number of elements in the Array."
 614   (declare (array array))
 615   (if (array-header-p array)
 616       (%array-available-elements array)
 617       (length (the vector array))))
 618
 619 (defun array-displacement (array)
 620   #!+sb-doc
 621   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 622    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 623   (declare (type array array))
 624   (if (and (array-header-p array) ; if unsimple and
 625            (%array-displaced-p array)) ; displaced
 626       (values (%array-data-vector array) (%array-displacement array))
 627       (values nil 0)))
 628
 629 (defun adjustable-array-p (array)
 630   #!+sb-doc
 631   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 632    to the argument, this happens for complex arrays."
 633   (declare (array array))
 634   (not (typep array 'simple-array)))
 635 \f
 636 ;;;; fill pointer frobbing stuff
 637
 638 (defun array-has-fill-pointer-p (array)
 639   #!+sb-doc
 640   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 641   (declare (array array))
 642   (and (array-header-p array) (%array-fill-pointer-p array)))
 643
 644 (defun fill-pointer (vector)
 645   #!+sb-doc
 646   "Return the FILL-POINTER of the given VECTOR."
 647   (declare (vector vector))
 648   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 649       (%array-fill-pointer vector)
 650       (error 'simple-type-error
 651              :datum vector
 652              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 653              :format-control "~S is not an array with a fill pointer."
 654              :format-arguments (list vector))))
 655
 656 (defun %set-fill-pointer (vector new)
 657   (declare (vector vector) (fixnum new))
 658   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 659       (if (> new (%array-available-elements vector))
 660         (error
 661          "The new fill pointer, ~S, is larger than the length of the vector."
 662          new)
 663         (setf (%array-fill-pointer vector) new))
 664       (error 'simple-type-error
 665              :datum vector
 666              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 667              :format-control "~S is not an array with a fill pointer."
 668              :format-arguments (list vector))))
 669
 670 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 671 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 672 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 673 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 674 ;;; back to CMU CL).
 675 (defun vector-push (new-el array)
 676   #!+sb-doc
 677   "Attempt to set the element of ARRAY designated by its fill pointer
 678    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 679    too large, NIL is returned, otherwise the index of the pushed element is
 680    returned."
 681   (declare (vector array))
 682   (let ((fill-pointer (fill-pointer array)))
 683     (declare (fixnum fill-pointer))
 684     (cond ((= fill-pointer (%array-available-elements array))
 685            nil)
 686           (t
 687            (setf (aref array fill-pointer) new-el)
 688            (setf (%array-fill-pointer array) (1+ fill-pointer))
 689            fill-pointer))))
 690
 691 (defun vector-push-extend (new-element
 692                            vector
 693                            &optional
 694                            (extension (1+ (length vector))))
 695   (declare (vector vector) (fixnum extension))
 696   (let ((fill-pointer (fill-pointer vector)))
 697     (declare (fixnum fill-pointer))
 698     (when (= fill-pointer (%array-available-elements vector))
 699       (adjust-array vector (+ fill-pointer extension)))
 700     (setf (aref vector fill-pointer) new-element)
 701     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 702     fill-pointer))
 703
 704 (defun vector-pop (array)
 705   #!+sb-doc
 706   "Decrease the fill pointer by 1 and return the element pointed to by the
 707   new fill pointer."
 708   (declare (vector array))
 709   (let ((fill-pointer (fill-pointer array)))
 710     (declare (fixnum fill-pointer))
 711     (if (zerop fill-pointer)
 712         (error "There is nothing left to pop.")
 713         (aref array
 714               (setf (%array-fill-pointer array)
 715                     (1- fill-pointer))))))
 716 \f
 717 ;;;; ADJUST-ARRAY
 718
 719 (defun adjust-array (array dimensions &key
 720                            (element-type (array-element-type array))
 721                            (initial-element nil initial-element-p)
 722                            initial-contents fill-pointer
 723                            displaced-to displaced-index-offset)
 724   #!+sb-doc
 725   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 726   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 727     (cond ((/= (the fixnum (length (the list dimensions)))
 728                (the fixnum (array-rank array)))
 729            (error "The number of dimensions not equal to rank of array."))
 730           ((not (subtypep element-type (array-element-type array)))
 731            (error "The new element type, ~S, is incompatible with old type."
 732                   element-type)))
 733     (let ((array-rank (length (the list dimensions))))
 734       (declare (fixnum array-rank))
 735       (when (and fill-pointer (> array-rank 1))
 736         (error "Multidimensional arrays can't have fill pointers."))
 737       (cond (initial-contents
 738              ;; array former contents replaced by INITIAL-CONTENTS
 739              (if (or initial-element-p displaced-to)
 740                  (error "INITIAL-CONTENTS may not be specified with ~
 741                  the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 742              (let* ((array-size (apply #'* dimensions))
 743                     (array-data (data-vector-from-inits
 744                                  dimensions array-size element-type
 745                                  initial-contents initial-element
 746                                  initial-element-p)))
 747                (if (adjustable-array-p array)
 748                    (set-array-header array array-data array-size
 749                                  (get-new-fill-pointer array array-size
 750                                                        fill-pointer)
 751                                  0 dimensions nil)
 752                    (if (array-header-p array)
 753                        ;; simple multidimensional or single dimensional array
 754                        (make-array dimensions
 755                                    :element-type element-type
 756                                    :initial-contents initial-contents)
 757                        array-data))))
 758             (displaced-to
 759              ;; We already established that no INITIAL-CONTENTS was supplied.
 760              (when initial-element
 761                (error "The :INITIAL-ELEMENT option may not be specified ~
 762                       with :DISPLACED-TO."))
 763              (unless (subtypep element-type (array-element-type displaced-to))
 764                (error "can't displace an array of type ~S into another of ~
 765                        type ~S"
 766                       element-type (array-element-type displaced-to)))
 767              (let ((displacement (or displaced-index-offset 0))
 768                    (array-size (apply #'* dimensions)))
 769                (declare (fixnum displacement array-size))
 770                (if (< (the fixnum (array-total-size displaced-to))
 771                       (the fixnum (+ displacement array-size)))
 772                    (error "The :DISPLACED-TO array is too small."))
 773                (if (adjustable-array-p array)
 774                    ;; None of the original contents appear in adjusted array.
 775                    (set-array-header array displaced-to array-size
 776                                      (get-new-fill-pointer array array-size
 777                                                            fill-pointer)
 778                                      displacement dimensions t)
 779                    ;; simple multidimensional or single dimensional array
 780                    (make-array dimensions
 781                                :element-type element-type
 782                                :displaced-to displaced-to
 783                                :displaced-index-offset
 784                                displaced-index-offset))))
 785             ((= array-rank 1)
 786              (let ((old-length (array-total-size array))
 787                    (new-length (car dimensions))
 788                    new-data)
 789                (declare (fixnum old-length new-length))
 790                (with-array-data ((old-data array) (old-start)
 791                                  (old-end old-length))
 792                  (cond ((or (%array-displaced-p array)
 793                             (< old-length new-length))
 794                         (setf new-data
 795                               (data-vector-from-inits
 796                                dimensions new-length element-type
 797                                initial-contents initial-element
 798                                initial-element-p))
 799                         (replace new-data old-data
 800                                  :start2 old-start :end2 old-end))
 801                        (t (setf new-data
 802                                 (shrink-vector old-data new-length))))
 803                  (if (adjustable-array-p array)
 804                      (set-array-header array new-data new-length
 805                                        (get-new-fill-pointer array new-length
 806                                                              fill-pointer)
 807                                        0 dimensions nil)
 808                      new-data))))
 809             (t
 810              (let ((old-length (%array-available-elements array))
 811                    (new-length (apply #'* dimensions)))
 812                (declare (fixnum old-length new-length))
 813                (with-array-data ((old-data array) (old-start)
 814                                  (old-end old-length))
 815                  (declare (ignore old-end))
 816                  (let ((new-data (if (or (%array-displaced-p array)
 817                                          (> new-length old-length))
 818                                      (data-vector-from-inits
 819                                       dimensions new-length
 820                                       element-type () initial-element
 821                                       initial-element-p)
 822                                      old-data)))
 823                    (if (or (zerop old-length) (zerop new-length))
 824                        (when initial-element-p (fill new-data initial-element))
 825                        (zap-array-data old-data (array-dimensions array)
 826                                        old-start
 827                                        new-data dimensions new-length
 828                                        element-type initial-element
 829                                        initial-element-p))
 830                    (set-array-header array new-data new-length
 831                                      new-length 0 dimensions nil)))))))))
 832
 833 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 834   (cond ((not fill-pointer)
 835          (when (array-has-fill-pointer-p old-array)
 836            (when (> (%array-fill-pointer old-array) new-array-size)
 837              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 838                     smaller than its fill pointer (~S)"
 839                     old-array new-array-size (fill-pointer old-array)))
 840            (%array-fill-pointer old-array)))
 841         ((not (array-has-fill-pointer-p old-array))
 842          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 843                 in ADJUST-ARRAY unless the array (~S) was originally ~
 844                 created with a fill pointer"
 845                 fill-pointer
 846                 old-array))
 847         ((numberp fill-pointer)
 848          (when (> fill-pointer new-array-size)
 849            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 850                   than the new length of the vector (~S)"
 851                   fill-pointer new-array-size))
 852          fill-pointer)
 853         ((eq fill-pointer t)
 854          new-array-size)
 855         (t
 856          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
 857                 fill-pointer))))
 858
 859 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
 860 ;;; which must be less than or equal to its current length.
 861 (defun shrink-vector (vector new-length)
 862   (declare (vector vector))
 863   (unless (array-header-p vector)
 864     (macrolet ((frob (name &rest things)
 865                  `(etypecase ,name
 866                     ,@(mapcar (lambda (thing)
 867                                 (destructuring-bind (type-spec fill-value)
 868                                     thing
 869                                   `(,type-spec
 870                                     (fill (truly-the ,type-spec ,name)
 871                                           ,fill-value
 872                                           :start new-length))))
 873                               things))))
 874       ;; FIXME: The associations between vector types and initial
 875       ;; values here are redundant with
 876       ;; *SPECIALIZED-ARRAY-ELEMENT-TYPE-PROPERTIES*.
 877       (frob vector
 878         (simple-vector 0)
 879         (simple-base-string #.*default-init-char-form*)
 880         (simple-bit-vector 0)
 881         ((simple-array (unsigned-byte 2) (*)) 0)
 882         ((simple-array (unsigned-byte 4) (*)) 0)
 883         ((simple-array (unsigned-byte 8) (*)) 0)
 884         ((simple-array (unsigned-byte 16) (*)) 0)
 885         ((simple-array (unsigned-byte 32) (*)) 0)
 886         ((simple-array (signed-byte 8) (*)) 0)
 887         ((simple-array (signed-byte 16) (*)) 0)
 888         ((simple-array (signed-byte 30) (*)) 0)
 889         ((simple-array (signed-byte 32) (*)) 0)
 890         ((simple-array single-float (*)) (coerce 0 'single-float))
 891         ((simple-array double-float (*)) (coerce 0 'double-float))
 892         #!+long-float
 893         ((simple-array long-float (*)) (coerce 0 'long-float))
 894         ((simple-array (complex single-float) (*))
 895          (coerce 0 '(complex single-float)))
 896         ((simple-array (complex double-float) (*))
 897          (coerce 0 '(complex double-float)))
 898         #!+long-float
 899         ((simple-array (complex long-float) (*))
 900          (coerce 0 '(complex long-float))))))
 901   ;; Only arrays have fill-pointers, but vectors have their length
 902   ;; parameter in the same place.
 903   (setf (%array-fill-pointer vector) new-length)
 904   vector)
 905
 906 ;;; Fill in array header with the provided information, and return the array.
 907 (defun set-array-header (array data length fill-pointer displacement dimensions
 908                          &optional displacedp)
 909   (setf (%array-data-vector array) data)
 910   (setf (%array-available-elements array) length)
 911   (cond (fill-pointer
 912          (setf (%array-fill-pointer array) fill-pointer)
 913          (setf (%array-fill-pointer-p array) t))
 914         (t
 915          (setf (%array-fill-pointer array) length)
 916          (setf (%array-fill-pointer-p array) nil)))
 917   (setf (%array-displacement array) displacement)
 918   (if (listp dimensions)
 919       (dotimes (axis (array-rank array))
 920         (declare (type index axis))
 921         (setf (%array-dimension array axis) (pop dimensions)))
 922       (setf (%array-dimension array 0) dimensions))
 923   (setf (%array-displaced-p array) displacedp)
 924   array)
 925 \f
 926 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
 927
 928 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
 929 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice.
 930 (defvar *zap-array-data-temp* (make-array 1000 :initial-element t))
 931
 932 (defun zap-array-data-temp (length element-type initial-element
 933                             initial-element-p)
 934   (declare (fixnum length))
 935   (when (> length (the fixnum (length *zap-array-data-temp*)))
 936     (setf *zap-array-data-temp*
 937           (make-array length :initial-element t)))
 938   (when initial-element-p
 939     (unless (typep initial-element element-type)
 940       (error "~S can't be used to initialize an array of type ~S."
 941              initial-element element-type))
 942     (fill (the simple-vector *zap-array-data-temp*) initial-element
 943           :end length))
 944   *zap-array-data-temp*)
 945
 946 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
 947 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
 948 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
 949 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
 950 ;;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and INITIAL-ELEMENT-P
 951 ;;; are used when OLD-DATA and NEW-DATA are EQ; in this case, a
 952 ;;; temporary must be used and filled appropriately. When OLD-DATA and
 953 ;;; NEW-DATA are not EQ, NEW-DATA has already been filled with any
 954 ;;; specified initial-element.
 955 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
 956                        element-type initial-element initial-element-p)
 957   (declare (list old-dims new-dims))
 958   (setq old-dims (nreverse old-dims))
 959   (setq new-dims (reverse new-dims))
 960   (if (eq old-data new-data)
 961       (let ((temp (zap-array-data-temp new-length element-type
 962                                        initial-element initial-element-p)))
 963         (zap-array-data-aux old-data old-dims offset temp new-dims)
 964         (dotimes (i new-length) (setf (aref new-data i) (aref temp i))))
 965       (zap-array-data-aux old-data old-dims offset new-data new-dims)))
 966
 967 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
 968   (declare (fixnum offset))
 969   (let ((limits (mapcar (lambda (x y)
 970                           (declare (fixnum x y))
 971                           (1- (the fixnum (min x y))))
 972                         old-dims new-dims)))
 973     (macrolet ((bump-index-list (index limits)
 974                  `(do ((subscripts ,index (cdr subscripts))
 975                        (limits ,limits (cdr limits)))
 976                       ((null subscripts) nil)
 977                     (cond ((< (the fixnum (car subscripts))
 978                               (the fixnum (car limits)))
 979                            (rplaca subscripts
 980                                    (1+ (the fixnum (car subscripts))))
 981                            (return ,index))
 982                           (t (rplaca subscripts 0))))))
 983       (do ((index (make-list (length old-dims) :initial-element 0)
 984                   (bump-index-list index limits)))
 985           ((null index))
 986         (setf (aref new-data (row-major-index-from-dims index new-dims))
 987               (aref old-data
 988                     (+ (the fixnum (row-major-index-from-dims index old-dims))
 989                        offset)))))))
 990
 991 ;;; Figure out the row-major-order index of an array reference from a
 992 ;;; list of subscripts and a list of dimensions. This is for internal
 993 ;;; calls only, and the subscripts and dim-list variables are assumed
 994 ;;; to be reversed from what the user supplied.
 995 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
 996   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
 997        (rev-dim-list rev-dim-list (cdr rev-dim-list))
 998        (chunk-size 1)
 999        (result 0))
1000       ((null rev-dim-list) result)
1001     (declare (fixnum chunk-size result))
1002     (setq result (+ result
1003                     (the fixnum (* (the fixnum (car rev-subscripts))
1004                                    chunk-size))))
1005     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1006 \f
1007 ;;;; some bit stuff
1008
1009 (defun bit-array-same-dimensions-p (array1 array2)
1010   (declare (type (array bit) array1 array2))
1011   (and (= (array-rank array1)
1012           (array-rank array2))
1013        (dotimes (index (array-rank array1) t)
1014          (when (/= (array-dimension array1 index)
1015                    (array-dimension array2 index))
1016            (return nil)))))
1017
1018 (defun pick-result-array (result-bit-array bit-array-1)
1019   (case result-bit-array
1020     ((t) bit-array-1)
1021     ((nil) (make-array (array-dimensions bit-array-1)
1022                        :element-type 'bit
1023                        :initial-element 0))
1024     (t
1025      (unless (bit-array-same-dimensions-p bit-array-1
1026                                           result-bit-array)
1027        (error "~S and ~S don't have the same dimensions."
1028               bit-array-1 result-bit-array))
1029      result-bit-array)))
1030
1031 (defmacro def-bit-array-op (name function)
1032   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1033      ,(format nil
1034               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1035               BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1036               If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1037               RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1038               All the arrays must have the same rank and dimensions."
1039               (symbol-name function))
1040      (declare (type (array bit) bit-array-1 bit-array-2)
1041               (type (or (array bit) (member t nil)) result-bit-array))
1042      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1043        (error "~S and ~S don't have the same dimensions."
1044               bit-array-1 bit-array-2))
1045      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1046        (if (and (simple-bit-vector-p bit-array-1)
1047                 (simple-bit-vector-p bit-array-2)
1048                 (simple-bit-vector-p result-bit-array))
1049            (locally (declare (optimize (speed 3) (safety 0)))
1050              (,name bit-array-1 bit-array-2 result-bit-array))
1051            (with-array-data ((data1 bit-array-1) (start1) (end1))
1052              (declare (ignore end1))
1053              (with-array-data ((data2 bit-array-2) (start2) (end2))
1054                (declare (ignore end2))
1055                (with-array-data ((data3 result-bit-array) (start3) (end3))
1056                  (do ((index-1 start1 (1+ index-1))
1057                       (index-2 start2 (1+ index-2))
1058                       (index-3 start3 (1+ index-3)))
1059                      ((>= index-3 end3) result-bit-array)
1060                    (declare (type index index-1 index-2 index-3))
1061                    (setf (sbit data3 index-3)
1062                          (logand (,function (sbit data1 index-1)
1063                                             (sbit data2 index-2))
1064                                  1))))))))))
1065
1066 (def-bit-array-op bit-and logand)
1067 (def-bit-array-op bit-ior logior)
1068 (def-bit-array-op bit-xor logxor)
1069 (def-bit-array-op bit-eqv logeqv)
1070 (def-bit-array-op bit-nand lognand)
1071 (def-bit-array-op bit-nor lognor)
1072 (def-bit-array-op bit-andc1 logandc1)
1073 (def-bit-array-op bit-andc2 logandc2)
1074 (def-bit-array-op bit-orc1 logorc1)
1075 (def-bit-array-op bit-orc2 logorc2)
1076
1077 (defun bit-not (bit-array &optional result-bit-array)
1078   #!+sb-doc
1079   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1080   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1081   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1082   created. Both arrays must have the same rank and dimensions."
1083   (declare (type (array bit) bit-array)
1084            (type (or (array bit) (member t nil)) result-bit-array))
1085   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1086     (if (and (simple-bit-vector-p bit-array)
1087              (simple-bit-vector-p result-bit-array))
1088         (locally (declare (optimize (speed 3) (safety 0)))
1089           (bit-not bit-array result-bit-array))
1090         (with-array-data ((src bit-array) (src-start) (src-end))
1091           (declare (ignore src-end))
1092           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1093             (do ((src-index src-start (1+ src-index))
1094                  (dst-index dst-start (1+ dst-index)))
1095                 ((>= dst-index dst-end) result-bit-array)
1096               (declare (type index src-index dst-index))
1097               (setf (sbit dst dst-index)
1098                     (logxor (sbit src src-index) 1))))))))