src/code/backq.lisp

   1 ;;;; the backquote reader macro
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 (/show0 "entering backq.lisp")
  15
  16 ;;; The flags passed back by BACKQUOTIFY can be interpreted as follows:
  17 ;;;
  18 ;;;   |`,|: [a] => a
  19 ;;;    NIL: [a] => a            ;the NIL flag is used only when a is NIL
  20 ;;;      T: [a] => a            ;the T flag is used when a is self-evaluating
  21 ;;;  QUOTE: [a] => (QUOTE a)
  22 ;;; APPEND: [a] => (APPEND . a)
  23 ;;;  NCONC: [a] => (NCONC . a)
  24 ;;;   LIST: [a] => (LIST . a)
  25 ;;;  LIST*: [a] => (LIST* . a)
  26 ;;;
  27 ;;; The flags are combined according to the following set of rules:
  28 ;;;  ([a] means that a should be converted according to the previous table)
  29 ;;;
  30 ;;;   \ car  ||    otherwise    |    QUOTE or     |     |`,@|      |     |`,.|
  31 ;;;cdr \     ||                 |    T or NIL     |                |
  32 ;;;================================================================================
  33 ;;;  |`,|    || LIST* ([a] [d]) | LIST* ([a] [d]) | APPEND (a [d]) | NCONC  (a [d])
  34 ;;;  NIL     || LIST    ([a])   | QUOTE    (a)    | <hair>    a    | <hair>    a
  35 ;;;QUOTE or T|| LIST* ([a] [d]) | QUOTE  (a . d)  | APPEND (a [d]) | NCONC (a [d])
  36 ;;; APPEND   || LIST* ([a] [d]) | LIST* ([a] [d]) | APPEND (a . d) | NCONC (a [d])
  37 ;;; NCONC    || LIST* ([a] [d]) | LIST* ([a] [d]) | APPEND (a [d]) | NCONC (a . d)
  38 ;;;  LIST    || LIST  ([a] . d) | LIST  ([a] . d) | APPEND (a [d]) | NCONC (a [d])
  39 ;;;  LIST*   || LIST* ([a] . d) | LIST* ([a] . d) | APPEND (a [d]) | NCONC  (a [d])
  40 ;;;
  41 ;;;<hair> involves starting over again pretending you had read ".,a)" instead
  42 ;;; of ",@a)"
  43
  44 (defvar *backquote-count* 0 #!+sb-doc "how deep we are into backquotes")
  45 (defvar *bq-comma-flag* '(|,|))
  46 (defvar *bq-at-flag* '(|,@|))
  47 (defvar *bq-dot-flag* '(|,.|))
  48 (defvar *bq-vector-flag* '(|bqv|))
  49
  50 (/show0 "backq.lisp 50")
  51
  52 ;;; the actual character macro
  53 (defun backquote-macro (stream ignore)
  54   (declare (ignore ignore))
  55   (let ((*backquote-count* (1+ *backquote-count*)))
  56     (multiple-value-bind (flag thing)
  57         (backquotify stream (read stream t nil t))
  58       (when (eq flag *bq-at-flag*)
  59         (simple-reader-error stream ",@ after backquote in ~S" thing))
  60       (when (eq flag *bq-dot-flag*)
  61         (simple-reader-error stream ",. after backquote in ~S" thing))
  62       (backquotify-1 flag thing))))
  63
  64 (/show0 "backq.lisp 64")
  65
  66 (defun comma-macro (stream ignore)
  67   (declare (ignore ignore))
  68   (unless (> *backquote-count* 0)
  69     (when *read-suppress*
  70       (return-from comma-macro nil))
  71     (simple-reader-error stream "comma not inside a backquote"))
  72   (let ((c (read-char stream))
  73         (*backquote-count* (1- *backquote-count*)))
  74     (cond ((char= c #\@)
  75            (cons *bq-at-flag* (read stream t nil t)))
  76           ((char= c #\.)
  77            (cons *bq-dot-flag* (read stream t nil t)))
  78           (t (unread-char c stream)
  79              (cons *bq-comma-flag* (read stream t nil t))))))
  80
  81 (/show0 "backq.lisp 83")
  82
  83 ;;;
  84 (defun expandable-backq-expression-p (object)
  85   (and (consp object)
  86        (let ((flag (car object)))
  87          (or (eq flag *bq-at-flag*)
  88              (eq flag *bq-dot-flag*)))))
  89
  90 ;;; This does the expansion from table 2.
  91 (defun backquotify (stream code)
  92   (cond ((atom code)
  93          (cond ((null code) (values nil nil))
  94                ((or (consp code)
  95                     (symbolp code))
  96                 ;; Keywords are self-evaluating. Install after packages.
  97                 (values 'quote code))
  98                (t (values t code))))
  99         ((or (eq (car code) *bq-at-flag*)
 100              (eq (car code) *bq-dot-flag*))
 101          (values (car code) (cdr code)))
 102         ((eq (car code) *bq-comma-flag*)
 103          (comma (cdr code)))
 104         ((eq (car code) *bq-vector-flag*)
 105          (multiple-value-bind (dflag d) (backquotify stream (cdr code))
 106            (values 'vector (backquotify-1 dflag d))))
 107         (t (multiple-value-bind (aflag a) (backquotify stream (car code))
 108              (multiple-value-bind (dflag d) (backquotify stream (cdr code))
 109                (when (eq dflag *bq-at-flag*)
 110                  ;; Get the errors later.
 111                  (simple-reader-error stream ",@ after dot in ~S" code))
 112                (when (eq dflag *bq-dot-flag*)
 113                  (simple-reader-error stream ",. after dot in ~S" code))
 114                (cond
 115                 ((eq aflag *bq-at-flag*)
 116                  (if (null dflag)
 117                      (if (expandable-backq-expression-p a)
 118                          (values 'append (list a))
 119                          (comma a))
 120                      (values 'append
 121                              (cond ((eq dflag 'append)
 122                                     (cons a d ))
 123                                    (t (list a (backquotify-1 dflag d)))))))
 124                 ((eq aflag *bq-dot-flag*)
 125                  (if (null dflag)
 126                      (if (expandable-backq-expression-p a)
 127                          (values 'nconc (list a))
 128                          (comma a))
 129                      (values 'nconc
 130                              (cond ((eq dflag 'nconc)
 131                                     (cons a d))
 132                                    (t (list a (backquotify-1 dflag d)))))))
 133                 ((null dflag)
 134                  (if (member aflag '(quote t nil))
 135                      (values 'quote (list a))
 136                      (values 'list (list (backquotify-1 aflag a)))))
 137                 ((member dflag '(quote t))
 138                  (if (member aflag '(quote t nil))
 139                      (values 'quote (cons a d ))
 140                      (values 'list* (list (backquotify-1 aflag a)
 141                                           (backquotify-1 dflag d)))))
 142                 (t (setq a (backquotify-1 aflag a))
 143                    (if (member dflag '(list list*))
 144                        (values dflag (cons a d))
 145                        (values 'list*
 146                                (list a (backquotify-1 dflag d)))))))))))
 147
 148 (/show0 "backq.lisp 139")
 149
 150 ;;; This handles the <hair> cases.
 151 (defun comma (code)
 152   (cond ((atom code)
 153          (cond ((null code)
 154                 (values nil nil))
 155                ((or (numberp code) (eq code t))
 156                 (values t code))
 157                (t (values *bq-comma-flag* code))))
 158         ((and (eq (car code) 'quote)
 159               (not (expandable-backq-expression-p (cadr code))))
 160          (values (car code) (cadr code)))
 161         ((member (car code) '(append list list* nconc))
 162          (values (car code) (cdr code)))
 163         ((eq (car code) 'cons)
 164          (values 'list* (cdr code)))
 165         (t (values *bq-comma-flag* code))))
 166
 167 (/show0 "backq.lisp 157")
 168
 169 ;;; This handles table 1.
 170 (defun backquotify-1 (flag thing)
 171   (cond ((or (eq flag *bq-comma-flag*)
 172              (member flag '(t nil)))
 173          thing)
 174         ((eq flag 'quote)
 175          (list  'quote thing))
 176         ((eq flag 'list*)
 177          (cond ((and (null (cddr thing))
 178                      (not (expandable-backq-expression-p (car thing)))
 179                      (not (expandable-backq-expression-p (cadr thing))))
 180                 (cons 'backq-cons thing))
 181                ((expandable-backq-expression-p (car (last thing)))
 182                 (list 'backq-append
 183                       (cons 'backq-list (butlast thing))
 184                       ;; Can it be optimized further? -- APD, 2001-12-21
 185                       (car (last thing))))
 186                (t
 187                 (cons 'backq-list* thing))))
 188         ((eq flag 'vector)
 189          (list 'backq-vector thing))
 190         (t (cons (ecase flag
 191                    ((list) 'backq-list)
 192                    ((append) 'backq-append)
 193                    ((nconc) 'backq-nconc))
 194                  thing))))
 195 \f
 196 ;;;; magic BACKQ- versions of builtin functions
 197
 198 (/show0 "backq.lisp 184")
 199
 200 ;;; Define synonyms for the lisp functions we use, so that by using
 201 ;;; them, the backquoted material will be recognizable to the
 202 ;;; pretty-printer.
 203 (macrolet ((def (b-name name)
 204                ;; FIXME: This function should be INLINE so that the lists
 205                ;; aren't consed twice, but I ran into an optimizer bug the
 206                ;; first time I tried to make this work for BACKQ-LIST. See
 207                ;; whether there's still an optimizer bug, and fix it if so, and
 208                ;; then make these INLINE.
 209                `(defun ,b-name (&rest rest)
 210                   (declare (truly-dynamic-extent rest))
 211                   (apply #',name rest))))
 212   (def backq-list list)
 213   (def backq-list* list*)
 214   (def backq-append append)
 215   (def backq-nconc nconc)
 216   (def backq-cons cons))
 217
 218 (/show0 "backq.lisp 204")
 219
 220 (defun backq-vector (list)
 221   (declare (list list))
 222   (coerce list 'simple-vector))
 223 \f
 224 ;;;; initialization
 225
 226 (/show0 "backq.lisp 212")
 227
 228 ;;; Install BACKQ stuff in the current *READTABLE*.
 229 ;;;
 230 ;;; In the target Lisp, we have to wait to do this until the readtable
 231 ;;; has been created. In the cross-compilation host Lisp, we can do
 232 ;;; this right away. (You may ask: In the cross-compilation host,
 233 ;;; which already has its own implementation of the backquote
 234 ;;; readmacro, why do we do this at all? Because the cross-compilation
 235 ;;; host might -- as SBCL itself does -- express the backquote
 236 ;;; expansion in terms of internal, nonportable functions. By
 237 ;;; redefining backquote in terms of functions which are guaranteed to
 238 ;;; exist on the target Lisp, we ensure that backquote expansions in
 239 ;;; code-generating code work properly.)
 240 (defun !backq-cold-init ()
 241   (set-macro-character #\` #'backquote-macro)
 242   (set-macro-character #\, #'comma-macro))
 243 #+sb-xc-host (!backq-cold-init)
 244
 245 ;;; The pretty-printer needs to know about our special tokens
 246 (defvar *backq-tokens*
 247   '(backq-comma backq-comma-at backq-comma-dot backq-list
 248     backq-list* backq-append backq-nconc backq-cons backq-vector))
 249
 250 ;;; Since our backquote is installed on the host lisp, and since
 251 ;;; developers make mistakes with backquotes and commas too, let's
 252 ;;; ensure that we can report errors rather than get an undefined
 253 ;;; function condition on SIMPLE-READER-ERROR.
 254 #+sb-xc-host ; proper definition happens for the target
 255 (defun simple-reader-error (stream format-string &rest format-args)
 256   (bug "READER-ERROR on stream ~S: ~?" stream format-string format-args))
 257
 258 (/show0 "done with backq.lisp")