src/code/cold-error.lisp

   1 ;;;; miscellaneous stuff that needs to be in the cold load which would
   2 ;;;; otherwise be byte-compiled
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (defvar *break-on-signals* nil
  16   #!+sb-doc
  17   "When (TYPEP condition *BREAK-ON-SIGNALS*) is true, then calls to SIGNAL will
  18    enter the debugger prior to signalling that condition.")
  19
  20 (defun signal (datum &rest arguments)
  21   #!+sb-doc
  22   "Invokes the signal facility on a condition formed from DATUM and
  23    ARGUMENTS. If the condition is not handled, NIL is returned. If
  24    (TYPEP condition *BREAK-ON-SIGNALS*) is true, the debugger is invoked
  25    before any signalling is done."
  26   (let ((condition (coerce-to-condition datum
  27                                         arguments
  28                                         'simple-condition
  29                                         'signal))
  30         (*handler-clusters* *handler-clusters*))
  31     (let ((old-bos *break-on-signals*)
  32           (*break-on-signals* nil))
  33       (when (typep condition old-bos)
  34         (break "~A~%BREAK was entered because of *BREAK-ON-SIGNALS* (now NIL)."
  35                condition)))
  36     (loop
  37       (unless *handler-clusters* (return))
  38       (let ((cluster (pop *handler-clusters*)))
  39         (dolist (handler cluster)
  40           (when (typep condition (car handler))
  41             (funcall (cdr handler) condition)))))
  42     nil))
  43
  44 ;;; COERCE-TO-CONDITION is used in SIGNAL, ERROR, CERROR, WARN, and
  45 ;;; INVOKE-DEBUGGER for parsing the hairy argument conventions into a single
  46 ;;; argument that's directly usable by all the other routines.
  47 (defun coerce-to-condition (datum arguments default-type function-name)
  48   (cond ((typep datum 'condition)
  49          (if arguments
  50              (cerror "Ignore the additional arguments."
  51                      'simple-type-error
  52                      :datum arguments
  53                      :expected-type 'null
  54                      :format-control "You may not supply additional arguments ~
  55                                      when giving ~S to ~S."
  56                      :format-arguments (list datum function-name)))
  57          datum)
  58         ((symbolp datum) ; roughly, (SUBTYPEP DATUM 'CONDITION)
  59          (apply #'make-condition datum arguments))
  60         ((or (stringp datum) (functionp datum))
  61          (make-condition default-type
  62                          :format-control datum
  63                          :format-arguments arguments))
  64         (t
  65          (error 'simple-type-error
  66                 :datum datum
  67                 :expected-type '(or symbol string)
  68                 :format-control "bad argument to ~S: ~S"
  69                 :format-arguments (list function-name datum)))))
  70
  71 (defun error (datum &rest arguments)
  72   #!+sb-doc
  73   "Invoke the signal facility on a condition formed from datum and arguments.
  74    If the condition is not handled, the debugger is invoked."
  75   (/show0 "entering ERROR, argument list=..")
  76   (/hexstr arguments)
  77   (/show0 "printing ERROR arguments one by one..")
  78   #!+sb-show (dolist (argument arguments)
  79                (sb!impl::cold-print argument))
  80   (sb!kernel:infinite-error-protect
  81     (let ((condition (coerce-to-condition datum arguments
  82                                           'simple-error 'error))
  83           ;; FIXME: Why is *STACK-TOP-HINT* in SB-DEBUG instead of SB-DI?
  84           ;; SB-DEBUG should probably be only for true interface stuff.
  85           (sb!debug:*stack-top-hint* sb!debug:*stack-top-hint*))
  86       (unless (and (condition-function-name condition)
  87                    sb!debug:*stack-top-hint*)
  88         (multiple-value-bind (name frame) (sb!kernel:find-caller-name)
  89           (unless (condition-function-name condition)
  90             (setf (condition-function-name condition) name))
  91           (unless sb!debug:*stack-top-hint*
  92             (setf sb!debug:*stack-top-hint* frame))))
  93       (let ((sb!debug:*stack-top-hint* nil))
  94         (signal condition))
  95       (invoke-debugger condition))))
  96
  97 (defun cerror (continue-string datum &rest arguments)
  98   (sb!kernel:infinite-error-protect
  99     (with-simple-restart
 100         (continue "~A" (apply #'format nil continue-string arguments))
 101       (let ((condition (if (typep datum 'condition)
 102                            datum
 103                            (coerce-to-condition datum
 104                                                 arguments
 105                                                 'simple-error
 106                                                 'error)))
 107             (sb!debug:*stack-top-hint* sb!debug:*stack-top-hint*))
 108         (unless (and (condition-function-name condition)
 109                      sb!debug:*stack-top-hint*)
 110           (multiple-value-bind (name frame) (sb!kernel:find-caller-name)
 111             (unless (condition-function-name condition)
 112               (setf (condition-function-name condition) name))
 113             (unless sb!debug:*stack-top-hint*
 114               (setf sb!debug:*stack-top-hint* frame))))
 115         (with-condition-restarts condition (list (find-restart 'continue))
 116           (let ((sb!debug:*stack-top-hint* nil))
 117             (signal condition))
 118           (invoke-debugger condition)))))
 119   nil)
 120
 121 (defun break (&optional (datum "break") &rest arguments)
 122   #!+sb-doc
 123   "Print a message and invoke the debugger without allowing any possibility
 124    of condition handling occurring."
 125   (sb!kernel:infinite-error-protect
 126     (with-simple-restart (continue "Return from BREAK.")
 127       (let ((sb!debug:*stack-top-hint*
 128              (or sb!debug:*stack-top-hint*
 129                  (nth-value 1 (sb!kernel:find-caller-name)))))
 130         (invoke-debugger
 131          (coerce-to-condition datum arguments 'simple-condition 'break)))))
 132   nil)
 133
 134 (defun warn (datum &rest arguments)
 135   #!+sb-doc
 136   "Warn about a situation by signalling a condition formed by DATUM and
 137    ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
 138    exists that causes WARN to immediately return NIL."
 139   (/noshow0 "entering WARN")
 140   ;; KLUDGE: The current cold load initialization logic causes several calls
 141   ;; to WARN, so we need to be able to handle them without dying. (And calling
 142   ;; FORMAT or even PRINC in cold load is a good way to die.) Of course, the
 143   ;; ideal would be to clean up cold load so that it doesn't call WARN..
 144   ;; -- WHN 19991009
 145   (if (not *cold-init-complete-p*)
 146       (progn
 147         (/show0 "ignoring WARN in cold init, arguments=..")
 148         #!+sb-show (dolist (argument arguments)
 149                      (sb!impl::cold-print argument)))
 150       (sb!kernel:infinite-error-protect
 151        (let ((condition (coerce-to-condition datum arguments
 152                                              'simple-warning 'warn)))
 153          (enforce-type condition warning)
 154          (restart-case (signal condition)
 155            (muffle-warning ()
 156              :report "Skip warning."
 157              (return-from warn nil)))
 158          (let ((badness (etypecase condition
 159                           (style-warning 'style-warning)
 160                           (warning 'warning))))
 161            (format *error-output*
 162                    "~&~@<~S: ~3i~:_~A~:>~%"
 163                    badness
 164                    condition)))))
 165   nil)