src/code/coerce.lisp

   1 ;;;; COERCE and related code
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 (macrolet ((def (name result access src-type &optional typep)
  15              `(defun ,name (object ,@(if typep '(type) ()))
  16                 (do* ((index 0 (1+ index))
  17                       (length (length (the ,(ecase src-type
  18                                               (:list 'list)
  19                                               (:vector 'vector))
  20                                            object)))
  21                       (result ,result)
  22                       (in-object object))
  23                      ((= index length) result)
  24                   (declare (fixnum length index))
  25                   (setf (,access result index)
  26                         ,(ecase src-type
  27                            (:list '(pop in-object))
  28                            (:vector '(aref in-object index))))))))
  29
  30   (def list-to-vector* (make-sequence type length)
  31     aref :list t)
  32
  33   (def vector-to-vector* (make-sequence type length)
  34     aref :vector t))
  35
  36 (defun vector-to-list* (object)
  37   (let ((result (list nil))
  38         (length (length object)))
  39     (declare (fixnum length))
  40     (do ((index 0 (1+ index))
  41          (splice result (cdr splice)))
  42         ((= index length) (cdr result))
  43       (declare (fixnum index))
  44       (rplacd splice (list (aref object index))))))
  45
  46 (defvar *offending-datum*); FIXME: Remove after debugging COERCE.
  47
  48 ;;; These are used both by the full DEFUN function and by various
  49 ;;; optimization transforms in the constant-OUTPUT-TYPE-SPEC case.
  50 ;;;
  51 ;;; Most of them are INLINE so that they can be optimized when the
  52 ;;; argument type is known. It might be better to do this with
  53 ;;; DEFTRANSFORMs, though.
  54 (declaim (inline coerce-to-list))
  55 (declaim (inline coerce-to-vector))
  56 (defun coerce-to-fun (object)
  57   ;; (Unlike the other COERCE-TO-FOOs, this one isn't inline, because
  58   ;; it's so big and because optimizing away the outer ETYPECASE
  59   ;; doesn't seem to buy us that much anyway.)
  60   (etypecase object
  61     (symbol
  62      ;; ANSI lets us return ordinary errors (non-TYPE-ERRORs) here.
  63      (cond ((macro-function object)
  64             (error "~S names a macro." object))
  65            ((special-operator-p object)
  66             (error "~S is a special operator." object))
  67            (t (fdefinition object))))
  68     (list
  69      (case (first object)
  70        ((setf)
  71         (fdefinition object))
  72        ((lambda instance-lambda)
  73         ;; FIXME: If we go to a compiler-only implementation, this can
  74         ;; become COMPILE instead of EVAL, which seems nicer to me.
  75         (eval `(function ,object)))
  76        (t
  77         (error 'simple-type-error
  78                :datum object
  79                :expected-type '(or symbol
  80                                    ;; KLUDGE: ANSI wants us to
  81                                    ;; return a TYPE-ERROR here, and
  82                                    ;; a TYPE-ERROR is supposed to
  83                                    ;; describe the expected type,
  84                                    ;; but it's not obvious how to
  85                                    ;; describe the coerceable cons
  86                                    ;; types, so we punt and just say
  87                                    ;; CONS. -- WHN 20000503
  88                                    cons)
  89                :format-control "~S can't be coerced to a function."
  90                :format-arguments (list object)))))))
  91
  92 (defun coerce-to-list (object)
  93   (etypecase object
  94     (vector (vector-to-list* object))))
  95
  96 (defun coerce-to-vector (object output-type-spec)
  97   (etypecase object
  98     (list (list-to-vector* object output-type-spec))
  99     (vector (vector-to-vector* object output-type-spec))))
 100
 101 ;;; old working version
 102 (defun coerce (object output-type-spec)
 103   #!+sb-doc
 104   "Coerce the Object to an object of type Output-Type-Spec."
 105   (flet ((coerce-error ()
 106            (/show0 "entering COERCE-ERROR")
 107            (error 'simple-type-error
 108                   :format-control "~S can't be converted to type ~S."
 109                   :format-arguments (list object output-type-spec))))
 110     (let ((type (specifier-type output-type-spec)))
 111       (cond
 112         ((%typep object output-type-spec)
 113          object)
 114         ((eq type *empty-type*)
 115          (coerce-error))
 116         ((csubtypep type (specifier-type 'character))
 117          (character object))
 118         ((csubtypep type (specifier-type 'function))
 119          (when (and (legal-fun-name-p object)
 120                     (not (fboundp object)))
 121            (error 'simple-type-error
 122                   :datum object
 123                   ;; FIXME: SATISFIES FBOUNDP is a kinda bizarre broken
 124                   ;; type specifier, since the set of values it describes
 125                   ;; isn't in general constant in time. Maybe we could
 126                   ;; find a better way of expressing this error? (Maybe
 127                   ;; with the UNDEFINED-FUNCTION condition?)
 128                   :expected-type '(satisfies fboundp)
 129                :format-control "~S isn't fbound."
 130                :format-arguments (list object)))
 131          (when (and (symbolp object)
 132                     (sb!xc:macro-function object))
 133            (error 'simple-type-error
 134                   :datum object
 135                   :expected-type '(not (satisfies sb!xc:macro-function))
 136                   :format-control "~S is a macro."
 137                   :format-arguments (list object)))
 138          (when (and (symbolp object)
 139                     (special-operator-p object))
 140            (error 'simple-type-error
 141                   :datum object
 142                   :expected-type '(not (satisfies special-operator-p))
 143                   :format-control "~S is a special operator."
 144                   :format-arguments (list object)))
 145          (eval `#',object))
 146         ((numberp object)
 147          (cond
 148            ((csubtypep type (specifier-type 'single-float))
 149             (let ((res (%single-float object)))
 150               (unless (typep res output-type-spec)
 151                 (coerce-error))
 152               res))
 153            ((csubtypep type (specifier-type 'double-float))
 154             (let ((res (%double-float object)))
 155               (unless (typep res output-type-spec)
 156                 (coerce-error))
 157               res))
 158            #!+long-float
 159            ((csubtypep type (specifier-type 'long-float))
 160             (let ((res (%long-float object)))
 161               (unless (typep res output-type-spec)
 162                 (coerce-error))
 163               res))
 164            ((csubtypep type (specifier-type 'float))
 165             (let ((res (%single-float object)))
 166               (unless (typep res output-type-spec)
 167                 (coerce-error))
 168               res))
 169            (t
 170             (let ((res
 171                    (cond
 172                      ((csubtypep type (specifier-type '(complex single-float)))
 173                       (complex (%single-float (realpart object))
 174                                (%single-float (imagpart object))))
 175                      ((csubtypep type (specifier-type '(complex double-float)))
 176                       (complex (%double-float (realpart object))
 177                                (%double-float (imagpart object))))
 178                      #!+long-float
 179                      ((csubtypep type (specifier-type '(complex long-float)))
 180                       (complex (%long-float (realpart object))
 181                                (%long-float (imagpart object))))
 182                      ((and (typep object 'rational)
 183                            (csubtypep type (specifier-type '(complex float))))
 184                       ;; Perhaps somewhat surprisingly, ANSI specifies
 185                       ;; that (COERCE FOO 'FLOAT) is a SINGLE-FLOAT,
 186                       ;; not dispatching on
 187                       ;; *READ-DEFAULT-FLOAT-FORMAT*.  By analogy, we
 188                       ;; do the same for complex numbers. -- CSR,
 189                       ;; 2002-08-06
 190                       (complex (%single-float object)))
 191                      ((csubtypep type (specifier-type 'complex))
 192                       (complex object))
 193                      (t
 194                       (coerce-error)))))
 195               ;; If RES has the wrong type, that means that rule of
 196               ;; canonical representation for complex rationals was
 197               ;; invoked. According to the Hyperspec, (coerce 7/2
 198               ;; 'complex) returns 7/2. Thus, if the object was a
 199               ;; rational, there is no error here.
 200               (unless (or (typep res output-type-spec)
 201                           (rationalp object))
 202                 (coerce-error))
 203               res))))
 204         ((csubtypep type (specifier-type 'list))
 205          (if (vectorp object)
 206              (cond ((type= type (specifier-type 'list))
 207                     (vector-to-list* object))
 208                    ((type= type (specifier-type 'null))
 209                     (if (= (length object) 0)
 210                         'nil
 211                         (sequence-type-length-mismatch-error type
 212                                                              (length object))))
 213                    ((csubtypep (specifier-type '(cons nil t)) type)
 214                     (if (> (length object) 0)
 215                         (vector-to-list* object)
 216                         (sequence-type-length-mismatch-error type 0)))
 217                    (t (sequence-type-too-hairy (type-specifier type))))
 218              (coerce-error)))
 219         ((csubtypep type (specifier-type 'vector))
 220          (typecase object
 221            ;; FOO-TO-VECTOR* go through MAKE-SEQUENCE, so length
 222            ;; errors are caught there. -- CSR, 2002-10-18
 223            (list (list-to-vector* object output-type-spec))
 224            (vector (vector-to-vector* object output-type-spec))
 225            (t
 226             (coerce-error))))
 227         (t
 228          (coerce-error))))))
 229
 230 ;;; new version, which seems as though it should be better, but which
 231 ;;; does not yet work
 232 #+nil
 233 (defun coerce (object output-type-spec)
 234   #!+sb-doc
 235   "Coerces the Object to an object of type Output-Type-Spec."
 236   (flet ((coerce-error ()
 237            (error 'simple-type-error
 238                   :format-control "~S can't be converted to type ~S."
 239                   :format-arguments (list object output-type-spec)))
 240          (check-result (result)
 241            #!+high-security (aver (typep result output-type-spec))
 242            result))
 243     (let ((type (specifier-type output-type-spec)))
 244       (cond
 245         ((%typep object output-type-spec)
 246          object)
 247         ((eq type *empty-type*)
 248          (coerce-error))
 249         ((csubtypep type (specifier-type 'character))
 250          (character object))
 251         ((csubtypep type (specifier-type 'function))
 252          (coerce-to-fun object))
 253         ((numberp object)
 254          (let ((res
 255                 (cond
 256                   ((csubtypep type (specifier-type 'single-float))
 257                    (%single-float object))
 258                   ((csubtypep type (specifier-type 'double-float))
 259                    (%double-float object))
 260                   #!+long-float
 261                   ((csubtypep type (specifier-type 'long-float))
 262                    (%long-float object))
 263                   ((csubtypep type (specifier-type 'float))
 264                    (%single-float object))
 265                   ((csubtypep type (specifier-type '(complex single-float)))
 266                    (complex (%single-float (realpart object))
 267                             (%single-float (imagpart object))))
 268                   ((csubtypep type (specifier-type '(complex double-float)))
 269                    (complex (%double-float (realpart object))
 270                             (%double-float (imagpart object))))
 271                   #!+long-float
 272                   ((csubtypep type (specifier-type '(complex long-float)))
 273                    (complex (%long-float (realpart object))
 274                             (%long-float (imagpart object))))
 275                   ((csubtypep type (specifier-type 'complex))
 276                    (complex object))
 277                   (t
 278                    (coerce-error)))))
 279            ;; If RES has the wrong type, that means that rule of
 280            ;; canonical representation for complex rationals was
 281            ;; invoked. According to the ANSI spec, (COERCE 7/2
 282            ;; 'COMPLEX) returns 7/2. Thus, if the object was a
 283            ;; rational, there is no error here.
 284            (unless (or (typep res output-type-spec) (rationalp object))
 285              (coerce-error))
 286            res))
 287         ((csubtypep type (specifier-type 'list))
 288          (coerce-to-list object))
 289         ((csubtypep type (specifier-type 'string))
 290          (check-result (coerce-to-simple-string object)))
 291         ((csubtypep type (specifier-type 'bit-vector))
 292          (check-result (coerce-to-bit-vector object)))
 293         ((csubtypep type (specifier-type 'vector))
 294          (check-result (coerce-to-vector object output-type-spec)))
 295         (t
 296          (coerce-error))))))