src/code/bignum.lisp

   1 ;;;; code to implement bignum support
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!BIGNUM")
  13 \f
  14 ;;;; notes
  15
  16 ;;; comments from CMU CL:
  17 ;;;   These symbols define the interface to the number code:
  18 ;;;       add-bignums multiply-bignums negate-bignum subtract-bignum
  19 ;;;       multiply-bignum-and-fixnum multiply-fixnums
  20 ;;;       bignum-ashift-right bignum-ashift-left bignum-gcd
  21 ;;;       bignum-to-float bignum-integer-length
  22 ;;;       bignum-logical-and bignum-logical-ior bignum-logical-xor
  23 ;;;       bignum-logical-not bignum-load-byte bignum-deposit-byte
  24 ;;;       bignum-truncate bignum-plus-p bignum-compare make-small-bignum
  25 ;;;       bignum-logbitp bignum-logcount
  26 ;;;   These symbols define the interface to the compiler:
  27 ;;;       bignum-type bignum-element-type bignum-index %allocate-bignum
  28 ;;;       %bignum-length %bignum-set-length %bignum-ref %bignum-set
  29 ;;;       %digit-0-or-plusp %add-with-carry %subtract-with-borrow
  30 ;;;       %multiply-and-add %multiply %lognot %logand %logior %logxor
  31 ;;;       %fixnum-to-digit %floor %fixnum-digit-with-correct-sign %ashl
  32 ;;;       %ashr %digit-logical-shift-right))
  33
  34 ;;; The following interfaces will either be assembler routines or code
  35 ;;; sequences expanded into the code as basic bignum operations:
  36 ;;;    General:
  37 ;;;       %BIGNUM-LENGTH
  38 ;;;       %ALLOCATE-BIGNUM
  39 ;;;       %BIGNUM-REF
  40 ;;;       %NORMALIZE-BIGNUM
  41 ;;;       %BIGNUM-SET-LENGTH
  42 ;;;       %FIXNUM-DIGIT-WITH-CORRECT-SIGN
  43 ;;;       %SIGN-DIGIT
  44 ;;;       %ASHR
  45 ;;;       %ASHL
  46 ;;;       %BIGNUM-0-OR-PLUSP
  47 ;;;       %DIGIT-LOGICAL-SHIFT-RIGHT
  48 ;;;    General (May not exist when done due to sole use in %-routines.)
  49 ;;;       %DIGIT-0-OR-PLUSP
  50 ;;;    Addition:
  51 ;;;       %ADD-WITH-CARRY
  52 ;;;    Subtraction:
  53 ;;;       %SUBTRACT-WITH-BORROW
  54 ;;;    Multiplication
  55 ;;;       %MULTIPLY
  56 ;;;    Negation
  57 ;;;       %LOGNOT
  58 ;;;    Shifting (in place)
  59 ;;;       %NORMALIZE-BIGNUM-BUFFER
  60 ;;;    GCD/Relational operators:
  61 ;;;       %DIGIT-COMPARE
  62 ;;;       %DIGIT-GREATER
  63 ;;;    Relational operators:
  64 ;;;       %LOGAND
  65 ;;;       %LOGIOR
  66 ;;;       %LOGXOR
  67 ;;;    LDB
  68 ;;;       %FIXNUM-TO-DIGIT
  69 ;;;    TRUNCATE
  70 ;;;       %FLOOR
  71 ;;;
  72 ;;; Note: The floating routines know about the float representation.
  73 ;;;
  74 ;;; PROBLEM 1:
  75 ;;; There might be a problem with various LET's and parameters that take a
  76 ;;; digit value. We need to write these so those things stay in machine
  77 ;;; registers and number stack slots. I bind locals to these values, and I
  78 ;;; use function on them -- ZEROP, ASH, etc.
  79 ;;;
  80 ;;; PROBLEM 2:
  81 ;;; In shifting and byte operations, I use masks and logical operations that
  82 ;;; could result in intermediate bignums. This is hidden by the current system,
  83 ;;; but I may need to write these in a way that keeps these masks and logical
  84 ;;; operations from diving into the Lisp level bignum code.
  85 ;;;
  86 ;;; To do:
  87 ;;;    fixnums
  88 ;;;       logior, logxor, logand
  89 ;;;       depending on relationals, < (twice) and <= (twice)
  90 ;;;       or write compare thing (twice).
  91 ;;;       LDB on fixnum with bignum result.
  92 ;;;       DPB on fixnum with bignum result.
  93 ;;;       TRUNCATE returns zero or one as one value and fixnum or minus fixnum
  94 ;;;       for the other value when given (truncate fixnum bignum).
  95 ;;;       Returns (truncate bignum fixnum) otherwise.
  96 ;;;       addition
  97 ;;;       subtraction (twice)
  98 ;;;       multiply
  99 ;;;       GCD
 100 ;;;    Write MASK-FIELD and DEPOSIT-FIELD in terms of logical operations.
 101 ;;;    DIVIDE
 102 ;;;       IF (/ x y) with bignums:
 103 ;;;       do the truncate, and if rem is 0, return quotient.
 104 ;;;       if rem is non-0
 105 ;;;          gcd of x and y.
 106 ;;;          "truncate" each by gcd, ignoring remainder 0.
 107 ;;;          form ratio of each result, bottom is positive.
 108 \f
 109 ;;;; What's a bignum?
 110
 111 (defconstant digit-size sb!vm:n-word-bits)
 112
 113 (defconstant maximum-bignum-length (1- (ash 1 (- sb!vm:n-word-bits
 114                                                  sb!vm:n-widetag-bits))))
 115
 116 (defconstant all-ones-digit (1- (ash 1 sb!vm:n-word-bits)))
 117 \f
 118 ;;;; internal inline routines
 119
 120 ;;; %ALLOCATE-BIGNUM must zero all elements.
 121 (defun %allocate-bignum (length)
 122   (declare (type bignum-index length))
 123   (%allocate-bignum length))
 124
 125 ;;; Extract the length of the bignum.
 126 (defun %bignum-length (bignum)
 127   (declare (type bignum-type bignum))
 128   (%bignum-length bignum))
 129
 130 ;;; %BIGNUM-REF needs to access bignums as obviously as possible, and it needs
 131 ;;; to be able to return the digit somewhere no one looks for real objects.
 132 (defun %bignum-ref (bignum i)
 133   (declare (type bignum-type bignum)
 134            (type bignum-index i))
 135   (%bignum-ref bignum i))
 136 (defun %bignum-set (bignum i value)
 137   (declare (type bignum-type bignum)
 138            (type bignum-index i)
 139            (type bignum-element-type value))
 140   (%bignum-set bignum i value))
 141
 142 ;;; Return T if digit is positive, or NIL if negative.
 143 (defun %digit-0-or-plusp (digit)
 144   (declare (type bignum-element-type digit))
 145   (not (logbitp (1- digit-size) digit)))
 146
 147 #!-sb-fluid (declaim (inline %bignum-0-or-plusp))
 148 (defun %bignum-0-or-plusp (bignum len)
 149   (declare (type bignum-type bignum)
 150            (type bignum-index len))
 151   (%digit-0-or-plusp (%bignum-ref bignum (1- len))))
 152
 153 ;;; This should be in assembler, and should not cons intermediate
 154 ;;; results. It returns a bignum digit and a carry resulting from adding
 155 ;;; together a, b, and an incoming carry.
 156 (defun %add-with-carry (a b carry)
 157   (declare (type bignum-element-type a b)
 158            (type (mod 2) carry))
 159   (%add-with-carry a b carry))
 160
 161 ;;; This should be in assembler, and should not cons intermediate
 162 ;;; results. It returns a bignum digit and a borrow resulting from
 163 ;;; subtracting b from a, and subtracting a possible incoming borrow.
 164 ;;;
 165 ;;; We really do:  a - b - 1 + borrow, where borrow is either 0 or 1.
 166 (defun %subtract-with-borrow (a b borrow)
 167   (declare (type bignum-element-type a b)
 168            (type (mod 2) borrow))
 169   (%subtract-with-borrow a b borrow))
 170
 171 ;;; Multiply two digit-size numbers, returning a 2*digit-size result
 172 ;;; split into two digit-size quantities.
 173 (defun %multiply (x y)
 174   (declare (type bignum-element-type x y))
 175   (%multiply x y))
 176
 177 ;;; This multiplies x-digit and y-digit, producing high and low digits
 178 ;;; manifesting the result. Then it adds the low digit, res-digit, and
 179 ;;; carry-in-digit. Any carries (note, you still have to add two digits
 180 ;;; at a time possibly producing two carries) from adding these three
 181 ;;; digits get added to the high digit from the multiply, producing the
 182 ;;; next carry digit.  Res-digit is optional since two uses of this
 183 ;;; primitive multiplies a single digit bignum by a multiple digit
 184 ;;; bignum, and in this situation there is no need for a result buffer
 185 ;;; accumulating partial results which is where the res-digit comes
 186 ;;; from.
 187 (defun %multiply-and-add (x-digit y-digit carry-in-digit
 188                           &optional (res-digit 0))
 189   (declare (type bignum-element-type x-digit y-digit res-digit carry-in-digit))
 190   (%multiply-and-add x-digit y-digit carry-in-digit res-digit))
 191
 192 (defun %lognot (digit)
 193   (declare (type bignum-element-type digit))
 194   (%lognot digit))
 195
 196 ;;; Each of these does the digit-size unsigned op.
 197 #!-sb-fluid (declaim (inline %logand %logior %logxor))
 198 (defun %logand (a b)
 199   (declare (type bignum-element-type a b))
 200   (logand a b))
 201 (defun %logior (a b)
 202   (declare (type bignum-element-type a b))
 203   (logior a b))
 204 (defun %logxor (a b)
 205   (declare (type bignum-element-type a b))
 206   (logxor a b))
 207
 208 ;;; This takes a fixnum and sets it up as an unsigned digit-size
 209 ;;; quantity.
 210 (defun %fixnum-to-digit (x)
 211   (declare (fixnum x))
 212   (logand x (1- (ash 1 digit-size))))
 213
 214 #!-32x16-divide
 215 ;;; This takes three digits and returns the FLOOR'ed result of
 216 ;;; dividing the first two as a 2*digit-size integer by the third.
 217 ;;;
 218 ;;; Do weird LET and SETQ stuff to bamboozle the compiler into allowing
 219 ;;; the %FLOOR transform to expand into pseudo-assembler for which the
 220 ;;; compiler can later correctly allocate registers.
 221 (defun %floor (a b c)
 222   (let ((a a) (b b) (c c))
 223     (declare (type bignum-element-type a b c))
 224     (setq a a b b c c)
 225     (%floor a b c)))
 226
 227 ;;; Convert the digit to a regular integer assuming that the digit is signed.
 228 (defun %fixnum-digit-with-correct-sign (digit)
 229   (declare (type bignum-element-type digit))
 230   (if (logbitp (1- digit-size) digit)
 231       (logior digit (ash -1 digit-size))
 232       digit))
 233
 234 ;;; Do an arithmetic shift right of data even though bignum-element-type is
 235 ;;; unsigned.
 236 (defun %ashr (data count)
 237   (declare (type bignum-element-type data)
 238            (type (mod #.sb!vm:n-word-bits) count))
 239   (%ashr data count))
 240
 241 ;;; This takes a digit-size quantity and shifts it to the left,
 242 ;;; returning a digit-size quantity.
 243 (defun %ashl (data count)
 244   (declare (type bignum-element-type data)
 245            (type (mod #.sb!vm:n-word-bits) count))
 246   (%ashl data count))
 247
 248 ;;; Do an unsigned (logical) right shift of a digit by Count.
 249 (defun %digit-logical-shift-right (data count)
 250   (declare (type bignum-element-type data)
 251            (type (mod #.sb!vm:n-word-bits) count))
 252   (%digit-logical-shift-right data count))
 253
 254 ;;; Change the length of bignum to be newlen. Newlen must be the same or
 255 ;;; smaller than the old length, and any elements beyond newlen must be zeroed.
 256 (defun %bignum-set-length (bignum newlen)
 257   (declare (type bignum-type bignum)
 258            (type bignum-index newlen))
 259   (%bignum-set-length bignum newlen))
 260
 261 ;;; This returns 0 or "-1" depending on whether the bignum is positive. This
 262 ;;; is suitable for infinite sign extension to complete additions,
 263 ;;; subtractions, negations, etc. This cannot return a -1 represented as
 264 ;;; a negative fixnum since it would then have to low zeros.
 265 #!-sb-fluid (declaim (inline %sign-digit))
 266 (defun %sign-digit (bignum len)
 267   (declare (type bignum-type bignum)
 268            (type bignum-index len))
 269   (%ashr (%bignum-ref bignum (1- len)) (1- digit-size)))
 270
 271 ;;; These take two digit-size quantities and compare or contrast them
 272 ;;; without wasting time with incorrect type checking.
 273 #!-sb-fluid (declaim (inline %digit-compare %digit-greater))
 274 (defun %digit-compare (x y)
 275   (= x y))
 276 (defun %digit-greater (x y)
 277   (> x y))
 278 \f
 279 (declaim (optimize (speed 3) (safety 0)))
 280 \f
 281 ;;;; addition
 282
 283 (defun add-bignums (a b)
 284   (declare (type bignum-type a b))
 285   (let ((len-a (%bignum-length a))
 286         (len-b (%bignum-length b)))
 287     (declare (type bignum-index len-a len-b))
 288     (multiple-value-bind (a len-a b len-b)
 289         (if (> len-a len-b)
 290             (values a len-a b len-b)
 291             (values b len-b a len-a))
 292       (declare (type bignum-type a b)
 293                (type bignum-index len-a len-b))
 294       (let* ((len-res (1+ len-a))
 295              (res (%allocate-bignum len-res))
 296              (carry 0))
 297         (declare (type bignum-index len-res)
 298                  (type bignum-type res)
 299                  (type (mod 2) carry))
 300         (dotimes (i len-b)
 301           (declare (type bignum-index i))
 302           (multiple-value-bind (v k)
 303               (%add-with-carry (%bignum-ref a i) (%bignum-ref b i) carry)
 304             (declare (type bignum-element-type v)
 305                      (type (mod 2) k))
 306             (setf (%bignum-ref res i) v)
 307             (setf carry k)))
 308         (if (/= len-a len-b)
 309             (finish-add a res carry (%sign-digit b len-b) len-b len-a)
 310             (setf (%bignum-ref res len-a)
 311                   (%add-with-carry (%sign-digit a len-a)
 312                                    (%sign-digit b len-b)
 313                                    carry)))
 314         (%normalize-bignum res len-res)))))
 315
 316 ;;; This takes the longer of two bignums and propagates the carry through its
 317 ;;; remaining high order digits.
 318 (defun finish-add (a res carry sign-digit-b start end)
 319   (declare (type bignum-type a res)
 320            (type (mod 2) carry)
 321            (type bignum-element-type sign-digit-b)
 322            (type bignum-index start end))
 323   (do ((i start (1+ i)))
 324       ((= i end)
 325        (setf (%bignum-ref res end)
 326              (%add-with-carry (%sign-digit a end) sign-digit-b carry)))
 327     (declare (type bignum-index i))
 328     (multiple-value-bind (v k)
 329         (%add-with-carry (%bignum-ref a i) sign-digit-b carry)
 330       (setf (%bignum-ref res i) v)
 331       (setf carry k)))
 332   (values))
 333 \f
 334 ;;;; subtraction
 335
 336 (eval-when (:compile-toplevel :execute)
 337
 338 ;;; This subtracts b from a plugging result into res. Return-fun is the
 339 ;;; function to call that fixes up the result returning any useful values, such
 340 ;;; as the result. This macro may evaluate its arguments more than once.
 341 (sb!xc:defmacro subtract-bignum-loop (a len-a b len-b res len-res return-fun)
 342   (let ((borrow (gensym))
 343         (a-digit (gensym))
 344         (a-sign (gensym))
 345         (b-digit (gensym))
 346         (b-sign (gensym))
 347         (i (gensym))
 348         (v (gensym))
 349         (k (gensym)))
 350     `(let* ((,borrow 1)
 351             (,a-sign (%sign-digit ,a ,len-a))
 352             (,b-sign (%sign-digit ,b ,len-b)))
 353        (declare (type bignum-element-type ,a-sign ,b-sign))
 354        (dotimes (,i ,len-res)
 355          (declare (type bignum-index ,i))
 356          (let ((,a-digit (if (< ,i ,len-a) (%bignum-ref ,a ,i) ,a-sign))
 357                (,b-digit (if (< ,i ,len-b) (%bignum-ref ,b ,i) ,b-sign)))
 358            (declare (type bignum-element-type ,a-digit ,b-digit))
 359            (multiple-value-bind (,v ,k)
 360                (%subtract-with-borrow ,a-digit ,b-digit ,borrow)
 361              (setf (%bignum-ref ,res ,i) ,v)
 362              (setf ,borrow ,k))))
 363        (,return-fun ,res ,len-res))))
 364
 365 ) ;EVAL-WHEN
 366
 367 (defun subtract-bignum (a b)
 368   (declare (type bignum-type a b))
 369   (let* ((len-a (%bignum-length a))
 370          (len-b (%bignum-length b))
 371          (len-res (1+ (max len-a len-b)))
 372          (res (%allocate-bignum len-res)))
 373     (declare (type bignum-index len-a len-b len-res)) ;Test len-res for bounds?
 374     (subtract-bignum-loop a len-a b len-b res len-res %normalize-bignum)))
 375
 376 ;;; Operations requiring a subtraction without the overhead of intermediate
 377 ;;; results, such as GCD, use this. It assumes Result is big enough for the
 378 ;;; result.
 379 (defun subtract-bignum-buffers-with-len (a len-a b len-b result len-res)
 380   (declare (type bignum-type a b)
 381            (type bignum-index len-a len-b))
 382   (subtract-bignum-loop a len-a b len-b result len-res
 383                         %normalize-bignum-buffer))
 384
 385 (defun subtract-bignum-buffers (a len-a b len-b result)
 386   (declare (type bignum-type a b)
 387            (type bignum-index len-a len-b))
 388   (subtract-bignum-loop a len-a b len-b result (max len-a len-b)
 389                         %normalize-bignum-buffer))
 390 \f
 391 ;;;; multiplication
 392
 393 (defun multiply-bignums (a b)
 394   (declare (type bignum-type a b))
 395   (let* ((a-plusp (%bignum-0-or-plusp a (%bignum-length a)))
 396          (b-plusp (%bignum-0-or-plusp b (%bignum-length b)))
 397          (a (if a-plusp a (negate-bignum a)))
 398          (b (if b-plusp b (negate-bignum b)))
 399          (len-a (%bignum-length a))
 400          (len-b (%bignum-length b))
 401          (len-res (+ len-a len-b))
 402          (res (%allocate-bignum len-res))
 403          (negate-res (not (eq a-plusp b-plusp))))
 404     (declare (type bignum-index len-a len-b len-res))
 405     (dotimes (i len-a)
 406       (declare (type bignum-index i))
 407       (let ((carry-digit 0)
 408             (x (%bignum-ref a i))
 409             (k i))
 410         (declare (type bignum-index k)
 411                  (type bignum-element-type carry-digit x))
 412         (dotimes (j len-b)
 413           (multiple-value-bind (big-carry res-digit)
 414               (%multiply-and-add x
 415                                  (%bignum-ref b j)
 416                                  (%bignum-ref res k)
 417                                  carry-digit)
 418             (declare (type bignum-element-type big-carry res-digit))
 419             (setf (%bignum-ref res k) res-digit)
 420             (setf carry-digit big-carry)
 421             (incf k)))
 422         (setf (%bignum-ref res k) carry-digit)))
 423     (when negate-res (negate-bignum-in-place res))
 424     (%normalize-bignum res len-res)))
 425
 426 (defun multiply-bignum-and-fixnum (bignum fixnum)
 427   (declare (type bignum-type bignum) (type fixnum fixnum))
 428   (let* ((bignum-plus-p (%bignum-0-or-plusp bignum (%bignum-length bignum)))
 429          (fixnum-plus-p (not (minusp fixnum)))
 430          (bignum (if bignum-plus-p bignum (negate-bignum bignum)))
 431          (bignum-len (%bignum-length bignum))
 432          (fixnum (if fixnum-plus-p fixnum (- fixnum)))
 433          (result (%allocate-bignum (1+ bignum-len)))
 434          (carry-digit 0))
 435     (declare (type bignum-type bignum result)
 436              (type bignum-index bignum-len)
 437              (type bignum-element-type fixnum carry-digit))
 438     (dotimes (index bignum-len)
 439       (declare (type bignum-index index))
 440       (multiple-value-bind (next-digit low)
 441           (%multiply-and-add (%bignum-ref bignum index) fixnum carry-digit)
 442         (declare (type bignum-element-type next-digit low))
 443         (setf carry-digit next-digit)
 444         (setf (%bignum-ref result index) low)))
 445     (setf (%bignum-ref result bignum-len) carry-digit)
 446     (unless (eq bignum-plus-p fixnum-plus-p)
 447       (negate-bignum-in-place result))
 448     (%normalize-bignum result (1+ bignum-len))))
 449
 450 (defun multiply-fixnums (a b)
 451   (declare (fixnum a b))
 452   (let* ((a-minusp (minusp a))
 453          (b-minusp (minusp b)))
 454     (multiple-value-bind (high low)
 455         (%multiply (if a-minusp (- a) a)
 456                    (if b-minusp (- b) b))
 457       (declare (type bignum-element-type high low))
 458       (if (and (zerop high)
 459                (%digit-0-or-plusp low))
 460           (let ((low (sb!ext:truly-the (unsigned-byte #.(1- sb!vm:n-word-bits))
 461                                        (%fixnum-digit-with-correct-sign low))))
 462             (if (eq a-minusp b-minusp)
 463                 low
 464                 (- low)))
 465           (let ((res (%allocate-bignum 2)))
 466             (%bignum-set res 0 low)
 467             (%bignum-set res 1 high)
 468             (unless (eq a-minusp b-minusp) (negate-bignum-in-place res))
 469             (%normalize-bignum res 2))))))
 470 \f
 471 ;;;; BIGNUM-REPLACE and WITH-BIGNUM-BUFFERS
 472
 473 (eval-when (:compile-toplevel :execute)
 474
 475 (sb!xc:defmacro bignum-replace (dest
 476                                 src
 477                                 &key
 478                                 (start1 '0)
 479                                 end1
 480                                 (start2 '0)
 481                                 end2
 482                                 from-end)
 483   (sb!int:once-only ((n-dest dest)
 484                      (n-src src))
 485     (let ((n-start1 (gensym))
 486           (n-end1 (gensym))
 487           (n-start2 (gensym))
 488           (n-end2 (gensym))
 489           (i1 (gensym))
 490           (i2 (gensym))
 491           (end1 (or end1 `(%bignum-length ,n-dest)))
 492           (end2 (or end2 `(%bignum-length ,n-src))))
 493       (if from-end
 494           `(let ((,n-start1 ,start1)
 495                  (,n-start2 ,start2))
 496              (do ((,i1 (1- ,end1) (1- ,i1))
 497                   (,i2 (1- ,end2) (1- ,i2)))
 498                  ((or (< ,i1 ,n-start1) (< ,i2 ,n-start2)))
 499                (declare (fixnum ,i1 ,i2))
 500                (%bignum-set ,n-dest ,i1
 501                             (%bignum-ref ,n-src ,i2))))
 502           `(let ((,n-end1 ,end1)
 503                  (,n-end2 ,end2))
 504              (do ((,i1 ,start1 (1+ ,i1))
 505                   (,i2 ,start2 (1+ ,i2)))
 506                  ((or (>= ,i1 ,n-end1) (>= ,i2 ,n-end2)))
 507                (declare (type bignum-index ,i1 ,i2))
 508                (%bignum-set ,n-dest ,i1
 509                             (%bignum-ref ,n-src ,i2))))))))
 510
 511 (sb!xc:defmacro with-bignum-buffers (specs &body body)
 512   #!+sb-doc
 513   "WITH-BIGNUM-BUFFERS ({(var size [init])}*) Form*"
 514   (sb!int:collect ((binds)
 515                    (inits))
 516     (dolist (spec specs)
 517       (let ((name (first spec))
 518             (size (second spec)))
 519         (binds `(,name (%allocate-bignum ,size)))
 520         (let ((init (third spec)))
 521           (when init
 522             (inits `(bignum-replace ,name ,init))))))
 523     `(let* ,(binds)
 524        ,@(inits)
 525        ,@body)))
 526
 527 ) ;EVAL-WHEN
 528 \f
 529 ;;;; GCD
 530
 531 (eval-when (:compile-toplevel :load-toplevel :execute)
 532   ;; The asserts in the GCD implementation are way too expensive to
 533   ;; check in normal use, and are disabled here.
 534   (sb!xc:defmacro gcd-assert (&rest args)
 535     (if nil
 536         `(assert ,@args)))
 537   ;; We'll be doing a lot of modular arithmetic.
 538   (sb!xc:defmacro M (form)
 539     `(logand all-ones-digit ,form)))
 540
 541 ;;; I'm not sure why I need this FTYPE declaration.  Compiled by the
 542 ;;; target compiler, it can deduce the return type fine, but without
 543 ;;; it, we pay a heavy price in BIGNUM-GCD when compiled by the
 544 ;;; cross-compiler. -- CSR, 2004-07-19
 545 (declaim (ftype (sfunction (bignum-type bignum-index bignum-type bignum-index)
 546                            sb!vm::positive-fixnum)
 547                 bignum-factors-of-two))
 548 (defun bignum-factors-of-two (a len-a b len-b)
 549   (declare (type bignum-index len-a len-b) (type bignum-type a b))
 550   (do ((i 0 (1+ i))
 551        (end (min len-a len-b)))
 552       ((= i end) (error "Unexpected zero bignums?"))
 553     (declare (type bignum-index i end))
 554     (let ((or-digits (%logior (%bignum-ref a i) (%bignum-ref b i))))
 555       (unless (zerop or-digits)
 556         (return (do ((j 0 (1+ j))
 557                      (or-digits or-digits (%ashr or-digits 1)))
 558                     ((oddp or-digits) (+ (* i digit-size) j))
 559                   (declare (type (mod #.sb!vm:n-word-bits) j))))))))
 560
 561 ;;; Multiply a bignum buffer with a fixnum or a digit, storing the
 562 ;;; result in another bignum buffer, and without using any
 563 ;;; temporaries. Inlined to avoid boxing smallnum if it's actually a
 564 ;;; digit. Needed by GCD, should possibly OAOO with
 565 ;;; MULTIPLY-BIGNUM-AND-FIXNUM.
 566 (declaim (inline multiply-bignum-buffer-and-smallnum-to-buffer))
 567 (defun multiply-bignum-buffer-and-smallnum-to-buffer (bignum bignum-len
 568                                                              smallnum res)
 569   (declare (type bignum-type bignum))
 570   (let* ((bignum-plus-p (%bignum-0-or-plusp bignum bignum-len))
 571          (smallnum-plus-p (not (minusp smallnum)))
 572          (smallnum (if smallnum-plus-p smallnum (- smallnum)))
 573          (carry-digit 0))
 574     (declare (type bignum-type bignum res)
 575              (type bignum-index bignum-len)
 576              (type bignum-element-type smallnum carry-digit))
 577     (unless bignum-plus-p
 578       (negate-bignum-buffer-in-place bignum bignum-len))
 579     (dotimes (index bignum-len)
 580       (declare (type bignum-index index))
 581       (multiple-value-bind (next-digit low)
 582           (%multiply-and-add (%bignum-ref bignum index)
 583                              smallnum
 584                              carry-digit)
 585         (declare (type bignum-element-type next-digit low))
 586         (setf carry-digit next-digit)
 587         (setf (%bignum-ref res index) low)))
 588     (setf (%bignum-ref res bignum-len) carry-digit)
 589     (unless bignum-plus-p
 590       (negate-bignum-buffer-in-place bignum bignum-len))
 591     (let ((res-len (%normalize-bignum-buffer res (1+ bignum-len))))
 592       (unless (eq bignum-plus-p smallnum-plus-p)
 593         (negate-bignum-buffer-in-place res res-len))
 594       res-len)))
 595
 596 ;;; Given U and V, return U / V mod 2^32. Implements the algorithm in the
 597 ;;; paper, but uses some clever bit-twiddling nicked from Nickle to do it.
 598 (declaim (inline bmod))
 599 (defun bmod (u v)
 600   (let ((ud (%bignum-ref u 0))
 601         (vd (%bignum-ref v 0))
 602         (umask 0)
 603         (imask 1)
 604         (m 0))
 605     (declare (type (unsigned-byte #.sb!vm:n-word-bits) ud vd umask imask m))
 606     (dotimes (i digit-size)
 607       (setf umask (logior umask imask))
 608       (unless (zerop (logand ud umask))
 609         (setf ud (M (- ud vd)))
 610         (setf m (M (logior m imask))))
 611       (setf imask (M (ash imask 1)))
 612       (setf vd (M (ash vd 1))))
 613     m))
 614
 615 (defun dmod (u u-len v v-len tmp1)
 616   (loop while (> (bignum-buffer-integer-length u u-len)
 617                  (+ (bignum-buffer-integer-length v v-len)
 618                     digit-size))
 619     do
 620     (unless (zerop (%bignum-ref u 0))
 621       (let* ((bmod (bmod u v))
 622              (tmp1-len (multiply-bignum-buffer-and-smallnum-to-buffer v v-len
 623                                                                       bmod
 624                                                                       tmp1)))
 625         (setf u-len (subtract-bignum-buffers u u-len
 626                                              tmp1 tmp1-len
 627                                              u))
 628         (bignum-abs-buffer u u-len)))
 629     (gcd-assert (zerop (%bignum-ref u 0)))
 630     (setf u-len (bignum-buffer-ashift-right u u-len digit-size)))
 631   (let* ((d (+ 1 (- (bignum-buffer-integer-length u u-len)
 632                     (bignum-buffer-integer-length v v-len))))
 633          (n (1- (ash 1 d))))
 634     (declare (type (unsigned-byte #.(integer-length #.sb!vm:n-word-bits)) d)
 635              (type (unsigned-byte #.sb!vm:n-word-bits) n))
 636     (gcd-assert (>= d 0))
 637     (unless (zerop (logand (%bignum-ref u 0) n))
 638       (let ((tmp1-len
 639              (multiply-bignum-buffer-and-smallnum-to-buffer v v-len
 640                                                             (logand n (bmod u
 641                                                                             v))
 642                                                             tmp1)))
 643         (setf u-len (subtract-bignum-buffers u u-len
 644                                              tmp1 tmp1-len
 645                                              u))
 646         (bignum-abs-buffer u u-len)))
 647     u-len))
 648
 649 (defconstant lower-ones-digit (1- (ash 1 (truncate sb!vm:n-word-bits 2))))
 650
 651 ;;; Find D and N such that (LOGAND ALL-ONES-DIGIT (- (* D X) (* N Y))) is 0,
 652 ;;; (< 0 N LOWER-ONES-DIGIT) and (< 0 (ABS D) LOWER-ONES-DIGIT).
 653 (defun reduced-ratio-mod (x y)
 654   (let* ((c (bmod x y))
 655          (n1 c)
 656          (d1 1)
 657          (n2 (M (1+ (M (lognot n1)))))
 658          (d2 (M -1)))
 659     (declare (type (unsigned-byte #.sb!vm:n-word-bits) n1 d1 n2 d2))
 660     (loop while (> n2 (expt 2 (truncate digit-size 2))) do
 661           (loop for i of-type (mod #.sb!vm:n-word-bits)
 662                 downfrom (- (integer-length n1) (integer-length n2))
 663                 while (>= n1 n2) do
 664                 (when (>= n1 (M (ash n2 i)))
 665                   (psetf n1 (M (- n1 (M (ash n2 i))))
 666                          d1 (M (- d1 (M (ash d2 i)))))))
 667           (psetf n1 n2
 668                  d1 d2
 669                  n2 n1
 670                  d2 d1))
 671     (values n2 (if (>= d2 (expt 2 (1- digit-size)))
 672                    (lognot (logand most-positive-fixnum (lognot d2)))
 673                    (logand lower-ones-digit d2)))))
 674
 675
 676 (defun copy-bignum (a &optional (len (%bignum-length a)))
 677   (let ((b (%allocate-bignum len)))
 678     (bignum-replace b a)
 679     (%bignum-set-length b len)
 680     b))
 681
 682 ;;; Allocate a single word bignum that holds fixnum. This is useful when
 683 ;;; we are trying to mix fixnum and bignum operands.
 684 #!-sb-fluid (declaim (inline make-small-bignum))
 685 (defun make-small-bignum (fixnum)
 686   (let ((res (%allocate-bignum 1)))
 687     (setf (%bignum-ref res 0) (%fixnum-to-digit fixnum))
 688     res))
 689
 690 ;; When the larger number is less than this many bignum digits long, revert
 691 ;; to old algorithm.
 692 (defparameter *accelerated-gcd-cutoff* 3)
 693
 694 ;;; Alternate between k-ary reduction with the help of
 695 ;;; REDUCED-RATIO-MOD and digit modulus reduction via DMOD. Once the
 696 ;;; arguments get small enough, drop through to BIGNUM-MOD-GCD (since
 697 ;;; k-ary reduction can introduce spurious factors, which need to be
 698 ;;; filtered out). Reference: Kenneth Weber, "The accelerated integer
 699 ;;; GCD algorithm", ACM Transactions on Mathematical Software, volume
 700 ;;; 21, number 1, March 1995, epp. 111-122.
 701 (defun bignum-gcd (u0 v0)
 702   (declare (type bignum-type u0 v0))
 703   (let* ((u1 (if (%bignum-0-or-plusp u0 (%bignum-length u0))
 704                  u0
 705                  (negate-bignum u0 nil)))
 706          (v1 (if (%bignum-0-or-plusp v0 (%bignum-length v0))
 707                  v0
 708                  (negate-bignum v0 nil))))
 709     (if (zerop v1)
 710         (return-from bignum-gcd u1))
 711     (when (> u1 v1)
 712       (rotatef u1 v1))
 713     (let ((n (mod v1 u1)))
 714       (setf v1 (if (fixnump n)
 715                    (make-small-bignum n)
 716                    n)))
 717     (if (and (= 1 (%bignum-length v1))
 718              (zerop (%bignum-ref v1 0)))
 719         (return-from bignum-gcd (%normalize-bignum u1
 720                                                    (%bignum-length u1))))
 721     (let* ((buffer-len (+ 2 (%bignum-length u1)))
 722            (u (%allocate-bignum buffer-len))
 723            (u-len (%bignum-length u1))
 724            (v (%allocate-bignum buffer-len))
 725            (v-len (%bignum-length v1))
 726            (tmp1 (%allocate-bignum buffer-len))
 727            (tmp1-len 0)
 728            (tmp2 (%allocate-bignum buffer-len))
 729            (tmp2-len 0)
 730            (factors-of-two
 731             (bignum-factors-of-two u1 (%bignum-length u1)
 732                                    v1 (%bignum-length v1))))
 733       (declare (type (or null bignum-index)
 734                      buffer-len u-len v-len tmp1-len tmp2-len))
 735       (bignum-replace u u1)
 736       (bignum-replace v v1)
 737       (setf u-len
 738             (make-gcd-bignum-odd u
 739                                  (bignum-buffer-ashift-right u u-len
 740                                                              factors-of-two)))
 741       (setf v-len
 742             (make-gcd-bignum-odd v
 743                                  (bignum-buffer-ashift-right v v-len
 744                                                              factors-of-two)))
 745       (loop until (or (< u-len *accelerated-gcd-cutoff*)
 746                       (not v-len)
 747                       (zerop v-len)
 748                       (and (= 1 v-len)
 749                            (zerop (%bignum-ref v 0))))
 750         do
 751         (gcd-assert (= buffer-len (%bignum-length u)
 752                        (%bignum-length v)
 753                        (%bignum-length tmp1)
 754                        (%bignum-length tmp2)))
 755         (if (> (bignum-buffer-integer-length u u-len)
 756                (+ #.(truncate sb!vm:n-word-bits 4)
 757                   (bignum-buffer-integer-length v v-len)))
 758             (setf u-len (dmod u u-len
 759                               v v-len
 760                               tmp1))
 761             (multiple-value-bind (n d) (reduced-ratio-mod u v)
 762               (setf tmp1-len
 763                     (multiply-bignum-buffer-and-smallnum-to-buffer v v-len
 764                                                                    n tmp1))
 765               (setf tmp2-len
 766                     (multiply-bignum-buffer-and-smallnum-to-buffer u u-len
 767                                                                    d tmp2))
 768               (gcd-assert (= (copy-bignum tmp2 tmp2-len)
 769                              (* (copy-bignum u u-len) d)))
 770               (gcd-assert (= (copy-bignum tmp1 tmp1-len)
 771                              (* (copy-bignum v v-len) n)))
 772               (setf u-len
 773                     (subtract-bignum-buffers-with-len tmp1 tmp1-len
 774                                                       tmp2 tmp2-len
 775                                                       u
 776                                                       (1+ (max tmp1-len
 777                                                                tmp2-len))))
 778               (gcd-assert (or (zerop (- (copy-bignum tmp1 tmp1-len)
 779                                         (copy-bignum tmp2 tmp2-len)))
 780                               (= (copy-bignum u u-len)
 781                                  (- (copy-bignum tmp1 tmp1-len)
 782                                     (copy-bignum tmp2 tmp2-len)))))
 783               (bignum-abs-buffer u u-len)
 784               (gcd-assert (zerop (M u)))))
 785         (setf u-len (make-gcd-bignum-odd u u-len))
 786         (rotatef u v)
 787         (rotatef u-len v-len))
 788       (setf u (copy-bignum u u-len))
 789       (let ((n (bignum-mod-gcd v1 u)))
 790         (ash (bignum-mod-gcd u1 (if (fixnump n)
 791                                     (make-small-bignum n)
 792                                     n))
 793              factors-of-two)))))
 794
 795 (defun bignum-mod-gcd (a b)
 796   (declare (type bignum-type a b))
 797   (when (< a b)
 798     (rotatef a b))
 799   ;; While the length difference of A and B is sufficiently large,
 800   ;; reduce using MOD (slowish, but it should equalize the sizes of
 801   ;; A and B pretty quickly). After that, use the binary GCD
 802   ;; algorithm to handle the rest.
 803   (loop until (and (= (%bignum-length b) 1) (zerop (%bignum-ref b 0))) do
 804         (when (<= (%bignum-length a) (1+ (%bignum-length b)))
 805           (return-from bignum-mod-gcd (bignum-binary-gcd a b)))
 806         (let ((rem (mod a b)))
 807           (if (fixnump rem)
 808               (setf a (make-small-bignum rem))
 809               (setf a rem))
 810           (rotatef a b)))
 811   (if (= (%bignum-length a) 1)
 812       (%normalize-bignum a 1)
 813       a))
 814
 815 (defun bignum-binary-gcd (a b)
 816   (declare (type bignum-type a b))
 817   (let* ((len-a (%bignum-length a))
 818          (len-b (%bignum-length b)))
 819     (declare (type bignum-index len-a len-b))
 820     (with-bignum-buffers ((a-buffer len-a a)
 821                           (b-buffer len-b b)
 822                           (res-buffer (max len-a len-b)))
 823       (let* ((factors-of-two
 824               (bignum-factors-of-two a-buffer len-a
 825                                      b-buffer len-b))
 826              (len-a (make-gcd-bignum-odd
 827                      a-buffer
 828                      (bignum-buffer-ashift-right a-buffer len-a
 829                                                  factors-of-two)))
 830              (len-b (make-gcd-bignum-odd
 831                      b-buffer
 832                      (bignum-buffer-ashift-right b-buffer len-b
 833                                                  factors-of-two))))
 834         (declare (type bignum-index len-a len-b))
 835         (let ((x a-buffer)
 836               (len-x len-a)
 837               (y b-buffer)
 838               (len-y len-b)
 839               (z res-buffer))
 840           (loop
 841             (multiple-value-bind (u v len-v r len-r)
 842                 (bignum-gcd-order-and-subtract x len-x y len-y z)
 843               (declare (type bignum-index len-v len-r))
 844               (when (and (= len-r 1) (zerop (%bignum-ref r 0)))
 845                 (if (zerop factors-of-two)
 846                     (let ((ret (%allocate-bignum len-v)))
 847                       (dotimes (i len-v)
 848                         (setf (%bignum-ref ret i) (%bignum-ref v i)))
 849                       (return (%normalize-bignum ret len-v)))
 850                     (return (bignum-ashift-left v factors-of-two len-v))))
 851               (setf x v  len-x len-v)
 852               (setf y r  len-y (make-gcd-bignum-odd r len-r))
 853               (setf z u))))))))
 854
 855 (defun bignum-gcd-order-and-subtract (a len-a b len-b res)
 856   (declare (type bignum-index len-a len-b) (type bignum-type a b))
 857   (cond ((= len-a len-b)
 858          (do ((i (1- len-a) (1- i)))
 859              ((= i -1)
 860               (setf (%bignum-ref res 0) 0)
 861               (values a b len-b res 1))
 862            (let ((a-digit (%bignum-ref a i))
 863                  (b-digit (%bignum-ref b i)))
 864              (cond ((%digit-compare a-digit b-digit))
 865                    ((%digit-greater a-digit b-digit)
 866                     (return
 867                      (values a b len-b res
 868                              (subtract-bignum-buffers a len-a b len-b
 869                                                       res))))
 870                    (t
 871                     (return
 872                      (values b a len-a res
 873                              (subtract-bignum-buffers b len-b
 874                                                       a len-a
 875                                                       res))))))))
 876         ((> len-a len-b)
 877          (values a b len-b res
 878                  (subtract-bignum-buffers a len-a b len-b res)))
 879         (t
 880          (values b a len-a res
 881                  (subtract-bignum-buffers b len-b a len-a res)))))
 882
 883 (defun make-gcd-bignum-odd (a len-a)
 884   (declare (type bignum-type a) (type bignum-index len-a))
 885   (dotimes (index len-a)
 886     (declare (type bignum-index index))
 887     (do ((digit (%bignum-ref a index) (%ashr digit 1))
 888          (increment 0 (1+ increment)))
 889         ((zerop digit))
 890       (declare (type (mod #.sb!vm:n-word-bits) increment))
 891       (when (oddp digit)
 892         (return-from make-gcd-bignum-odd
 893                      (bignum-buffer-ashift-right a len-a
 894                                                  (+ (* index digit-size)
 895                                                     increment)))))))
 896
 897 \f
 898 ;;;; negation
 899
 900 (eval-when (:compile-toplevel :execute)
 901
 902 ;;; This negates bignum-len digits of bignum, storing the resulting digits into
 903 ;;; result (possibly EQ to bignum) and returning whatever end-carry there is.
 904 (sb!xc:defmacro bignum-negate-loop (bignum
 905                                     bignum-len
 906                                     &optional (result nil resultp))
 907   (let ((carry (gensym))
 908         (end (gensym))
 909         (value (gensym))
 910         (last (gensym)))
 911     `(let* (,@(if (not resultp) `(,last))
 912             (,carry
 913              (multiple-value-bind (,value ,carry)
 914                  (%add-with-carry (%lognot (%bignum-ref ,bignum 0)) 1 0)
 915                ,(if resultp
 916                     `(setf (%bignum-ref ,result 0) ,value)
 917                     `(setf ,last ,value))
 918                ,carry))
 919             (i 1)
 920             (,end ,bignum-len))
 921        (declare (type bit ,carry)
 922                 (type bignum-index i ,end))
 923        (loop
 924          (when (= i ,end) (return))
 925          (multiple-value-bind (,value temp)
 926              (%add-with-carry (%lognot (%bignum-ref ,bignum i)) 0 ,carry)
 927            ,(if resultp
 928                 `(setf (%bignum-ref ,result i) ,value)
 929                 `(setf ,last ,value))
 930            (setf ,carry temp))
 931          (incf i))
 932        ,(if resultp carry `(values ,carry ,last)))))
 933
 934 ) ; EVAL-WHEN
 935
 936 ;;; Fully-normalize is an internal optional. It cause this to always return
 937 ;;; a bignum, without any extraneous digits, and it never returns a fixnum.
 938 (defun negate-bignum (x &optional (fully-normalize t))
 939   (declare (type bignum-type x))
 940   (let* ((len-x (%bignum-length x))
 941          (len-res (1+ len-x))
 942          (res (%allocate-bignum len-res)))
 943     (declare (type bignum-index len-x len-res)) ;Test len-res for range?
 944     (let ((carry (bignum-negate-loop x len-x res)))
 945       (setf (%bignum-ref res len-x)
 946             (%add-with-carry (%lognot (%sign-digit x len-x)) 0 carry)))
 947     (if fully-normalize
 948         (%normalize-bignum res len-res)
 949         (%mostly-normalize-bignum res len-res))))
 950
 951 ;;; This assumes bignum is positive; that is, the result of negating it will
 952 ;;; stay in the provided allocated bignum.
 953 (defun negate-bignum-buffer-in-place (bignum bignum-len)
 954   (bignum-negate-loop bignum bignum-len bignum)
 955   bignum)
 956
 957 (defun negate-bignum-in-place (bignum)
 958   (declare (inline negate-bignum-buffer-in-place))
 959   (negate-bignum-buffer-in-place bignum (%bignum-length bignum)))
 960
 961 (defun bignum-abs-buffer (bignum len)
 962   (unless (%bignum-0-or-plusp bignum len)
 963     (negate-bignum-in-place bignum len)))
 964 \f
 965 ;;;; shifting
 966
 967 (eval-when (:compile-toplevel :execute)
 968
 969 ;;; This macro is used by BIGNUM-ASHIFT-RIGHT, BIGNUM-BUFFER-ASHIFT-RIGHT, and
 970 ;;; BIGNUM-LDB-BIGNUM-RES. They supply a termination form that references
 971 ;;; locals established by this form. Source is the source bignum. Start-digit
 972 ;;; is the first digit in source from which we pull bits. Start-pos is the
 973 ;;; first bit we want. Res-len-form is the form that computes the length of
 974 ;;; the resulting bignum. Termination is a DO termination form with a test and
 975 ;;; body. When result is supplied, it is the variable to which this binds a
 976 ;;; newly allocated bignum.
 977 ;;;
 978 ;;; Given start-pos, 1-31 inclusively, of shift, we form the j'th resulting
 979 ;;; digit from high bits of the i'th source digit and the start-pos number of
 980 ;;; bits from the i+1'th source digit.
 981 (sb!xc:defmacro shift-right-unaligned (source
 982                                        start-digit
 983                                        start-pos
 984                                        res-len-form
 985                                        termination
 986                                        &optional result)
 987   `(let* ((high-bits-in-first-digit (- digit-size ,start-pos))
 988           (res-len ,res-len-form)
 989           (res-len-1 (1- res-len))
 990           ,@(if result `((,result (%allocate-bignum res-len)))))
 991      (declare (type bignum-index res-len res-len-1))
 992      (do ((i ,start-digit i+1)
 993           (i+1 (1+ ,start-digit) (1+ i+1))
 994           (j 0 (1+ j)))
 995          ,termination
 996        (declare (type bignum-index i i+1 j))
 997        (setf (%bignum-ref ,(if result result source) j)
 998              (%logior (%digit-logical-shift-right (%bignum-ref ,source i)
 999                                                   ,start-pos)
1000                       (%ashl (%bignum-ref ,source i+1)
1001                              high-bits-in-first-digit))))))
1002
1003 ) ; EVAL-WHEN
1004
1005 ;;; First compute the number of whole digits to shift, shifting them by
1006 ;;; skipping them when we start to pick up bits, and the number of bits to
1007 ;;; shift the remaining digits into place. If the number of digits is greater
1008 ;;; than the length of the bignum, then the result is either 0 or -1. If we
1009 ;;; shift on a digit boundary (that is, n-bits is zero), then we just copy
1010 ;;; digits. The last branch handles the general case which uses a macro that a
1011 ;;; couple other routines use. The fifth argument to the macro references
1012 ;;; locals established by the macro.
1013 (defun bignum-ashift-right (bignum count)
1014   (declare (type bignum-type bignum)
1015            (type unsigned-byte count))
1016   (let ((bignum-len (%bignum-length bignum)))
1017     (declare (type bignum-index bignum-len))
1018     (cond ((fixnump count)
1019            (multiple-value-bind (digits n-bits) (truncate count digit-size)
1020              (declare (type bignum-index digits))
1021              (cond
1022               ((>= digits bignum-len)
1023                (if (%bignum-0-or-plusp bignum bignum-len) 0 -1))
1024               ((zerop n-bits)
1025                (bignum-ashift-right-digits bignum digits))
1026               (t
1027                (shift-right-unaligned bignum digits n-bits (- bignum-len digits)
1028                                       ((= j res-len-1)
1029                                        (setf (%bignum-ref res j)
1030                                              (%ashr (%bignum-ref bignum i) n-bits))
1031                                        (%normalize-bignum res res-len))
1032                                       res)))))
1033           ((> count bignum-len)
1034            (if (%bignum-0-or-plusp bignum bignum-len) 0 -1))
1035            ;; Since a FIXNUM should be big enough to address anything in
1036            ;; memory, including arrays of bits, and since arrays of bits
1037            ;; take up about the same space as corresponding fixnums, there
1038            ;; should be no way that we fall through to this case: any shift
1039            ;; right by a bignum should give zero. But let's check anyway:
1040           (t (error "bignum overflow: can't shift right by ~S" count)))))
1041
1042 (defun bignum-ashift-right-digits (bignum digits)
1043   (declare (type bignum-type bignum)
1044            (type bignum-index digits))
1045   (let* ((res-len (- (%bignum-length bignum) digits))
1046          (res (%allocate-bignum res-len)))
1047     (declare (type bignum-index res-len)
1048              (type bignum-type res))
1049     (bignum-replace res bignum :start2 digits)
1050     (%normalize-bignum res res-len)))
1051
1052 ;;; GCD uses this for an in-place shifting operation. This is different enough
1053 ;;; from BIGNUM-ASHIFT-RIGHT that it isn't worth folding the bodies into a
1054 ;;; macro, but they share the basic algorithm. This routine foregoes a first
1055 ;;; test for digits being greater than or equal to bignum-len since that will
1056 ;;; never happen for its uses in GCD. We did fold the last branch into a macro
1057 ;;; since it was duplicated a few times, and the fifth argument to it
1058 ;;; references locals established by the macro.
1059 (defun bignum-buffer-ashift-right (bignum bignum-len x)
1060   (declare (type bignum-index bignum-len) (fixnum x))
1061   (multiple-value-bind (digits n-bits) (truncate x digit-size)
1062     (declare (type bignum-index digits))
1063     (cond
1064      ((zerop n-bits)
1065       (let ((new-end (- bignum-len digits)))
1066         (bignum-replace bignum bignum :end1 new-end :start2 digits
1067                         :end2 bignum-len)
1068         (%normalize-bignum-buffer bignum new-end)))
1069      (t
1070       (shift-right-unaligned bignum digits n-bits (- bignum-len digits)
1071                              ((= j res-len-1)
1072                               (setf (%bignum-ref bignum j)
1073                                     (%ashr (%bignum-ref bignum i) n-bits))
1074                               (%normalize-bignum-buffer bignum res-len)))))))
1075
1076 ;;; This handles shifting a bignum buffer to provide fresh bignum data for some
1077 ;;; internal routines. We know bignum is safe when called with bignum-len.
1078 ;;; First we compute the number of whole digits to shift, shifting them
1079 ;;; starting to store farther along the result bignum. If we shift on a digit
1080 ;;; boundary (that is, n-bits is zero), then we just copy digits. The last
1081 ;;; branch handles the general case.
1082 (defun bignum-ashift-left (bignum x &optional bignum-len)
1083   (declare (type bignum-type bignum)
1084            (type unsigned-byte x)
1085            (type (or null bignum-index) bignum-len))
1086   (if (fixnump x)
1087     (multiple-value-bind (digits n-bits) (truncate x digit-size)
1088       (let* ((bignum-len (or bignum-len (%bignum-length bignum)))
1089              (res-len (+ digits bignum-len 1)))
1090         (when (> res-len maximum-bignum-length)
1091           (error "can't represent result of left shift"))
1092         (if (zerop n-bits)
1093           (bignum-ashift-left-digits bignum bignum-len digits)
1094           (bignum-ashift-left-unaligned bignum digits n-bits res-len))))
1095     ;; Left shift by a number too big to be represented as a fixnum
1096     ;; would exceed our memory capacity, since a fixnum is big enough
1097     ;; to index any array, including a bit array.
1098     (error "can't represent result of left shift")))
1099
1100 (defun bignum-ashift-left-digits (bignum bignum-len digits)
1101   (declare (type bignum-index bignum-len digits))
1102   (let* ((res-len (+ bignum-len digits))
1103          (res (%allocate-bignum res-len)))
1104     (declare (type bignum-index res-len))
1105     (bignum-replace res bignum :start1 digits :end1 res-len :end2 bignum-len
1106                     :from-end t)
1107     res))
1108
1109 ;;; BIGNUM-TRUNCATE uses this to store into a bignum buffer by supplying res.
1110 ;;; When res comes in non-nil, then this foregoes allocating a result, and it
1111 ;;; normalizes the buffer instead of the would-be allocated result.
1112 ;;;
1113 ;;; We start storing into one digit higher than digits, storing a whole result
1114 ;;; digit from parts of two contiguous digits from bignum. When the loop
1115 ;;; finishes, we store the remaining bits from bignum's first digit in the
1116 ;;; first non-zero result digit, digits. We also grab some left over high
1117 ;;; bits from the last digit of bignum.
1118 (defun bignum-ashift-left-unaligned (bignum digits n-bits res-len
1119                                      &optional (res nil resp))
1120   (declare (type bignum-index digits res-len)
1121            (type (mod #.digit-size) n-bits))
1122   (let* ((remaining-bits (- digit-size n-bits))
1123          (res-len-1 (1- res-len))
1124          (res (or res (%allocate-bignum res-len))))
1125     (declare (type bignum-index res-len res-len-1))
1126     (do ((i 0 i+1)
1127          (i+1 1 (1+ i+1))
1128          (j (1+ digits) (1+ j)))
1129         ((= j res-len-1)
1130          (setf (%bignum-ref res digits)
1131                (%ashl (%bignum-ref bignum 0) n-bits))
1132          (setf (%bignum-ref res j)
1133                (%ashr (%bignum-ref bignum i) remaining-bits))
1134          (if resp
1135              (%normalize-bignum-buffer res res-len)
1136              (%normalize-bignum res res-len)))
1137       (declare (type bignum-index i i+1 j))
1138       (setf (%bignum-ref res j)
1139             (%logior (%digit-logical-shift-right (%bignum-ref bignum i)
1140                                                  remaining-bits)
1141                      (%ashl (%bignum-ref bignum i+1) n-bits))))))
1142 \f
1143 ;;;; relational operators
1144
1145 ;;; Return T iff bignum is positive.
1146 (defun bignum-plus-p (bignum)
1147   (declare (type bignum-type bignum))
1148   (%bignum-0-or-plusp bignum (%bignum-length bignum)))
1149
1150 ;;; This compares two bignums returning -1, 0, or 1, depending on
1151 ;;; whether a is less than, equal to, or greater than b.
1152 (declaim (ftype (function (bignum bignum) (integer -1 1)) bignum-compare))
1153 (defun bignum-compare (a b)
1154   (declare (type bignum-type a b))
1155   (let* ((len-a (%bignum-length a))
1156          (len-b (%bignum-length b))
1157          (a-plusp (%bignum-0-or-plusp a len-a))
1158          (b-plusp (%bignum-0-or-plusp b len-b)))
1159     (declare (type bignum-index len-a len-b))
1160     (cond ((not (eq a-plusp b-plusp))
1161            (if a-plusp 1 -1))
1162           ((= len-a len-b)
1163            (do ((i (1- len-a) (1- i)))
1164                (())
1165              (declare (type bignum-index i))
1166              (let ((a-digit (%bignum-ref a i))
1167                    (b-digit (%bignum-ref b i)))
1168                (declare (type bignum-element-type a-digit b-digit))
1169                (when (%digit-greater a-digit b-digit)
1170                  (return 1))
1171                (when (%digit-greater b-digit a-digit)
1172                  (return -1)))
1173              (when (zerop i) (return 0))))
1174           ((> len-a len-b)
1175            (if a-plusp 1 -1))
1176           (t (if a-plusp -1 1)))))
1177 \f
1178 ;;;; float conversion
1179
1180 ;;; Make a single or double float with the specified significand,
1181 ;;; exponent and sign.
1182 (defun single-float-from-bits (bits exp plusp)
1183   (declare (fixnum exp))
1184   (declare (optimize #-sb-xc-host (sb!ext:inhibit-warnings 3)))
1185   (let ((res (dpb exp
1186                   sb!vm:single-float-exponent-byte
1187                   (logandc2 (sb!ext:truly-the (unsigned-byte #.(1- sb!vm:n-word-bits))
1188                                               (%bignum-ref bits 1))
1189                             sb!vm:single-float-hidden-bit))))
1190     (make-single-float
1191      (if plusp
1192          res
1193          (logior res (ash -1 sb!vm:float-sign-shift))))))
1194 (defun double-float-from-bits (bits exp plusp)
1195   (declare (fixnum exp))
1196   (declare (optimize #-sb-xc-host (sb!ext:inhibit-warnings 3)))
1197   (let ((hi (dpb exp
1198                  sb!vm:double-float-exponent-byte
1199                  (logandc2 (sb!ext:truly-the (unsigned-byte #.(1- sb!vm:n-word-bits))
1200                                              (%bignum-ref bits 2))
1201                            sb!vm:double-float-hidden-bit))))
1202     (make-double-float
1203      (if plusp
1204          hi
1205          (logior hi (ash -1 sb!vm:float-sign-shift)))
1206      (%bignum-ref bits 1))))
1207 #!+(and long-float x86)
1208 (defun long-float-from-bits (bits exp plusp)
1209   (declare (fixnum exp))
1210   (declare (optimize #-sb-xc-host (sb!ext:inhibit-warnings 3)))
1211   (make-long-float
1212    (if plusp
1213        exp
1214        (logior exp (ash 1 15)))
1215    (%bignum-ref bits 2)
1216    (%bignum-ref bits 1)))
1217
1218 ;;; Convert Bignum to a float in the specified Format, rounding to the best
1219 ;;; approximation.
1220 (defun bignum-to-float (bignum format)
1221   (let* ((plusp (bignum-plus-p bignum))
1222          (x (if plusp bignum (negate-bignum bignum)))
1223          (len (bignum-integer-length x))
1224          (digits (float-format-digits format))
1225          (keep (+ digits digit-size))
1226          (shift (- keep len))
1227          (shifted (if (minusp shift)
1228                       (bignum-ashift-right x (- shift))
1229                       (bignum-ashift-left x shift)))
1230          (low (%bignum-ref shifted 0))
1231          (round-bit (ash 1 (1- digit-size))))
1232     (declare (type bignum-index len digits keep) (fixnum shift))
1233     (labels ((round-up ()
1234                (let ((rounded (add-bignums shifted round-bit)))
1235                  (if (> (integer-length rounded) keep)
1236                      (float-from-bits (bignum-ashift-right rounded 1)
1237                                       (1+ len))
1238                      (float-from-bits rounded len))))
1239              (float-from-bits (bits len)
1240                (declare (type bignum-index len))
1241                (ecase format
1242                  (single-float
1243                   (single-float-from-bits
1244                    bits
1245                    (check-exponent len sb!vm:single-float-bias
1246                                    sb!vm:single-float-normal-exponent-max)
1247                    plusp))
1248                  (double-float
1249                   (double-float-from-bits
1250                    bits
1251                    (check-exponent len sb!vm:double-float-bias
1252                                    sb!vm:double-float-normal-exponent-max)
1253                    plusp))
1254                  #!+long-float
1255                  (long-float
1256                   (long-float-from-bits
1257                    bits
1258                    (check-exponent len sb!vm:long-float-bias
1259                                    sb!vm:long-float-normal-exponent-max)
1260                    plusp))))
1261              (check-exponent (exp bias max)
1262                (declare (type bignum-index len))
1263                (let ((exp (+ exp bias)))
1264                  (when (> exp max)
1265                    ;; Why a SIMPLE-TYPE-ERROR? Well, this is mainly
1266                    ;; called by COERCE, which requires an error of
1267                    ;; TYPE-ERROR if the conversion can't happen
1268                    ;; (except in certain circumstances when we are
1269                    ;; coercing to a FUNCTION) -- CSR, 2002-09-18
1270                    (error 'simple-type-error
1271                           :format-control "Too large to be represented as a ~S:~%  ~S"
1272                           :format-arguments (list format x)
1273                           :expected-type format
1274                           :datum x))
1275                  exp)))
1276
1277     (cond
1278      ;; Round down if round bit is 0.
1279      ((zerop (logand round-bit low))
1280       (float-from-bits shifted len))
1281      ;; If only round bit is set, then round to even.
1282      ((and (= low round-bit)
1283            (dotimes (i (- (%bignum-length x) (ceiling keep digit-size))
1284                        t)
1285              (unless (zerop (%bignum-ref x i)) (return nil))))
1286       (let ((next (%bignum-ref shifted 1)))
1287         (if (oddp next)
1288             (round-up)
1289             (float-from-bits shifted len))))
1290      ;; Otherwise, round up.
1291      (t
1292       (round-up))))))
1293 \f
1294 ;;;; integer length and logbitp/logcount
1295
1296 (defun bignum-buffer-integer-length (bignum len)
1297   (declare (type bignum-type bignum))
1298   (let* ((len-1 (1- len))
1299          (digit (%bignum-ref bignum len-1)))
1300     (declare (type bignum-index len len-1)
1301              (type bignum-element-type digit))
1302     (+ (integer-length (%fixnum-digit-with-correct-sign digit))
1303        (* len-1 digit-size))))
1304
1305 (defun bignum-integer-length (bignum)
1306   (declare (type bignum-type bignum))
1307   (bignum-buffer-integer-length bignum (%bignum-length bignum)))
1308
1309 (defun bignum-logbitp (index bignum)
1310   (declare (type bignum-type bignum))
1311   (let ((len (%bignum-length bignum)))
1312     (declare (type bignum-index len))
1313     (multiple-value-bind (word-index bit-index)
1314         (floor index digit-size)
1315       (if (>= word-index len)
1316           (not (bignum-plus-p bignum))
1317           (not (zerop (logand (%bignum-ref bignum word-index)
1318                               (ash 1 bit-index))))))))
1319
1320 (defun bignum-logcount (bignum)
1321   (declare (type bignum-type bignum))
1322   (let* ((length (%bignum-length bignum))
1323          (plusp (%bignum-0-or-plusp bignum length))
1324          (result 0))
1325     (declare (type bignum-index length)
1326              (fixnum result))
1327     (do ((index 0 (1+ index)))
1328         ((= index length) result)
1329       (let ((digit (%bignum-ref bignum index)))
1330         (declare (type bignum-element-type digit))
1331         (incf result (logcount (if plusp digit (%lognot digit))))))))
1332 \f
1333 ;;;; logical operations
1334
1335 ;;;; NOT
1336
1337 (defun bignum-logical-not (a)
1338   (declare (type bignum-type a))
1339   (let* ((len (%bignum-length a))
1340          (res (%allocate-bignum len)))
1341     (declare (type bignum-index len))
1342     (dotimes (i len res)
1343       (declare (type bignum-index i))
1344       (setf (%bignum-ref res i) (%lognot (%bignum-ref a i))))))
1345
1346 ;;;; AND
1347
1348 (defun bignum-logical-and (a b)
1349   (declare (type bignum-type a b))
1350   (let* ((len-a (%bignum-length a))
1351          (len-b (%bignum-length b))
1352          (a-plusp (%bignum-0-or-plusp a len-a))
1353          (b-plusp (%bignum-0-or-plusp b len-b)))
1354     (declare (type bignum-index len-a len-b))
1355     (cond
1356      ((< len-a len-b)
1357       (if a-plusp
1358           (logand-shorter-positive a len-a b (%allocate-bignum len-a))
1359           (logand-shorter-negative a len-a b len-b (%allocate-bignum len-b))))
1360      ((< len-b len-a)
1361       (if b-plusp
1362           (logand-shorter-positive b len-b a (%allocate-bignum len-b))
1363           (logand-shorter-negative b len-b a len-a (%allocate-bignum len-a))))
1364      (t (logand-shorter-positive a len-a b (%allocate-bignum len-a))))))
1365
1366 ;;; This takes a shorter bignum, a and len-a, that is positive. Because this
1367 ;;; is AND, we don't care about any bits longer than a's since its infinite 0
1368 ;;; sign bits will mask the other bits out of b. The result is len-a big.
1369 (defun logand-shorter-positive (a len-a b res)
1370   (declare (type bignum-type a b res)
1371            (type bignum-index len-a))
1372   (dotimes (i len-a)
1373     (declare (type bignum-index i))
1374     (setf (%bignum-ref res i)
1375           (%logand (%bignum-ref a i) (%bignum-ref b i))))
1376   (%normalize-bignum res len-a))
1377
1378 ;;; This takes a shorter bignum, a and len-a, that is negative. Because this
1379 ;;; is AND, we just copy any bits longer than a's since its infinite 1 sign
1380 ;;; bits will include any bits from b. The result is len-b big.
1381 (defun logand-shorter-negative (a len-a b len-b res)
1382   (declare (type bignum-type a b res)
1383            (type bignum-index len-a len-b))
1384   (dotimes (i len-a)
1385     (declare (type bignum-index i))
1386     (setf (%bignum-ref res i)
1387           (%logand (%bignum-ref a i) (%bignum-ref b i))))
1388   (do ((i len-a (1+ i)))
1389       ((= i len-b))
1390     (declare (type bignum-index i))
1391     (setf (%bignum-ref res i) (%bignum-ref b i)))
1392   (%normalize-bignum res len-b))
1393
1394 ;;;; IOR
1395
1396 (defun bignum-logical-ior (a b)
1397   (declare (type bignum-type a b))
1398   (let* ((len-a (%bignum-length a))
1399          (len-b (%bignum-length b))
1400          (a-plusp (%bignum-0-or-plusp a len-a))
1401          (b-plusp (%bignum-0-or-plusp b len-b)))
1402     (declare (type bignum-index len-a len-b))
1403     (cond
1404      ((< len-a len-b)
1405       (if a-plusp
1406           (logior-shorter-positive a len-a b len-b (%allocate-bignum len-b))
1407           (logior-shorter-negative a len-a b len-b (%allocate-bignum len-b))))
1408      ((< len-b len-a)
1409       (if b-plusp
1410           (logior-shorter-positive b len-b a len-a (%allocate-bignum len-a))
1411           (logior-shorter-negative b len-b a len-a (%allocate-bignum len-a))))
1412      (t (logior-shorter-positive a len-a b len-b (%allocate-bignum len-a))))))
1413
1414 ;;; This takes a shorter bignum, a and len-a, that is positive. Because this
1415 ;;; is IOR, we don't care about any bits longer than a's since its infinite
1416 ;;; 0 sign bits will mask the other bits out of b out to len-b. The result
1417 ;;; is len-b long.
1418 (defun logior-shorter-positive (a len-a b len-b res)
1419   (declare (type bignum-type a b res)
1420            (type bignum-index len-a len-b))
1421   (dotimes (i len-a)
1422     (declare (type bignum-index i))
1423     (setf (%bignum-ref res i)
1424           (%logior (%bignum-ref a i) (%bignum-ref b i))))
1425   (do ((i len-a (1+ i)))
1426       ((= i len-b))
1427     (declare (type bignum-index i))
1428     (setf (%bignum-ref res i) (%bignum-ref b i)))
1429   (%normalize-bignum res len-b))
1430
1431 ;;; This takes a shorter bignum, a and len-a, that is negative. Because this
1432 ;;; is IOR, we just copy any bits longer than a's since its infinite 1 sign
1433 ;;; bits will include any bits from b. The result is len-b long.
1434 (defun logior-shorter-negative (a len-a b len-b res)
1435   (declare (type bignum-type a b res)
1436            (type bignum-index len-a len-b))
1437   (dotimes (i len-a)
1438     (declare (type bignum-index i))
1439     (setf (%bignum-ref res i)
1440           (%logior (%bignum-ref a i) (%bignum-ref b i))))
1441   (do ((i len-a (1+ i))
1442        (sign (%sign-digit a len-a)))
1443       ((= i len-b))
1444     (declare (type bignum-index i))
1445     (setf (%bignum-ref res i) sign))
1446   (%normalize-bignum res len-b))
1447
1448 ;;;; XOR
1449
1450 (defun bignum-logical-xor (a b)
1451   (declare (type bignum-type a b))
1452   (let ((len-a (%bignum-length a))
1453         (len-b (%bignum-length b)))
1454     (declare (type bignum-index len-a len-b))
1455     (if (< len-a len-b)
1456         (bignum-logical-xor-aux a len-a b len-b (%allocate-bignum len-b))
1457         (bignum-logical-xor-aux b len-b a len-a (%allocate-bignum len-a)))))
1458
1459 ;;; This takes the shorter of two bignums in a and len-a. Res is len-b
1460 ;;; long. Do the XOR.
1461 (defun bignum-logical-xor-aux (a len-a b len-b res)
1462   (declare (type bignum-type a b res)
1463            (type bignum-index len-a len-b))
1464   (dotimes (i len-a)
1465     (declare (type bignum-index i))
1466     (setf (%bignum-ref res i)
1467           (%logxor (%bignum-ref a i) (%bignum-ref b i))))
1468   (do ((i len-a (1+ i))
1469        (sign (%sign-digit a len-a)))
1470       ((= i len-b))
1471     (declare (type bignum-index i))
1472     (setf (%bignum-ref res i) (%logxor sign (%bignum-ref b i))))
1473   (%normalize-bignum res len-b))
1474 \f
1475 ;;;; LDB (load byte)
1476
1477 #|
1478 FOR NOW WE DON'T USE LDB OR DPB. WE USE SHIFTS AND MASKS IN NUMBERS.LISP WHICH
1479 IS LESS EFFICIENT BUT EASIER TO MAINTAIN. BILL SAYS THIS CODE CERTAINLY WORKS!
1480
1481 (defconstant maximum-fixnum-bits (- sb!vm:n-word-bits sb!vm:n-lowtag-bits))
1482
1483 (defun bignum-load-byte (byte bignum)
1484   (declare (type bignum-type bignum))
1485   (let ((byte-len (byte-size byte))
1486         (byte-pos (byte-position byte)))
1487     (if (< byte-len maximum-fixnum-bits)
1488         (bignum-ldb-fixnum-res bignum byte-len byte-pos)
1489         (bignum-ldb-bignum-res bignum byte-len byte-pos))))
1490
1491 ;;; This returns a fixnum result of loading a byte from a bignum. In order, we
1492 ;;; check for the following conditions:
1493 ;;;    Insufficient bignum digits to start loading a byte --
1494 ;;;       Return 0 or byte-len 1's depending on sign of bignum.
1495 ;;;    One bignum digit containing the whole byte spec --
1496 ;;;       Grab 'em, shift 'em, and mask out what we don't want.
1497 ;;;    Insufficient bignum digits to cover crossing a digit boundary --
1498 ;;;       Grab the available bits in the last digit, and or in whatever
1499 ;;;       virtual sign bits we need to return a full byte spec.
1500 ;;;    Else (we cross a digit boundary with all bits available) --
1501 ;;;       Make a couple masks, grab what we want, shift it around, and
1502 ;;;       LOGIOR it all together.
1503 ;;; Because (< maximum-fixnum-bits digit-size) and
1504 ;;;      (< byte-len maximum-fixnum-bits),
1505 ;;; we only cross one digit boundary if any.
1506 (defun bignum-ldb-fixnum-res (bignum byte-len byte-pos)
1507   (multiple-value-bind (skipped-digits pos) (truncate byte-pos digit-size)
1508     (let ((bignum-len (%bignum-length bignum))
1509           (s-digits+1 (1+ skipped-digits)))
1510       (declare (type bignum-index bignum-len s-digits+1))
1511       (if (>= skipped-digits bignum-len)
1512           (if (%bignum-0-or-plusp bignum bignum-len)
1513               0
1514               (%make-ones byte-len))
1515           (let ((end (+ pos byte-len)))
1516             (cond ((<= end digit-size)
1517                    (logand (ash (%bignum-ref bignum skipped-digits) (- pos))
1518                            ;; Must LOGAND after shift here.
1519                            (%make-ones byte-len)))
1520                   ((>= s-digits+1 bignum-len)
1521                    (let* ((available-bits (- digit-size pos))
1522                           (res (logand (ash (%bignum-ref bignum skipped-digits)
1523                                             (- pos))
1524                                        ;; LOGAND should be unnecessary here
1525                                        ;; with a logical right shift or a
1526                                        ;; correct digit-sized one.
1527                                        (%make-ones available-bits))))
1528                      (if (%bignum-0-or-plusp bignum bignum-len)
1529                          res
1530                          (logior (%ashl (%make-ones (- end digit-size))
1531                                         available-bits)
1532                                  res))))
1533                   (t
1534                    (let* ((high-bits-in-first-digit (- digit-size pos))
1535                           (high-mask (%make-ones high-bits-in-first-digit))
1536                           (low-bits-in-next-digit (- end digit-size))
1537                           (low-mask (%make-ones low-bits-in-next-digit)))
1538                      (declare (type bignum-element-type high-mask low-mask))
1539                      (logior (%ashl (logand (%bignum-ref bignum s-digits+1)
1540                                             low-mask)
1541                                     high-bits-in-first-digit)
1542                              (logand (ash (%bignum-ref bignum skipped-digits)
1543                                           (- pos))
1544                                      ;; LOGAND should be unnecessary here with
1545                                      ;; a logical right shift or a correct
1546                                      ;; digit-sized one.
1547                                      high-mask))))))))))
1548
1549 ;;; This returns a bignum result of loading a byte from a bignum. In order, we
1550 ;;; check for the following conditions:
1551 ;;;    Insufficient bignum digits to start loading a byte --
1552 ;;;    Byte-pos starting on a digit boundary --
1553 ;;;    Byte spec contained in one bignum digit --
1554 ;;;       Grab the bits we want and stick them in a single digit result.
1555 ;;;       Since we know byte-pos is non-zero here, we know our single digit
1556 ;;;       will have a zero high sign bit.
1557 ;;;    Else (unaligned multiple digits) --
1558 ;;;       This is like doing a shift right combined with either masking
1559 ;;;       out unwanted high bits from bignum or filling in virtual sign
1560 ;;;       bits if bignum had insufficient bits. We use SHIFT-RIGHT-ALIGNED
1561 ;;;       and reference lots of local variables this macro establishes.
1562 (defun bignum-ldb-bignum-res (bignum byte-len byte-pos)
1563   (multiple-value-bind (skipped-digits pos) (truncate byte-pos digit-size)
1564     (let ((bignum-len (%bignum-length bignum)))
1565       (declare (type bignum-index bignum-len))
1566       (cond
1567        ((>= skipped-digits bignum-len)
1568         (make-bignum-virtual-ldb-bits bignum bignum-len byte-len))
1569        ((zerop pos)
1570         (make-aligned-ldb-bignum bignum bignum-len byte-len skipped-digits))
1571        ((< (+ pos byte-len) digit-size)
1572         (let ((res (%allocate-bignum 1)))
1573           (setf (%bignum-ref res 0)
1574                 (logand (%ashr (%bignum-ref bignum skipped-digits) pos)
1575                         (%make-ones byte-len)))
1576           res))
1577        (t
1578         (make-unaligned-ldb-bignum bignum bignum-len
1579                                    byte-len skipped-digits pos))))))
1580
1581 ;;; This returns bits from bignum that don't physically exist. These are
1582 ;;; all zero or one depending on the sign of the bignum.
1583 (defun make-bignum-virtual-ldb-bits (bignum bignum-len byte-len)
1584   (if (%bignum-0-or-plusp bignum bignum-len)
1585       0
1586       (multiple-value-bind (res-len-1 extra) (truncate byte-len digit-size)
1587         (declare (type bignum-index res-len-1))
1588         (let* ((res-len (1+ res-len-1))
1589                (res (%allocate-bignum res-len)))
1590           (declare (type bignum-index res-len))
1591           (do ((j 0 (1+ j)))
1592               ((= j res-len-1)
1593                (setf (%bignum-ref res j) (%make-ones extra))
1594                (%normalize-bignum res res-len))
1595             (declare (type bignum-index j))
1596             (setf (%bignum-ref res j) all-ones-digit))))))
1597
1598 ;;; Since we are picking up aligned digits, we just copy the whole digits
1599 ;;; we want and fill in extra bits. We might have a byte-len that extends
1600 ;;; off the end of the bignum, so we may have to fill in extra 1's if the
1601 ;;; bignum is negative.
1602 (defun make-aligned-ldb-bignum (bignum bignum-len byte-len skipped-digits)
1603   (multiple-value-bind (res-len-1 extra) (truncate byte-len digit-size)
1604     (declare (type bignum-index res-len-1))
1605     (let* ((res-len (1+ res-len-1))
1606            (res (%allocate-bignum res-len)))
1607       (declare (type bignum-index res-len))
1608       (do ((i skipped-digits (1+ i))
1609            (j 0 (1+ j)))
1610           ((or (= j res-len-1) (= i bignum-len))
1611            (cond ((< i bignum-len)
1612                   (setf (%bignum-ref res j)
1613                         (logand (%bignum-ref bignum i)
1614                                 (the bignum-element-type (%make-ones extra)))))
1615                  ((%bignum-0-or-plusp bignum bignum-len))
1616                  (t
1617                   (do ((j j (1+ j)))
1618                       ((= j res-len-1)
1619                        (setf (%bignum-ref res j) (%make-ones extra)))
1620                     (setf (%bignum-ref res j) all-ones-digit))))
1621            (%normalize-bignum res res-len))
1622       (declare (type bignum-index i j))
1623       (setf (%bignum-ref res j) (%bignum-ref bignum i))))))
1624
1625 ;;; This grabs unaligned bignum bits from bignum assuming byte-len causes at
1626 ;;; least one digit boundary crossing. We use SHIFT-RIGHT-UNALIGNED referencing
1627 ;;; lots of local variables established by it.
1628 (defun make-unaligned-ldb-bignum (bignum
1629                                   bignum-len
1630                                   byte-len
1631                                   skipped-digits
1632                                   pos)
1633   (multiple-value-bind (res-len-1 extra) (truncate byte-len digit-size)
1634     (shift-right-unaligned
1635      bignum skipped-digits pos (1+ res-len-1)
1636      ((or (= j res-len-1) (= i+1 bignum-len))
1637       (cond ((= j res-len-1)
1638              (cond
1639               ((< extra high-bits-in-first-digit)
1640                (setf (%bignum-ref res j)
1641                      (logand (ash (%bignum-ref bignum i) minus-start-pos)
1642                              ;; Must LOGAND after shift here.
1643                              (%make-ones extra))))
1644               (t
1645                (setf (%bignum-ref res j)
1646                      (logand (ash (%bignum-ref bignum i) minus-start-pos)
1647                              ;; LOGAND should be unnecessary here with a logical
1648                              ;; right shift or a correct digit-sized one.
1649                              high-mask))
1650                (when (%bignum-0-or-plusp bignum bignum-len)
1651                  (setf (%bignum-ref res j)
1652                        (logior (%bignum-ref res j)
1653                                (%ashl (%make-ones
1654                                        (- extra high-bits-in-first-digit))
1655                                       high-bits-in-first-digit)))))))
1656             (t
1657              (setf (%bignum-ref res j)
1658                    (logand (ash (%bignum-ref bignum i) minus-start-pos)
1659                            ;; LOGAND should be unnecessary here with a logical
1660                            ;; right shift or a correct digit-sized one.
1661                            high-mask))
1662              (unless (%bignum-0-or-plusp bignum bignum-len)
1663                ;; Fill in upper half of this result digit with 1's.
1664                (setf (%bignum-ref res j)
1665                      (logior (%bignum-ref res j)
1666                              (%ashl low-mask high-bits-in-first-digit)))
1667                ;; Fill in any extra 1's we need to be byte-len long.
1668                (do ((j (1+ j) (1+ j)))
1669                    ((>= j res-len-1)
1670                     (setf (%bignum-ref res j) (%make-ones extra)))
1671                  (setf (%bignum-ref res j) all-ones-digit)))))
1672       (%normalize-bignum res res-len))
1673      res)))
1674 \f
1675 ;;;; DPB (deposit byte)
1676
1677 (defun bignum-deposit-byte (new-byte byte-spec bignum)
1678   (declare (type bignum-type bignum))
1679   (let* ((byte-len (byte-size byte-spec))
1680          (byte-pos (byte-position byte-spec))
1681          (bignum-len (%bignum-length bignum))
1682          (bignum-plusp (%bignum-0-or-plusp bignum bignum-len))
1683          (byte-end (+ byte-pos byte-len))
1684          (res-len (1+ (max (ceiling byte-end digit-size) bignum-len)))
1685          (res (%allocate-bignum res-len)))
1686     (declare (type bignum-index bignum-len res-len))
1687     ;; Fill in an extra sign digit in case we set what would otherwise be the
1688     ;; last digit's last bit. Normalize at the end in case this was
1689     ;; unnecessary.
1690     (unless bignum-plusp
1691       (setf (%bignum-ref res (1- res-len)) all-ones-digit))
1692     (multiple-value-bind (end-digit end-bits) (truncate byte-end digit-size)
1693       (declare (type bignum-index end-digit))
1694       ;; Fill in bits from bignum up to byte-pos.
1695       (multiple-value-bind (pos-digit pos-bits) (truncate byte-pos digit-size)
1696         (declare (type bignum-index pos-digit))
1697         (do ((i 0 (1+ i))
1698              (end (min pos-digit bignum-len)))
1699             ((= i end)
1700              (cond ((< i bignum-len)
1701                     (unless (zerop pos-bits)
1702                       (setf (%bignum-ref res i)
1703                             (logand (%bignum-ref bignum i)
1704                                     (%make-ones pos-bits)))))
1705                    (bignum-plusp)
1706                    (t
1707                     (do ((i i (1+ i)))
1708                         ((= i pos-digit)
1709                          (unless (zerop pos-bits)
1710                            (setf (%bignum-ref res i) (%make-ones pos-bits))))
1711                       (setf (%bignum-ref res i) all-ones-digit)))))
1712           (setf (%bignum-ref res i) (%bignum-ref bignum i)))
1713         ;; Fill in bits from new-byte.
1714         (if (typep new-byte 'fixnum)
1715             (deposit-fixnum-bits new-byte byte-len pos-digit pos-bits
1716                                  end-digit end-bits res)
1717             (deposit-bignum-bits new-byte byte-len pos-digit pos-bits
1718                                  end-digit end-bits res)))
1719       ;; Fill in remaining bits from bignum after byte-spec.
1720       (when (< end-digit bignum-len)
1721         (setf (%bignum-ref res end-digit)
1722               (logior (logand (%bignum-ref bignum end-digit)
1723                               (%ashl (%make-ones (- digit-size end-bits))
1724                                      end-bits))
1725                       ;; DEPOSIT-FIXNUM-BITS and DEPOSIT-BIGNUM-BITS only store
1726                       ;; bits from new-byte into res's end-digit element, so
1727                       ;; we don't need to mask out unwanted high bits.
1728                       (%bignum-ref res end-digit)))
1729         (do ((i (1+ end-digit) (1+ i)))
1730             ((= i bignum-len))
1731           (setf (%bignum-ref res i) (%bignum-ref bignum i)))))
1732     (%normalize-bignum res res-len)))
1733
1734 ;;; This starts at result's pos-digit skipping pos-bits, and it stores bits
1735 ;;; from new-byte, a fixnum, into result. It effectively stores byte-len
1736 ;;; number of bits, but never stores past end-digit and end-bits in result.
1737 ;;; The first branch fires when all the bits we want from new-byte are present;
1738 ;;; if byte-len crosses from the current result digit into the next, the last
1739 ;;; argument to DEPOSIT-FIXNUM-DIGIT is a mask for those bits. The second
1740 ;;; branch handles the need to grab more bits than the fixnum new-byte has, but
1741 ;;; new-byte is positive; therefore, any virtual bits are zero. The mask for
1742 ;;; bits that don't fit in the current result digit is simply the remaining
1743 ;;; bits in the bignum digit containing new-byte; we don't care if we store
1744 ;;; some extra in the next result digit since they will be zeros. The last
1745 ;;; branch handles the need to grab more bits than the fixnum new-byte has, but
1746 ;;; new-byte is negative; therefore, any virtual bits must be explicitly filled
1747 ;;; in as ones. We call DEPOSIT-FIXNUM-DIGIT to grab what bits actually exist
1748 ;;; and to fill in the current result digit.
1749 (defun deposit-fixnum-bits (new-byte byte-len pos-digit pos-bits
1750                             end-digit end-bits result)
1751   (declare (type bignum-index pos-digit end-digit))
1752   (let ((other-bits (- digit-size pos-bits))
1753         (new-byte-digit (%fixnum-to-digit new-byte)))
1754     (declare (type bignum-element-type new-byte-digit))
1755     (cond ((< byte-len maximum-fixnum-bits)
1756            (deposit-fixnum-digit new-byte-digit byte-len pos-digit pos-bits
1757                                  other-bits result
1758                                  (- byte-len other-bits)))
1759           ((or (plusp new-byte) (zerop new-byte))
1760            (deposit-fixnum-digit new-byte-digit byte-len pos-digit pos-bits
1761                                  other-bits result pos-bits))
1762           (t
1763            (multiple-value-bind (digit bits)
1764                (deposit-fixnum-digit new-byte-digit byte-len pos-digit pos-bits
1765                                      other-bits result
1766                                      (if (< (- byte-len other-bits) digit-size)
1767                                          (- byte-len other-bits)
1768                                          digit-size))
1769              (declare (type bignum-index digit))
1770              (cond ((< digit end-digit)
1771                     (setf (%bignum-ref result digit)
1772                           (logior (%bignum-ref result digit)
1773                                   (%ashl (%make-ones (- digit-size bits)) bits)))
1774                     (do ((i (1+ digit) (1+ i)))
1775                         ((= i end-digit)
1776                          (setf (%bignum-ref result i) (%make-ones end-bits)))
1777                       (setf (%bignum-ref result i) all-ones-digit)))
1778                    ((> digit end-digit))
1779                    ((< bits end-bits)
1780                     (setf (%bignum-ref result digit)
1781                           (logior (%bignum-ref result digit)
1782                                   (%ashl (%make-ones (- end-bits bits))
1783                                          bits))))))))))
1784
1785 ;;; This fills in the current result digit from new-byte-digit. The first case
1786 ;;; handles everything we want fitting in the current digit, and other-bits is
1787 ;;; the number of bits remaining to be filled in result's current digit. This
1788 ;;; number is digit-size minus pos-bits. The second branch handles filling in
1789 ;;; result's current digit, and it shoves the unused bits of new-byte-digit
1790 ;;; into the next result digit. This is correct regardless of new-byte-digit's
1791 ;;; sign. It returns the new current result digit and how many bits already
1792 ;;; filled in the result digit.
1793 (defun deposit-fixnum-digit (new-byte-digit byte-len pos-digit pos-bits
1794                              other-bits result next-digit-bits-needed)
1795   (declare (type bignum-index pos-digit)
1796            (type bignum-element-type new-byte-digit next-digit-mask))
1797   (cond ((<= byte-len other-bits)
1798          ;; Bits from new-byte fit in the current result digit.
1799          (setf (%bignum-ref result pos-digit)
1800                (logior (%bignum-ref result pos-digit)
1801                        (%ashl (logand new-byte-digit (%make-ones byte-len))
1802                               pos-bits)))
1803          (if (= byte-len other-bits)
1804              (values (1+ pos-digit) 0)
1805              (values pos-digit (+ byte-len pos-bits))))
1806         (t
1807          ;; Some of new-byte's bits go in current result digit.
1808          (setf (%bignum-ref result pos-digit)
1809                (logior (%bignum-ref result pos-digit)
1810                        (%ashl (logand new-byte-digit (%make-ones other-bits))
1811                               pos-bits)))
1812          (let ((pos-digit+1 (1+ pos-digit)))
1813            ;; The rest of new-byte's bits go in the next result digit.
1814            (setf (%bignum-ref result pos-digit+1)
1815                  (logand (ash new-byte-digit (- other-bits))
1816                          ;; Must LOGAND after shift here.
1817                          (%make-ones next-digit-bits-needed)))
1818            (if (= next-digit-bits-needed digit-size)
1819                (values (1+ pos-digit+1) 0)
1820                (values pos-digit+1 next-digit-bits-needed))))))
1821
1822 ;;; This starts at result's pos-digit skipping pos-bits, and it stores bits
1823 ;;; from new-byte, a bignum, into result. It effectively stores byte-len
1824 ;;; number of bits, but never stores past end-digit and end-bits in result.
1825 ;;; When handling a starting bit unaligned with a digit boundary, we check
1826 ;;; in the second branch for the byte spec fitting into the pos-digit element
1827 ;;; after after pos-bits; DEPOSIT-UNALIGNED-BIGNUM-BITS expects at least one
1828 ;;; digit boundary crossing.
1829 (defun deposit-bignum-bits (bignum-byte byte-len pos-digit pos-bits
1830                             end-digit end-bits result)
1831   (declare (type bignum-index pos-digit end-digit))
1832   (cond ((zerop pos-bits)
1833          (deposit-aligned-bignum-bits bignum-byte pos-digit end-digit end-bits
1834                                       result))
1835         ((or (= end-digit pos-digit)
1836              (and (= end-digit (1+ pos-digit))
1837                   (zerop end-bits)))
1838          (setf (%bignum-ref result pos-digit)
1839                (logior (%bignum-ref result pos-digit)
1840                        (%ashl (logand (%bignum-ref bignum-byte 0)
1841                                       (%make-ones byte-len))
1842                               pos-bits))))
1843         (t (deposit-unaligned-bignum-bits bignum-byte pos-digit pos-bits
1844                                           end-digit end-bits result))))
1845
1846 ;;; This deposits bits from bignum-byte into result starting at pos-digit and
1847 ;;; the zero'th bit. It effectively only stores bits to end-bits in the
1848 ;;; end-digit element of result. The loop termination code takes care of
1849 ;;; picking up the last digit's bits or filling in virtual negative sign bits.
1850 (defun deposit-aligned-bignum-bits (bignum-byte pos-digit end-digit end-bits
1851                                     result)
1852   (declare (type bignum-index pos-digit end-digit))
1853   (let* ((bignum-len (%bignum-length bignum-byte))
1854          (bignum-plusp (%bignum-0-or-plusp bignum-byte bignum-len)))
1855     (declare (type bignum-index bignum-len))
1856     (do ((i 0 (1+ i ))
1857          (j pos-digit (1+ j)))
1858         ((or (= j end-digit) (= i bignum-len))
1859          (cond ((= j end-digit)
1860                 (cond ((< i bignum-len)
1861                        (setf (%bignum-ref result j)
1862                              (logand (%bignum-ref bignum-byte i)
1863                                      (%make-ones end-bits))))
1864                       (bignum-plusp)
1865                       (t
1866                        (setf (%bignum-ref result j) (%make-ones end-bits)))))
1867                (bignum-plusp)
1868                (t
1869                 (do ((j j (1+ j)))
1870                     ((= j end-digit)
1871                      (setf (%bignum-ref result j) (%make-ones end-bits)))
1872                   (setf (%bignum-ref result j) all-ones-digit)))))
1873       (setf (%bignum-ref result j) (%bignum-ref bignum-byte i)))))
1874
1875 ;;; This assumes at least one digit crossing.
1876 (defun deposit-unaligned-bignum-bits (bignum-byte pos-digit pos-bits
1877                                       end-digit end-bits result)
1878   (declare (type bignum-index pos-digit end-digit))
1879   (let* ((bignum-len (%bignum-length bignum-byte))
1880          (bignum-plusp (%bignum-0-or-plusp bignum-byte bignum-len))
1881          (low-mask (%make-ones pos-bits))
1882          (bits-past-pos-bits (- digit-size pos-bits))
1883          (high-mask (%make-ones bits-past-pos-bits))
1884          (minus-high-bits (- bits-past-pos-bits)))
1885     (declare (type bignum-element-type low-mask high-mask)
1886              (type bignum-index bignum-len))
1887     (do ((i 0 (1+ i))
1888          (j pos-digit j+1)
1889          (j+1 (1+ pos-digit) (1+ j+1)))
1890         ((or (= j end-digit) (= i bignum-len))
1891          (cond
1892           ((= j end-digit)
1893            (setf (%bignum-ref result j)
1894                  (cond
1895                   ((>= pos-bits end-bits)
1896                    (logand (%bignum-ref result j) (%make-ones end-bits)))
1897                   ((< i bignum-len)
1898                    (logior (%bignum-ref result j)
1899                            (%ashl (logand (%bignum-ref bignum-byte i)
1900                                           (%make-ones (- end-bits pos-bits)))
1901                                   pos-bits)))
1902                   (bignum-plusp
1903                    (logand (%bignum-ref result j)
1904                            ;; 0's between pos-bits and end-bits positions.
1905                            (logior (%ashl (%make-ones (- digit-size end-bits))
1906                                           end-bits)
1907                                    low-mask)))
1908                   (t (logior (%bignum-ref result j)
1909                              (%ashl (%make-ones (- end-bits pos-bits))
1910                                     pos-bits))))))
1911           (bignum-plusp)
1912           (t
1913            (setf (%bignum-ref result j)
1914                  (%ashl (%make-ones bits-past-pos-bits) pos-bits))
1915            (do ((j j+1 (1+ j)))
1916                ((= j end-digit)
1917                 (setf (%bignum-ref result j) (%make-ones end-bits)))
1918              (declare (type bignum-index j))
1919              (setf (%bignum-ref result j) all-ones-digit)))))
1920       (declare (type bignum-index i j j+1))
1921       (let ((digit (%bignum-ref bignum-byte i)))
1922         (declare (type bignum-element-type digit))
1923         (setf (%bignum-ref result j)
1924               (logior (%bignum-ref result j)
1925                       (%ashl (logand digit high-mask) pos-bits)))
1926         (setf (%bignum-ref result j+1)
1927               (logand (ash digit minus-high-bits)
1928                       ;; LOGAND should be unnecessary here with a logical right
1929                       ;; shift or a correct digit-sized one.
1930                       low-mask))))))
1931 |#
1932 \f
1933 ;;;; TRUNCATE
1934
1935 ;;; This is the original sketch of the algorithm from which I implemented this
1936 ;;; TRUNCATE, assuming both operands are bignums. I should modify this to work
1937 ;;; with the documentation on my functions, as a general introduction. I've
1938 ;;; left this here just in case someone needs it in the future. Don't look at
1939 ;;; this unless reading the functions' comments leaves you at a loss. Remember
1940 ;;; this comes from Knuth, so the book might give you the right general
1941 ;;; overview.
1942 ;;;
1943 ;;; (truncate x y):
1944 ;;;
1945 ;;; If X's magnitude is less than Y's, then result is 0 with remainder X.
1946 ;;;
1947 ;;; Make x and y positive, copying x if it is already positive.
1948 ;;;
1949 ;;; Shift y left until there's a 1 in the 30'th bit (most significant, non-sign
1950 ;;;       digit)
1951 ;;;    Just do most sig digit to determine how much to shift whole number.
1952 ;;; Shift x this much too.
1953 ;;; Remember this initial shift count.
1954 ;;;
1955 ;;; Allocate q to be len-x minus len-y quantity plus 1.
1956 ;;;
1957 ;;; i = last digit of x.
1958 ;;; k = last digit of q.
1959 ;;;
1960 ;;; LOOP
1961 ;;;
1962 ;;; j = last digit of y.
1963 ;;;
1964 ;;; compute guess.
1965 ;;; if x[i] = y[j] then g = (1- (ash 1 digit-size))
1966 ;;; else g = x[i]x[i-1]/y[j].
1967 ;;;
1968 ;;; check guess.
1969 ;;; %UNSIGNED-MULTIPLY returns b and c defined below.
1970 ;;;    a = x[i-1] - (logand (* g y[j]) #xFFFFFFFF).
1971 ;;;       Use %UNSIGNED-MULTIPLY taking low-order result.
1972 ;;;    b = (logand (ash (* g y[j-1]) (- digit-size)) (1- (ash 1 digit-size))).
1973 ;;;    c = (logand (* g y[j-1]) (1- (ash 1 digit-size))).
1974 ;;; if a < b, okay.
1975 ;;; if a > b, guess is too high
1976 ;;;    g = g - 1; go back to "check guess".
1977 ;;; if a = b and c > x[i-2], guess is too high
1978 ;;;    g = g - 1; go back to "check guess".
1979 ;;; GUESS IS 32-BIT NUMBER, SO USE THING TO KEEP IN SPECIAL REGISTER
1980 ;;; SAME FOR A, B, AND C.
1981 ;;;
1982 ;;; Subtract g * y from x[i - len-y+1]..x[i]. See paper for doing this in step.
1983 ;;; If x[i] < 0, guess is screwed up.
1984 ;;;    negative g, then add 1
1985 ;;;    zero or positive g, then subtract 1
1986 ;;; AND add y back into x[len-y+1..i].
1987 ;;;
1988 ;;; q[k] = g.
1989 ;;; i = i - 1.
1990 ;;; k = k - 1.
1991 ;;;
1992 ;;; If k>=0, goto LOOP.
1993 ;;;
1994 ;;; Now quotient is good, but remainder is not.
1995 ;;; Shift x right by saved initial left shifting count.
1996 ;;;
1997 ;;; Check quotient and remainder signs.
1998 ;;; x pos y pos --> q pos r pos
1999 ;;; x pos y neg --> q neg r pos
2000 ;;; x neg y pos --> q neg r neg
2001 ;;; x neg y neg --> q pos r neg
2002 ;;;
2003 ;;; Normalize quotient and remainder. Cons result if necessary.
2004
2005
2006 ;;; This used to be split into multiple functions, which shared state
2007 ;;; in special variables *TRUNCATE-X* and *TRUNCATE-Y*. Having so many
2008 ;;; special variable accesses in tight inner loops was having a large
2009 ;;; effect on performance, so the helper functions have now been
2010 ;;; refactored into local functions and the special variables into
2011 ;;; lexicals.  There was also a lot of boxing and unboxing of
2012 ;;; (UNSIGNED-BYTE 32)'s going on, which this refactoring
2013 ;;; eliminated. This improves the performance on some CL-BENCH tests
2014 ;;; by up to 50%, which is probably signigicant enough to justify the
2015 ;;; reduction in readability that was introduced. --JES, 2004-08-07
2016 (defun bignum-truncate (x y)
2017   (declare (type bignum-type x y))
2018   (let (truncate-x truncate-y)
2019     (labels
2020         ;;; Divide X by Y when Y is a single bignum digit. BIGNUM-TRUNCATE
2021         ;;; fixes up the quotient and remainder with respect to sign and
2022         ;;; normalization.
2023         ;;;
2024         ;;; We don't have to worry about shifting Y to make its most
2025         ;;; significant digit sufficiently large for %FLOOR to return
2026         ;;; digit-size quantities for the q-digit and r-digit. If Y is
2027         ;;; a single digit bignum, it is already large enough for
2028         ;;; %FLOOR. That is, it has some bits on pretty high in the
2029         ;;; digit.
2030         ((bignum-truncate-single-digit (x len-x y)
2031            (declare (type bignum-index len-x))
2032            (let ((q (%allocate-bignum len-x))
2033                  (r 0)
2034                  (y (%bignum-ref y 0)))
2035              (declare (type bignum-element-type r y))
2036              (do ((i (1- len-x) (1- i)))
2037                  ((minusp i))
2038                (multiple-value-bind (q-digit r-digit)
2039                    (%floor r (%bignum-ref x i) y)
2040                  (declare (type bignum-element-type q-digit r-digit))
2041                  (setf (%bignum-ref q i) q-digit)
2042                  (setf r r-digit)))
2043              (let ((rem (%allocate-bignum 1)))
2044                (setf (%bignum-ref rem 0) r)
2045                (values q rem))))
2046         ;;; This returns a guess for the next division step. Y1 is the
2047         ;;; highest y digit, and y2 is the second to highest y
2048         ;;; digit. The x... variables are the three highest x digits
2049         ;;; for the next division step.
2050         ;;;
2051         ;;; From Knuth, our guess is either all ones or x-i and x-i-1
2052         ;;; divided by y1, depending on whether x-i and y1 are the
2053         ;;; same. We test this guess by determining whether guess*y2
2054         ;;; is greater than the three high digits of x minus guess*y1
2055         ;;; shifted left one digit:
2056         ;;;    ------------------------------
2057         ;;;   |    x-i    |   x-i-1  | x-i-2 |
2058         ;;;    ------------------------------
2059         ;;;    ------------------------------
2060         ;;; - | g*y1 high | g*y1 low |   0   |
2061         ;;;    ------------------------------
2062         ;;;             ...               <   guess*y2     ???
2063         ;;; If guess*y2 is greater, then we decrement our guess by one
2064         ;;; and try again.  This returns a guess that is either
2065         ;;; correct or one too large.
2066          (bignum-truncate-guess (y1 y2 x-i x-i-1 x-i-2)
2067            (declare (type bignum-element-type y1 y2 x-i x-i-1 x-i-2))
2068            (let ((guess (if (%digit-compare x-i y1)
2069                             all-ones-digit
2070                             (%floor x-i x-i-1 y1))))
2071              (declare (type bignum-element-type guess))
2072              (loop
2073                  (multiple-value-bind (high-guess*y1 low-guess*y1)
2074                      (%multiply guess y1)
2075                    (declare (type bignum-element-type low-guess*y1
2076                                   high-guess*y1))
2077                    (multiple-value-bind (high-guess*y2 low-guess*y2)
2078                        (%multiply guess y2)
2079                      (declare (type bignum-element-type high-guess*y2
2080                                     low-guess*y2))
2081                      (multiple-value-bind (middle-digit borrow)
2082                          (%subtract-with-borrow x-i-1 low-guess*y1 1)
2083                        (declare (type bignum-element-type middle-digit)
2084                                 (fixnum borrow))
2085                        ;; Supplying borrow of 1 means there was no
2086                        ;; borrow, and we know x-i-2 minus 0 requires
2087                        ;; no borrow.
2088                        (let ((high-digit (%subtract-with-borrow x-i
2089                                                                 high-guess*y1
2090                                                                 borrow)))
2091                          (declare (type bignum-element-type high-digit))
2092                          (if (and (%digit-compare high-digit 0)
2093                                   (or (%digit-greater high-guess*y2
2094                                                       middle-digit)
2095                                       (and (%digit-compare middle-digit
2096                                                            high-guess*y2)
2097                                            (%digit-greater low-guess*y2
2098                                                            x-i-2))))
2099                              (setf guess (%subtract-with-borrow guess 1 1))
2100                              (return guess)))))))))
2101         ;;; Divide TRUNCATE-X by TRUNCATE-Y, returning the quotient
2102         ;;; and destructively modifying TRUNCATE-X so that it holds
2103         ;;; the remainder.
2104         ;;;
2105         ;;; LEN-X and LEN-Y tell us how much of the buffers we care about.
2106         ;;;
2107         ;;; TRUNCATE-X definitely has at least three digits, and it has one
2108         ;;; more than TRUNCATE-Y. This keeps i, i-1, i-2, and low-x-digit
2109         ;;; happy. Thanks to SHIFT-AND-STORE-TRUNCATE-BUFFERS.
2110          (return-quotient-leaving-remainder (len-x len-y)
2111            (declare (type bignum-index len-x len-y))
2112            (let* ((len-q (- len-x len-y))
2113                   ;; Add one for extra sign digit in case high bit is on.
2114                   (q (%allocate-bignum (1+ len-q)))
2115                   (k (1- len-q))
2116                   (y1 (%bignum-ref truncate-y (1- len-y)))
2117                   (y2 (%bignum-ref truncate-y (- len-y 2)))
2118                   (i (1- len-x))
2119                   (i-1 (1- i))
2120                   (i-2 (1- i-1))
2121                   (low-x-digit (- i len-y)))
2122              (declare (type bignum-index len-q k i i-1 i-2 low-x-digit)
2123                       (type bignum-element-type y1 y2))
2124              (loop
2125                  (setf (%bignum-ref q k)
2126                        (try-bignum-truncate-guess
2127                         ;; This modifies TRUNCATE-X. Must access
2128                         ;; elements each pass.
2129                         (bignum-truncate-guess y1 y2
2130                                                (%bignum-ref truncate-x i)
2131                                                (%bignum-ref truncate-x i-1)
2132                                                (%bignum-ref truncate-x i-2))
2133                         len-y low-x-digit))
2134                  (cond ((zerop k) (return))
2135                        (t (decf k)
2136                           (decf low-x-digit)
2137                           (shiftf i i-1 i-2 (1- i-2)))))
2138              q))
2139         ;;; This takes a digit guess, multiplies it by TRUNCATE-Y for a
2140         ;;; result one greater in length than LEN-Y, and subtracts this result
2141         ;;; from TRUNCATE-X. LOW-X-DIGIT is the first digit of X to start
2142         ;;; the subtraction, and we know X is long enough to subtract a LEN-Y
2143         ;;; plus one length bignum from it. Next we check the result of the
2144         ;;; subtraction, and if the high digit in X became negative, then our
2145         ;;; guess was one too big. In this case, return one less than GUESS
2146         ;;; passed in, and add one value of Y back into X to account for
2147         ;;; subtracting one too many. Knuth shows that the guess is wrong on
2148         ;;; the order of 3/b, where b is the base (2 to the digit-size power)
2149         ;;; -- pretty rarely.
2150          (try-bignum-truncate-guess (guess len-y low-x-digit)
2151            (declare (type bignum-index low-x-digit len-y)
2152                     (type bignum-element-type guess))
2153            (let ((carry-digit 0)
2154                  (borrow 1)
2155                  (i low-x-digit))
2156              (declare (type bignum-element-type carry-digit)
2157                       (type bignum-index i)
2158                       (fixnum borrow))
2159              ;; Multiply guess and divisor, subtracting from dividend
2160              ;; simultaneously.
2161              (dotimes (j len-y)
2162                (multiple-value-bind (high-digit low-digit)
2163                    (%multiply-and-add guess
2164                                       (%bignum-ref truncate-y j)
2165                                       carry-digit)
2166                  (declare (type bignum-element-type high-digit low-digit))
2167                  (setf carry-digit high-digit)
2168                  (multiple-value-bind (x temp-borrow)
2169                      (%subtract-with-borrow (%bignum-ref truncate-x i)
2170                                             low-digit
2171                                             borrow)
2172                    (declare (type bignum-element-type x)
2173                             (fixnum temp-borrow))
2174                    (setf (%bignum-ref truncate-x i) x)
2175                    (setf borrow temp-borrow)))
2176                (incf i))
2177              (setf (%bignum-ref truncate-x i)
2178                    (%subtract-with-borrow (%bignum-ref truncate-x i)
2179                                           carry-digit borrow))
2180              ;; See whether guess is off by one, adding one
2181              ;; Y back in if necessary.
2182              (cond ((%digit-0-or-plusp (%bignum-ref truncate-x i))
2183                     guess)
2184                    (t
2185                     ;; If subtraction has negative result, add one
2186                     ;; divisor value back in. The guess was one too
2187                     ;; large in magnitude.
2188                     (let ((i low-x-digit)
2189                           (carry 0))
2190                       (dotimes (j len-y)
2191                         (multiple-value-bind (v k)
2192                             (%add-with-carry (%bignum-ref truncate-y j)
2193                                              (%bignum-ref truncate-x i)
2194                                              carry)
2195                           (declare (type bignum-element-type v))
2196                           (setf (%bignum-ref truncate-x i) v)
2197                           (setf carry k))
2198                         (incf i))
2199                       (setf (%bignum-ref truncate-x i)
2200                             (%add-with-carry (%bignum-ref truncate-x i)
2201                                              0 carry)))
2202                     (%subtract-with-borrow guess 1 1)))))
2203         ;;; This returns the amount to shift y to place a one in the
2204         ;;; second highest bit. Y must be positive. If the last digit
2205         ;;; of y is zero, then y has a one in the previous digit's
2206         ;;; sign bit, so we know it will take one less than digit-size
2207         ;;; to get a one where we want. Otherwise, we count how many
2208         ;;; right shifts it takes to get zero; subtracting this value
2209         ;;; from digit-size tells us how many high zeros there are
2210         ;;; which is one more than the shift amount sought.
2211         ;;;
2212         ;;; Note: This is exactly the same as one less than the
2213         ;;; integer-length of the last digit subtracted from the
2214         ;;; digit-size.
2215         ;;;
2216         ;;; We shift y to make it sufficiently large that doing the
2217         ;;; 2*digit-size by digit-size %FLOOR calls ensures the quotient and
2218         ;;; remainder fit in digit-size.
2219          (shift-y-for-truncate (y)
2220            (let* ((len (%bignum-length y))
2221                   (last (%bignum-ref y (1- len))))
2222              (declare (type bignum-index len)
2223                       (type bignum-element-type last))
2224              (- digit-size (integer-length last) 1)))
2225          ;;; Stores two bignums into the truncation bignum buffers,
2226          ;;; shifting them on the way in. This assumes x and y are
2227          ;;; positive and at least two in length, and it assumes
2228          ;;; truncate-x and truncate-y are one digit longer than x and
2229          ;;; y.
2230          (shift-and-store-truncate-buffers (x len-x y len-y shift)
2231            (declare (type bignum-index len-x len-y)
2232                     (type (integer 0 (#.digit-size)) shift))
2233            (cond ((zerop shift)
2234                   (bignum-replace truncate-x x :end1 len-x)
2235                   (bignum-replace truncate-y y :end1 len-y))
2236                  (t
2237                   (bignum-ashift-left-unaligned x 0 shift (1+ len-x)
2238                                                 truncate-x)
2239                   (bignum-ashift-left-unaligned y 0 shift (1+ len-y)
2240                                                 truncate-y))))) ;; LABELS
2241       ;;; Divide X by Y returning the quotient and remainder. In the
2242       ;;; general case, we shift Y to set up for the algorithm, and we
2243       ;;; use two buffers to save consing intermediate values. X gets
2244       ;;; destructively modified to become the remainder, and we have
2245       ;;; to shift it to account for the initial Y shift. After we
2246       ;;; multiple bind q and r, we first fix up the signs and then
2247       ;;; return the normalized results.
2248       (let* ((x-plusp (%bignum-0-or-plusp x (%bignum-length x)))
2249              (y-plusp (%bignum-0-or-plusp y (%bignum-length y)))
2250              (x (if x-plusp x (negate-bignum x nil)))
2251              (y (if y-plusp y (negate-bignum y nil)))
2252              (len-x (%bignum-length x))
2253              (len-y (%bignum-length y)))
2254         (multiple-value-bind (q r)
2255             (cond ((< len-y 2)
2256                    (bignum-truncate-single-digit x len-x y))
2257                   ((plusp (bignum-compare y x))
2258                    (let ((res (%allocate-bignum len-x)))
2259                      (dotimes (i len-x)
2260                        (setf (%bignum-ref res i) (%bignum-ref x i)))
2261                      (values 0 res)))
2262                   (t
2263                    (let ((len-x+1 (1+ len-x)))
2264                      (setf truncate-x (%allocate-bignum len-x+1))
2265                      (setf truncate-y (%allocate-bignum (1+ len-y)))
2266                      (let ((y-shift (shift-y-for-truncate y)))
2267                        (shift-and-store-truncate-buffers x len-x y
2268                                                          len-y y-shift)
2269                        (values (return-quotient-leaving-remainder len-x+1
2270                                                                   len-y)
2271                                ;; Now that RETURN-QUOTIENT-LEAVING-REMAINDER
2272                                ;; has executed, we just tidy up the remainder
2273                                ;; (in TRUNCATE-X) and return it.
2274                                (cond
2275                                  ((zerop y-shift)
2276                                   (let ((res (%allocate-bignum len-y)))
2277                                     (declare (type bignum-type res))
2278                                     (bignum-replace res truncate-x :end2 len-y)
2279                                     (%normalize-bignum res len-y)))
2280                                  (t
2281                                   (shift-right-unaligned
2282                                    truncate-x 0 y-shift len-y
2283                                    ((= j res-len-1)
2284                                     (setf (%bignum-ref res j)
2285                                           (%ashr (%bignum-ref truncate-x i)
2286                                                  y-shift))
2287                                     (%normalize-bignum res res-len))
2288                                    res))))))))
2289           (let ((quotient (cond ((eq x-plusp y-plusp) q)
2290                                 ((typep q 'fixnum) (the fixnum (- q)))
2291                                 (t (negate-bignum-in-place q))))
2292                 (rem (cond (x-plusp r)
2293                            ((typep r 'fixnum) (the fixnum (- r)))
2294                            (t (negate-bignum-in-place r)))))
2295             (values (if (typep quotient 'fixnum)
2296                         quotient
2297                         (%normalize-bignum quotient (%bignum-length quotient)))
2298                     (if (typep rem 'fixnum)
2299                         rem
2300                         (%normalize-bignum rem (%bignum-length rem))))))))))
2301
2302 \f
2303 ;;;; %FLOOR primitive for BIGNUM-TRUNCATE
2304
2305 ;;; When a machine leaves out a 2*digit-size by digit-size divide
2306 ;;; instruction (that is, two bignum-digits divided by one), we have to
2307 ;;; roll our own (the hard way).  Basically, we treat the operation as
2308 ;;; four digit-size/2 digits divided by two digit-size/2 digits. This
2309 ;;; means we have duplicated most of the code above to do this nearly
2310 ;;; general digit-size/2 digit bignum divide, but we've unrolled loops
2311 ;;; and made use of other properties of this specific divide situation.
2312
2313 ;;;; %FLOOR for machines with a 32x32 divider.
2314
2315 #!-sb-fluid
2316 (declaim (inline 32x16-subtract-with-borrow 32x16-add-with-carry
2317                  32x16-divide 32x16-multiply 32x16-multiply-split))
2318
2319 #!+32x16-divide
2320 (defconstant 32x16-base-1 (1- (ash 1 (/ sb!vm:n-word-bits 2))))
2321
2322 #!+32x16-divide
2323 (deftype bignum-half-element-type () `(unsigned-byte ,(/ sb!vm:n-word-bits 2)))
2324 #!+32x16-divide
2325 (defconstant half-digit-size (/ digit-size 2))
2326
2327 ;;; This is similar to %SUBTRACT-WITH-BORROW. It returns a
2328 ;;; half-digit-size difference and a borrow. Returning a 1 for the
2329 ;;; borrow means there was no borrow, and 0 means there was one.
2330 #!+32x16-divide
2331 (defun 32x16-subtract-with-borrow (a b borrow)
2332   (declare (type bignum-half-element-type a b)
2333            (type (integer 0 1) borrow))
2334   (let ((diff (+ (- a b) borrow 32x16-base-1)))
2335     (declare (type (unsigned-byte #.(1+ half-digit-size)) diff))
2336     (values (logand diff (1- (ash 1 half-digit-size)))
2337             (ash diff (- half-digit-size)))))
2338
2339 ;;; This adds a and b, half-digit-size quantities, with the carry k. It
2340 ;;; returns a half-digit-size sum and a second value, 0 or 1, indicating
2341 ;;; whether there was a carry.
2342 #!+32x16-divide
2343 (defun 32x16-add-with-carry (a b k)
2344   (declare (type bignum-half-element-type a b)
2345            (type (integer 0 1) k))
2346   (let ((res (the fixnum (+ a b k))))
2347     (declare (type (unsigned-byte #.(1+ half-digit-size)) res))
2348     (if (zerop (the fixnum (logand (ash 1 half-digit-size) res)))
2349         (values res 0)
2350         (values (the bignum-half-element-type (logand (1- (ash 1 half-digit-size)) res))
2351                 1))))
2352
2353 ;;; This is probably a digit-size by digit-size divide instruction.
2354 #!+32x16-divide
2355 (defun 32x16-divide (a b c)
2356   (declare (type bignum-half-element-type a b c))
2357   (floor (the bignum-element-type
2358               (logior (the bignum-element-type (ash a 16))
2359                       b))
2360          c))
2361
2362 ;;; This basically exists since we know the answer won't overflow
2363 ;;; bignum-element-type. It's probably just a basic multiply instruction, but
2364 ;;; it can't cons an intermediate bignum. The result goes in a non-descriptor
2365 ;;; register.
2366 #!+32x16-divide
2367 (defun 32x16-multiply (a b)
2368   (declare (type bignum-half-element-type a b))
2369   (the bignum-element-type (* a b)))
2370
2371 ;;; This multiplies a and b, half-digit-size quantities, and returns the
2372 ;;; result as two half-digit-size quantities, high and low.
2373 #!+32x16-divide
2374 (defun 32x16-multiply-split (a b)
2375   (let ((res (32x16-multiply a b)))
2376     (declare (the bignum-element-type res))
2377     (values (the bignum-half-element-type (logand (1- (ash 1 half-digit-size)) (ash res (- half-digit-size))))
2378             (the bignum-half-element-type (logand (1- (ash 1 half-digit-size)) res)))))
2379
2380 ;;; The %FLOOR below uses this buffer the same way BIGNUM-TRUNCATE uses
2381 ;;; *truncate-x*. There's no y buffer since we pass around the two
2382 ;;; half-digit-size digits and use them slightly differently than the
2383 ;;; general truncation algorithm above.
2384 #!+32x16-divide
2385 (defvar *32x16-truncate-x* (make-array 4 :element-type 'bignum-half-element-type
2386                                        :initial-element 0))
2387
2388 ;;; This does the same thing as the %FLOOR above, but it does it at Lisp level
2389 ;;; when there is no 64x32-bit divide instruction on the machine.
2390 ;;;
2391 ;;; It implements the higher level tactics of BIGNUM-TRUNCATE, but it
2392 ;;; makes use of special situation provided, four half-digit-size digits
2393 ;;; divided by two half-digit-size digits.
2394 #!+32x16-divide
2395 (defun %floor (a b c)
2396   (declare (type bignum-element-type a b c))
2397   ;; Setup *32x16-truncate-x* buffer from a and b.
2398   (setf (aref *32x16-truncate-x* 0)
2399         (the bignum-half-element-type (logand (1- (ash 1 half-digit-size)) b)))
2400   (setf (aref *32x16-truncate-x* 1)
2401         (the bignum-half-element-type
2402              (logand (1- (ash 1 half-digit-size))
2403                      (the bignum-half-element-type (ash b (- half-digit-size))))))
2404   (setf (aref *32x16-truncate-x* 2)
2405         (the bignum-half-element-type (logand (1- (ash 1 half-digit-size)) a)))
2406   (setf (aref *32x16-truncate-x* 3)
2407         (the bignum-half-element-type
2408              (logand (1- (ash 1 half-digit-size))
2409                      (the bignum-half-element-type (ash a (- half-digit-size))))))
2410   ;; From DO-TRUNCATE, but unroll the loop.
2411   (let* ((y1 (logand (1- (ash 1 half-digit-size)) (ash c (- half-digit-size))))
2412          (y2 (logand (1- (ash 1 half-digit-size)) c))
2413          (q (the bignum-element-type
2414                  (ash (32x16-try-bignum-truncate-guess
2415                        (32x16-truncate-guess y1 y2
2416                                              (aref *32x16-truncate-x* 3)
2417                                              (aref *32x16-truncate-x* 2)
2418                                              (aref *32x16-truncate-x* 1))
2419                        y1 y2 1)
2420                       16))))
2421     (declare (type bignum-element-type q)
2422              (type bignum-half-element-type y1 y2))
2423     (values (the bignum-element-type
2424                  (logior q
2425                          (the bignum-half-element-type
2426                               (32x16-try-bignum-truncate-guess
2427                                (32x16-truncate-guess
2428                                 y1 y2
2429                                 (aref *32x16-truncate-x* 2)
2430                                 (aref *32x16-truncate-x* 1)
2431                                 (aref *32x16-truncate-x* 0))
2432                                y1 y2 0))))
2433             (the bignum-element-type
2434                  (logior (the bignum-element-type
2435                               (ash (aref *32x16-truncate-x* 1) 16))
2436                          (the bignum-half-element-type
2437                               (aref *32x16-truncate-x* 0)))))))
2438
2439 ;;; This is similar to TRY-BIGNUM-TRUNCATE-GUESS, but this unrolls the two
2440 ;;; loops. This also substitutes for %DIGIT-0-OR-PLUSP the equivalent
2441 ;;; expression without any embellishment or pretense of abstraction. The first
2442 ;;; loop is unrolled, but we've put the body of the loop into the function
2443 ;;; 32X16-TRY-GUESS-ONE-RESULT-DIGIT.
2444 #!+32x16-divide
2445 (defun 32x16-try-bignum-truncate-guess (guess y-high y-low low-x-digit)
2446   (declare (type bignum-index low-x-digit)
2447            (type bignum-half-element-type guess y-high y-low))
2448   (let ((high-x-digit (+ 2 low-x-digit)))
2449     ;; Multiply guess and divisor, subtracting from dividend simultaneously.
2450     (multiple-value-bind (guess*y-hold carry borrow)
2451         (32x16-try-guess-one-result-digit guess y-low 0 0 1 low-x-digit)
2452       (declare (type bignum-half-element-type guess*y-hold)
2453                (fixnum carry borrow))
2454       (multiple-value-bind (guess*y-hold carry borrow)
2455           (32x16-try-guess-one-result-digit guess y-high guess*y-hold
2456                                             carry borrow (1+ low-x-digit))
2457         (declare (type bignum-half-element-type guess*y-hold)
2458                  (fixnum borrow)
2459                  (ignore carry))
2460         (setf (aref *32x16-truncate-x* high-x-digit)
2461               (32x16-subtract-with-borrow (aref *32x16-truncate-x* high-x-digit)
2462                                           guess*y-hold borrow))))
2463     ;; See whether guess is off by one, adding one Y back in if necessary.
2464     (cond ((zerop (logand (ash 1 (1- half-digit-size))
2465                           (aref *32x16-truncate-x* high-x-digit)))
2466            ;; The subtraction result is zero or positive.
2467            guess)
2468           (t
2469            ;; If subtraction has negative result, add one divisor value back
2470            ;; in. The guess was one too large in magnitude.
2471            (multiple-value-bind (v carry)
2472                (32x16-add-with-carry y-low
2473                                      (aref *32x16-truncate-x* low-x-digit)
2474                                      0)
2475              (declare (type bignum-half-element-type v))
2476              (setf (aref *32x16-truncate-x* low-x-digit) v)
2477              (multiple-value-bind (v carry)
2478                  (32x16-add-with-carry y-high
2479                                        (aref *32x16-truncate-x*
2480                                              (1+ low-x-digit))
2481                                        carry)
2482                (setf (aref *32x16-truncate-x* (1+ low-x-digit)) v)
2483                (setf (aref *32x16-truncate-x* high-x-digit)
2484                      (32x16-add-with-carry (aref *32x16-truncate-x* high-x-digit)
2485                                            carry 0))))
2486            (if (zerop (logand (ash 1 (1- half-digit-size)) guess))
2487                (1- guess)
2488                (1+ guess))))))
2489
2490 ;;; This is similar to the body of the loop in TRY-BIGNUM-TRUNCATE-GUESS that
2491 ;;; multiplies the guess by y and subtracts the result from x simultaneously.
2492 ;;; This returns the digit remembered as part of the multiplication, the carry
2493 ;;; from additions done on behalf of the multiplication, and the borrow from
2494 ;;; doing the subtraction.
2495 #!+32x16-divide
2496 (defun 32x16-try-guess-one-result-digit (guess y-digit guess*y-hold
2497                                          carry borrow x-index)
2498   (multiple-value-bind (high-digit low-digit)
2499       (32x16-multiply-split guess y-digit)
2500     (declare (type bignum-half-element-type high-digit low-digit))
2501     (multiple-value-bind (low-digit temp-carry)
2502         (32x16-add-with-carry low-digit guess*y-hold carry)
2503       (declare (type bignum-half-element-type low-digit))
2504       (multiple-value-bind (high-digit temp-carry)
2505           (32x16-add-with-carry high-digit temp-carry 0)
2506         (declare (type bignum-half-element-type high-digit))
2507         (multiple-value-bind (x temp-borrow)
2508             (32x16-subtract-with-borrow (aref *32x16-truncate-x* x-index)
2509                                         low-digit borrow)
2510           (declare (type bignum-half-element-type x))
2511           (setf (aref *32x16-truncate-x* x-index) x)
2512           (values high-digit temp-carry temp-borrow))))))
2513
2514 ;;; This is similar to BIGNUM-TRUNCATE-GUESS, but instead of computing
2515 ;;; the guess exactly as described in the its comments (digit by digit),
2516 ;;; this massages the digit-size/2 quantities into digit-size quantities
2517 ;;; and performs the
2518 #!+32x16-divide
2519 (defun 32x16-truncate-guess (y1 y2 x-i x-i-1 x-i-2)
2520   (declare (type bignum-half-element-type y1 y2 x-i x-i-1 x-i-2))
2521   (let ((guess (if (= x-i y1)
2522                    (1- (ash 1 half-digit-size))
2523                    (32x16-divide x-i x-i-1 y1))))
2524     (declare (type bignum-half-element-type guess))
2525     (loop
2526       (let* ((guess*y1 (the bignum-element-type
2527                             (ash (logand (1- (ash 1 half-digit-size))
2528                                          (the bignum-element-type
2529                                               (32x16-multiply guess y1)))
2530                                  16)))
2531              (x-y (%subtract-with-borrow
2532                    (the bignum-element-type
2533                         (logior (the bignum-element-type
2534                                      (ash x-i-1 16))
2535                                 x-i-2))
2536                    guess*y1
2537                    1))
2538              (guess*y2 (the bignum-element-type (%multiply guess y2))))
2539         (declare (type bignum-element-type guess*y1 x-y guess*y2))
2540         (if (%digit-greater guess*y2 x-y)
2541             (decf guess)
2542             (return guess))))))
2543 \f
2544 ;;;; general utilities
2545
2546 ;;; Internal in-place operations use this to fixup remaining digits in the
2547 ;;; incoming data, such as in-place shifting. This is basically the same as
2548 ;;; the first form in %NORMALIZE-BIGNUM, but we return the length of the buffer
2549 ;;; instead of shrinking the bignum.
2550 #!-sb-fluid (declaim (sb!ext:maybe-inline %normalize-bignum-buffer))
2551 (defun %normalize-bignum-buffer (result len)
2552   (declare (type bignum-type result)
2553            (type bignum-index len))
2554   (unless (= len 1)
2555     (do ((next-digit (%bignum-ref result (- len 2))
2556                      (%bignum-ref result (- len 2)))
2557          (sign-digit (%bignum-ref result (1- len)) next-digit))
2558         ((not (zerop (logxor sign-digit (%ashr next-digit (1- digit-size))))))
2559         (decf len)
2560         (setf (%bignum-ref result len) 0)
2561         (when (= len 1)
2562               (return))))
2563   len)
2564
2565 ;;; This drops the last digit if it is unnecessary sign information. It repeats
2566 ;;; this as needed, possibly ending with a fixnum. If the resulting length from
2567 ;;; shrinking is one, see whether our one word is a fixnum. Shift the possible
2568 ;;; fixnum bits completely out of the word, and compare this with shifting the
2569 ;;; sign bit all the way through. If the bits are all 1's or 0's in both words,
2570 ;;; then there are just sign bits between the fixnum bits and the sign bit. If
2571 ;;; we do have a fixnum, shift it over for the two low-tag bits.
2572 (defun %normalize-bignum (result len)
2573   (declare (type bignum-type result)
2574            (type bignum-index len)
2575            (inline %normalize-bignum-buffer))
2576   (let ((newlen (%normalize-bignum-buffer result len)))
2577     (declare (type bignum-index newlen))
2578     (unless (= newlen len)
2579       (%bignum-set-length result newlen))
2580     (if (= newlen 1)
2581         (let ((digit (%bignum-ref result 0)))
2582           (if (= (%ashr digit sb!vm:n-positive-fixnum-bits)
2583                  (%ashr digit (1- digit-size)))
2584               (%fixnum-digit-with-correct-sign digit)
2585               result))
2586         result)))
2587
2588 ;;; This drops the last digit if it is unnecessary sign information. It
2589 ;;; repeats this as needed, possibly ending with a fixnum magnitude but never
2590 ;;; returning a fixnum.
2591 (defun %mostly-normalize-bignum (result len)
2592   (declare (type bignum-type result)
2593            (type bignum-index len)
2594            (inline %normalize-bignum-buffer))
2595   (let ((newlen (%normalize-bignum-buffer result len)))
2596     (declare (type bignum-index newlen))
2597     (unless (= newlen len)
2598       (%bignum-set-length result newlen))
2599     result))
2600 \f
2601 ;;;; hashing
2602
2603 ;;; the bignum case of the SXHASH function
2604 (defun sxhash-bignum (x)
2605   (let ((result 316495330))
2606     (declare (type fixnum result))
2607     (dotimes (i (%bignum-length x))
2608       (declare (type index i))
2609       (let ((xi (%bignum-ref x i)))
2610         (mixf result
2611               (logand most-positive-fixnum
2612                       xi
2613                       (ash xi -7)))))
2614     result))