src/code/array.lisp

   1 ;;;; functions to implement arrays
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid
  15 (declaim (inline fill-pointer array-has-fill-pointer-p adjustable-array-p
  16                  array-displacement))
  17 \f
  18 ;;;; miscellaneous accessor functions
  19
  20 ;;; These functions are only needed by the interpreter, 'cause the
  21 ;;; compiler inlines them.
  22 (macrolet ((def (name)
  23              `(progn
  24                 (defun ,name (array)
  25                   (,name array))
  26                 (defun (setf ,name) (value array)
  27                   (setf (,name array) value)))))
  28   (def %array-fill-pointer)
  29   (def %array-fill-pointer-p)
  30   (def %array-available-elements)
  31   (def %array-data-vector)
  32   (def %array-displacement)
  33   (def %array-displaced-p))
  34
  35 (defun %array-rank (array)
  36   (%array-rank array))
  37
  38 (defun %array-dimension (array axis)
  39   (%array-dimension array axis))
  40
  41 (defun %set-array-dimension (array axis value)
  42   (%set-array-dimension array axis value))
  43
  44 (defun %check-bound (array bound index)
  45   (declare (type index bound)
  46            (fixnum index))
  47   (%check-bound array bound index))
  48
  49 (defun %with-array-data (array start end)
  50   (%with-array-data-macro array start end :fail-inline? t))
  51
  52 (defun %data-vector-and-index (array index)
  53   (if (array-header-p array)
  54       (multiple-value-bind (vector index)
  55           (%with-array-data array index nil)
  56         (values vector index))
  57       (values array index)))
  58
  59 ;;; It'd waste space to expand copies of error handling in every
  60 ;;; inline %WITH-ARRAY-DATA, so we have them call this function
  61 ;;; instead. This is just a wrapper which is known never to return.
  62 (defun failed-%with-array-data (array start end)
  63   (declare (notinline %with-array-data))
  64   (%with-array-data array start end)
  65   (bug "called FAILED-%WITH-ARRAY-DATA with valid array parameters?"))
  66 \f
  67 ;;;; MAKE-ARRAY
  68 (eval-when (:compile-toplevel :execute)
  69   (sb!xc:defmacro pick-vector-type (type &rest specs)
  70     `(cond ,@(mapcar (lambda (spec)
  71                        `(,(if (eq (car spec) t)
  72                               t
  73                               `(subtypep ,type ',(car spec)))
  74                          ,@(cdr spec)))
  75                      specs))))
  76
  77 ;;; These functions are used in the implementation of MAKE-ARRAY for
  78 ;;; complex arrays. There are lots of transforms to simplify
  79 ;;; MAKE-ARRAY for various easy cases, but not for all reasonable
  80 ;;; cases, so e.g. as of sbcl-0.6.6 we still make full calls to
  81 ;;; MAKE-ARRAY for any non-simple array. Thus, there's some value to
  82 ;;; making this somewhat efficient, at least not doing full calls to
  83 ;;; SUBTYPEP in the easy cases.
  84 (defun %vector-widetag-and-n-bits (type)
  85   (case type
  86     ;; Pick off some easy common cases.
  87     ;;
  88     ;; (Perhaps we should make a much more exhaustive table of easy
  89     ;; common cases here. Or perhaps the effort would be better spent
  90     ;; on smarter compiler transforms which do the calculation once
  91     ;; and for all in any reasonable user programs.)
  92     ((t)
  93      (values #.sb!vm:simple-vector-widetag #.sb!vm:n-word-bits))
  94     ((base-char standard-char #!-sb-unicode character)
  95      (values #.sb!vm:simple-base-string-widetag #.sb!vm:n-byte-bits))
  96     #!+sb-unicode
  97     ((character)
  98      (values #.sb!vm:simple-character-string-widetag #.sb!vm:n-word-bits))
  99     ((bit)
 100      (values #.sb!vm:simple-bit-vector-widetag 1))
 101     ;; OK, we have to wade into SUBTYPEPing after all.
 102     (t
 103      #.`(pick-vector-type type
 104          ,@(map 'list
 105                 (lambda (saetp)
 106                   `(,(sb!vm:saetp-specifier saetp)
 107                     (values ,(sb!vm:saetp-typecode saetp)
 108                             ,(sb!vm:saetp-n-bits saetp))))
 109                 sb!vm:*specialized-array-element-type-properties*)))))
 110
 111 (defun %complex-vector-widetag (type)
 112   (case type
 113     ;; Pick off some easy common cases.
 114     ((t)
 115      #.sb!vm:complex-vector-widetag)
 116     ((base-char #!-sb-unicode character)
 117      #.sb!vm:complex-base-string-widetag)
 118     #!+sb-unicode
 119     ((character)
 120      #.sb!vm:complex-character-string-widetag)
 121     ((nil)
 122      #.sb!vm:complex-vector-nil-widetag)
 123     ((bit)
 124      #.sb!vm:complex-bit-vector-widetag)
 125     ;; OK, we have to wade into SUBTYPEPing after all.
 126     (t
 127      (pick-vector-type type
 128        (nil #.sb!vm:complex-vector-nil-widetag)
 129        #!-sb-unicode
 130        (character #.sb!vm:complex-base-string-widetag)
 131        #!+sb-unicode
 132        (base-char #.sb!vm:complex-base-string-widetag)
 133        #!+sb-unicode
 134        (character #.sb!vm:complex-character-string-widetag)
 135        (bit #.sb!vm:complex-bit-vector-widetag)
 136        (t #.sb!vm:complex-vector-widetag)))))
 137
 138 (defun make-array (dimensions &key
 139                               (element-type t)
 140                               (initial-element nil initial-element-p)
 141                               (initial-contents nil initial-contents-p)
 142                               adjustable fill-pointer
 143                               displaced-to displaced-index-offset)
 144   (let* ((dimensions (if (listp dimensions) dimensions (list dimensions)))
 145          (array-rank (length (the list dimensions)))
 146          (simple (and (null fill-pointer)
 147                       (not adjustable)
 148                       (null displaced-to))))
 149     (declare (fixnum array-rank))
 150     (when (and displaced-index-offset (null displaced-to))
 151       (error "can't specify :DISPLACED-INDEX-OFFSET without :DISPLACED-TO"))
 152     (when (and displaced-to
 153                (arrayp displaced-to)
 154                (not (equal (array-element-type displaced-to)
 155                            (upgraded-array-element-type element-type))))
 156       (error "Array element type of :DISPLACED-TO array does not match specified element type"))
 157     (if (and simple (= array-rank 1))
 158         ;; it's a (SIMPLE-ARRAY * (*))
 159         (multiple-value-bind (type n-bits)
 160             (%vector-widetag-and-n-bits element-type)
 161           (declare (type (unsigned-byte 8) type)
 162                    (type (integer 0 256) n-bits))
 163           (let* ((length (car dimensions))
 164                  (array (allocate-vector
 165                          type
 166                          length
 167                          (ceiling
 168                           (* (if (or (= type sb!vm:simple-base-string-widetag)
 169                                      #!+sb-unicode
 170                                      (= type
 171                                         sb!vm:simple-character-string-widetag))
 172                                  (1+ length)
 173                                  length)
 174                              n-bits)
 175                           sb!vm:n-word-bits))))
 176             (declare (type index length))
 177             (when initial-element-p
 178               (fill array initial-element))
 179             (when initial-contents-p
 180               (when initial-element-p
 181                 (error "can't specify both :INITIAL-ELEMENT and ~
 182                        :INITIAL-CONTENTS"))
 183               (unless (= length (length initial-contents))
 184                 (error "There are ~W elements in the :INITIAL-CONTENTS, but ~
 185                        the vector length is ~W."
 186                        (length initial-contents)
 187                        length))
 188               (replace array initial-contents))
 189             array))
 190         ;; it's either a complex array or a multidimensional array.
 191         (let* ((total-size (reduce #'* dimensions))
 192                (data (or displaced-to
 193                          (data-vector-from-inits
 194                           dimensions total-size element-type
 195                           initial-contents initial-contents-p
 196                           initial-element initial-element-p)))
 197                (array (make-array-header
 198                        (cond ((= array-rank 1)
 199                               (%complex-vector-widetag element-type))
 200                              (simple sb!vm:simple-array-widetag)
 201                              (t sb!vm:complex-array-widetag))
 202                        array-rank)))
 203           (cond (fill-pointer
 204                  (unless (= array-rank 1)
 205                    (error "Only vectors can have fill pointers."))
 206                  (let ((length (car dimensions)))
 207                    (declare (fixnum length))
 208                    (setf (%array-fill-pointer array)
 209                      (cond ((eq fill-pointer t)
 210                             length)
 211                            (t
 212                             (unless (and (fixnump fill-pointer)
 213                                          (>= fill-pointer 0)
 214                                          (<= fill-pointer length))
 215                               ;; FIXME: should be TYPE-ERROR?
 216                               (error "invalid fill-pointer ~W"
 217                                      fill-pointer))
 218                             fill-pointer))))
 219                  (setf (%array-fill-pointer-p array) t))
 220                 (t
 221                  (setf (%array-fill-pointer array) total-size)
 222                  (setf (%array-fill-pointer-p array) nil)))
 223           (setf (%array-available-elements array) total-size)
 224           (setf (%array-data-vector array) data)
 225           (cond (displaced-to
 226                  (when (or initial-element-p initial-contents-p)
 227                    (error "Neither :INITIAL-ELEMENT nor :INITIAL-CONTENTS ~
 228                    can be specified along with :DISPLACED-TO"))
 229                  (let ((offset (or displaced-index-offset 0)))
 230                    (when (> (+ offset total-size)
 231                             (array-total-size displaced-to))
 232                      (error "~S doesn't have enough elements." displaced-to))
 233                    (setf (%array-displacement array) offset)
 234                    (setf (%array-displaced-p array) t)))
 235                 (t
 236                  (setf (%array-displaced-p array) nil)))
 237           (let ((axis 0))
 238             (dolist (dim dimensions)
 239               (setf (%array-dimension array axis) dim)
 240               (incf axis)))
 241           array))))
 242
 243 (defun make-static-vector (length &key
 244                            (element-type '(unsigned-byte 8))
 245                            (initial-contents nil initial-contents-p)
 246                            (initial-element nil initial-element-p))
 247   "Allocate vector of LENGTH elements in static space. Only allocation
 248 of specialized arrays is supported."
 249   ;; STEP 1: check inputs fully
 250   ;;
 251   ;; This way of doing explicit checks before the vector is allocated
 252   ;; is expensive, but probably worth the trouble as once we've allocated
 253   ;; the vector we have no way to get rid of it anymore...
 254   (when (eq t (upgraded-array-element-type element-type))
 255     (error "Static arrays of type ~S not supported."
 256            element-type))
 257   (when initial-contents-p
 258     (when initial-element-p
 259       (error "can't specify both :INITIAL-ELEMENT and :INITIAL-CONTENTS"))
 260     (unless (= length (length initial-contents))
 261       (error "There are ~W elements in the :INITIAL-CONTENTS, but the ~
 262               vector length is ~W."
 263              (length initial-contents)
 264              length))
 265     (unless (every (lambda (x) (typep x element-type)) initial-contents)
 266       (error ":INITIAL-CONTENTS contains elements not of type ~S."
 267              element-type)))
 268   (when initial-element-p
 269     (unless (typep initial-element element-type)
 270       (error ":INITIAL-ELEMENT ~S is not of type ~S."
 271              initial-element element-type)))
 272   ;; STEP 2
 273   ;;
 274   ;; Allocate and possibly initialize the vector.
 275   (multiple-value-bind (type n-bits)
 276       (sb!impl::%vector-widetag-and-n-bits element-type)
 277     (let ((vector
 278            (allocate-static-vector type length
 279                                    (ceiling (* length n-bits)
 280                                             sb!vm:n-word-bits))))
 281       (cond (initial-element-p
 282              (fill vector initial-element))
 283             (initial-contents-p
 284              (replace vector initial-contents))
 285             (t
 286              vector)))))
 287
 288 ;;; DATA-VECTOR-FROM-INITS returns a simple vector that has the
 289 ;;; specified array characteristics. Dimensions is only used to pass
 290 ;;; to FILL-DATA-VECTOR for error checking on the structure of
 291 ;;; initial-contents.
 292 (defun data-vector-from-inits (dimensions total-size element-type
 293                                initial-contents initial-contents-p
 294                                initial-element initial-element-p)
 295   (when (and initial-contents-p initial-element-p)
 296     (error "cannot supply both :INITIAL-CONTENTS and :INITIAL-ELEMENT to
 297             either MAKE-ARRAY or ADJUST-ARRAY."))
 298   (let ((data (if initial-element-p
 299                   (make-array total-size
 300                               :element-type element-type
 301                               :initial-element initial-element)
 302                   (make-array total-size
 303                               :element-type element-type))))
 304     (cond (initial-element-p
 305            (unless (simple-vector-p data)
 306              (unless (typep initial-element element-type)
 307                (error "~S cannot be used to initialize an array of type ~S."
 308                       initial-element element-type))
 309              (fill (the vector data) initial-element)))
 310           (initial-contents-p
 311            (fill-data-vector data dimensions initial-contents)))
 312     data))
 313
 314 (defun vector (&rest objects)
 315   #!+sb-doc
 316   "Construct a SIMPLE-VECTOR from the given objects."
 317   (coerce (the list objects) 'simple-vector))
 318 \f
 319
 320 ;;;; accessor/setter functions
 321
 322 ;;; Dispatch to an optimized routine the data vector accessors for
 323 ;;; each different specialized vector type. Do dispatching by looking
 324 ;;; up the widetag in the array rather than with the typecases, which
 325 ;;; as of 1.0.5 compiles to a naive sequence of linear TYPEPs. Also
 326 ;;; provide separate versions where bounds checking has been moved
 327 ;;; from the callee to the caller, since it's much cheaper to do once
 328 ;;; the type information is available. Finally, for each of these
 329 ;;; routines also provide a slow path, taken for arrays that are not
 330 ;;; vectors or not simple.
 331 (macrolet ((%define (table-name extra-params)
 332              `(funcall
 333                (the function
 334                  (let ((tag 0)
 335                        (offset
 336                         #.(ecase sb!c:*backend-byte-order*
 337                             (:little-endian
 338                              (- sb!vm:other-pointer-lowtag))
 339                             (:big-endian
 340                              ;; I'm not completely sure of what this
 341                              ;; 3 represents symbolically. It's
 342                              ;; just what all the LOAD-TYPE vops
 343                              ;; are doing.
 344                              (- 3 sb!vm:other-pointer-lowtag)))))
 345                    ;; WIDETAG-OF needs extra code to handle
 346                    ;; LIST and FUNCTION lowtags. We're only
 347                    ;; dispatching on other pointers, so let's
 348                    ;; do the lowtag extraction manually.
 349                    (when (sb!vm::%other-pointer-p array)
 350                      (setf tag
 351                            (sb!sys:sap-ref-8 (int-sap (get-lisp-obj-address array))
 352                                              offset)))
 353                    ;; SYMBOL-GLOBAL-VALUE is a performance hack
 354                    ;; for threaded builds.
 355                    (svref (sb!vm::symbol-global-value ',table-name) tag)))
 356                array index ,@extra-params))
 357            (define (accessor-name slow-accessor-name table-name extra-params
 358                                   check-bounds)
 359                `(progn
 360                  (defvar ,table-name)
 361                  (defun ,accessor-name (array index ,@extra-params)
 362                    (declare (optimize speed
 363                                       ;; (SAFETY 0) is ok. All calls to
 364                                       ;; these functions are generated by
 365                                       ;; the compiler, so argument count
 366                                       ;; checking isn't needed. Type checking
 367                                       ;; is done implicitly via the widetag
 368                                       ;; dispatch.
 369                                       (safety 0)))
 370                    (%define ,table-name ,extra-params))
 371                  (defun ,slow-accessor-name (array index ,@extra-params)
 372                    (declare (optimize speed (safety 0)))
 373                    (if (not (%array-displaced-p array))
 374                        ;; The reasonably quick path of non-displaced complex
 375                        ;; arrays.
 376                        (let ((array (%array-data-vector array)))
 377                          (%define ,table-name ,extra-params))
 378                        ;; The real slow path.
 379                        (with-array-data
 380                            ((vector array)
 381                             (index (locally
 382                                        (declare (optimize (speed 1) (safety 1)))
 383                                      (,@check-bounds index)))
 384                             (end)
 385                             :force-inline t)
 386                          (declare (ignore end))
 387                          (,accessor-name vector index ,@extra-params)))))))
 388   (define hairy-data-vector-ref slow-hairy-data-vector-ref
 389     *data-vector-reffers* nil (progn))
 390   (define hairy-data-vector-set slow-hairy-data-vector-set
 391     *data-vector-setters* (new-value) (progn))
 392   (define hairy-data-vector-ref/check-bounds
 393       slow-hairy-data-vector-ref/check-bounds
 394     *data-vector-reffers/check-bounds* nil
 395     (%check-bound array (array-dimension array 0)))
 396   (define hairy-data-vector-set/check-bounds
 397       slow-hairy-data-vector-set/check-bounds
 398     *data-vector-setters/check-bounds* (new-value)
 399     (%check-bound array (array-dimension array 0))))
 400
 401 (defun hairy-ref-error (array index &optional new-value)
 402   (declare (ignore index new-value))
 403   (error 'type-error
 404          :datum array
 405          :expected-type 'vector))
 406
 407 ;;; Populate the dispatch tables.
 408 (macrolet ((define-reffer (saetp check-form)
 409              (let* ((type (sb!vm:saetp-specifier saetp))
 410                     (atype `(simple-array ,type (*))))
 411                `(named-lambda optimized-data-vector-ref (vector index)
 412                   (declare (optimize speed (safety 0)))
 413                   (data-vector-ref (the ,atype vector)
 414                                    (locally
 415                                        (declare (optimize (safety 1)))
 416                                      (the index
 417                                        (,@check-form index)))))))
 418            (define-setter (saetp check-form)
 419              (let* ((type (sb!vm:saetp-specifier saetp))
 420                     (atype `(simple-array ,type (*))))
 421                `(named-lambda optimized-data-vector-set (vector index new-value)
 422                   (declare (optimize speed (safety 0)))
 423                   (data-vector-set (the ,atype vector)
 424                                    (locally
 425                                        (declare (optimize (safety 1)))
 426                                      (the index
 427                                        (,@check-form index)))
 428                                    (locally
 429                                        ;; SPEED 1 needed to avoid the compiler
 430                                        ;; from downgrading the type check to
 431                                        ;; a cheaper one.
 432                                        (declare (optimize (speed 1)
 433                                                           (safety 1)))
 434                                      (the ,type new-value)))
 435                   ;; For specialized arrays, the return from
 436                   ;; data-vector-set would have to be reboxed to be a
 437                   ;; (Lisp) return value; instead, we use the
 438                   ;; already-boxed value as the return.
 439                   new-value)))
 440            (define-reffers (symbol deffer check-form slow-path)
 441              `(progn
 442                 (setf ,symbol (make-array sb!vm::widetag-mask
 443                                           :initial-element #'hairy-ref-error))
 444                 ,@(loop for widetag in '(sb!vm:complex-vector-widetag
 445                                          sb!vm:complex-vector-nil-widetag
 446                                          sb!vm:complex-bit-vector-widetag
 447                                          sb!vm:complex-character-string-widetag
 448                                          sb!vm:complex-base-string-widetag
 449                                          sb!vm:simple-array-widetag
 450                                          sb!vm:complex-array-widetag)
 451                         collect `(setf (svref ,symbol ,widetag) ,slow-path))
 452                 ,@(loop for saetp across sb!vm:*specialized-array-element-type-properties*
 453                         for widetag = (sb!vm:saetp-typecode saetp)
 454                         collect `(setf (svref ,symbol ,widetag)
 455                                        (,deffer ,saetp ,check-form))))))
 456   (defun !hairy-data-vector-reffer-init ()
 457     (define-reffers *data-vector-reffers* define-reffer
 458       (progn)
 459       #'slow-hairy-data-vector-ref)
 460     (define-reffers *data-vector-setters* define-setter
 461       (progn)
 462       #'slow-hairy-data-vector-set)
 463     (define-reffers *data-vector-reffers/check-bounds* define-reffer
 464       (%check-bound vector (length vector))
 465       #'slow-hairy-data-vector-ref/check-bounds)
 466     (define-reffers *data-vector-setters/check-bounds* define-setter
 467       (%check-bound vector (length vector))
 468       #'slow-hairy-data-vector-set/check-bounds)))
 469
 470 ;;; (Ordinary DATA-VECTOR-REF usage compiles into a vop, but
 471 ;;; DATA-VECTOR-REF is also FOLDABLE, and this ordinary function
 472 ;;; definition is needed for the compiler to use in constant folding.)
 473 (defun data-vector-ref (array index)
 474   (hairy-data-vector-ref array index))
 475
 476 ;;; SUBSCRIPTS has a dynamic-extent list structure and is destroyed
 477 (defun %array-row-major-index (array subscripts
 478                                      &optional (invalid-index-error-p t))
 479   (declare (array array)
 480            (list subscripts))
 481   (let ((rank (array-rank array)))
 482     (unless (= rank (length subscripts))
 483       (error "wrong number of subscripts, ~W, for array of rank ~W"
 484              (length subscripts) rank))
 485     (if (array-header-p array)
 486         (do ((subs (nreverse subscripts) (cdr subs))
 487              (axis (1- (array-rank array)) (1- axis))
 488              (chunk-size 1)
 489              (result 0))
 490             ((null subs) result)
 491           (declare (list subs) (fixnum axis chunk-size result))
 492           (let ((index (car subs))
 493                 (dim (%array-dimension array axis)))
 494             (declare (fixnum dim))
 495             (unless (and (fixnump index) (< -1 index dim))
 496               (if invalid-index-error-p
 497                   (error 'simple-type-error
 498                          :format-control "invalid index ~W~[~;~:; on axis ~:*~W~] in ~S"
 499                          :format-arguments (list index axis array)
 500                          :datum index
 501                          :expected-type `(integer 0 (,dim)))
 502                   (return-from %array-row-major-index nil)))
 503             (incf result (* chunk-size (the fixnum index)))
 504             (setf chunk-size (* chunk-size dim))))
 505         (let ((index (first subscripts))
 506               (length (length (the (simple-array * (*)) array))))
 507           (unless (and (fixnump index) (< -1 index length))
 508             (if invalid-index-error-p
 509                 ;; FIXME: perhaps this should share a format-string
 510                 ;; with INVALID-ARRAY-INDEX-ERROR or
 511                 ;; INDEX-TOO-LARGE-ERROR?
 512                 (error 'simple-type-error
 513                        :format-control "invalid index ~W in ~S"
 514                        :format-arguments (list index array)
 515                        :datum index
 516                        :expected-type `(integer 0 (,length)))
 517                 (return-from %array-row-major-index nil)))
 518           index))))
 519
 520 (defun array-in-bounds-p (array &rest subscripts)
 521   #!+sb-doc
 522   "Return T if the SUBSCIPTS are in bounds for the ARRAY, NIL otherwise."
 523   (if (%array-row-major-index array subscripts nil)
 524       t))
 525
 526 (defun array-row-major-index (array &rest subscripts)
 527   (declare (dynamic-extent subscripts))
 528   (%array-row-major-index array subscripts))
 529
 530 (defun aref (array &rest subscripts)
 531   #!+sb-doc
 532   "Return the element of the ARRAY specified by the SUBSCRIPTS."
 533   (declare (dynamic-extent subscripts))
 534   (row-major-aref array (%array-row-major-index array subscripts)))
 535
 536 (defun %aset (array &rest stuff)
 537   (declare (dynamic-extent stuff))
 538   (let ((subscripts (butlast stuff))
 539         (new-value (car (last stuff))))
 540     (setf (row-major-aref array (%array-row-major-index array subscripts))
 541           new-value)))
 542
 543 ;;; FIXME: What's supposed to happen with functions
 544 ;;; like AREF when we (DEFUN (SETF FOO) ..) when
 545 ;;; DEFSETF FOO is also defined? It seems as though the logical
 546 ;;; thing to do would be to nuke the macro definition for (SETF FOO)
 547 ;;; and replace it with the (SETF FOO) function, issuing a warning,
 548 ;;; just as for ordinary functions
 549 ;;;  * (LISP-IMPLEMENTATION-VERSION)
 550 ;;;  "18a+ release x86-linux 2.4.7 6 November 1998 cvs"
 551 ;;;  * (DEFMACRO ZOO (X) `(+ ,X ,X))
 552 ;;;  ZOO
 553 ;;;  * (DEFUN ZOO (X) (* 3 X))
 554 ;;;  Warning: ZOO previously defined as a macro.
 555 ;;;  ZOO
 556 ;;; But that doesn't seem to be what happens in CMU CL.
 557 ;;;
 558 ;;; KLUDGE: this is probably because ANSI, in its wisdom (CLHS
 559 ;;; 5.1.2.5) requires implementations to support
 560 ;;;   (SETF (APPLY #'AREF ...) ...)
 561 ;;; [and also #'BIT and #'SBIT].  Yes, this is terrifying, and it's
 562 ;;; also terrifying that this sequence of definitions causes it to
 563 ;;; work.
 564 ;;;
 565 ;;; Also, it would be nice to make DESCRIBE FOO tell whether a symbol
 566 ;;; has a setf expansion and/or a setf function defined.
 567
 568 #!-sb-fluid (declaim (inline (setf aref)))
 569 (defun (setf aref) (new-value array &rest subscripts)
 570   (declare (dynamic-extent subscripts))
 571   (declare (type array array))
 572   (setf (row-major-aref array (%array-row-major-index array subscripts))
 573         new-value))
 574
 575 (defun row-major-aref (array index)
 576   #!+sb-doc
 577   "Return the element of array corressponding to the row-major index. This is
 578    SETF'able."
 579   (declare (optimize (safety 1)))
 580   (row-major-aref array index))
 581
 582 (defun %set-row-major-aref (array index new-value)
 583   (declare (optimize (safety 1)))
 584   (setf (row-major-aref array index) new-value))
 585
 586 (defun svref (simple-vector index)
 587   #!+sb-doc
 588   "Return the INDEX'th element of the given Simple-Vector."
 589   (declare (optimize (safety 1)))
 590   (aref simple-vector index))
 591
 592 (defun %svset (simple-vector index new)
 593   (declare (optimize (safety 1)))
 594   (setf (aref simple-vector index) new))
 595
 596 (defun bit (bit-array &rest subscripts)
 597   #!+sb-doc
 598   "Return the bit from the BIT-ARRAY at the specified SUBSCRIPTS."
 599   (declare (type (array bit) bit-array) (optimize (safety 1)))
 600   (row-major-aref bit-array (%array-row-major-index bit-array subscripts)))
 601
 602 (defun %bitset (bit-array &rest stuff)
 603   (declare (type (array bit) bit-array) (optimize (safety 1)))
 604   (let ((subscripts (butlast stuff))
 605         (new-value (car (last stuff))))
 606     (setf (row-major-aref bit-array
 607                           (%array-row-major-index bit-array subscripts))
 608           new-value)))
 609
 610 #!-sb-fluid (declaim (inline (setf bit)))
 611 (defun (setf bit) (new-value bit-array &rest subscripts)
 612   (declare (type (array bit) bit-array) (optimize (safety 1)))
 613   (setf (row-major-aref bit-array
 614                         (%array-row-major-index bit-array subscripts))
 615         new-value))
 616
 617 (defun sbit (simple-bit-array &rest subscripts)
 618   #!+sb-doc
 619   "Return the bit from SIMPLE-BIT-ARRAY at the specified SUBSCRIPTS."
 620   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 621   (row-major-aref simple-bit-array
 622                   (%array-row-major-index simple-bit-array subscripts)))
 623
 624 ;;; KLUDGE: Not all these things (%SET-ROW-MAJOR-AREF, %SET-FILL-POINTER,
 625 ;;; %SET-FDEFINITION, %SCHARSET, %SBITSET..) seem to deserve separate names.
 626 ;;; Could we just DEFUN (SETF SBIT) etc. and get rid of the non-ANSI names?
 627 ;;; -- WHN 19990911
 628 (defun %sbitset (simple-bit-array &rest stuff)
 629   (declare (type (simple-array bit) simple-bit-array) (optimize (safety 1)))
 630   (let ((subscripts (butlast stuff))
 631         (new-value (car (last stuff))))
 632     (setf (row-major-aref simple-bit-array
 633                           (%array-row-major-index simple-bit-array subscripts))
 634           new-value)))
 635
 636 #!-sb-fluid (declaim (inline (setf sbit)))
 637 (defun (setf sbit) (new-value bit-array &rest subscripts)
 638   (declare (type (simple-array bit) bit-array) (optimize (safety 1)))
 639   (setf (row-major-aref bit-array
 640                         (%array-row-major-index bit-array subscripts))
 641         new-value))
 642 \f
 643 ;;;; miscellaneous array properties
 644
 645 (defun array-element-type (array)
 646   #!+sb-doc
 647   "Return the type of the elements of the array"
 648   (let ((widetag (widetag-of array)))
 649     (macrolet ((pick-element-type (&rest stuff)
 650                  `(cond ,@(mapcar (lambda (stuff)
 651                                     (cons
 652                                      (let ((item (car stuff)))
 653                                        (cond ((eq item t)
 654                                               t)
 655                                              ((listp item)
 656                                               (cons 'or
 657                                                     (mapcar (lambda (x)
 658                                                               `(= widetag ,x))
 659                                                             item)))
 660                                              (t
 661                                               `(= widetag ,item))))
 662                                      (cdr stuff)))
 663                                   stuff))))
 664       #.`(pick-element-type
 665           ,@(map 'list
 666                  (lambda (saetp)
 667                    `(,(if (sb!vm:saetp-complex-typecode saetp)
 668                           (list (sb!vm:saetp-typecode saetp)
 669                                 (sb!vm:saetp-complex-typecode saetp))
 670                           (sb!vm:saetp-typecode saetp))
 671                      ',(sb!vm:saetp-specifier saetp)))
 672                  sb!vm:*specialized-array-element-type-properties*)
 673           ((sb!vm:simple-array-widetag
 674             sb!vm:complex-vector-widetag
 675             sb!vm:complex-array-widetag)
 676            (with-array-data ((array array) (start) (end))
 677              (declare (ignore start end))
 678              (array-element-type array)))
 679           (t
 680            (error 'type-error :datum array :expected-type 'array))))))
 681
 682 (defun array-rank (array)
 683   #!+sb-doc
 684   "Return the number of dimensions of ARRAY."
 685   (if (array-header-p array)
 686       (%array-rank array)
 687       1))
 688
 689 (defun array-dimension (array axis-number)
 690   #!+sb-doc
 691   "Return the length of dimension AXIS-NUMBER of ARRAY."
 692   (declare (array array) (type index axis-number))
 693   (cond ((not (array-header-p array))
 694          (unless (= axis-number 0)
 695            (error "Vector axis is not zero: ~S" axis-number))
 696          (length (the (simple-array * (*)) array)))
 697         ((>= axis-number (%array-rank array))
 698          (error "Axis number ~W is too big; ~S only has ~D dimension~:P."
 699                 axis-number array (%array-rank array)))
 700         (t
 701          ;; ANSI sayeth (ADJUST-ARRAY dictionary entry):
 702          ;;
 703          ;;   "If A is displaced to B, the consequences are
 704          ;;   unspecified if B is adjusted in such a way that it no
 705          ;;   longer has enough elements to satisfy A.
 706          ;;
 707          ;; In situations where this matters we should be doing a
 708          ;; bounds-check, which in turn uses ARRAY-DIMENSION -- so
 709          ;; this seems like a good place to signal an error.
 710          (multiple-value-bind (target offset) (array-displacement array)
 711            (when (and target
 712                       (> (array-total-size array)
 713                          (- (array-total-size target) offset)))
 714                (error 'displaced-to-array-too-small-error
 715                       :format-control "~@<The displaced-to array is too small. ~S ~
 716                                       elements after offset required, ~S available.~:@>"
 717                       :format-arguments (list (array-total-size array)
 718                                               (- (array-total-size target) offset))))
 719            (%array-dimension array axis-number)))))
 720
 721 (defun array-dimensions (array)
 722   #!+sb-doc
 723   "Return a list whose elements are the dimensions of the array"
 724   (declare (array array))
 725   (if (array-header-p array)
 726       (do ((results nil (cons (array-dimension array index) results))
 727            (index (1- (array-rank array)) (1- index)))
 728           ((minusp index) results))
 729       (list (array-dimension array 0))))
 730
 731 (defun array-total-size (array)
 732   #!+sb-doc
 733   "Return the total number of elements in the Array."
 734   (declare (array array))
 735   (if (array-header-p array)
 736       (%array-available-elements array)
 737       (length (the vector array))))
 738
 739 (defun array-displacement (array)
 740   #!+sb-doc
 741   "Return the values of :DISPLACED-TO and :DISPLACED-INDEX-offset
 742    options to MAKE-ARRAY, or NIL and 0 if not a displaced array."
 743   (declare (type array array))
 744   (if (and (array-header-p array) ; if unsimple and
 745            (%array-displaced-p array)) ; displaced
 746       (values (%array-data-vector array) (%array-displacement array))
 747       (values nil 0)))
 748
 749 (defun adjustable-array-p (array)
 750   #!+sb-doc
 751   "Return T if (ADJUST-ARRAY ARRAY...) would return an array identical
 752    to the argument, this happens for complex arrays."
 753   (declare (array array))
 754   ;; Note that this appears not to be a fundamental limitation.
 755   ;; non-vector SIMPLE-ARRAYs are in fact capable of being adjusted,
 756   ;; but in practice we test using ADJUSTABLE-ARRAY-P in ADJUST-ARRAY.
 757   ;; -- CSR, 2004-03-01.
 758   (not (typep array 'simple-array)))
 759 \f
 760 ;;;; fill pointer frobbing stuff
 761
 762 (defun array-has-fill-pointer-p (array)
 763   #!+sb-doc
 764   "Return T if the given ARRAY has a fill pointer, or NIL otherwise."
 765   (declare (array array))
 766   (and (array-header-p array) (%array-fill-pointer-p array)))
 767
 768 (defun fill-pointer (vector)
 769   #!+sb-doc
 770   "Return the FILL-POINTER of the given VECTOR."
 771   (declare (vector vector))
 772   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 773       (%array-fill-pointer vector)
 774       (error 'simple-type-error
 775              :datum vector
 776              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 777              :format-control "~S is not an array with a fill pointer."
 778              :format-arguments (list vector))))
 779
 780 (defun %set-fill-pointer (vector new)
 781   (declare (vector vector) (fixnum new))
 782   (if (and (array-header-p vector) (%array-fill-pointer-p vector))
 783       (if (> new (%array-available-elements vector))
 784         (error
 785          "The new fill pointer, ~S, is larger than the length of the vector."
 786          new)
 787         (setf (%array-fill-pointer vector) new))
 788       (error 'simple-type-error
 789              :datum vector
 790              :expected-type '(and vector (satisfies array-has-fill-pointer-p))
 791              :format-control "~S is not an array with a fill pointer."
 792              :format-arguments (list vector))))
 793
 794 ;;; FIXME: It'd probably make sense to use a MACROLET to share the
 795 ;;; guts of VECTOR-PUSH between VECTOR-PUSH-EXTEND. Such a macro
 796 ;;; should probably be based on the VECTOR-PUSH-EXTEND code (which is
 797 ;;; new ca. sbcl-0.7.0) rather than the VECTOR-PUSH code (which dates
 798 ;;; back to CMU CL).
 799 (defun vector-push (new-el array)
 800   #!+sb-doc
 801   "Attempt to set the element of ARRAY designated by its fill pointer
 802    to NEW-EL, and increment the fill pointer by one. If the fill pointer is
 803    too large, NIL is returned, otherwise the index of the pushed element is
 804    returned."
 805   (declare (vector array))
 806   (let ((fill-pointer (fill-pointer array)))
 807     (declare (fixnum fill-pointer))
 808     (cond ((= fill-pointer (%array-available-elements array))
 809            nil)
 810           (t
 811            (setf (aref array fill-pointer) new-el)
 812            (setf (%array-fill-pointer array) (1+ fill-pointer))
 813            fill-pointer))))
 814
 815 (defun vector-push-extend (new-element
 816                            vector
 817                            &optional
 818                            (extension (1+ (length vector))))
 819   (declare (vector vector) (fixnum extension))
 820   (let ((fill-pointer (fill-pointer vector)))
 821     (declare (fixnum fill-pointer))
 822     (when (= fill-pointer (%array-available-elements vector))
 823       (adjust-array vector (+ fill-pointer extension)))
 824     ;; disable bounds checking
 825     (locally (declare (optimize (safety 0)))
 826       (setf (aref vector fill-pointer) new-element))
 827     (setf (%array-fill-pointer vector) (1+ fill-pointer))
 828     fill-pointer))
 829
 830 (defun vector-pop (array)
 831   #!+sb-doc
 832   "Decrease the fill pointer by 1 and return the element pointed to by the
 833   new fill pointer."
 834   (declare (vector array))
 835   (let ((fill-pointer (fill-pointer array)))
 836     (declare (fixnum fill-pointer))
 837     (if (zerop fill-pointer)
 838         (error "There is nothing left to pop.")
 839         ;; disable bounds checking (and any fixnum test)
 840         (locally (declare (optimize (safety 0)))
 841           (aref array
 842                 (setf (%array-fill-pointer array)
 843                       (1- fill-pointer)))))))
 844
 845 \f
 846 ;;;; ADJUST-ARRAY
 847
 848 (defun adjust-array (array dimensions &key
 849                            (element-type (array-element-type array))
 850                            (initial-element nil initial-element-p)
 851                            (initial-contents nil initial-contents-p)
 852                            fill-pointer
 853                            displaced-to displaced-index-offset)
 854   #!+sb-doc
 855   "Adjust ARRAY's dimensions to the given DIMENSIONS and stuff."
 856   (let ((dimensions (if (listp dimensions) dimensions (list dimensions))))
 857     (cond ((/= (the fixnum (length (the list dimensions)))
 858                (the fixnum (array-rank array)))
 859            (error "The number of dimensions not equal to rank of array."))
 860           ((not (subtypep element-type (array-element-type array)))
 861            (error "The new element type, ~S, is incompatible with old type."
 862                   element-type))
 863           ((and fill-pointer (not (array-has-fill-pointer-p array)))
 864            (error 'type-error
 865                   :datum array
 866                   :expected-type '(satisfies array-has-fill-pointer-p))))
 867     (let ((array-rank (length (the list dimensions))))
 868       (declare (fixnum array-rank))
 869       (unless (= array-rank 1)
 870         (when fill-pointer
 871           (error "Only vectors can have fill pointers.")))
 872       (cond (initial-contents-p
 873              ;; array former contents replaced by INITIAL-CONTENTS
 874              (if (or initial-element-p displaced-to)
 875                  (error "INITIAL-CONTENTS may not be specified with ~
 876                          the :INITIAL-ELEMENT or :DISPLACED-TO option."))
 877              (let* ((array-size (apply #'* dimensions))
 878                     (array-data (data-vector-from-inits
 879                                  dimensions array-size element-type
 880                                  initial-contents initial-contents-p
 881                                  initial-element initial-element-p)))
 882                (if (adjustable-array-p array)
 883                    (set-array-header array array-data array-size
 884                                  (get-new-fill-pointer array array-size
 885                                                        fill-pointer)
 886                                  0 dimensions nil)
 887                    (if (array-header-p array)
 888                        ;; simple multidimensional or single dimensional array
 889                        (make-array dimensions
 890                                    :element-type element-type
 891                                    :initial-contents initial-contents)
 892                        array-data))))
 893             (displaced-to
 894              ;; We already established that no INITIAL-CONTENTS was supplied.
 895              (when initial-element
 896                (error "The :INITIAL-ELEMENT option may not be specified ~
 897                        with :DISPLACED-TO."))
 898              (unless (subtypep element-type (array-element-type displaced-to))
 899                (error "can't displace an array of type ~S into another of ~
 900                        type ~S"
 901                       element-type (array-element-type displaced-to)))
 902              (let ((displacement (or displaced-index-offset 0))
 903                    (array-size (apply #'* dimensions)))
 904                (declare (fixnum displacement array-size))
 905                (if (< (the fixnum (array-total-size displaced-to))
 906                       (the fixnum (+ displacement array-size)))
 907                    (error "The :DISPLACED-TO array is too small."))
 908                (if (adjustable-array-p array)
 909                    ;; None of the original contents appear in adjusted array.
 910                    (set-array-header array displaced-to array-size
 911                                      (get-new-fill-pointer array array-size
 912                                                            fill-pointer)
 913                                      displacement dimensions t)
 914                    ;; simple multidimensional or single dimensional array
 915                    (make-array dimensions
 916                                :element-type element-type
 917                                :displaced-to displaced-to
 918                                :displaced-index-offset
 919                                displaced-index-offset))))
 920             ((= array-rank 1)
 921              (let ((old-length (array-total-size array))
 922                    (new-length (car dimensions))
 923                    new-data)
 924                (declare (fixnum old-length new-length))
 925                (with-array-data ((old-data array) (old-start)
 926                                  (old-end old-length))
 927                  (cond ((or (and (array-header-p array)
 928                                  (%array-displaced-p array))
 929                             (< old-length new-length))
 930                         (setf new-data
 931                               (data-vector-from-inits
 932                                dimensions new-length element-type
 933                                initial-contents initial-contents-p
 934                                initial-element initial-element-p))
 935                         (replace new-data old-data
 936                                  :start2 old-start :end2 old-end))
 937                        (t (setf new-data
 938                                 (shrink-vector old-data new-length))))
 939                  (if (adjustable-array-p array)
 940                      (set-array-header array new-data new-length
 941                                        (get-new-fill-pointer array new-length
 942                                                              fill-pointer)
 943                                        0 dimensions nil)
 944                      new-data))))
 945             (t
 946              (let ((old-length (%array-available-elements array))
 947                    (new-length (apply #'* dimensions)))
 948                (declare (fixnum old-length new-length))
 949                (with-array-data ((old-data array) (old-start)
 950                                  (old-end old-length))
 951                  (declare (ignore old-end))
 952                  (let ((new-data (if (or (and (array-header-p array)
 953                                               (%array-displaced-p array))
 954                                          (> new-length old-length))
 955                                      (data-vector-from-inits
 956                                       dimensions new-length
 957                                       element-type () nil
 958                                       initial-element initial-element-p)
 959                                      old-data)))
 960                    (if (or (zerop old-length) (zerop new-length))
 961                        (when initial-element-p (fill new-data initial-element))
 962                        (zap-array-data old-data (array-dimensions array)
 963                                        old-start
 964                                        new-data dimensions new-length
 965                                        element-type initial-element
 966                                        initial-element-p))
 967                    (if (adjustable-array-p array)
 968                        (set-array-header array new-data new-length
 969                                          new-length 0 dimensions nil)
 970                        (let ((new-array
 971                               (make-array-header
 972                                sb!vm:simple-array-widetag array-rank)))
 973                          (set-array-header new-array new-data new-length
 974                                            new-length 0 dimensions nil)))))))))))
 975
 976
 977 (defun get-new-fill-pointer (old-array new-array-size fill-pointer)
 978   (cond ((not fill-pointer)
 979          (when (array-has-fill-pointer-p old-array)
 980            (when (> (%array-fill-pointer old-array) new-array-size)
 981              (error "cannot ADJUST-ARRAY an array (~S) to a size (~S) that is ~
 982                      smaller than its fill pointer (~S)"
 983                     old-array new-array-size (fill-pointer old-array)))
 984            (%array-fill-pointer old-array)))
 985         ((not (array-has-fill-pointer-p old-array))
 986          (error "cannot supply a non-NIL value (~S) for :FILL-POINTER ~
 987                  in ADJUST-ARRAY unless the array (~S) was originally ~
 988                  created with a fill pointer"
 989                 fill-pointer
 990                 old-array))
 991         ((numberp fill-pointer)
 992          (when (> fill-pointer new-array-size)
 993            (error "can't supply a value for :FILL-POINTER (~S) that is larger ~
 994                    than the new length of the vector (~S)"
 995                   fill-pointer new-array-size))
 996          fill-pointer)
 997         ((eq fill-pointer t)
 998          new-array-size)
 999         (t
1000          (error "bogus value for :FILL-POINTER in ADJUST-ARRAY: ~S"
1001                 fill-pointer))))
1002
1003 ;;; Destructively alter VECTOR, changing its length to NEW-LENGTH,
1004 ;;; which must be less than or equal to its current length. This can
1005 ;;; be called on vectors without a fill pointer but it is extremely
1006 ;;; dangerous to do so: shrinking the size of an object (as viewed by
1007 ;;; the gc) makes bounds checking unreliable in the face of interrupts
1008 ;;; or multi-threading. Call it only on provably local vectors.
1009 (defun %shrink-vector (vector new-length)
1010   (declare (vector vector))
1011   (unless (array-header-p vector)
1012     (macrolet ((frob (name &rest things)
1013                  `(etypecase ,name
1014                     ((simple-array nil (*)) (error 'nil-array-accessed-error))
1015                     ,@(mapcar (lambda (thing)
1016                                 (destructuring-bind (type-spec fill-value)
1017                                     thing
1018                                   `(,type-spec
1019                                     (fill (truly-the ,type-spec ,name)
1020                                           ,fill-value
1021                                           :start new-length))))
1022                               things))))
1023       ;; Set the 'tail' of the vector to the appropriate type of zero,
1024       ;; "because in some cases we'll scavenge larger areas in one go,
1025       ;; like groups of pages that had triggered the write barrier, or
1026       ;; the whole static space" according to jsnell.
1027       #.`(frob vector
1028           ,@(map 'list
1029                  (lambda (saetp)
1030                    `((simple-array ,(sb!vm:saetp-specifier saetp) (*))
1031                      ,(if (or (eq (sb!vm:saetp-specifier saetp) 'character)
1032                               #!+sb-unicode
1033                               (eq (sb!vm:saetp-specifier saetp) 'base-char))
1034                           *default-init-char-form*
1035                           (sb!vm:saetp-initial-element-default saetp))))
1036                  (remove-if-not
1037                   #'sb!vm:saetp-specifier
1038                   sb!vm:*specialized-array-element-type-properties*)))))
1039   ;; Only arrays have fill-pointers, but vectors have their length
1040   ;; parameter in the same place.
1041   (setf (%array-fill-pointer vector) new-length)
1042   vector)
1043
1044 (defun shrink-vector (vector new-length)
1045   (declare (vector vector))
1046   (cond
1047     ((eq (length vector) new-length)
1048      vector)
1049     ((array-has-fill-pointer-p vector)
1050      (setf (%array-fill-pointer vector) new-length)
1051      vector)
1052     (t (subseq vector 0 new-length))))
1053
1054 ;;; Fill in array header with the provided information, and return the array.
1055 (defun set-array-header (array data length fill-pointer displacement dimensions
1056                          &optional displacedp)
1057   (setf (%array-data-vector array) data)
1058   (setf (%array-available-elements array) length)
1059   (cond (fill-pointer
1060          (setf (%array-fill-pointer array) fill-pointer)
1061          (setf (%array-fill-pointer-p array) t))
1062         (t
1063          (setf (%array-fill-pointer array) length)
1064          (setf (%array-fill-pointer-p array) nil)))
1065   (setf (%array-displacement array) displacement)
1066   (if (listp dimensions)
1067       (dotimes (axis (array-rank array))
1068         (declare (type index axis))
1069         (setf (%array-dimension array axis) (pop dimensions)))
1070       (setf (%array-dimension array 0) dimensions))
1071   (setf (%array-displaced-p array) displacedp)
1072   array)
1073 \f
1074 ;;;; ZAP-ARRAY-DATA for ADJUST-ARRAY
1075
1076 ;;; a temporary to be used when OLD-DATA and NEW-DATA are EQ.
1077 ;;; KLUDGE: Boy, DYNAMIC-EXTENT would be nice. This is rebound
1078 ;;; to length zero array in each new thread.
1079 ;;;
1080 ;;; DX is probably a bad idea, because a with a big array it would
1081 ;;; be fairly easy to blow the stack.
1082 (defvar *zap-array-data-temp* (vector))
1083 (declaim (simple-vector *zap-array-data-temp*))
1084
1085 (defun zap-array-data-temp (length initial-element initial-element-p)
1086   (declare (fixnum length))
1087   (let ((tmp *zap-array-data-temp*))
1088     (declare (simple-vector tmp))
1089     (cond ((> length (length tmp))
1090            (setf *zap-array-data-temp*
1091                  (if initial-element-p
1092                      (make-array length :initial-element initial-element)
1093                      (make-array length))))
1094           (initial-element-p
1095            (fill tmp initial-element :end length))
1096           (t
1097            tmp))))
1098
1099 ;;; This does the grinding work for ADJUST-ARRAY. It zaps the data
1100 ;;; from the OLD-DATA in an arrangement specified by the OLD-DIMS to
1101 ;;; the NEW-DATA in an arrangement specified by the NEW-DIMS. OFFSET
1102 ;;; is a displaced offset to be added to computed indices of OLD-DATA.
1103 (defun zap-array-data (old-data old-dims offset new-data new-dims new-length
1104                        element-type initial-element initial-element-p)
1105   (declare (list old-dims new-dims))
1106   ;; OLD-DIMS comes from array-dimensions, which returns a fresh list
1107   ;; at least in SBCL.
1108   ;; NEW-DIMS comes from the user.
1109   (setf old-dims (nreverse old-dims)
1110         new-dims (reverse new-dims))
1111   (cond ((eq old-data new-data)
1112          ;; NEW-LENGTH, ELEMENT-TYPE, INITIAL-ELEMENT, and
1113          ;; INITIAL-ELEMENT-P are used when OLD-DATA and NEW-DATA are
1114          ;; EQ; in this case, a temporary must be used and filled
1115          ;; appropriately. specified initial-element.
1116          (when initial-element-p
1117            ;; FIXME: transforming this TYPEP to someting a bit faster
1118            ;; would be a win...
1119            (unless (typep initial-element element-type)
1120              (error "~S can't be used to initialize an array of type ~S."
1121                     initial-element element-type)))
1122          (without-interrupts
1123            ;; Need to disable interrupts while using the temp-vector.
1124            ;; An interrupt handler that also happened to call
1125            ;; ADJUST-ARRAY could otherwise stomp on our data here.
1126            (let ((temp (zap-array-data-temp new-length
1127                                             initial-element initial-element-p)))
1128              (declare (simple-vector temp))
1129              (zap-array-data-aux old-data old-dims offset temp new-dims)
1130              (dotimes (i new-length)
1131                (setf (aref new-data i) (aref temp i)
1132                      ;; zero out any garbage right away
1133                      (aref temp i) 0)))))
1134         (t
1135          ;; When OLD-DATA and NEW-DATA are not EQ, NEW-DATA has
1136          ;; already been filled with any
1137          (zap-array-data-aux old-data old-dims offset new-data new-dims))))
1138
1139 (defun zap-array-data-aux (old-data old-dims offset new-data new-dims)
1140   (declare (fixnum offset))
1141   (let ((limits (mapcar (lambda (x y)
1142                           (declare (fixnum x y))
1143                           (1- (the fixnum (min x y))))
1144                         old-dims new-dims)))
1145     (macrolet ((bump-index-list (index limits)
1146                  `(do ((subscripts ,index (cdr subscripts))
1147                        (limits ,limits (cdr limits)))
1148                       ((null subscripts) :eof)
1149                     (cond ((< (the fixnum (car subscripts))
1150                               (the fixnum (car limits)))
1151                            (rplaca subscripts
1152                                    (1+ (the fixnum (car subscripts))))
1153                            (return ,index))
1154                           (t (rplaca subscripts 0))))))
1155       (do ((index (make-list (length old-dims) :initial-element 0)
1156                   (bump-index-list index limits)))
1157           ((eq index :eof))
1158         (setf (aref new-data (row-major-index-from-dims index new-dims))
1159               (aref old-data
1160                     (+ (the fixnum (row-major-index-from-dims index old-dims))
1161                        offset)))))))
1162
1163 ;;; Figure out the row-major-order index of an array reference from a
1164 ;;; list of subscripts and a list of dimensions. This is for internal
1165 ;;; calls only, and the subscripts and dim-list variables are assumed
1166 ;;; to be reversed from what the user supplied.
1167 (defun row-major-index-from-dims (rev-subscripts rev-dim-list)
1168   (do ((rev-subscripts rev-subscripts (cdr rev-subscripts))
1169        (rev-dim-list rev-dim-list (cdr rev-dim-list))
1170        (chunk-size 1)
1171        (result 0))
1172       ((null rev-dim-list) result)
1173     (declare (fixnum chunk-size result))
1174     (setq result (+ result
1175                     (the fixnum (* (the fixnum (car rev-subscripts))
1176                                    chunk-size))))
1177     (setq chunk-size (* chunk-size (the fixnum (car rev-dim-list))))))
1178 \f
1179 ;;;; some bit stuff
1180
1181 (defun bit-array-same-dimensions-p (array1 array2)
1182   (declare (type (array bit) array1 array2))
1183   (and (= (array-rank array1)
1184           (array-rank array2))
1185        (dotimes (index (array-rank array1) t)
1186          (when (/= (array-dimension array1 index)
1187                    (array-dimension array2 index))
1188            (return nil)))))
1189
1190 (defun pick-result-array (result-bit-array bit-array-1)
1191   (case result-bit-array
1192     ((t) bit-array-1)
1193     ((nil) (make-array (array-dimensions bit-array-1)
1194                        :element-type 'bit
1195                        :initial-element 0))
1196     (t
1197      (unless (bit-array-same-dimensions-p bit-array-1
1198                                           result-bit-array)
1199        (error "~S and ~S don't have the same dimensions."
1200               bit-array-1 result-bit-array))
1201      result-bit-array)))
1202
1203 (defmacro def-bit-array-op (name function)
1204   `(defun ,name (bit-array-1 bit-array-2 &optional result-bit-array)
1205      #!+sb-doc
1206      ,(format nil
1207               "Perform a bit-wise ~A on the elements of BIT-ARRAY-1 and ~
1208                BIT-ARRAY-2,~%  putting the results in RESULT-BIT-ARRAY. ~
1209                If RESULT-BIT-ARRAY is T,~%  BIT-ARRAY-1 is used. If ~
1210                RESULT-BIT-ARRAY is NIL or omitted, a new array is~%  created. ~
1211                All the arrays must have the same rank and dimensions."
1212               (symbol-name function))
1213      (declare (type (array bit) bit-array-1 bit-array-2)
1214               (type (or (array bit) (member t nil)) result-bit-array))
1215      (unless (bit-array-same-dimensions-p bit-array-1 bit-array-2)
1216        (error "~S and ~S don't have the same dimensions."
1217               bit-array-1 bit-array-2))
1218      (let ((result-bit-array (pick-result-array result-bit-array bit-array-1)))
1219        (if (and (simple-bit-vector-p bit-array-1)
1220                 (simple-bit-vector-p bit-array-2)
1221                 (simple-bit-vector-p result-bit-array))
1222            (locally (declare (optimize (speed 3) (safety 0)))
1223              (,name bit-array-1 bit-array-2 result-bit-array))
1224            (with-array-data ((data1 bit-array-1) (start1) (end1))
1225              (declare (ignore end1))
1226              (with-array-data ((data2 bit-array-2) (start2) (end2))
1227                (declare (ignore end2))
1228                (with-array-data ((data3 result-bit-array) (start3) (end3))
1229                  (do ((index-1 start1 (1+ index-1))
1230                       (index-2 start2 (1+ index-2))
1231                       (index-3 start3 (1+ index-3)))
1232                      ((>= index-3 end3) result-bit-array)
1233                    (declare (type index index-1 index-2 index-3))
1234                    (setf (sbit data3 index-3)
1235                          (logand (,function (sbit data1 index-1)
1236                                             (sbit data2 index-2))
1237                                  1))))))))))
1238
1239 (def-bit-array-op bit-and logand)
1240 (def-bit-array-op bit-ior logior)
1241 (def-bit-array-op bit-xor logxor)
1242 (def-bit-array-op bit-eqv logeqv)
1243 (def-bit-array-op bit-nand lognand)
1244 (def-bit-array-op bit-nor lognor)
1245 (def-bit-array-op bit-andc1 logandc1)
1246 (def-bit-array-op bit-andc2 logandc2)
1247 (def-bit-array-op bit-orc1 logorc1)
1248 (def-bit-array-op bit-orc2 logorc2)
1249
1250 (defun bit-not (bit-array &optional result-bit-array)
1251   #!+sb-doc
1252   "Performs a bit-wise logical NOT on the elements of BIT-ARRAY,
1253   putting the results in RESULT-BIT-ARRAY. If RESULT-BIT-ARRAY is T,
1254   BIT-ARRAY is used. If RESULT-BIT-ARRAY is NIL or omitted, a new array is
1255   created. Both arrays must have the same rank and dimensions."
1256   (declare (type (array bit) bit-array)
1257            (type (or (array bit) (member t nil)) result-bit-array))
1258   (let ((result-bit-array (pick-result-array result-bit-array bit-array)))
1259     (if (and (simple-bit-vector-p bit-array)
1260              (simple-bit-vector-p result-bit-array))
1261         (locally (declare (optimize (speed 3) (safety 0)))
1262           (bit-not bit-array result-bit-array))
1263         (with-array-data ((src bit-array) (src-start) (src-end))
1264           (declare (ignore src-end))
1265           (with-array-data ((dst result-bit-array) (dst-start) (dst-end))
1266             (do ((src-index src-start (1+ src-index))
1267                  (dst-index dst-start (1+ dst-index)))
1268                 ((>= dst-index dst-end) result-bit-array)
1269               (declare (type index src-index dst-index))
1270               (setf (sbit dst dst-index)
1271                     (logxor (sbit src src-index) 1))))))))