src/code/coerce.lisp

   1 ;;;; COERCE and related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 (macrolet ((def (name result access src-type &optional typep)
  15              `(defun ,name (object ,@(if typep '(type) ()))
  16                 (do* ((index 0 (1+ index))
  17                       (length (length (the ,(ecase src-type
  18                                               (:list 'list)
  19                                               (:vector 'vector))
  20                                            object)))
  21                       (result ,result)
  22                       (in-object object))
  23                      ((= index length) result)
  24                   (declare (fixnum length index))
  25                   (setf (,access result index)
  26                         ,(ecase src-type
  27                            (:list '(pop in-object))
  28                            (:vector '(aref in-object index))))))))
  29
  30   (def list-to-vector* (make-sequence type length)
  31     aref :list t)
  32
  33   (def vector-to-vector* (make-sequence type length)
  34     aref :vector t))
  35
  36 (defun vector-to-list* (object)
  37   (let ((result (list nil))
  38         (length (length object)))
  39     (declare (fixnum length))
  40     (do ((index 0 (1+ index))
  41          (splice result (cdr splice)))
  42         ((= index length) (cdr result))
  43       (declare (fixnum index))
  44       (rplacd splice (list (aref object index))))))
  45
  46 (defvar *offending-datum*); FIXME: Remove after debugging COERCE.
  47
  48 ;;; These are used both by the full DEFUN function and by various
  49 ;;; optimization transforms in the constant-OUTPUT-TYPE-SPEC case.
  50 ;;;
  51 ;;; Most of them are INLINE so that they can be optimized when the
  52 ;;; argument type is known. It might be better to do this with
  53 ;;; DEFTRANSFORMs, though.
  54 (declaim (inline coerce-to-list))
  55 (declaim (inline coerce-to-vector))
  56 (defun coerce-to-fun (object)
  57   ;; (Unlike the other COERCE-TO-FOOs, this one isn't inline, because
  58   ;; it's so big and because optimizing away the outer ETYPECASE
  59   ;; doesn't seem to buy us that much anyway.)
  60   (etypecase object
  61     (symbol
  62      ;; ANSI lets us return ordinary errors (non-TYPE-ERRORs) here.
  63      (cond ((macro-function object)
  64             (error "~S names a macro." object))
  65            ((special-operator-p object)
  66             (error "~S is a special operator." object))
  67            (t (fdefinition object))))
  68     (list
  69      (case (first object)
  70        ((setf)
  71         (fdefinition object))
  72        ((lambda instance-lambda)
  73         ;; FIXME: If we go to a compiler-only implementation, this can
  74         ;; become COMPILE instead of EVAL, which seems nicer to me.
  75         (eval `(function ,object)))
  76        (t
  77         (error 'simple-type-error
  78                :datum object
  79                :expected-type '(or symbol
  80                                    ;; KLUDGE: ANSI wants us to
  81                                    ;; return a TYPE-ERROR here, and
  82                                    ;; a TYPE-ERROR is supposed to
  83                                    ;; describe the expected type,
  84                                    ;; but it's not obvious how to
  85                                    ;; describe the coerceable cons
  86                                    ;; types, so we punt and just say
  87                                    ;; CONS. -- WHN 20000503
  88                                    cons)
  89                :format-control "~S can't be coerced to a function."
  90                :format-arguments (list object)))))))
  91
  92 (defun coerce-to-list (object)
  93   (etypecase object
  94     (vector (vector-to-list* object))))
  95
  96 (defun coerce-to-vector (object output-type-spec)
  97   (etypecase object
  98     (list (list-to-vector* object output-type-spec))
  99     (vector (vector-to-vector* object output-type-spec))))
 100
 101 ;;; old working version
 102 (defun coerce (object output-type-spec)
 103   #!+sb-doc
 104   "Coerce the Object to an object of type Output-Type-Spec."
 105   (flet ((coerce-error ()
 106            (/show0 "entering COERCE-ERROR")
 107            (error 'simple-type-error
 108                   :format-control "~S can't be converted to type ~S."
 109                   :format-arguments (list object output-type-spec))))
 110     (let ((type (specifier-type output-type-spec)))
 111       (cond
 112         ((%typep object output-type-spec)
 113          object)
 114         ((eq type *empty-type*)
 115          (coerce-error))
 116         ((csubtypep type (specifier-type 'character))
 117          (character object))
 118         ((csubtypep type (specifier-type 'function))
 119          #!+high-security
 120          (when (and (legal-fun-name-p object)
 121                     (not (fboundp object)))
 122            (error 'simple-type-error
 123                   :datum object
 124                   ;; FIXME: SATISFIES FBOUNDP is a kinda bizarre broken
 125                   ;; type specifier, since the set of values it describes
 126                   ;; isn't in general constant in time. Maybe we could
 127                   ;; find a better way of expressing this error? (Maybe
 128                   ;; with the UNDEFINED-FUNCTION condition?)
 129                   :expected-type '(satisfies fboundp)
 130                :format-control "~S isn't fbound."
 131                :format-arguments (list object)))
 132          #!+high-security
 133          (when (and (symbolp object)
 134                     (sb!xc:macro-function object))
 135            (error 'simple-type-error
 136                   :datum object
 137                   :expected-type '(not (satisfies sb!xc:macro-function))
 138                   :format-control "~S is a macro."
 139                   :format-arguments (list object)))
 140          #!+high-security
 141          (when (and (symbolp object)
 142                     (special-operator-p object))
 143            (error 'simple-type-error
 144                   :datum object
 145                   :expected-type '(not (satisfies special-operator-p))
 146                   :format-control "~S is a special operator."
 147                   :format-arguments (list object)))
 148          (eval `#',object))
 149         ((numberp object)
 150          (cond
 151            ((csubtypep type (specifier-type 'single-float))
 152             (let ((res (%single-float object)))
 153               (unless (typep res output-type-spec)
 154                 (coerce-error))
 155               res))
 156            ((csubtypep type (specifier-type 'double-float))
 157             (let ((res (%double-float object)))
 158               (unless (typep res output-type-spec)
 159                 (coerce-error))
 160               res))
 161            #!+long-float
 162            ((csubtypep type (specifier-type 'long-float))
 163             (let ((res (%long-float object)))
 164               (unless (typep res output-type-spec)
 165                 (coerce-error))
 166               res))
 167            ((csubtypep type (specifier-type 'float))
 168             (let ((res (%single-float object)))
 169               (unless (typep res output-type-spec)
 170                 (coerce-error))
 171               res))
 172            (t
 173             (let ((res
 174                    (cond
 175                      ((csubtypep type (specifier-type '(complex single-float)))
 176                       (complex (%single-float (realpart object))
 177                                (%single-float (imagpart object))))
 178                      ((csubtypep type (specifier-type '(complex double-float)))
 179                       (complex (%double-float (realpart object))
 180                                (%double-float (imagpart object))))
 181                      #!+long-float
 182                      ((csubtypep type (specifier-type '(complex long-float)))
 183                       (complex (%long-float (realpart object))
 184                                (%long-float (imagpart object))))
 185                      ((and (typep object 'rational)
 186                            (csubtypep type (specifier-type '(complex float))))
 187                       ;; Perhaps somewhat surprisingly, ANSI specifies
 188                       ;; that (COERCE FOO 'FLOAT) is a SINGLE-FLOAT,
 189                       ;; not dispatching on
 190                       ;; *READ-DEFAULT-FLOAT-FORMAT*.  By analogy, we
 191                       ;; do the same for complex numbers. -- CSR,
 192                       ;; 2002-08-06
 193                       (complex (%single-float object)))
 194                      ((csubtypep type (specifier-type 'complex))
 195                       (complex object))
 196                      (t
 197                       (coerce-error)))))
 198               ;; If RES has the wrong type, that means that rule of
 199               ;; canonical representation for complex rationals was
 200               ;; invoked. According to the Hyperspec, (coerce 7/2
 201               ;; 'complex) returns 7/2. Thus, if the object was a
 202               ;; rational, there is no error here.
 203               (unless (or (typep res output-type-spec)
 204                           (rationalp object))
 205                 (coerce-error))
 206               res))))
 207         ((csubtypep type (specifier-type 'list))
 208          (if (vectorp object)
 209              (cond ((type= type (specifier-type 'list))
 210                     (vector-to-list* object))
 211                    ((type= type (specifier-type 'null))
 212                     (if (= (length object) 0)
 213                         'nil
 214                         (sequence-type-length-mismatch-error type
 215                                                              (length object))))
 216                    ((csubtypep (specifier-type '(cons nil t)) type)
 217                     (if (> (length object) 0)
 218                         (vector-to-list* object)
 219                         (sequence-type-length-mismatch-error type 0)))
 220                    (t (sequence-type-too-hairy (type-specifier type))))
 221              (coerce-error)))
 222         ((csubtypep type (specifier-type 'vector))
 223          (typecase object
 224            ;; FOO-TO-VECTOR* go through MAKE-SEQUENCE, so length
 225            ;; errors are caught there. -- CSR, 2002-10-18
 226            (list (list-to-vector* object output-type-spec))
 227            (vector (vector-to-vector* object output-type-spec))
 228            (t
 229             (coerce-error))))
 230         (t
 231          (coerce-error))))))
 232
 233 ;;; new version, which seems as though it should be better, but which
 234 ;;; does not yet work
 235 #+nil
 236 (defun coerce (object output-type-spec)
 237   #!+sb-doc
 238   "Coerces the Object to an object of type Output-Type-Spec."
 239   (flet ((coerce-error ()
 240            (error 'simple-type-error
 241                   :format-control "~S can't be converted to type ~S."
 242                   :format-arguments (list object output-type-spec)))
 243          (check-result (result)
 244            #!+high-security (aver (typep result output-type-spec))
 245            result))
 246     (let ((type (specifier-type output-type-spec)))
 247       (cond
 248         ((%typep object output-type-spec)
 249          object)
 250         ((eq type *empty-type*)
 251          (coerce-error))
 252         ((csubtypep type (specifier-type 'character))
 253          (character object))
 254         ((csubtypep type (specifier-type 'function))
 255          (coerce-to-fun object))
 256         ((numberp object)
 257          (let ((res
 258                 (cond
 259                   ((csubtypep type (specifier-type 'single-float))
 260                    (%single-float object))
 261                   ((csubtypep type (specifier-type 'double-float))
 262                    (%double-float object))
 263                   #!+long-float
 264                   ((csubtypep type (specifier-type 'long-float))
 265                    (%long-float object))
 266                   ((csubtypep type (specifier-type 'float))
 267                    (%single-float object))
 268                   ((csubtypep type (specifier-type '(complex single-float)))
 269                    (complex (%single-float (realpart object))
 270                             (%single-float (imagpart object))))
 271                   ((csubtypep type (specifier-type '(complex double-float)))
 272                    (complex (%double-float (realpart object))
 273                             (%double-float (imagpart object))))
 274                   #!+long-float
 275                   ((csubtypep type (specifier-type '(complex long-float)))
 276                    (complex (%long-float (realpart object))
 277                             (%long-float (imagpart object))))
 278                   ((csubtypep type (specifier-type 'complex))
 279                    (complex object))
 280                   (t
 281                    (coerce-error)))))
 282            ;; If RES has the wrong type, that means that rule of
 283            ;; canonical representation for complex rationals was
 284            ;; invoked. According to the ANSI spec, (COERCE 7/2
 285            ;; 'COMPLEX) returns 7/2. Thus, if the object was a
 286            ;; rational, there is no error here.
 287            (unless (or (typep res output-type-spec) (rationalp object))
 288              (coerce-error))
 289            res))
 290         ((csubtypep type (specifier-type 'list))
 291          (coerce-to-list object))
 292         ((csubtypep type (specifier-type 'string))
 293          (check-result (coerce-to-simple-string object)))
 294         ((csubtypep type (specifier-type 'bit-vector))
 295          (check-result (coerce-to-bit-vector object)))
 296         ((csubtypep type (specifier-type 'vector))
 297          (check-result (coerce-to-vector object output-type-spec)))
 298         (t
 299          (coerce-error))))))