src/code/cold-error.lisp

   1 ;;;; miscellaneous stuff that needs to be in the cold load which would
   2 ;;;; otherwise be byte-compiled
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (defvar *break-on-signals* nil
  16   #!+sb-doc
  17   "When (TYPEP condition *BREAK-ON-SIGNALS*) is true, then calls to SIGNAL will
  18    enter the debugger prior to signalling that condition.")
  19
  20 (defun signal (datum &rest arguments)
  21   #!+sb-doc
  22   "Invokes the signal facility on a condition formed from DATUM and
  23    ARGUMENTS. If the condition is not handled, NIL is returned. If
  24    (TYPEP condition *BREAK-ON-SIGNALS*) is true, the debugger is invoked
  25    before any signalling is done."
  26   (let ((condition (coerce-to-condition datum
  27                                         arguments
  28                                         'simple-condition
  29                                         'signal))
  30         (*handler-clusters* *handler-clusters*))
  31     (let ((old-bos *break-on-signals*)
  32           (*break-on-signals* nil))
  33       (when (typep condition old-bos)
  34         (break "~A~%BREAK was entered because of *BREAK-ON-SIGNALS* (now NIL)."
  35                condition)))
  36     (loop
  37       (unless *handler-clusters* (return))
  38       (let ((cluster (pop *handler-clusters*)))
  39         (dolist (handler cluster)
  40           (when (typep condition (car handler))
  41             (funcall (cdr handler) condition)))))
  42     nil))
  43
  44 ;;; COERCE-TO-CONDITION is used in SIGNAL, ERROR, CERROR, WARN, and
  45 ;;; INVOKE-DEBUGGER for parsing the hairy argument conventions into a single
  46 ;;; argument that's directly usable by all the other routines.
  47 (defun coerce-to-condition (datum arguments default-type function-name)
  48   (cond ((typep datum 'condition)
  49          (if arguments
  50              (cerror "Ignore the additional arguments."
  51                      'simple-type-error
  52                      :datum arguments
  53                      :expected-type 'null
  54                      :format-control "You may not supply additional arguments ~
  55                                      when giving ~S to ~S."
  56                      :format-arguments (list datum function-name)))
  57          datum)
  58         ((symbolp datum) ; roughly, (SUBTYPEP DATUM 'CONDITION)
  59          (apply #'make-condition datum arguments))
  60         ((or (stringp datum) (functionp datum))
  61          (make-condition default-type
  62                          :format-control datum
  63                          :format-arguments arguments))
  64         (t
  65          (error 'simple-type-error
  66                 :datum datum
  67                 :expected-type '(or symbol string)
  68                 :format-control "bad argument to ~S: ~S"
  69                 :format-arguments (list function-name datum)))))
  70
  71 ;;; a shared idiom in ERROR, CERROR, and BREAK: The user probably
  72 ;;; doesn't want to hear that the error "occurred in" one of these
  73 ;;; functions, so we try to point the top of the stack to our caller
  74 ;;; instead.
  75 (eval-when (:compile-toplevel :execute)
  76   (defmacro-mundanely maybe-find-stack-top-hint ()
  77     `(or sb!debug:*stack-top-hint*
  78          (nth-value 1 (sb!kernel:find-caller-name-and-frame)))))
  79
  80 (defun error (datum &rest arguments)
  81   #!+sb-doc
  82   "Invoke the signal facility on a condition formed from datum and arguments.
  83    If the condition is not handled, the debugger is invoked."
  84   (/show0 "entering ERROR, argument list=..")
  85   (/hexstr arguments)
  86   (/show0 "printing ERROR arguments one by one..")
  87   #!+sb-show (dolist (argument arguments)
  88                (sb!impl::cold-print argument))
  89   (sb!kernel:infinite-error-protect
  90     (let ((condition (coerce-to-condition datum arguments
  91                                           'simple-error 'error))
  92           (sb!debug:*stack-top-hint* (maybe-find-stack-top-hint)))
  93       (let ((sb!debug:*stack-top-hint* nil))
  94         (signal condition))
  95       (invoke-debugger condition))))
  96
  97 (defun cerror (continue-string datum &rest arguments)
  98   (sb!kernel:infinite-error-protect
  99     (with-simple-restart
 100         (continue "~A" (apply #'format nil continue-string arguments))
 101       (let ((condition (if (typep datum 'condition)
 102                            datum
 103                            (coerce-to-condition datum
 104                                                 arguments
 105                                                 'simple-error
 106                                                 'error)))
 107             (sb!debug:*stack-top-hint* (maybe-find-stack-top-hint)))
 108         (with-condition-restarts condition (list (find-restart 'continue))
 109           (let ((sb!debug:*stack-top-hint* nil))
 110             (signal condition))
 111           (invoke-debugger condition)))))
 112   nil)
 113
 114 ;;; like BREAK, but without rebinding *DEBUGGER-HOOK* to NIL, so that
 115 ;;; we can use it in system code (e.g. in SIGINT handling) without
 116 ;;; messing up --noprogrammer mode (which works by setting
 117 ;;; *DEBUGGER-HOOK*)
 118 (defun %break (what &optional (datum "break") &rest arguments)
 119   (sb!kernel:infinite-error-protect
 120     (with-simple-restart (continue "Return from ~S." what)
 121       (let ((sb!debug:*stack-top-hint* (maybe-find-stack-top-hint)))
 122         (invoke-debugger
 123          (coerce-to-condition datum arguments 'simple-condition what)))))
 124   nil)
 125
 126 (defun break (&optional (datum "break") &rest arguments)
 127   #!+sb-doc
 128   "Print a message and invoke the debugger without allowing any possibility
 129    of condition handling occurring."
 130   (let ((*debugger-hook* nil)) ; as specifically required by ANSI
 131     (apply #'%break 'break datum arguments)))
 132
 133 (defun warn (datum &rest arguments)
 134   #!+sb-doc
 135   "Warn about a situation by signalling a condition formed by DATUM and
 136    ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
 137    exists that causes WARN to immediately return NIL."
 138   (/noshow0 "entering WARN")
 139   ;; KLUDGE: The current cold load initialization logic causes several calls
 140   ;; to WARN, so we need to be able to handle them without dying. (And calling
 141   ;; FORMAT or even PRINC in cold load is a good way to die.) Of course, the
 142   ;; ideal would be to clean up cold load so that it doesn't call WARN..
 143   ;; -- WHN 19991009
 144   (if (not *cold-init-complete-p*)
 145       (progn
 146         (/show0 "ignoring WARN in cold init, arguments=..")
 147         #!+sb-show (dolist (argument arguments)
 148                      (sb!impl::cold-print argument)))
 149       (sb!kernel:infinite-error-protect
 150        (let ((condition (coerce-to-condition datum arguments
 151                                              'simple-warning 'warn)))
 152          (enforce-type condition warning)
 153          (restart-case (signal condition)
 154            (muffle-warning ()
 155              :report "Skip warning."
 156              (return-from warn nil)))
 157          (let ((badness (etypecase condition
 158                           (style-warning 'style-warning)
 159                           (warning 'warning))))
 160            (format *error-output*
 161                    "~&~@<~S: ~3i~:_~A~:>~%"
 162                    badness
 163                    condition)))))
 164   nil)